elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.1
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.1"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     (file elpher-get-file-page nil "~" elpher-gemini)
  98     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
  99     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 100     ((about history) elpher-get-history-page nil "E" elpher-index)
 101     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 102   "Association list from types to getters, renderers, margin codes and index faces.")
 103
 104
 105 ;;; Declarations to avoid compiler warnings.
 106 ;;
 107
 108 (eval-when-compile
 109   (declare-function ansi-color-filter-apply "ansi-color")
 110   (declare-function ansi-color-apply "ansi-color")
 111   (declare-function bookmark-store "bookmark")
 112   (declare-function org-link-store-props "ol")
 113   (declare-function org-link-set-parameters "ol")
 114   (defvar ansi-color-context)
 115   (defvar xterm-color--current-fg)
 116   (defvar xterm-color--current-bg)
 117   (defvar bookmark-make-record-function)
 118   (defvar mu4e~view-beginning-of-url-regexp)
 119   (defvar eww-use-browse-url)
 120   (defvar thing-at-point-uri-schemes))
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher and gemini client."
 128   :group 'applications)
 129
 130 ;; General appearance and customizations
 131
 132 (defcustom elpher-open-urls-with-eww nil
 133   "If non-nil, open URL selectors using eww.
 134 Otherwise, use the system browser via the `browse-url' function."
 135   :type '(boolean))
 136
 137 (defcustom elpher-use-header t
 138   "If non-nil, display current page information in buffer header."
 139   :type '(boolean))
 140
 141 (defcustom elpher-auto-disengage-TLS nil
 142   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 143 While enabling this may seem convenient, it is also potentially
 144 dangerous as it allows switching from an encrypted channel back to
 145 plain text without user input."
 146   :type '(boolean))
 147
 148 (defcustom elpher-connection-timeout 5
 149   "Specifies the number of seconds to wait for a network connection to time out."
 150   :type '(integer))
 151
 152 (defcustom elpher-filter-ansi-from-text nil
 153   "If non-nil, filter ANSI escape sequences from text.
 154 The default behaviour is to use the ansi-color package (or xterm-color if it is
 155 available) to interpret these sequences."
 156   :type '(boolean))
 157
 158 (defcustom elpher-certificate-directory
 159   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 160   "Specify the name of the directory where client certificates will be stored.
 161 These certificates may be used for establishing authenticated TLS connections."
 162   :type '(directory))
 163
 164 (defcustom elpher-openssl-command "openssl"
 165   "The command used to launch openssl when generating TLS client certificates."
 166   :type '(file))
 167
 168 (defcustom elpher-default-url-type "gopher"
 169   "Default URL type (i.e. scheme) to assume if not explicitly given."
 170   :type '(choice (const "gopher")
 171                  (const "gemini")))
 172
 173 (defcustom elpher-gemini-TLS-cert-checks nil
 174   "If non-nil, verify gemini server TLS certs using the default security level.
 175 Otherwise, certificate verification is disabled.
 176
 177 This defaults to off because it is standard practice for Gemini servers
 178 to use self-signed certificates, meaning that most servers provide what
 179 EMACS considers to be an invalid certificate."
 180   :type '(boolean))
 181
 182 (defcustom elpher-gemini-max-fill-width 80
 183   "Specify the maximum default width (in columns) of text/gemini documents.
 184 The actual width used is the minimum of this value and the window width at
 185 the time when the text is rendered."
 186   :type '(integer))
 187
 188 (defcustom elpher-gemini-link-string "→ "
 189   "Specify the string used to indicate links when rendering gemini maps.
 190 May be empty."
 191   :type '(string))
 192
 193 (defcustom elpher-gemini-bullet-string "•"
 194   "Specify the string used for bullets when rendering gemini maps."
 195   :type '(string))
 196
 197 (defcustom elpher-ipv4-always nil
 198   "If non-nil, elpher will always use IPv4 to establish network connections.
 199 This can be useful when browsing from a computer that supports IPv6, because
 200 some servers which do not support IPv6 can take a long time to time-out."
 201   :type '(boolean))
 202
 203 (defcustom elpher-socks-always nil
 204   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 205 Otherwise, the SOCKS proxy is only used for connections to onion services."
 206   :type '(boolean))
 207
 208 (defcustom elpher-use-emacs-bookmark-menu nil
 209   "If non-nil, elpher will only use the native Emacs bookmark menu.
 210 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 211 page within which all of the standard elpher keybindings are active."
 212   :type '(boolean))
 213
 214 (defcustom elpher-start-page-url "about:welcome"
 215   "Specify the page displayed initially by elpher.
 216 The default welcome screen is \"about:welcome\", while the bookmarks list
 217 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 218
 219 Beware that using \"about:bookmarks\" as a start page in combination with
 220 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 221 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 222 the start page."
 223   :type '(string))
 224
 225 (defcustom elpher-gemini-hide-preformatted nil
 226   "Cause elpher to hide preformatted gemini text by default.
 227 When this option is enabled, preformatted text in text/gemini documents
 228 is replaced with a button which can be used to toggle its display.
 229
 230 This is intended to improve accessibility, as preformatted text often
 231 includes art which can be difficult for screen readers to interpret
 232 meaningfully."
 233   :type '(boolean))
 234
 235 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 236   "Margin symbol used to distinguish the preformatted text toggle."
 237   :type '(string))
 238
 239 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 240   "Label of button used to toggle formatted text."
 241   :type '(string))
 242
 243 ;; Face customizations
 244
 245 (defgroup elpher-faces nil
 246   "Elpher face customizations."
 247   :group 'elpher)
 248
 249 (defface elpher-index
 250   '((t :inherit font-lock-keyword-face))
 251   "Face used for directory type directory records.")
 252
 253 (defface elpher-text
 254   '((t :inherit bold))
 255   "Face used for text type directory records.")
 256
 257 (defface elpher-info
 258   '((t :inherit default))
 259   "Face used for info type directory records.")
 260
 261 (defface elpher-image
 262   '((t :inherit font-lock-string-face))
 263   "Face used for image type directory records.")
 264
 265 (defface elpher-search
 266   '((t :inherit warning))
 267   "Face used for search type directory records.")
 268
 269 (defface elpher-html
 270   '((t :inherit font-lock-comment-face))
 271   "Face used for html type directory records.")
 272
 273 (defface elpher-gemini
 274   '((t :inherit font-lock-constant-face))
 275   "Face used for Gemini type directory records.")
 276
 277 (defface elpher-other-url
 278   '((t :inherit font-lock-comment-face))
 279   "Face used for other URL type links records.")
 280
 281 (defface elpher-telnet
 282   '((t :inherit font-lock-function-name-face))
 283   "Face used for telnet type directory records.")
 284
 285 (defface elpher-binary
 286   '((t :inherit font-lock-doc-face))
 287   "Face used for binary type directory records.")
 288
 289 (defface elpher-unknown
 290   '((t :inherit error))
 291   "Face used for directory records with unknown/unsupported types.")
 292
 293 (defface elpher-margin-key
 294   '((t :inherit bold))
 295   "Face used for directory margin key.")
 296
 297 (defface elpher-margin-brackets
 298   '((t :inherit shadow))
 299   "Face used for brackets around directory margin key.")
 300
 301 (defface elpher-gemini-heading1
 302   '((t :inherit bold :height 1.8))
 303   "Face used for gemini heading level 1.")
 304
 305 (defface elpher-gemini-heading2
 306   '((t :inherit bold :height 1.5))
 307   "Face used for gemini heading level 2.")
 308
 309 (defface elpher-gemini-heading3
 310   '((t :inherit bold :height 1.2))
 311   "Face used for gemini heading level 3.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 (defface elpher-gemini-preformatted
 318   '((t :inherit elpher-text))
 319   "Face used for gemini preformatted text.")
 320
 321 (defface elpher-gemini-preformatted-toggle
 322   '((t :inherit button))
 323   "Face used for buttons used to toggle display of preformatted text.")
 324
 325 ;;; Model
 326 ;;
 327
 328 ;; Address
 329
 330 ;; An elpher "address" object is either a url object or a symbol.
 331 ;; Addresses with the "about" type, corresponding to pages generated
 332 ;; dynamically for and by elpher.  All others represent pages which
 333 ;; rely on content retrieved over the network.
 334
 335 (defun elpher-address-from-url (url-string &optional default-scheme)
 336   "Create a ADDRESS object corresponding to the given URL-STRING.
 337 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 338 is not explicitly given."
 339   (let ((data (match-data))) ; Prevent parsing clobbering match data
 340     (unwind-protect
 341         (let ((url (url-generic-parse-url url-string)))
 342           (unless (and (not (url-fullness url)) (url-type url))
 343             (unless (url-type url)
 344               (setf (url-type url) default-scheme))
 345             (unless (url-host url)
 346               (let ((p (split-string (url-filename url) "/" nil nil)))
 347                 (setf (url-host url) (car p))
 348                 (setf (url-filename url)
 349                       (if (cdr p)
 350                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 351                         ""))))
 352             (when (not (string-empty-p (url-host url)))
 353               (setf (url-fullness url) t)
 354               (setf (url-host url) (puny-encode-domain (url-host url))))
 355             (when (or (equal "gopher" (url-type url))
 356                       (equal "gophers" (url-type url)))
 357               ;; Gopher defaults
 358               (when (or (equal (url-filename url) "")
 359                         (equal (url-filename url) "/"))
 360                 (setf (url-filename url) "/1")))
 361             (when (equal "gemini" (url-type url))
 362               ;; Gemini defaults
 363               (if (equal (url-filename url) "")
 364                   (setf (url-filename url) "/"))))
 365           (elpher-remove-redundant-ports url))
 366       (set-match-data data))))
 367
 368 (defun elpher-remove-redundant-ports (address)
 369   "Remove redundant port specifiers from ADDRESS.
 370 Here 'redundant' means that the specified port matches the default
 371 for that protocol, eg 70 for gopher."
 372   (if (and (not (elpher-address-about-p address))
 373            (eq (url-portspec address) ; (url-port) is too slow!
 374                (pcase (url-type address)
 375                  ("gemini" 1965)
 376                  ((or "gopher" "gophers") 70)
 377                  ("finger" 79)
 378                  (_ -1))))
 379       (setf (url-portspec address) nil))
 380   address)
 381
 382 (defun elpher-make-gopher-address (type selector host port &optional tls)
 383   "Create an ADDRESS object using gopher directory record attributes.
 384 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 385 If the optional attribute TLS is non-nil, the address will be marked as
 386 requiring gopher-over-TLS."
 387   (cond
 388    ((equal type ?i) nil)
 389    ((and (equal type ?h)
 390          (string-prefix-p "URL:" selector))
 391     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 392    ((equal type ?8)
 393     (elpher-address-from-url
 394      (concat "telnet"
 395              "://" host
 396              ":" (number-to-string port))))
 397    (t
 398     (elpher-address-from-url
 399      (concat "gopher" (if tls "s" "")
 400              "://" host
 401              ":" (number-to-string port)
 402              "/" (string type)
 403              selector)))))
 404
 405 (defun elpher-make-about-address (type)
 406   "Create an ADDRESS object corresponding to the given about address TYPE."
 407   (elpher-address-from-url (concat "about:" (symbol-name type))))
 408
 409 (defun elpher-address-to-url (address)
 410   "Get string representation of ADDRESS."
 411   (url-encode-url (url-recreate-url address)))
 412
 413 (defun elpher-address-type (address)
 414   "Retrieve type of ADDRESS object.
 415 This is used to determine how to retrieve and render the document the
 416 address refers to, via the table `elpher-type-map'."
 417   (pcase (url-type address)
 418     ("about"
 419      (list 'about (intern (url-filename address))))
 420     ((or "gopher" "gophers")
 421      (list 'gopher
 422            (if (member (url-filename address) '("" "/"))
 423                ?1
 424              (string-to-char (substring (url-filename address) 1)))))
 425     ("gemini" 'gemini)
 426     ("telnet" 'telnet)
 427     ("finger" 'finger)
 428     ("file" 'file)
 429     (_ 'other-url)))
 430
 431 (defun elpher-address-about-p (address)
 432   "Return non-nil if ADDRESS is an about address."
 433   (pcase (elpher-address-type address) (`(about ,_) t)))
 434
 435 (defun elpher-address-gopher-p (address)
 436   "Return non-nil if ADDRESS object is a gopher address."
 437   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 438
 439 (defun elpher-address-protocol (address)
 440   "Retrieve the transport protocol for ADDRESS."
 441   (url-type address))
 442
 443 (defun elpher-address-filename (address)
 444   "Retrieve the filename component of ADDRESS.
 445 For gopher addresses this is a combination of the selector type and selector."
 446   (url-unhex-string (url-filename address)))
 447
 448 (defun elpher-address-host (address)
 449   "Retrieve host from ADDRESS object."
 450   (let ((host-pre (url-host address)))
 451     ;; The following strips out square brackets which sometimes enclose IPv6
 452     ;; addresses.  Doing this here rather than at the parsing stage may seem
 453     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 454     ;; and reconstruction.  It's also more efficient, as this method is not
 455     ;; called during page rendering.
 456     (if (and (> (length host-pre) 2)
 457              (eq (elt host-pre 0) ?\[)
 458              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 459         (substring host-pre 1 (- (length host-pre) 1))
 460       host-pre)))
 461
 462 (defun elpher-address-user (address)
 463   "Retrieve user from ADDRESS object."
 464   (url-user address))
 465
 466 (defun elpher-address-port (address)
 467   "Retrieve port from ADDRESS object.
 468 If no address is defined, returns 0.  (This is for compatibility with
 469 the URL library.)"
 470   (let ((port (url-portspec address))) ; (url-port) is too slow!
 471     (if port port 0)))
 472
 473 (defun elpher-gopher-address-selector (address)
 474   "Retrieve gopher selector from ADDRESS object."
 475   (if (member (url-filename address) '("" "/"))
 476       ""
 477     (url-unhex-string (substring (url-filename address) 2))))
 478
 479
 480 ;; Cache
 481
 482 (defvar elpher-content-cache (make-hash-table :test 'equal))
 483 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 484
 485 (defun elpher-get-cached-content (address)
 486   "Retrieve the cached content for ADDRESS, or nil if none exists."
 487   (gethash address elpher-content-cache))
 488
 489 (defun elpher-cache-content (address content)
 490   "Set the content cache for ADDRESS to CONTENT."
 491   (puthash address content elpher-content-cache))
 492
 493 (defun elpher-get-cached-pos (address)
 494   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 495   (gethash address elpher-pos-cache))
 496
 497 (defun elpher-cache-pos (address pos)
 498   "Set the cursor position cache for ADDRESS to POS."
 499   (puthash address pos elpher-pos-cache))
 500
 501
 502 ;; Page
 503
 504 (defun elpher-make-page (display-string address)
 505   "Create a page with DISPLAY-STRING and ADDRESS."
 506   (list display-string address))
 507
 508 (defun elpher-make-start-page ()
 509   "Create the start page."
 510   (elpher-make-page "Start Page"
 511                     (elpher-address-from-url elpher-start-page-url)))
 512
 513 (defun elpher-page-display-string (page)
 514   "Retrieve the display string corresponding to PAGE."
 515   (elt page 0))
 516
 517 (defun elpher-page-address (page)
 518   "Retrieve the address corresponding to PAGE."
 519   (elt page 1))
 520
 521 (defun elpher-page-set-address (page new-address)
 522   "Set the address corresponding to PAGE to NEW-ADDRESS."
 523   (setcar (cdr page) new-address))
 524
 525 (defun elpher-page-from-url (url &optional default-scheme)
 526   "Create a page with address and display string defined by URL.
 527 The URL is unhexed prior to its use as a display string to improve
 528 readability.
 529
 530 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 531 in the instance that URL itself doesn't specify one."
 532   (let ((address (elpher-address-from-url url default-scheme)))
 533     (elpher-make-page (elpher-address-to-iri address) address)))
 534
 535 (defun elpher-address-to-iri (address)
 536   "Return an IRI for ADDRESS.
 537 Decode percent-escapes and handle punycode in the domain name.
 538 Drop the password, if any."
 539   (let ((data (match-data)) ; Prevent parsing clobbering match data
 540         (host (url-host address))
 541         (pass (url-password address)))
 542     (unwind-protect
 543         (let* ((host (url-host address))
 544                (pass (url-password address)))
 545           (when host
 546             (setf (url-host address) (puny-decode-domain host)))
 547           (when pass                             ; RFC 3986 says we should not render
 548             (setf (url-password address) nil)) ; the password as clear text
 549           (elpher-decode (url-unhex-string (url-recreate-url address))))
 550       (setf (url-host address) host)
 551       (setf (url-password address) pass)
 552       (set-match-data data))))
 553
 554 (defvar elpher-current-page nil
 555   "The current page for this Elpher buffer.")
 556
 557 (defvar elpher-history nil
 558   "The local history stack for this Elpher buffer.
 559 This variable is used by `elpher-back' and
 560 `elpher-show-history'.")
 561
 562 (defvar elpher-visited-pages nil
 563   "The global history for all Elpher buffers.
 564 This variable is used by `elpher-show-visited-pages'.")
 565
 566 (defun elpher-visit-page (page &optional renderer no-history)
 567   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 568 Additionally, push PAGE onto the history stack and the list of
 569 previously-visited pages,unless NO-HISTORY is non-nil."
 570   (elpher-save-pos)
 571   (elpher-process-cleanup)
 572   (unless no-history
 573     (unless (or (not elpher-current-page)
 574                  (equal (elpher-page-address elpher-current-page)
 575                         (elpher-page-address page)))
 576       (push elpher-current-page elpher-history)
 577       (unless (or (elpher-address-about-p (elpher-page-address page))
 578                   (and elpher-visited-pages
 579                        (equal page (car elpher-visited-pages))))
 580         (push page elpher-visited-pages))))
 581   (setq-local elpher-current-page page)
 582   (let* ((address (elpher-page-address page))
 583          (type (elpher-address-type address))
 584          (type-record (cdr (assoc type elpher-type-map))))
 585     (if type-record
 586         (funcall (car type-record)
 587                  (if renderer
 588                      renderer
 589                    (cadr type-record)))
 590       (elpher-visit-previous-page)
 591       (pcase type
 592         (`(gopher ,type-char)
 593          (error "Unsupported gopher selector type '%c' for '%s'"
 594                 type-char (elpher-address-to-url address)))
 595         (other
 596          (error "Unsupported address type '%S' for '%s'"
 597                 other (elpher-address-to-url address)))))))
 598
 599 (defun elpher-visit-previous-page ()
 600   "Visit the previous page in the history."
 601   (if elpher-history
 602       (elpher-visit-page (pop elpher-history) nil t)
 603     (error "No previous page")))
 604
 605 (defun elpher-reload-current-page ()
 606   "Reload the current page, discarding any existing cached content."
 607   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 608   (elpher-visit-page elpher-current-page))
 609
 610 (defun elpher-save-pos ()
 611   "Save the current position of point to the current page."
 612   (when elpher-current-page
 613     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 614
 615 (defun elpher-restore-pos ()
 616   "Restore the position of point to that cached in the current page."
 617   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 618     (if pos
 619         (goto-char pos)
 620       (goto-char (point-min)))))
 621
 622 (defun elpher-get-default-url-scheme ()
 623   "Suggest default URL scheme for visiting addresses based on the current page."
 624   (if elpher-current-page
 625       (let* ((address (elpher-page-address elpher-current-page))
 626              (current-type (elpher-address-type address)))
 627         (pcase current-type
 628           ((or (and 'file (guard (not elpher-history)))
 629                `(about ,_))
 630            elpher-default-url-type)
 631           (_
 632            (url-type address))))
 633       elpher-default-url-type))
 634
 635
 636 ;;; Buffer preparation
 637 ;;
 638
 639 (defvar elpher-buffer-name "*elpher*"
 640   "The default name of the Elpher buffer.")
 641
 642 (defun elpher-update-header ()
 643   "If `elpher-use-header' is true, display current page info in window header."
 644   (if (and elpher-use-header elpher-current-page)
 645       (let* ((display-string (elpher-page-display-string elpher-current-page))
 646              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 647              (address (elpher-page-address elpher-current-page))
 648              (tls-string (if (and (not (elpher-address-about-p address))
 649                                   (member (elpher-address-protocol address)
 650                                           '("gophers" "gemini")))
 651                              " [TLS encryption]"
 652                            ""))
 653              (header (concat sanitized-display-string
 654                              (propertize tls-string 'face 'bold))))
 655         (setq header-line-format header))))
 656
 657 (defmacro elpher-with-clean-buffer (&rest args)
 658   "Evaluate ARGS with a clean *elpher* buffer as current."
 659   (declare (debug (body))) ;; Allow edebug to step through body
 660   `(with-current-buffer elpher-buffer-name
 661      (unless (eq major-mode 'elpher-mode)
 662        ;; avoid resetting buffer-local variables
 663        (elpher-mode))
 664      (let ((inhibit-read-only t)
 665            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 666        (setq-local xterm-color--current-fg nil)
 667        (setq-local xterm-color--current-bg nil)
 668        (setq-local network-security-level
 669                    (default-value 'network-security-level))
 670        (erase-buffer)
 671        (elpher-update-header)
 672        ,@args)))
 673
 674 (defun elpher-buffer-message (string &optional line)
 675   "Replace first line in elpher buffer with STRING.
 676 If LINE is non-nil, replace that line instead."
 677   (with-current-buffer elpher-buffer-name
 678     (let ((inhibit-read-only t))
 679       (goto-char (point-min))
 680       (if line
 681           (forward-line line))
 682       (let ((data (match-data)))
 683         (unwind-protect
 684             (progn
 685               (re-search-forward "^.*$")
 686               (replace-match string))
 687           (set-match-data data))))))
 688
 689
 690 ;;; Text Processing
 691 ;;
 692
 693 (defvar elpher-user-coding-system nil
 694   "User-specified coding system to use for decoding text responses.")
 695
 696 (defun elpher-decode (string)
 697   "Decode STRING using autodetected or user-specified coding system."
 698   (decode-coding-string string
 699                         (if elpher-user-coding-system
 700                             elpher-user-coding-system
 701                           (detect-coding-string string t))))
 702
 703 (defun elpher-preprocess-text-response (string)
 704   "Preprocess text selector response contained in STRING.
 705 This involes decoding the character representation, and clearing
 706 away CRs and any terminating period."
 707   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 708                                            (replace-regexp-in-string "\r" "" string))))
 709
 710 ;;; Buttonify urls
 711
 712 (defconst elpher-url-regex
 713   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 714   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 715
 716 (defun elpher-buttonify-urls (string)
 717   "Turn substrings which look like urls in STRING into clickable buttons."
 718   (with-temp-buffer
 719     (insert string)
 720     (goto-char (point-min))
 721     (while (re-search-forward elpher-url-regex nil t)
 722       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 723         (make-text-button (match-beginning 0)
 724                           (match-end 0)
 725                           'elpher-page  page
 726                           'action #'elpher-click-link
 727                           'follow-link t
 728                           'help-echo #'elpher--page-button-help
 729                           'face 'button)))
 730     (buffer-string)))
 731
 732 ;;; ANSI colors or XTerm colors (application and filtering)
 733
 734 (or (require 'xterm-color nil t)
 735     (require 'ansi-color))
 736
 737 (defalias 'elpher-color-filter-apply
 738   (if (fboundp 'xterm-color-filter)
 739       (lambda (s)
 740         (let ((_xterm-color-render nil))
 741           (xterm-color-filter s)))
 742     #'ansi-color-filter-apply)
 743   "A function to filter out ANSI escape sequences.")
 744
 745 (defalias 'elpher-color-apply
 746   (if (fboundp 'xterm-color-filter)
 747       #'xterm-color-filter
 748     #'ansi-color-apply)
 749   "A function to apply ANSI escape sequences.")
 750
 751 (defun elpher-text-has-ansi-escapes-p (string)
 752   "Return non-nil if STRING includes an ANSI escape code."
 753   (save-match-data
 754     (string-match "\x1b\\[" string)))
 755
 756 ;;; Processing text for display
 757
 758 (defun elpher-process-text-for-display (string)
 759   "Perform any desired processing of STRING prior to display as text.
 760 Currently includes buttonifying URLs and processing ANSI escape codes."
 761   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 762                              (if elpher-filter-ansi-from-text
 763                                  (elpher-color-filter-apply string)
 764                                (elpher-color-apply string))
 765                            string)))
 766
 767
 768 ;;; Network error reporting
 769 ;;
 770
 771 (defun elpher-network-error (address error)
 772   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 773 ERROR can be either an error object or a string."
 774   (elpher-with-clean-buffer
 775    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 776            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 777            (if (stringp error) error (error-message-string error)) "\n"
 778            (propertize "\n----------------\n\n" 'face 'error)
 779            "Press 'u' to return to the previous page.")))
 780
 781
 782 ;;; General network communication
 783 ;;
 784
 785 (defvar elpher-network-timer nil
 786   "Timer used for network connections.")
 787
 788 (defvar elpher-use-tls nil
 789   "If non-nil, use TLS to communicate with gopher servers.")
 790
 791 (defvar elpher-client-certificate nil
 792   "If non-nil, contains client certificate details to use for TLS connections.")
 793
 794 (defun elpher-process-cleanup ()
 795   "Immediately shut down any extant elpher process and timers."
 796   (let ((p (get-process "elpher-process")))
 797     (if p (delete-process p)))
 798   (if (timerp elpher-network-timer)
 799       (cancel-timer elpher-network-timer)))
 800
 801 (defun elpher-make-network-timer (thunk)
 802   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 803 This is just a wraper around `run-at-time' which additionally sets the
 804 buffer-local variable `elpher-network-timer' to allow
 805 `elpher-process-cleanup' to also clear the timer."
 806   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 807     (setq-local elpher-network-timer timer)
 808     timer))
 809
 810 (defun elpher-get-host-response (address default-port query-string response-processor
 811                                          &optional use-tls force-ipv4)
 812   "Generic function for retrieving data from ADDRESS.
 813
 814 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 815 QUERY-STRING is a string sent to the host specified by ADDRESS to
 816 illicet a response.  This response is passed as an argument to the
 817 function RESPONSE-PROCESSOR.
 818
 819 If non-nil, USE-TLS specifies that the connection is to be made over
 820 TLS.  If set to gemini, the certificate verification will be disabled
 821 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 822
 823 If non-nil, FORCE-IPV4 causes the network connection to be made over
 824 ipv4 only.  (The default behaviour when this is not set depends on
 825 the host operating system and the local network capabilities.)"
 826   (if (and use-tls (not (gnutls-available-p)))
 827       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 828     (unless (< (elpher-address-port address) 65536)
 829       (error "Cannot establish network connection: port number > 65536"))
 830     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 831       (setq-local network-security-level 'low)
 832       (setq-local gnutls-verify-error nil))
 833     (condition-case nil
 834         (let* ((kill-buffer-query-functions nil)
 835                (port (elpher-address-port address))
 836                (host (elpher-address-host address))
 837                (service (if (> port 0) port default-port))
 838                (response-string-parts nil)
 839                (bytes-received 0)
 840                (hkbytes-received 0)
 841                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 842                (gnutls-params (list :type 'gnutls-x509pki
 843                                     :hostname host
 844                                     :keylist
 845                                     (elpher-get-current-keylist address)))
 846                (timer (elpher-make-network-timer
 847                                    (lambda ()
 848                                      (elpher-process-cleanup)
 849                                      (cond
 850                                         ; Try again with IPv4
 851                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 852                                        (message "Connection timed out.  Retrying with IPv4.")
 853                                        (elpher-get-host-response address default-port
 854                                                                  query-string
 855                                                                  response-processor
 856                                                                  use-tls t))
 857                                       ((and use-tls
 858                                             (not (eq use-tls 'gemini))
 859                                             (or elpher-auto-disengage-TLS
 860                                                 (y-or-n-p
 861                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 862                                        (setq elpher-use-tls nil)
 863                                        (elpher-get-host-response address default-port
 864                                                                  query-string
 865                                                                  response-processor
 866                                                                  nil force-ipv4))
 867                                       (t
 868                                        (elpher-network-error address "Connection time-out."))))))
 869                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 870                        (make-network-process :name "elpher-process"
 871                                              :host host
 872                                              :family (and (or force-ipv4
 873                                                               elpher-ipv4-always)
 874                                                           'ipv4)
 875                                              :service service
 876                                              :buffer nil
 877                                              :nowait t
 878                                              :tls-parameters
 879                                              (and use-tls
 880                                                   (cons 'gnutls-x509pki
 881                                                         (apply #'gnutls-boot-parameters
 882                                                                gnutls-params)))))))
 883           (setq elpher-network-timer timer)
 884           (set-process-coding-system proc 'binary 'binary)
 885           (set-process-query-on-exit-flag proc nil)
 886           (elpher-buffer-message (concat "Connecting to " host "..."
 887                                          " (press 'u' to abort)"))
 888           (set-process-filter proc
 889                               (lambda (_proc string)
 890                                 (when timer
 891                                   (cancel-timer timer)
 892                                   (setq timer nil))
 893                                 (setq bytes-received (+ bytes-received (length string)))
 894                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 895                                   (when (> new-hkbytes-received hkbytes-received)
 896                                     (setq hkbytes-received new-hkbytes-received)
 897                                     (elpher-buffer-message
 898                                      (concat "("
 899                                              (number-to-string (/ hkbytes-received 10.0))
 900                                              " MB read)")
 901                                      1)))
 902                                 (setq response-string-parts
 903                                       (cons string response-string-parts))))
 904           (set-process-sentinel proc
 905                                 (lambda (proc event)
 906                                   (when timer
 907                                     (cancel-timer timer))
 908                                   (condition-case the-error
 909                                       (cond
 910                                        ((string-prefix-p "open" event)    ; request URL
 911                                         (elpher-buffer-message
 912                                          (concat "Connected to " host ". Receiving data..."
 913                                                  " (press 'u' to abort)"))
 914                                         (let ((inhibit-eol-conversion t))
 915                                           (process-send-string proc query-string)))
 916                                        ((string-prefix-p "deleted" event)) ; do nothing
 917                                        ((and (not response-string-parts)
 918                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 919                                         ; Try again with IPv4
 920                                         (message "Connection failed. Retrying with IPv4.")
 921                                         (elpher-get-host-response address default-port
 922                                                                   query-string
 923                                                                   response-processor
 924                                                                   use-tls t))
 925                                        (response-string-parts
 926                                         (elpher-with-clean-buffer
 927                                          (insert "Data received.  Rendering..."))
 928                                         (funcall response-processor
 929                                                  (apply #'concat (reverse response-string-parts)))
 930                                         (elpher-restore-pos))
 931                                        (t
 932                                         (error "No response from server")))
 933                                     (error
 934                                      (elpher-network-error address the-error)))))
 935           (when socks
 936             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 937             (funcall (process-sentinel proc) proc "open\n")))
 938       (error
 939        (elpher-process-cleanup)
 940        (error "Error initiating connection to server")))))
 941
 942
 943 ;;; Client-side TLS Certificate Management
 944 ;;
 945
 946 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 947   "Generate a key and a self-signed client TLS certificate using openssl.
 948
 949 The Common Name field of the certificate is set to COMMON-NAME.  The
 950 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 951 the key and certificate files to write.
 952
 953 If TEMPORARY is non-nil, the certificate will be given an exporation
 954 period of one day, and the key and certificate files will be deleted
 955 when the certificate is no longer needed for the current session.
 956
 957 Otherwise, the certificate will be given a 100 year expiration period
 958 and the files will not be deleted.
 959
 960 The function returns a list containing the current host name, the
 961 temporary flag, and the key and cert file names in the form required
 962 by `gnutls-boot-parameters`."
 963   (let ((exp-key-file (expand-file-name key-file))
 964         (exp-cert-file (expand-file-name cert-file)))
 965     (condition-case nil
 966         (progn
 967           (call-process elpher-openssl-command nil nil nil
 968                         "req" "-x509" "-newkey" "rsa:2048"
 969                         "-days" (if temporary "1" "36500")
 970                         "-nodes"
 971                         "-subj" (concat "/CN=" common-name)
 972                         "-keyout" exp-key-file
 973                         "-out" exp-cert-file)
 974           (list (elpher-address-host (elpher-page-address elpher-current-page))
 975                 temporary exp-key-file exp-cert-file))
 976       (error
 977        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 978        (error "Program 'openssl', required for certificate generation, not found")))))
 979
 980 (defun elpher-generate-throwaway-certificate ()
 981   "Generate and return details of a throwaway certificate.
 982 The key and certificate files will be deleted when they are no
 983 longer needed for this session."
 984   (let* ((file-base (make-temp-name "elpher"))
 985          (key-file (concat temporary-file-directory file-base ".key"))
 986          (cert-file (concat temporary-file-directory file-base ".crt")))
 987     (elpher-generate-certificate file-base key-file cert-file t)))
 988
 989 (defun elpher-generate-persistent-certificate (file-base common-name)
 990   "Generate and return details of a persistent certificate.
 991 The argument FILE-BASE is used as the base for the key and certificate
 992 files, while COMMON-NAME specifies the common name field of the
 993 certificate.
 994
 995 The key and certificate files are written to in `elpher-certificate-directory'."
 996   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 997          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 998     (elpher-generate-certificate common-name key-file cert-file)))
 999
1000 (defun elpher-get-existing-certificate (file-base)
1001   "Return a certificate object corresponding to an existing certificate.
1002 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1003 the directory `elpher-certificate-directory'."
1004   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1005          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1006     (list (elpher-address-host (elpher-page-address elpher-current-page))
1007           nil
1008           (expand-file-name key-file)
1009           (expand-file-name cert-file))))
1010
1011 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1012   "Install a key+certificate file pair in `elpher-certificate-directory'.
1013 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1014 certificate files to install.  The argument FILE-BASE is used as the
1015 base for the installed key and certificate files."
1016   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1017          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1018     (if (or (file-exists-p key-file)
1019             (file-exists-p cert-file))
1020         (error "A certificate with base name %s is already installed" file-base))
1021     (copy-file key-file-src key-file)
1022     (copy-file cert-file-src cert-file)
1023     (list (elpher-address-host (elpher-page-address elpher-current-page))
1024           nil
1025           (expand-file-name key-file)
1026           (expand-file-name cert-file))))
1027
1028 (defun elpher-list-existing-certificates ()
1029   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1030   (unless (file-directory-p elpher-certificate-directory)
1031     (make-directory elpher-certificate-directory))
1032   (mapcar
1033    (lambda (file)
1034      (file-name-sans-extension file))
1035    (directory-files elpher-certificate-directory nil "\\.key$")))
1036
1037 (defun elpher-forget-current-certificate ()
1038   "Causes any current certificate to be forgotten.)
1039 In the case of throwaway certificates, the key and certificate files
1040 are also deleted."
1041   (interactive)
1042   (when elpher-client-certificate
1043     (unless (and (called-interactively-p 'any)
1044                  (not (y-or-n-p (concat "Really forget client certificate? "
1045                                         "(Throwaway certificates will be deleted.)"))))
1046       (when (cadr elpher-client-certificate)
1047         (delete-file (elt elpher-client-certificate 2))
1048         (delete-file (elt elpher-client-certificate 3)))
1049       (setq elpher-client-certificate nil)
1050       (if (called-interactively-p 'any)
1051           (message "Client certificate forgotten.")))))
1052
1053 (defun elpher-get-current-keylist (address)
1054   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1055
1056 This is obtained from the client certificate described by
1057 `elpher-current-certificate', if one is available and the host for
1058 that certificate matches the host in ADDRESS.
1059
1060 If `elpher-current-certificate' is non-nil, and its host name doesn't
1061 match that of ADDRESS, the certificate is forgotten."
1062   (if elpher-client-certificate
1063       (if (string= (car elpher-client-certificate)
1064                    (elpher-address-host address))
1065           (list (cddr elpher-client-certificate))
1066         (elpher-forget-current-certificate)
1067         (message "Disabling client certificate for new host")
1068         nil)
1069     nil))
1070
1071
1072 ;;; Gopher selector retrieval
1073 ;;
1074
1075 (defun elpher-get-gopher-response (address renderer)
1076   "Get response string from gopher server at ADDRESS and render using RENDERER."
1077   (elpher-get-host-response address 70
1078                             (concat (elpher-gopher-address-selector address) "\r\n")
1079                             renderer
1080                             (or (string= (elpher-address-protocol address) "gophers")
1081                                 elpher-use-tls)))
1082
1083 (defun elpher-get-gopher-page (renderer)
1084   "Getter function for gopher pages.
1085 The RENDERER procedure is used to display the contents of the page
1086 once they are retrieved from the gopher server."
1087   (let* ((address (elpher-page-address elpher-current-page))
1088          (content (elpher-get-cached-content address)))
1089     (if (and content (funcall renderer nil))
1090         (elpher-with-clean-buffer
1091          (insert content)
1092          (elpher-restore-pos))
1093       (elpher-with-clean-buffer
1094        (insert "LOADING... (use 'u' to cancel)\n"))
1095       (condition-case the-error
1096           (elpher-get-gopher-response address renderer)
1097         (error
1098          (elpher-network-error address the-error))))))
1099
1100 ;; Index rendering
1101
1102 (defun elpher-insert-margin (&optional type-name)
1103   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1104   (if type-name
1105       (progn
1106         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1107                         (concat
1108                          (propertize "[" 'face 'elpher-margin-brackets)
1109                          (propertize type-name 'face 'elpher-margin-key)
1110                          (propertize "]" 'face 'elpher-margin-brackets))))
1111         (insert " "))
1112     (insert (make-string elpher-margin-width ?\s))))
1113
1114 (defun elpher--page-button-help (_window buffer pos)
1115   "Function called by Emacs to generate mouse-over text.
1116 The arguments specify the BUFFER and the POS within the buffer of the item
1117 for which help is required.  The function returns the help to be
1118 displayed.  The _WINDOW argument is currently unused."
1119   (with-current-buffer buffer
1120     (let ((button (button-at pos)))
1121       (when button
1122         (let* ((page (button-get button 'elpher-page))
1123                (address (elpher-page-address page)))
1124           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1125
1126 (defun elpher-insert-index-record (display-string &optional address)
1127   "Function to insert an index record into the current buffer.
1128 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1129 If ADDRESS is not supplied or nil the record is rendered as an
1130 'information' line."
1131   (let* ((type (if address (elpher-address-type address) nil))
1132          (type-map-entry (cdr (assoc type elpher-type-map))))
1133     (if type-map-entry
1134         (let* ((margin-code (elt type-map-entry 2))
1135                (face (elt type-map-entry 3))
1136                (filtered-display-string (elpher-color-filter-apply display-string))
1137                (page (elpher-make-page filtered-display-string address)))
1138           (elpher-insert-margin margin-code)
1139           (insert-text-button filtered-display-string
1140                               'face face
1141                               'elpher-page page
1142                               'action #'elpher-click-link
1143                               'follow-link t
1144                               'help-echo #'elpher--page-button-help))
1145       (pcase type
1146         ('nil ;; Information
1147          (elpher-insert-margin)
1148          (let ((propertized-display-string
1149                 (propertize display-string 'face 'elpher-info)))
1150            (insert (elpher-process-text-for-display propertized-display-string))))
1151         (`(gopher ,selector-type) ;; Unknown
1152          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1153          (insert (propertize display-string
1154                              'face 'elpher-unknown)))))
1155     (insert "\n")))
1156
1157 (defun elpher-click-link (button)
1158   "Function called when the gopher link BUTTON is activated."
1159   (let ((page (button-get button 'elpher-page)))
1160     (elpher-visit-page page)))
1161
1162 (defun elpher-render-index (data &optional _mime-type-string)
1163   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1164   (elpher-with-clean-buffer
1165    (if (not data)
1166        t
1167      (let ((data-processed (elpher-preprocess-text-response data)))
1168        (dolist (line (split-string data-processed "\n"))
1169          (ignore-errors
1170            (unless (= (length line) 0)
1171              (let* ((type (elt line 0))
1172                     (fields (split-string (substring line 1) "\t"))
1173                     (display-string (elt fields 0))
1174                     (selector (elt fields 1))
1175                     (host (elt fields 2))
1176                     (port (if (elt fields 3)
1177                               (string-to-number (elt fields 3))
1178                             nil))
1179                     (address (elpher-make-gopher-address type selector host port)))
1180                (elpher-insert-index-record display-string address))))))
1181      (elpher-cache-content (elpher-page-address elpher-current-page)
1182                            (buffer-string)))))
1183
1184 ;; Text rendering
1185
1186 (defun elpher-render-text (data &optional _mime-type-string)
1187   "Render DATA as text.  MIME-TYPE-STRING is unused."
1188   (elpher-with-clean-buffer
1189    (if (not data)
1190        t
1191      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1192      (elpher-cache-content
1193       (elpher-page-address elpher-current-page)
1194       (buffer-string)))))
1195
1196 ;; Image retrieval
1197
1198 (defun elpher-render-image (data &optional _mime-type-string)
1199   "Display DATA as image.  MIME-TYPE-STRING is unused."
1200   (if (not data)
1201       nil
1202     (if (display-images-p)
1203         (let* ((image (create-image
1204                        data
1205                        nil t)))
1206           (if (not image)
1207               (error "Unsupported image format")
1208             (let ((window (get-buffer-window elpher-buffer-name)))
1209               (when window
1210                 (setf (image-property image :max-width) (window-body-width window t))
1211                 (setf (image-property image :max-height) (window-body-height window t))))
1212             (elpher-with-clean-buffer
1213              (insert-image image)
1214              (elpher-restore-pos))))
1215       (elpher-render-download data))))
1216
1217 ;; Search retrieval and rendering
1218
1219 (defun elpher-get-gopher-query-page (renderer)
1220   "Getter for gopher addresses requiring input.
1221 The response is rendered using the rendering function RENDERER."
1222   (let* ((address (elpher-page-address elpher-current-page))
1223          (content (elpher-get-cached-content address))
1224          (aborted t))
1225     (if (and content (funcall renderer nil))
1226         (elpher-with-clean-buffer
1227          (insert content)
1228          (elpher-restore-pos)
1229          (message "Displaying cached search results.  Reload to perform a new search."))
1230       (unwind-protect
1231           (let* ((query-string (read-string "Query: "))
1232                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1233                  (search-address (elpher-make-gopher-address ?1
1234                                                              query-selector
1235                                                              (elpher-address-host address)
1236                                                              (elpher-address-port address)
1237                                                              (equal (elpher-address-type address) "gophers"))))
1238             (setq aborted nil)
1239
1240             (elpher-with-clean-buffer
1241              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1242             (elpher-get-gopher-response search-address renderer))
1243         (if aborted
1244             (elpher-visit-previous-page))))))
1245
1246 ;; Raw server response rendering
1247
1248 (defun elpher-render-raw (data &optional mime-type-string)
1249   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1250   (if (not data)
1251       nil
1252     (elpher-with-clean-buffer
1253      (when mime-type-string
1254        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1255      (insert data)
1256      (goto-char (point-min)))
1257     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1258
1259 ;; File save "rendering"
1260
1261 (defun elpher-render-download (data &optional _mime-type-string)
1262   "Save DATA to file.  MIME-TYPE-STRING is unused."
1263   (if (not data)
1264       nil
1265     (let* ((address (elpher-page-address elpher-current-page))
1266            (selector (if (elpher-address-gopher-p address)
1267                          (elpher-gopher-address-selector address)
1268                        (elpher-address-filename address))))
1269       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1270       (let* ((filename-proposal (file-name-nondirectory selector))
1271              (filename (read-file-name "Download complete. Save file as: "
1272                                        nil nil nil
1273                                        (if (> (length filename-proposal) 0)
1274                                            filename-proposal
1275                                          "download.file"))))
1276         (let ((coding-system-for-write 'binary))
1277           (with-temp-file filename
1278             (insert data)))
1279         (message (format "Saved to file %s." filename))))))
1280
1281 ;; HTML rendering
1282
1283 (defun elpher-render-html (data &optional _mime-type-string)
1284   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1285   (elpher-with-clean-buffer
1286    (if (not data)
1287        t
1288      (let ((dom (with-temp-buffer
1289                   (insert data)
1290                   (libxml-parse-html-region (point-min) (point-max)))))
1291        (shr-insert-document dom)))))
1292
1293 ;; Gemini page retrieval
1294
1295 (defvar elpher-gemini-redirect-chain)
1296
1297 (defun elpher-get-gemini-response (address renderer)
1298   "Get response string from gemini server at ADDRESS and render using RENDERER."
1299   (elpher-get-host-response address 1965
1300                             (concat (elpher-address-to-url address) "\r\n")
1301                             (lambda (response-string)
1302                               (elpher-process-gemini-response response-string renderer))
1303                             'gemini))
1304
1305 (defun elpher-parse-gemini-response (response)
1306   "Parse the RESPONSE string and return a list of components.
1307 The list is of the form (code meta body).  A response of nil implies
1308 that the response was malformed."
1309   (let ((header-end-idx (string-match "\r\n" response)))
1310     (if header-end-idx
1311         (let ((header (string-trim (substring response 0 header-end-idx)))
1312               (body (substring response (+ header-end-idx 2))))
1313           (if (>= (length header) 2)
1314               (let ((code (substring header 0 2))
1315                     (meta (string-trim (substring header 2))))
1316                 (list code meta body))
1317             (error "Malformed response: No response status found in header %s" header)))
1318       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1319
1320 (defun elpher-process-gemini-response (response-string renderer)
1321   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1322   (let ((response-components (elpher-parse-gemini-response response-string)))
1323     (let ((response-code (elt response-components 0))
1324           (response-meta (elt response-components 1))
1325           (response-body (elt response-components 2)))
1326       (pcase (elt response-code 0)
1327         (?1 ; Input required
1328          (elpher-with-clean-buffer
1329           (insert "Gemini server is requesting input."))
1330          (let* ((query-string
1331                  (if (eq (elt response-code 1) ?1)
1332                      (read-passwd (concat response-meta ": "))
1333                    (read-string (concat response-meta ": "))))
1334                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1335                 (old-fname (url-filename query-address)))
1336            (setf (url-filename query-address)
1337                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1338            (elpher-get-gemini-response query-address renderer)))
1339         (?2 ; Normal response
1340          (funcall renderer response-body response-meta))
1341         (?3 ; Redirect
1342          (message "Following redirect to %s" response-meta)
1343          (if (>= (length elpher-gemini-redirect-chain) 5)
1344              (error "More than 5 consecutive redirects followed"))
1345          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1346            (if (member redirect-address elpher-gemini-redirect-chain)
1347                (error "Redirect loop detected"))
1348            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1349                (error "Server tried to automatically redirect to non-gemini URL: %s"
1350                       response-meta))
1351            (elpher-page-set-address elpher-current-page redirect-address)
1352            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1353            (elpher-get-gemini-response redirect-address renderer)))
1354         (?4 ; Temporary failure
1355          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1356                 response-code response-meta))
1357         (?5 ; Permanent failure
1358          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1359                 response-code response-meta))
1360         (?6 ; Client certificate required
1361          (elpher-with-clean-buffer
1362           (if elpher-client-certificate
1363               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1364             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1365           (auto-fill-mode 1)
1366           (elpher-gemini-insert-text response-meta))
1367          (let ((chosen-certificate (elpher-choose-client-certificate)))
1368            (unless chosen-certificate
1369              (error "Gemini server requires a client certificate and none was provided"))
1370            (setq elpher-client-certificate chosen-certificate))
1371          (elpher-with-clean-buffer)
1372          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1373         (_other
1374          (error "Gemini server response unknown: %s %s"
1375                 response-code response-meta))))))
1376
1377 (defun elpher--read-answer-polyfill (question answers)
1378   "Polyfill for `read-answer' in Emacs 26.1.
1379 QUESTION is a string containing a question, and ANSWERS
1380 is a list of possible answers."
1381     (completing-read question (mapcar 'identity answers)))
1382
1383 (if (fboundp 'read-answer)
1384     (defalias 'elpher-read-answer 'read-answer)
1385   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1386
1387 (defun elpher-choose-client-certificate ()
1388   "Prompt for a client certificate to use to establish a TLS connection."
1389   (let* ((read-answer-short t))
1390     (pcase (read-answer "What do you want to do? "
1391                         '(("throwaway" ?t
1392                            "generate and use throw-away certificate")
1393                           ("persistent" ?p
1394                            "generate new or use existing persistent certificate")
1395                           ("abort" ?a
1396                            "stop immediately")))
1397       ("throwaway"
1398        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1399       ("persistent"
1400        (let* ((existing-certificates (elpher-list-existing-certificates))
1401               (file-base (completing-read
1402                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1403                           existing-certificates)))
1404          (if (string-empty-p (string-trim file-base))
1405              nil
1406            (if (member file-base existing-certificates)
1407                (setq elpher-client-certificate
1408                      (elpher-get-existing-certificate file-base))
1409              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1410                                  '(("new" ?n
1411                                     "generate new certificate")
1412                                    ("install" ?i
1413                                     "install existing certificate")
1414                                    ("abort" ?a
1415                                     "stop immediately")))
1416                ("new"
1417                 (let ((common-name (read-string "Common Name field for new certificate: "
1418                                                 file-base)))
1419                   (message "New key and self-signed certificate written to %s"
1420                            elpher-certificate-directory)
1421                   (elpher-generate-persistent-certificate file-base common-name)))
1422                ("install"
1423                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1424                        (key-file (read-file-name "Key file: " nil nil t)))
1425                   (message "Key and certificate installed in %s for future use"
1426                            elpher-certificate-directory)
1427                   (elpher-install-and-use-existing-certificate key-file
1428                                                                cert-file
1429                                                                file-base)))
1430                ("abort" nil))))))
1431       ("abort" nil))))
1432
1433 (defun elpher-get-gemini-page (renderer)
1434   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1435   (let* ((address (elpher-page-address elpher-current-page))
1436          (content (elpher-get-cached-content address)))
1437     (condition-case the-error
1438         (if (and content (funcall renderer nil))
1439             (elpher-with-clean-buffer
1440              (insert content)
1441              (elpher-restore-pos))
1442           (elpher-with-clean-buffer
1443            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1444           (setq elpher-gemini-redirect-chain nil)
1445           (elpher-get-gemini-response address renderer))
1446       (error
1447        (elpher-network-error address the-error)))))
1448
1449 (defun elpher-render-gemini (body &optional mime-type-string)
1450   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1451   (if (not body)
1452       t
1453     (let* ((mime-type-string* (if (or (not mime-type-string)
1454                                       (string-empty-p mime-type-string))
1455                                   "text/gemini; charset=utf-8"
1456                                 mime-type-string))
1457            (mime-type-split (split-string mime-type-string* ";" t))
1458            (mime-type (string-trim (car mime-type-split)))
1459            (parameters (mapcar (lambda (s)
1460                                  (let ((key-val (split-string s "=")))
1461                                    (list (downcase (string-trim (car key-val)))
1462                                          (downcase (string-trim (cadr key-val))))))
1463                                (cdr mime-type-split))))
1464       (when (string-prefix-p "text/" mime-type)
1465         (setq body (decode-coding-string
1466                     body
1467                     (if (assoc "charset" parameters)
1468                         (intern (cadr (assoc "charset" parameters)))
1469                       'utf-8)))
1470         (setq body (replace-regexp-in-string "\r" "" body)))
1471       (pcase mime-type
1472         ((or "text/gemini" "")
1473          (elpher-render-gemini-map body parameters))
1474         ("text/html"
1475          (elpher-render-html body))
1476         ((pred (string-prefix-p "text/"))
1477          (elpher-render-gemini-plain-text body parameters))
1478         ((pred (string-prefix-p "image/"))
1479          (elpher-render-image body))
1480         (_other
1481          (elpher-render-download body))))))
1482
1483 (defun elpher-gemini-get-link-url (link-line)
1484   "Extract the url portion of LINK-LINE, a gemini map file link line.
1485 Returns nil in the event that the contents of the line following the
1486 => prefix are empty."
1487   (let ((l (split-string (substring link-line 2))))
1488     (if l
1489         (string-trim (elt l 0))
1490       nil)))
1491
1492 (defun elpher-gemini-get-link-display-string (link-line)
1493   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1494 Return nil if this portion is not provided."
1495   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1496          (idx (string-match "[ \t]" rest)))
1497     (and idx
1498          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1499
1500 (defun elpher-collapse-dot-sequences (filename)
1501   "Collapse dot sequences in the (absolute) FILENAME.
1502 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1503   (let* ((path (split-string filename "/" t))
1504          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1505          (path-reversed-normalized
1506           (seq-reduce (lambda (a b)
1507                         (cond ((equal b "..") (cdr a))
1508                               ((equal b ".") a)
1509                               (t (cons b a))))
1510                       path nil))
1511          (path-normalized (reverse path-reversed-normalized)))
1512     (if path-normalized
1513         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1514       "/")))
1515
1516 (defun elpher-address-from-gemini-url (url)
1517   "Extract address from URL with defaults as per gemini map files.
1518 While there's obviously some redundancy here between this function and
1519 `elpher-address-from-url', gemini map file URLs require enough special
1520 treatment that a separate function is warranted."
1521   (let ((address (url-generic-parse-url url))
1522         (current-address (elpher-page-address elpher-current-page)))
1523     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1524       (if (url-host address) ;if there is an explicit host, filenames are absolute
1525           (if (string-empty-p (url-filename address))
1526               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1527         (setf (url-host address) (url-host current-address))
1528         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1529         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1530         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1531           (setf (url-filename address)
1532                 (concat (file-name-directory (url-filename current-address))
1533                         (url-filename address)))))
1534       (when (url-host address)
1535         (setf (url-host address) (puny-encode-domain (url-host address))))
1536       (unless (url-type address)
1537         (setf (url-type address) (url-type current-address)))
1538       (when (equal (url-type address) "gemini")
1539         (setf (url-filename address)
1540               (elpher-collapse-dot-sequences (url-filename address)))))
1541     (elpher-remove-redundant-ports address)))
1542
1543 (defun elpher-gemini-insert-link (link-line)
1544   "Insert link described by LINK-LINE into a text/gemini document."
1545   (let ((url (elpher-gemini-get-link-url link-line)))
1546     (when url
1547       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1548              (address (elpher-address-from-gemini-url url))
1549              (type (if address (elpher-address-type address) nil))
1550              (type-map-entry (cdr (assoc type elpher-type-map)))
1551              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1552         (when type-map-entry
1553           (insert elpher-gemini-link-string)
1554           (let* ((face (elt type-map-entry 3))
1555                  (display-string (or given-display-string
1556                                      (elpher-address-to-iri address)))
1557                  (page (elpher-make-page display-string
1558                                          address)))
1559             (insert-text-button display-string
1560                                 'face face
1561                                 'elpher-page page
1562                                 'action #'elpher-click-link
1563                                 'follow-link t
1564                                 'help-echo #'elpher--page-button-help))
1565           (newline))))))
1566
1567 (defun elpher-gemini-insert-header (header-line)
1568   "Insert header described by HEADER-LINE into a text/gemini document.
1569 The gemini map file line describing the header is given
1570 by HEADER-LINE."
1571   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1572     (let* ((level (length (match-string 1 header-line)))
1573            (header (substring header-line (match-end 0)))
1574            (face (pcase level
1575                    (1 'elpher-gemini-heading1)
1576                    (2 'elpher-gemini-heading2)
1577                    (3 'elpher-gemini-heading3)
1578                    (_ 'default)))
1579            (fill-column (if (display-graphic-p)
1580                             (/ (* fill-column
1581                                   (font-get (font-spec :name (face-font 'default)) :size))
1582                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1583       (unless (display-graphic-p)
1584         (insert (make-string level ?#) " "))
1585       (insert (propertize header
1586                           'face face
1587                           'gemini-heading t
1588                           'rear-nonsticky t))
1589       (newline))))
1590
1591 (defun elpher-gemini-insert-text (text-line)
1592   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1593 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1594 width defined by `elpher-gemini-max-fill-width'."
1595   (string-match
1596    (rx (: line-start
1597           (optional
1598            (group (or (: "*" (+ (any " \t")))
1599                       (: ">" (* (any " \t"))))))))
1600    text-line)
1601   (let* ((line-prefix (match-string 1 text-line))
1602          (processed-text-line
1603           (if line-prefix
1604               (cond ((string-prefix-p "*" line-prefix)
1605                      (concat
1606                       (replace-regexp-in-string "\\*"
1607                                                 elpher-gemini-bullet-string
1608                                                 (match-string 0 text-line))
1609                       (substring text-line (match-end 0))))
1610                     ((string-prefix-p ">" line-prefix)
1611                      (propertize text-line 'face 'elpher-gemini-quoted))
1612                     (t text-line))
1613             text-line))
1614          (fill-prefix (if line-prefix
1615                           (make-string (length (match-string 0 text-line)) ?\s)
1616                         "")))
1617     (insert (elpher-process-text-for-display processed-text-line))
1618     (newline)))
1619
1620 (defun elpher-gemini-pref-expand-collapse (button)
1621   "Function called when the preformatted text toggle BUTTON is activated."
1622   (let ((id (button-get button 'pref-id)))
1623     (if (invisible-p id)
1624         (remove-from-invisibility-spec id)
1625       (add-to-invisibility-spec id))
1626     (redraw-display)))
1627
1628 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1629   "Insert a button for toggling the visibility of preformatted text.
1630 If non-nil, ALT-TEXT is displayed alongside the button."
1631   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1632          (pref-id (intern (concat "pref-"
1633                                   (number-to-string (point))
1634                                   "-"
1635                                   url-string))))
1636     (insert elpher-gemini-preformatted-toggle-bullet)
1637     (when alt-text
1638       (insert (propertize (concat alt-text " ")
1639                           'face 'elpher-gemin-preformatted)))
1640     (insert-text-button elpher-gemini-preformatted-toggle-label
1641                         'action #'elpher-gemini-pref-expand-collapse
1642                         'pref-id pref-id
1643                         'face 'elpher-gemini-preformatted-toggle)
1644     (add-to-invisibility-spec pref-id)
1645     (newline)
1646     pref-id))
1647
1648 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1649   "Insert a LINE of preformatted text.
1650 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1651 can be used to toggle the display of the preformatted text."
1652   (insert (propertize (concat (elpher-process-text-for-display
1653                                (propertize line 'face 'elpher-gemini-preformatted))
1654                               "\n")
1655                       'invisible pref-id
1656                       'rear-nonsticky t)))
1657
1658 (defun elpher-render-gemini-map (data _parameters)
1659   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1660   (elpher-with-clean-buffer
1661    (auto-fill-mode 1)
1662    (setq-local buffer-invisibility-spec nil)
1663    (let ((preformatted nil)
1664          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1665      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1666      (dolist (line (split-string data "\n"))
1667        (pcase line
1668          ((rx (: "```" (opt (let alt-text (+ any)))))
1669           (setq preformatted
1670                 (if preformatted
1671                     nil
1672                   (if elpher-gemini-hide-preformatted
1673                       (elpher-gemini-insert-preformatted-toggler alt-text)
1674                     t))))
1675          ((guard  preformatted)
1676           (elpher-gemini-insert-preformatted-line line preformatted))
1677          ((pred (string-prefix-p "=>"))
1678           (elpher-gemini-insert-link line))
1679          ((pred (string-prefix-p "#"))
1680           (elpher-gemini-insert-header line))
1681          (_ (elpher-gemini-insert-text line))))
1682    (elpher-cache-content
1683     (elpher-page-address elpher-current-page)
1684     (buffer-string)))))
1685
1686 (defun elpher-render-gemini-plain-text (data _parameters)
1687   "Render DATA as plain text file.  PARAMETERS is currently unused."
1688   (elpher-with-clean-buffer
1689    (insert (elpher-process-text-for-display data))
1690    (elpher-cache-content
1691     (elpher-page-address elpher-current-page)
1692     (buffer-string))))
1693
1694 (defun elpher-build-current-imenu-index ()
1695   "Build imenu index for current elpher buffer."
1696   (save-excursion
1697     (goto-char (point-min))
1698     (let ((match nil)
1699           (headers nil))
1700       (while (setq match (text-property-search-forward 'gemini-heading t t))
1701         (push (cons
1702                (buffer-substring-no-properties (prop-match-beginning match)
1703                                                (prop-match-end match))
1704                (prop-match-beginning match))
1705               headers))
1706       (reverse headers))))
1707
1708
1709 ;; Finger page connection
1710
1711 (defun elpher-get-finger-page (renderer)
1712   "Opens a finger connection to the current page address.
1713 The result is rendered using RENDERER."
1714   (let* ((address (elpher-page-address elpher-current-page))
1715          (content (elpher-get-cached-content address)))
1716     (if (and content (funcall renderer nil))
1717         (elpher-with-clean-buffer
1718          (insert content)
1719          (elpher-restore-pos))
1720       (elpher-with-clean-buffer
1721        (insert "LOADING... (use 'u' to cancel)\n"))
1722       (condition-case the-error
1723           (let* ((kill-buffer-query-functions nil)
1724                  (user (let ((filename (elpher-address-filename address)))
1725                          (if (> (length filename) 1)
1726                              (substring filename 1)
1727                            (elpher-address-user address)))))
1728             (elpher-get-host-response address 79
1729                                       (concat user "\r\n")
1730                                       renderer))
1731         (error
1732          (elpher-network-error address the-error))))))
1733
1734
1735 ;; Telnet page connection
1736
1737 (defun elpher-get-telnet-page (renderer)
1738   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1739   (when renderer
1740     (elpher-visit-previous-page)
1741     (error "Command not supported for telnet URLs"))
1742   (let* ((address (elpher-page-address elpher-current-page))
1743          (host (elpher-address-host address))
1744          (port (elpher-address-port address)))
1745     (elpher-visit-previous-page)
1746     (if (> port 0)
1747         (telnet host port)
1748       (telnet host))))
1749
1750
1751 ;; Other URL page opening
1752
1753 (defun elpher-get-other-url-page (renderer)
1754   "Getter which attempts to open the URL specified by the current page.
1755 The RENDERER argument to this getter must be nil."
1756   (when renderer
1757     (elpher-visit-previous-page)
1758     (error "Command not supported for general URLs"))
1759   (let* ((address (elpher-page-address elpher-current-page))
1760          (url (elpher-address-to-url address)))
1761     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1762     (message "Opening URL...")
1763     (if elpher-open-urls-with-eww
1764         (browse-web url)
1765       (browse-url url))))
1766
1767
1768 ;; File page
1769
1770 (defun elpher-get-file-page (renderer)
1771   "Getter which renders a local file using RENDERER.
1772 Assumes UTF-8 encoding for all text files."
1773   (let* ((address (elpher-page-address elpher-current-page))
1774          (filename (elpher-address-filename address)))
1775     (unless (file-exists-p filename)
1776       (elpher-visit-previous-page)
1777         (error "File not found"))
1778     (unless (file-readable-p filename)
1779       (elpher-visit-previous-page)
1780         (error "Could not read from file"))
1781     (let ((body (with-temp-buffer
1782        (let ((coding-system-for-read 'binary)
1783              (coding-system-for-write 'binary))
1784          (insert-file-contents-literally filename)
1785          (encode-coding-string (buffer-string) 'raw-text)))))
1786        (if renderer
1787            (funcall renderer body nil)
1788          (pcase (file-name-extension filename)
1789            ((or  "gmi" "gemini")
1790             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1791            ((or "htm" "html")
1792             (elpher-render-html (decode-coding-string body 'utf-8)))
1793            ((or "txt" "")
1794             (elpher-render-text (decode-coding-string body 'utf-8)))
1795            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1796             (elpher-render-image body))
1797            ((or "gopher" "gophermap")
1798             (elpher-render-index (elpher-decode body)))
1799            (_
1800             (elpher-render-download body))))
1801        (elpher-restore-pos))))
1802
1803
1804 ;; Welcome page retrieval
1805
1806 (defun elpher-get-welcome-page (renderer)
1807   "Getter which displays the welcome page (RENDERER must be nil)."
1808   (when renderer
1809     (elpher-visit-previous-page)
1810     (error "Command not supported for welcome page"))
1811   (elpher-with-clean-buffer
1812    (insert "     --------------------------------------------\n"
1813            "           Elpher Gopher and Gemini Client       \n"
1814            "                   version " elpher-version "\n"
1815            "     --------------------------------------------\n"
1816            "\n"
1817            "Default bindings:\n"
1818            "\n"
1819            " - TAB/Shift-TAB: next/prev item on current page\n"
1820            " - RET/mouse-1: open item under cursor\n"
1821            " - m: select an item on current page by name (autocompletes)\n"
1822            " - u/mouse-3/U: return to previous page or to the start page\n"
1823            " - g: go to a particular address (gopher, gemini, finger)\n"
1824            " - o/O: open a different address selector or the root menu of the current server\n"
1825            " - d/D: download item under cursor or current page\n"
1826            " - i/I: info on item under cursor or current page\n"
1827            " - c/C: copy URL representation of item under cursor or current page\n"
1828            " - a/A: bookmark the item under cursor or current page\n"
1829            " - B: list all bookmarks\n"
1830            " - s/S: show current history stack or all previously visted pages\n"
1831            " - r: redraw current page (using cached contents if available)\n"
1832            " - R: reload current page (regenerates cache)\n"
1833            " - !: set character coding system for gopher (default is to autodetect)\n"
1834            " - T: toggle TLS gopher mode\n"
1835            " - F: forget/discard current TLS client certificate\n"
1836            " - .: display the raw server response for the current page\n"
1837            "\n"
1838            "Start your exploration of gopher space and gemini:\n")
1839    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1840                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1841    (elpher-insert-index-record "Project Gemini home page"
1842                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1843    (insert "\n"
1844            "Alternatively, select a search engine and enter some search terms:\n")
1845    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1846                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1847    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1848                                (elpher-address-from-url "gemini://geminispace.info/search"))
1849    (insert "\n"
1850            "Your bookmarks are stored in your ")
1851    (insert-text-button "bookmark list"
1852                        'face 'link
1853                        'action #'elpher-click-link
1854                        'follow-link t
1855                        'help-echo #'elpher--page-button-help
1856                        'elpher-page
1857                        (elpher-make-page "Elpher Bookmarks"
1858                                          (elpher-make-about-address 'bookmarks)))
1859    (insert ".\n")
1860    (insert (propertize
1861             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1862             'face 'shadow))
1863    (insert "\n"
1864            "The gopher home of the Elpher project is here:\n")
1865    (elpher-insert-index-record "The Elpher Project Page"
1866                                (elpher-make-gopher-address ?1
1867                                                            "/projects/elpher/"
1868                                                            "thelambdalab.xyz"
1869                                                            70))
1870    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1871      (insert "\n"
1872              "The following info documentation is available:\n"
1873              "   - ")
1874      (insert-text-button "Elpher Manual"
1875                          'face 'link
1876                          'action (lambda (_)
1877                                    (interactive)
1878                                    (info "(elpher)"))
1879                          'follow-link t
1880                          'help-echo help-string)
1881      (insert "\n   - ")
1882      (insert-text-button "Changes introduced by the latest release"
1883                        'face 'link
1884                        'action (lambda (_)
1885                                  (interactive)
1886                                  (info "(elpher)News"))
1887                        'follow-link t
1888                        'help-echo help-string))
1889    (insert "\n")
1890    (insert (propertize
1891             (concat "(These documents should be available if you have installed Elpher\n"
1892                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1893                     " manual yourself.)\n")
1894             'face 'shadow))
1895    (elpher-restore-pos)))
1896
1897
1898 ;; History page retrieval
1899
1900 (defun elpher-show-history ()
1901   "Show the current contents of elpher's history stack.
1902 Use \\[elpher-show-visited-pages] to see the entire history.
1903 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1904   (interactive)
1905   (elpher-visit-page
1906    (elpher-make-page "Current History Stack"
1907                      (elpher-make-about-address 'history))))
1908
1909 (defun elpher-show-visited-pages ()
1910   "Show the all the pages you've visited using Elpher.
1911 Use \\[elpher-show-history] to see just the current history stack.
1912 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1913   (interactive)
1914   (elpher-visit-page
1915    (elpher-make-page "Elpher Visted Pages"
1916                      (elpher-make-about-address 'visited-pages))))
1917
1918 (defun elpher-get-history-page (renderer)
1919   "Getter which displays the history page (RENDERER must be nil)."
1920   (when renderer
1921     (elpher-visit-previous-page)
1922     (error "Command not supported for history page"))
1923   (elpher-display-history-links elpher-history "Current history stack"))
1924
1925 (defun elpher-get-visited-pages-page (renderer)
1926   "Getter which displays the list of visited pages (RENDERER must be nil)."
1927   (when renderer
1928     (elpher-visit-previous-page)
1929     (error "Command not supported for history page"))
1930   (elpher-display-history-links
1931    (seq-filter (lambda (page)
1932                  (not (elpher-address-about-p (elpher-page-address page))))
1933                elpher-visited-pages)
1934    "All visited pages"))
1935
1936 (defun elpher-display-history-links (pages title)
1937   "Show all PAGES in an Elpher buffer with a given TITLE."
1938   (let* ((title-line (concat " ---- " title " ----"))
1939          (footer-line (make-string (length title-line) ?-)))
1940     (elpher-with-clean-buffer
1941      (insert title-line "\n\n")
1942      (if pages
1943          (dolist (page pages)
1944            (when page
1945              (let ((display-string (elpher-page-display-string page))
1946                    (address (elpher-page-address page)))
1947                (elpher-insert-index-record display-string address))))
1948        (insert "No history items found.\n"))
1949      (insert "\n " footer-line "\n"
1950              "Select an entry or press 'u' to return to the previous page.")
1951      (elpher-restore-pos))))
1952
1953
1954 ;;; Bookmarks
1955
1956 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1957 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1958 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1959 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1960
1961 (defvar elpher-bookmark-link nil
1962   "Prefer bookmarking a link or the current page.
1963 Bind this variable dynamically, or set it to t.
1964 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1965 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1966
1967 (defun elpher-bookmark-make-record ()
1968   "Return a bookmark record.
1969 If `elpher-bookmark-link' is non-nil and point is on a link button,
1970 return a bookmark record for that link.  Otherwise, return a bookmark
1971 record for the current elpher page."
1972   (let* ((button (and elpher-bookmark-link (button-at (point))))
1973          (page (if button
1974                    (button-get button 'elpher-page)
1975                  elpher-current-page)))
1976     (unless page
1977       (error "Cannot bookmark this link"))
1978     (let* ((address (elpher-page-address page))
1979            (url (elpher-address-to-url address))
1980            (display-string (elpher-page-display-string page))
1981            (pos (if button nil (point))))
1982       (if (elpher-address-about-p address)
1983           (error "Cannot bookmark %s" display-string)
1984         `(,display-string
1985           (defaults . (,display-string))
1986           (position . ,pos)
1987           (location . ,url)
1988           (handler . elpher-bookmark-jump))))))
1989
1990 ;;;###autoload
1991 (defun elpher-bookmark-jump (bookmark)
1992   "Handler used to open a bookmark using elpher.
1993 The argument BOOKMARK is a bookmark record passed to the function.
1994 This handler is responsible for loading the bookmark in some buffer,
1995 then making that buffer the current buffer.  It should not switch
1996 to the buffer."
1997   (let* ((url (cdr (assq 'location bookmark)))
1998          (cleaned-url (string-trim url))
1999          (page (elpher-page-from-url cleaned-url))
2000          (buffer (get-buffer-create elpher-buffer-name)))
2001     (elpher-with-clean-buffer
2002      (elpher-visit-page page))
2003     (set-buffer buffer)
2004     nil))
2005
2006 (defun elpher-bookmark-link ()
2007   "Bookmark the link at point.
2008 To bookmark the current page, use \\[elpher-bookmark-current]."
2009   (interactive)
2010   (let ((elpher-bookmark-link t))
2011     (bookmark-set-no-overwrite)))
2012
2013 (defun elpher-bookmark-current ()
2014   "Bookmark the current page.
2015 To bookmark the link at point use \\[elpher-bookmark-link]."
2016   (interactive)
2017   (call-interactively #'bookmark-set-no-overwrite))
2018
2019 (defun elpher-bookmark-import (file)
2020   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2021   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2022                               (file-readable-p elpher-bookmarks-file))
2023                          elpher-bookmarks-file
2024                        (read-file-name "Old Elpher bookmarks: "
2025                                        user-emacs-directory nil t
2026                                        "elpher-bookmarks"))))
2027   (dolist (bookmark (with-temp-buffer
2028                       (insert-file-contents file)
2029                       (read (current-buffer))))
2030     (let* ((display-string (car bookmark))
2031            (url (cadr bookmark))
2032            (record `(,display-string
2033                      (location . ,url)
2034                      (handler . elpher-bookmark-jump))))
2035       (bookmark-store display-string (cdr record) t)))
2036   (bookmark-save))
2037
2038 (defun elpher-get-bookmarks-page (renderer)
2039   "Getter which displays the bookmarks (RENDERER must be nil)."
2040   (when renderer
2041     (elpher-visit-previous-page)
2042     (error "Command not supported for bookmarks page"))
2043
2044   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2045                                      elpher-bookmarks-file)
2046                                 (locate-user-emacs-file "elpher-bookmarks"))))
2047     (when (and (file-readable-p old-bookmarks-file)
2048                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2049                                  old-bookmarks-file
2050                                  "\" found. Import now?")))
2051       (elpher-bookmark-import old-bookmarks-file)
2052       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2053
2054   (if (and elpher-use-emacs-bookmark-menu
2055            elpher-history)
2056       (progn
2057         (elpher-visit-previous-page)
2058         (call-interactively #'bookmark-bmenu-list))
2059     (elpher-with-clean-buffer
2060      (insert " ---- Elpher Bookmarks ---- \n\n")
2061      (bookmark-maybe-load-default-file)
2062      (dolist (bookmark (bookmark-maybe-sort-alist))
2063        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2064          (let* ((name (car bookmark))
2065                 (url (alist-get 'location (cdr bookmark)))
2066                 (address (elpher-address-from-url url)))
2067            (elpher-insert-index-record name address))))
2068      (when (<= (line-number-at-pos) 3)
2069        (insert "No bookmarked pages found.\n"))
2070      (insert "\n --------------------------\n\n"
2071              "Select an entry or press 'u' to return to the previous page.\n\n"
2072              "Bookmarks can be renamed or deleted via the ")
2073      (insert-text-button "Emacs bookmark menu"
2074                          'action (lambda (_)
2075                                    (interactive)
2076                                    (call-interactively #'bookmark-bmenu-list))
2077                          'follow-link t
2078                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2079      (insert (substitute-command-keys
2080               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2081      (elpher-restore-pos))))
2082
2083 (defun elpher-show-bookmarks ()
2084   "Interactive function to display the current list of elpher bookmarks."
2085   (interactive)
2086   (elpher-visit-page
2087    (elpher-make-page "Elpher Bookmarks"
2088                      (elpher-make-about-address 'bookmarks))))
2089
2090
2091 ;;; Integrations
2092 ;;
2093
2094 ;;; Org
2095
2096 (defun elpher-org-export-link (link description format protocol)
2097   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2098
2099 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2100 of gemini, gopher or finger."
2101   (let* ((url (if (equal protocol "elpher")
2102                   (string-remove-prefix "elpher:" link)
2103                 (format "%s:%s" protocol link)))
2104          (desc (or description url)))
2105     (pcase format
2106       (`gemini (format "=> %s %s" url desc))
2107       (`html (format "<a href=\"%s\">%s</a>" url desc))
2108       (`latex (format "\\href{%s}{%s}" url desc))
2109       (_ (if (not description)
2110              url
2111            (format "%s (%s)" desc url))))))
2112
2113 (defun elpher-org-store-link ()
2114   "Store link to an `elpher' page in Org."
2115   (when (eq major-mode 'elpher-mode)
2116     (let* ((url (elpher-info-current))
2117            (desc (car elpher-current-page))
2118            (protocol (cond
2119                       ((string-prefix-p "gemini:" url) "gemini")
2120                       ((string-prefix-p "gopher:" url) "gopher")
2121                       ((string-prefix-p "finger:" url) "finger")
2122                       (t "elpher"))))
2123       (when (equal "elpher" protocol)
2124         ;; Weird link. Or special inner link?
2125         (setq url (concat "elpher:" url)))
2126       (org-link-store-props :type protocol :link url :description desc)
2127       t)))
2128
2129 (defun elpher-org-follow-link (link protocol)
2130   "Visit a LINK for the given PROTOCOL.
2131
2132 PROTOCOL may be one of gemini, gopher or finger.  This method also
2133 supports the old protocol elpher, where the link is self-contained."
2134   (let ((url (if (equal protocol "elpher")
2135                  (string-remove-prefix "elpher:" link)
2136                (format "%s:%s" protocol link))))
2137     (elpher-go url)))
2138
2139 (defun elpher-org-mode-integration ()
2140   "Set up `elpher' integration for `org-mode'."
2141   (org-link-set-parameters
2142    "elpher"
2143    :store #'elpher-org-store-link
2144    :export (lambda (link description format _plist)
2145              (elpher-org-export-link link description format "elpher"))
2146    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2147   (org-link-set-parameters
2148    "gemini"
2149    :export (lambda (link description format _plist)
2150              (elpher-org-export-link link description format "gemini"))
2151    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2152   (org-link-set-parameters
2153    "gopher"
2154    :export (lambda (link description format _plist)
2155              (elpher-org-export-link link description format "gopher"))
2156    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2157   (org-link-set-parameters
2158    "finger"
2159    :export (lambda (link description format _plist)
2160              (elpher-org-export-link link description format "finger"))
2161    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2162
2163 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2164
2165 ;;; Browse URL
2166
2167 ;;;###autoload
2168 (defun elpher-browse-url-elpher (url &rest _args)
2169   "Browse URL using Elpher.  This function is used by `browse-url'."
2170   (interactive (browse-url-interactive-arg "Elpher URL: "))
2171   (elpher-go url))
2172
2173 ;; Use elpher to open gopher, finger and gemini links
2174 ;; For recent version of `browse-url' package
2175 (if (boundp 'browse-url-default-handlers)
2176     (add-to-list
2177      'browse-url-default-handlers
2178      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2179   ;; Patch `browse-url-browser-function' for older ones. The value of
2180   ;; that variable is `browse-url-default-browser' by default, so
2181   ;; that's the function that gets advised. If the value is an alist,
2182   ;; however, we don't know what to do. Better not interfere?
2183   (when (and (symbolp browse-url-browser-function)
2184              (fboundp browse-url-browser-function))
2185     (advice-add browse-url-browser-function :before-while
2186                 (lambda (url &rest _args)
2187                   "Handle gemini, gopher, and finger schemes using Elpher."
2188                   (let ((scheme (downcase (car (split-string url ":" t)))))
2189                     (if (member scheme '("gemini" "gopher" "finger"))
2190                         ;; `elpher-go' always returns nil, which will stop the
2191                         ;; advice chain here in a before-while
2192                         (elpher-go url)
2193                       ;; chain must continue, then return t.
2194                       t))))))
2195
2196 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2197 (with-eval-after-load 'thingatpt
2198   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2199
2200 ;;; Mu4e:
2201
2202 ;; Make mu4e aware of the gemini world
2203 (setq mu4e~view-beginning-of-url-regexp
2204       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2205
2206 ;;; eww:
2207
2208 ;; Let elpher handle gemini, gopher links in eww buffer.
2209 (setq eww-use-browse-url
2210       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2211
2212
2213 ;;; Interactive procedures
2214 ;;
2215
2216 (defun elpher-next-link ()
2217   "Move point to the next link on the current page."
2218   (interactive)
2219   (forward-button 1))
2220
2221 (defun elpher-prev-link ()
2222   "Move point to the previous link on the current page."
2223   (interactive)
2224   (backward-button 1))
2225
2226 (defun elpher-follow-current-link ()
2227   "Open the link or url at point."
2228   (interactive)
2229   (push-button))
2230
2231 ;;;###autoload
2232 (defun elpher-go (host-or-url)
2233   "Go to a particular gopher site HOST-OR-URL.
2234 When run interactively HOST-OR-URL is read from the minibuffer."
2235   (interactive (list
2236                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2237   (let ((trimmed-host-or-url (string-trim host-or-url)))
2238     (unless (string-empty-p trimmed-host-or-url)
2239       (let ((page (elpher-page-from-url trimmed-host-or-url
2240                                         (elpher-get-default-url-scheme))))
2241         (unless (get-buffer-window elpher-buffer-name t)
2242           (switch-to-buffer elpher-buffer-name))
2243         (elpher-with-clean-buffer
2244          (elpher-visit-page page))
2245         nil)))) ; non-nil value is displayed by eshell
2246
2247 (defun elpher-go-current ()
2248   "Go to a particular URL which is read from the minibuffer.
2249 Unlike `elpher-go', the reader is initialized with the URL of the
2250 current page."
2251   (interactive)
2252   (let* ((address (elpher-page-address elpher-current-page))
2253          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2254                            (elpher-address-to-url address))))
2255     (unless (string-empty-p (string-trim url))
2256       (elpher-visit-page (elpher-page-from-url url)))))
2257
2258 (defun elpher-redraw ()
2259   "Redraw current page."
2260   (interactive)
2261   (elpher-visit-page elpher-current-page))
2262
2263 (defun elpher-reload ()
2264   "Reload current page."
2265   (interactive)
2266   (elpher-reload-current-page))
2267
2268 (defun elpher-toggle-tls ()
2269   "Toggle TLS encryption mode for gopher."
2270   (interactive)
2271   (setq elpher-use-tls (not elpher-use-tls))
2272   (if elpher-use-tls
2273       (if (gnutls-available-p)
2274           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2275         (setq elpher-use-tls nil)
2276         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2277     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2278
2279 (defun elpher-view-raw ()
2280   "View raw server response for current page."
2281   (interactive)
2282   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2283       (error "This page was not generated by a server")
2284     (elpher-visit-page elpher-current-page
2285                        #'elpher-render-raw)))
2286
2287 (defun elpher-back ()
2288   "Go to previous site."
2289   (interactive)
2290   (elpher-visit-previous-page))
2291
2292 (defun elpher-back-to-start ()
2293   "Go all the way back to the start page."
2294   (interactive)
2295   (setq-local elpher-current-page nil)
2296   (setq-local elpher-history nil)
2297   (elpher-visit-page (elpher-make-start-page)))
2298
2299 (defun elpher-download ()
2300   "Download the link at point."
2301   (interactive)
2302   (let ((button (button-at (point))))
2303     (if button
2304         (let ((page (button-get button 'elpher-page)))
2305           (unless page
2306             (error "Not an elpher page"))
2307           (when (elpher-address-about-p (elpher-page-address page))
2308             (error "Cannot download %s" (elpher-page-display-string page)))
2309           (elpher-visit-page (button-get button 'elpher-page)
2310                              #'elpher-render-download))
2311       (error "No link selected"))))
2312
2313 (defun elpher-download-current ()
2314   "Download the current page."
2315   (interactive)
2316   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2317       (error "Cannot download %s"
2318              (elpher-page-display-string elpher-current-page))
2319     (elpher-visit-page (elpher-make-page
2320                         (elpher-page-display-string elpher-current-page)
2321                         (elpher-page-address elpher-current-page))
2322                        #'elpher-render-download
2323                        t)))
2324
2325 (defun elpher--build-link-map ()
2326   "Build alist mapping link names to destination pages in current buffer."
2327   (let ((link-map nil)
2328         (b (next-button (point-min) t)))
2329     (while b
2330       (push (cons (button-label b) b) link-map)
2331       (setq b (next-button (button-start b))))
2332     link-map))
2333
2334 (defun elpher-jump ()
2335   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2336   (interactive)
2337   (let* ((link-map (elpher--build-link-map)))
2338     (if link-map
2339         (let ((key (let ((completion-ignore-case t))
2340                      (completing-read "Directory item/link: "
2341                                       link-map nil t))))
2342           (if (and key (> (length key) 0))
2343               (let ((b (cdr (assoc key link-map))))
2344                 (goto-char (button-start b))
2345                 (button-activate b)))))))
2346
2347 (defun elpher-root-dir ()
2348   "Visit root of current server."
2349   (interactive)
2350   (let ((address (elpher-page-address elpher-current-page)))
2351     (if (not (elpher-address-about-p address))
2352         (if (or (member (url-filename address) '("/" ""))
2353                 (and (elpher-address-gopher-p address)
2354                      (= (length (elpher-gopher-address-selector address)) 0)))
2355             (error "Already at root directory of current server")
2356           (let ((address-copy (elpher-address-from-url
2357                                (elpher-address-to-url address))))
2358             (setf (url-filename address-copy) "")
2359             (elpher-go (elpher-address-to-url address-copy))))
2360       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2361
2362 (defun elpher-info-page (page)
2363   "Display URL of PAGE in minibuffer."
2364   (let* ((address (elpher-page-address page))
2365          (url (elpher-address-to-url address))
2366          (iri (elpher-address-to-iri address)))
2367     (if (equal url iri)
2368         (message "%s" url)
2369       (message "%s (Raw: %s)" iri url))))
2370
2371 (defun elpher-info-link ()
2372   "Display information on page corresponding to link at point."
2373   (interactive)
2374   (let ((button (button-at (point))))
2375     (unless button
2376       (error "No item selected"))
2377     (let ((page (button-get button 'elpher-page)))
2378       (unless page
2379         (error "Not an elpher page"))
2380       (elpher-info-page page))))
2381
2382 (defun elpher-info-current ()
2383   "Display information on current page."
2384   (interactive)
2385   (elpher-info-page elpher-current-page))
2386
2387 (defun elpher-copy-page-url (page)
2388   "Copy URL representation of address of PAGE to `kill-ring'."
2389   (let* ((address (elpher-page-address page))
2390          (url (elpher-address-to-url address)))
2391     (message "Copied \"%s\" to kill-ring/clipboard." url)
2392     (kill-new url)))
2393
2394 (defun elpher-copy-link-url ()
2395   "Copy URL of item at point to `kill-ring'."
2396   (interactive)
2397   (let ((button (button-at (point))))
2398     (unless button
2399       (error "No item selected"))
2400     (let ((page (button-get button 'elpher-page)))
2401       (unless page
2402         (error "Not an elpher page"))
2403       (elpher-copy-page-url page))))
2404
2405 (defun elpher-copy-current-url ()
2406   "Copy URL of current page to `kill-ring'."
2407   (interactive)
2408   (elpher-copy-page-url elpher-current-page))
2409
2410 (defun elpher-set-gopher-coding-system ()
2411   "Specify an explicit character coding system for gopher selectors."
2412   (interactive)
2413   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2414     (setq elpher-user-coding-system system)
2415     (if system
2416         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2417       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2418
2419
2420 ;;; Mode and keymap
2421 ;;
2422
2423 (defvar elpher-mode-map
2424   (let ((map (make-sparse-keymap)))
2425     (define-key map (kbd "TAB") 'elpher-next-link)
2426     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2427     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2428     (define-key map (kbd "u") 'elpher-back)
2429     (define-key map (kbd "-") 'elpher-back)
2430     (define-key map (kbd "^") 'elpher-back)
2431     (define-key map [mouse-3] 'elpher-back)
2432     (define-key map (kbd "U") 'elpher-back-to-start)
2433     (define-key map (kbd "g") 'elpher-go)
2434     (define-key map (kbd "o") 'elpher-go-current)
2435     (define-key map (kbd "O") 'elpher-root-dir)
2436     (define-key map (kbd "s") 'elpher-show-history)
2437     (define-key map (kbd "S") 'elpher-show-visited-pages)
2438     (define-key map (kbd "r") 'elpher-redraw)
2439     (define-key map (kbd "R") 'elpher-reload)
2440     (define-key map (kbd "T") 'elpher-toggle-tls)
2441     (define-key map (kbd ".") 'elpher-view-raw)
2442     (define-key map (kbd "d") 'elpher-download)
2443     (define-key map (kbd "D") 'elpher-download-current)
2444     (define-key map (kbd "m") 'elpher-jump)
2445     (define-key map (kbd "i") 'elpher-info-link)
2446     (define-key map (kbd "I") 'elpher-info-current)
2447     (define-key map (kbd "c") 'elpher-copy-link-url)
2448     (define-key map (kbd "C") 'elpher-copy-current-url)
2449     (define-key map (kbd "a") 'elpher-bookmark-link)
2450     (define-key map (kbd "A") 'elpher-bookmark-current)
2451     (define-key map (kbd "B") 'elpher-show-bookmarks)
2452     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2453     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2454     (when (fboundp 'evil-define-key*)
2455       (evil-define-key*
2456        'motion map
2457        (kbd "TAB") 'elpher-next-link
2458        (kbd "C-") 'elpher-follow-current-link
2459        (kbd "C-t") 'elpher-back
2460        (kbd "u") 'elpher-back
2461        (kbd "-") 'elpher-back
2462        (kbd "^") 'elpher-back
2463        [mouse-3] 'elpher-back
2464        (kbd "U") 'elpher-back-to-start
2465        (kbd "g") 'elpher-go
2466        (kbd "o") 'elpher-go-current
2467        (kbd "O") 'elpher-root-dir
2468        (kbd "s") 'elpher-show-history
2469        (kbd "S") 'elpher-show-visited-pages
2470        (kbd "r") 'elpher-redraw
2471        (kbd "R") 'elpher-reload
2472        (kbd "T") 'elpher-toggle-tls
2473        (kbd ".") 'elpher-view-raw
2474        (kbd "d") 'elpher-download
2475        (kbd "D") 'elpher-download-current
2476        (kbd "m") 'elpher-jump
2477        (kbd "i") 'elpher-info-link
2478        (kbd "I") 'elpher-info-current
2479        (kbd "c") 'elpher-copy-link-url
2480        (kbd "C") 'elpher-copy-current-url
2481        (kbd "a") 'elpher-bookmark-link
2482        (kbd "A") 'elpher-bookmark-current
2483        (kbd "B") 'elpher-show-bookmarks
2484        (kbd "!") 'elpher-set-gopher-coding-system
2485        (kbd "F") 'elpher-forget-current-certificate))
2486     map)
2487   "Keymap for gopher client.")
2488
2489 (define-derived-mode elpher-mode special-mode "elpher"
2490   "Major mode for elpher, an elisp gopher client.
2491
2492 This mode is automatically enabled by the interactive
2493 functions which initialize the client, namely
2494 `elpher', and `elpher-go'."
2495   (setq-local elpher-current-page nil)
2496   (setq-local elpher-history nil)
2497   (setq-local elpher-buffer-name (buffer-name))
2498   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2499   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2500
2501 (when (fboundp 'evil-set-initial-state)
2502   (evil-set-initial-state 'elpher-mode 'motion))
2503
2504
2505 ;;; Main start procedure
2506 ;;
2507
2508 ;;;###autoload
2509 (defun elpher (&optional arg)
2510   "Start elpher with default landing page.
2511 The buffer used for Elpher sessions is determined by the value of
2512 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2513 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2514 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2515 \\[execute-extended-command] elpher RET’) switches to the session with
2516 that number, creating it if necessary.  A non numeric prefix ARG means
2517 to create a new session.  Returns the buffer selected (or created)."
2518   (interactive "P")
2519   (let* ((name (default-value 'elpher-buffer-name))
2520          (buf (cond ((numberp arg)
2521                      (get-buffer-create (format "%s<%d>" name arg)))
2522                     (arg
2523                      (generate-new-buffer name))
2524                     (t
2525                      (get-buffer-create name)))))
2526     (pop-to-buffer-same-window buf)
2527     (unless (buffer-modified-p)
2528       (elpher-mode)
2529       (elpher-visit-page (elpher-make-start-page))
2530       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2531
2532 ;;; elpher.el ends here