elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.1
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.1"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (spartan elpher-get-spartan-page elpher-render-gemini "spt" elpher-spartan)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 ;; Face customizations
 245
 246 (defgroup elpher-faces nil
 247   "Elpher face customizations."
 248   :group 'elpher)
 249
 250 (defface elpher-index
 251   '((t :inherit font-lock-keyword-face))
 252   "Face used for directory type directory records.")
 253
 254 (defface elpher-text
 255   '((t :inherit bold))
 256   "Face used for text type directory records.")
 257
 258 (defface elpher-info
 259   '((t :inherit default))
 260   "Face used for info type directory records.")
 261
 262 (defface elpher-image
 263   '((t :inherit font-lock-string-face))
 264   "Face used for image type directory records.")
 265
 266 (defface elpher-search
 267   '((t :inherit warning))
 268   "Face used for search type directory records.")
 269
 270 (defface elpher-html
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for html type directory records.")
 273
 274 (defface elpher-gemini
 275   '((t :inherit font-lock-constant-face))
 276   "Face used for Gemini type directory records.")
 277
 278 (defface elpher-spartan
 279   '((t :inherit font-lock-constant-face))
 280   "Face used for Spartan type directory records.")
 281
 282 (defface elpher-other-url
 283   '((t :inherit font-lock-comment-face))
 284   "Face used for other URL type links records.")
 285
 286 (defface elpher-telnet
 287   '((t :inherit font-lock-function-name-face))
 288   "Face used for telnet type directory records.")
 289
 290 (defface elpher-binary
 291   '((t :inherit font-lock-doc-face))
 292   "Face used for binary type directory records.")
 293
 294 (defface elpher-unknown
 295   '((t :inherit error))
 296   "Face used for directory records with unknown/unsupported types.")
 297
 298 (defface elpher-margin-key
 299   '((t :inherit bold))
 300   "Face used for directory margin key.")
 301
 302 (defface elpher-margin-brackets
 303   '((t :inherit shadow))
 304   "Face used for brackets around directory margin key.")
 305
 306 (defface elpher-gemini-heading1
 307   '((t :inherit bold :height 1.8))
 308   "Face used for gemini heading level 1.")
 309
 310 (defface elpher-gemini-heading2
 311   '((t :inherit bold :height 1.5))
 312   "Face used for gemini heading level 2.")
 313
 314 (defface elpher-gemini-heading3
 315   '((t :inherit bold :height 1.2))
 316   "Face used for gemini heading level 3.")
 317
 318 (defface elpher-gemini-quoted
 319   '((t :inherit font-lock-doc-face))
 320   "Face used for gemini quoted texts.")
 321
 322 (defface elpher-gemini-preformatted-toggle
 323   '((t :inherit button))
 324   "Face used for buttons used to toggle display of preformatted text.")
 325
 326 ;;; Model
 327 ;;
 328
 329 ;; Address
 330
 331 ;; An elpher "address" object is either a url object or a symbol.
 332 ;; Addresses with the "about" type, corresponding to pages generated
 333 ;; dynamically for and by elpher.  All others represent pages which
 334 ;; rely on content retrieved over the network.
 335
 336 (defun elpher-address-from-url (url-string &optional default-scheme)
 337   "Create a ADDRESS object corresponding to the given URL-STRING.
 338 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 339 is not explicitly given."
 340   (let ((data (match-data))) ; Prevent parsing clobbering match data
 341     (unwind-protect
 342         (let ((url (url-generic-parse-url url-string)))
 343           (unless (and (not (url-fullness url)) (url-type url))
 344             (unless (url-type url)
 345               (setf (url-type url) default-scheme))
 346             (unless (url-host url)
 347               (let ((p (split-string (url-filename url) "/" nil nil)))
 348                 (setf (url-host url) (car p))
 349                 (setf (url-filename url)
 350                       (if (cdr p)
 351                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 352                         ""))))
 353             (when (not (string-empty-p (url-host url)))
 354               (setf (url-fullness url) t)
 355               (setf (url-host url) (puny-encode-domain (url-host url))))
 356             (when (or (equal "gopher" (url-type url))
 357                       (equal "gophers" (url-type url)))
 358               ;; Gopher defaults
 359               (when (or (equal (url-filename url) "")
 360                         (equal (url-filename url) "/"))
 361                 (setf (url-filename url) "/1")))
 362             (when (equal "gemini" (url-type url))
 363               ;; Gemini defaults
 364               (if (equal (url-filename url) "")
 365                   (setf (url-filename url) "/"))))
 366           (elpher-remove-redundant-ports url))
 367       (set-match-data data))))
 368
 369 (defun elpher-remove-redundant-ports (address)
 370   "Remove redundant port specifiers from ADDRESS.
 371 Here 'redundant' means that the specified port matches the default
 372 for that protocol, eg 70 for gopher."
 373   (if (and (not (elpher-address-about-p address))
 374            (eq (url-portspec address) ; (url-port) is too slow!
 375                (pcase (url-type address)
 376                  ("gemini" 1965)
 377                  ((or "gopher" "gophers") 70)
 378                  ("finger" 79)
 379                  (_ -1))))
 380       (setf (url-portspec address) nil))
 381   address)
 382
 383 (defun elpher-make-gopher-address (type selector host port &optional tls)
 384   "Create an ADDRESS object using gopher directory record attributes.
 385 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 386 If the optional attribute TLS is non-nil, the address will be marked as
 387 requiring gopher-over-TLS."
 388   (cond
 389    ((equal type ?i) nil)
 390    ((and (equal type ?h)
 391          (string-prefix-p "URL:" selector))
 392     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 393    ((equal type ?8)
 394     (elpher-address-from-url
 395      (concat "telnet"
 396              "://" host
 397              ":" (number-to-string port))))
 398    (t
 399     (elpher-address-from-url
 400      (concat "gopher" (if tls "s" "")
 401              "://" host
 402              ":" (number-to-string port)
 403              "/" (string type)
 404              selector)))))
 405
 406 (defun elpher-make-about-address (type)
 407   "Create an ADDRESS object corresponding to the given about address TYPE."
 408   (elpher-address-from-url (concat "about:" (symbol-name type))))
 409
 410 (defun elpher-address-to-url (address)
 411   "Get string representation of ADDRESS."
 412   (url-encode-url (url-recreate-url address)))
 413
 414 (defun elpher-address-type (address)
 415   "Retrieve type of ADDRESS object.
 416 This is used to determine how to retrieve and render the document the
 417 address refers to, via the table `elpher-type-map'."
 418   (pcase (url-type address)
 419     ("about"
 420      (list 'about (intern (url-filename address))))
 421     ((or "gopher" "gophers")
 422      (list 'gopher
 423            (if (member (url-filename address) '("" "/"))
 424                ?1
 425              (string-to-char (substring (url-filename address) 1)))))
 426     ("gemini" 'gemini)
 427     ("spartan" 'spartan)
 428     ("telnet" 'telnet)
 429     ("finger" 'finger)
 430     ("file" 'file)
 431     (_ 'other-url)))
 432
 433 (defun elpher-address-about-p (address)
 434   "Return non-nil if ADDRESS is an  about address."
 435   (pcase (elpher-address-type address) (`(about ,_) t)))
 436
 437 (defun elpher-address-gopher-p (address)
 438   "Return non-nill if ADDRESS object is a gopher address."
 439   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 440
 441 (defun elpher-address-protocol (address)
 442   "Retrieve the transport protocol for ADDRESS."
 443   (url-type address))
 444
 445 (defun elpher-address-filename (address)
 446   "Retrieve the filename component of ADDRESS.
 447 For gopher addresses this is a combination of the selector type and selector."
 448   (url-unhex-string (url-filename address)))
 449
 450 (defun elpher-address-host (address)
 451   "Retrieve host from ADDRESS object."
 452   (let ((host-pre (url-host address)))
 453     ;; The following strips out square brackets which sometimes enclose IPv6
 454     ;; addresses.  Doing this here rather than at the parsing stage may seem
 455     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 456     ;; and reconstruction.  It's also more efficient, as this method is not
 457     ;; called during page rendering.
 458     (if (and (> (length host-pre) 2)
 459              (eq (elt host-pre 0) ?\[)
 460              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 461         (substring host-pre 1 (- (length host-pre) 1))
 462       host-pre)))
 463
 464 (defun elpher-address-user (address)
 465   "Retrieve user from ADDRESS object."
 466   (url-user address))
 467
 468 (defun elpher-address-port (address)
 469   "Retrieve port from ADDRESS object.
 470 If no address is defined, returns 0.  (This is for compatibility with
 471 the URL library.)"
 472   (url-port address))
 473
 474 (defun elpher-gopher-address-selector (address)
 475   "Retrieve gopher selector from ADDRESS object."
 476   (if (member (url-filename address) '("" "/"))
 477       ""
 478     (url-unhex-string (substring (url-filename address) 2))))
 479
 480
 481 ;; Cache
 482
 483 (defvar elpher-content-cache (make-hash-table :test 'equal))
 484 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 485
 486 (defun elpher-get-cached-content (address)
 487   "Retrieve the cached content for ADDRESS, or nil if none exists."
 488   (gethash address elpher-content-cache))
 489
 490 (defun elpher-cache-content (address content)
 491   "Set the content cache for ADDRESS to CONTENT."
 492   (puthash address content elpher-content-cache))
 493
 494 (defun elpher-get-cached-pos (address)
 495   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 496   (gethash address elpher-pos-cache))
 497
 498 (defun elpher-cache-pos (address pos)
 499   "Set the cursor position cache for ADDRESS to POS."
 500   (puthash address pos elpher-pos-cache))
 501
 502
 503 ;; Page
 504
 505 (defun elpher-make-page (display-string address)
 506   "Create a page with DISPLAY-STRING and ADDRESS."
 507   (list display-string address))
 508
 509 (defun elpher-make-start-page ()
 510   "Create the start page."
 511   (elpher-make-page "Start Page"
 512                     (elpher-address-from-url elpher-start-page-url)))
 513
 514 (defun elpher-page-display-string (page)
 515   "Retrieve the display string corresponding to PAGE."
 516   (elt page 0))
 517
 518 (defun elpher-page-address (page)
 519   "Retrieve the address corresponding to PAGE."
 520   (elt page 1))
 521
 522 (defun elpher-page-set-address (page new-address)
 523   "Set the address corresponding to PAGE to NEW-ADDRESS."
 524   (setcar (cdr page) new-address))
 525
 526 (defun elpher-page-from-url (url &optional default-scheme)
 527   "Create a page with address and display string defined by URL.
 528 The URL is unhexed prior to its use as a display string to improve
 529 readability.
 530
 531 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 532 in the instance that URL itself doesn't specify one."
 533   (let ((address (elpher-address-from-url url default-scheme)))
 534     (elpher-make-page (elpher-address-to-iri address) address)))
 535
 536 (defun elpher-address-to-iri (address)
 537   "Return an IRI for ADDRESS.
 538 Decode percent-escapes and handle punycode in the domain name.
 539 Drop the password, if any."
 540   (let ((data (match-data)) ; Prevent parsing clobbering match data
 541         (host (url-host address))
 542         (pass (url-password address)))
 543     (unwind-protect
 544         (let* ((host (url-host address))
 545                (pass (url-password address)))
 546           (when host
 547             (setf (url-host address) (puny-decode-domain host)))
 548           (when pass                             ; RFC 3986 says we should not render
 549             (setf (url-password address) nil)) ; the password as clear text
 550           (elpher-decode (url-unhex-string (url-recreate-url address))))
 551       (setf (url-host address) host)
 552       (setf (url-password address) pass)
 553       (set-match-data data))))
 554
 555 (defvar elpher-current-page nil
 556   "The current page for this Elpher buffer.")
 557
 558 (defvar elpher-history nil
 559   "The local history stack for this Elpher buffer.
 560 This variable is used by `elpher-back' and
 561 `elpher-show-history'.")
 562
 563 (defvar elpher-visited-pages nil
 564   "The global history for all Elpher buffers.
 565 This variable is used by `elpher-show-visited-pages'.")
 566
 567 (defun elpher-visit-page (page &optional renderer no-history)
 568   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 569 Additionally, push PAGE onto the history stack and the list of
 570 previously-visited pages,unless NO-HISTORY is non-nil."
 571   (elpher-save-pos)
 572   (elpher-process-cleanup)
 573   (unless no-history
 574     (unless (or (not elpher-current-page)
 575                  (equal (elpher-page-address elpher-current-page)
 576                         (elpher-page-address page)))
 577       (push elpher-current-page elpher-history)
 578       (unless (or (elpher-address-about-p (elpher-page-address page))
 579                   (and elpher-visited-pages
 580                        (equal page (car elpher-visited-pages))))
 581         (push page elpher-visited-pages))))
 582   (setq-local elpher-current-page page)
 583   (let* ((address (elpher-page-address page))
 584          (type (elpher-address-type address))
 585          (type-record (cdr (assoc type elpher-type-map))))
 586     (if type-record
 587         (funcall (car type-record)
 588                  (if renderer
 589                      renderer
 590                    (cadr type-record)))
 591       (elpher-visit-previous-page)
 592       (pcase type
 593         (`(gopher ,type-char)
 594          (error "Unsupported gopher selector type '%c' for '%s'"
 595                 type-char (elpher-address-to-url address)))
 596         (other
 597          (error "Unsupported address type '%S' for '%s'"
 598                 other (elpher-address-to-url address)))))))
 599
 600 (defun elpher-visit-previous-page ()
 601   "Visit the previous page in the history."
 602   (if elpher-history
 603       (elpher-visit-page (pop elpher-history) nil t)
 604     (error "No previous page")))
 605
 606 (defun elpher-reload-current-page ()
 607   "Reload the current page, discarding any existing cached content."
 608   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 609   (elpher-visit-page elpher-current-page))
 610
 611 (defun elpher-save-pos ()
 612   "Save the current position of point to the current page."
 613   (when elpher-current-page
 614     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 615
 616 (defun elpher-restore-pos ()
 617   "Restore the position of point to that cached in the current page."
 618   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 619     (if pos
 620         (goto-char pos)
 621       (goto-char (point-min)))))
 622
 623 (defun elpher-get-default-url-scheme ()
 624   "Suggest default URL scheme for visiting addresses based on the current page."
 625   (if elpher-current-page
 626       (let* ((address (elpher-page-address elpher-current-page))
 627              (current-type (elpher-address-type address)))
 628         (pcase current-type
 629           ((or (and 'file (guard (not elpher-history)))
 630                `(about ,_))
 631            elpher-default-url-type)
 632           (_
 633            (url-type address))))
 634       elpher-default-url-type))
 635
 636
 637 ;;; Buffer preparation
 638 ;;
 639
 640 (defvar elpher-buffer-name "*elpher*"
 641   "The default name of the Elpher buffer.")
 642
 643 (defun elpher-update-header ()
 644   "If `elpher-use-header' is true, display current page info in window header."
 645   (if (and elpher-use-header elpher-current-page)
 646       (let* ((display-string (elpher-page-display-string elpher-current-page))
 647              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 648              (address (elpher-page-address elpher-current-page))
 649              (tls-string (if (and (not (elpher-address-about-p address))
 650                                   (member (elpher-address-protocol address)
 651                                           '("gophers" "gemini")))
 652                              " [TLS encryption]"
 653                            ""))
 654              (header (concat sanitized-display-string
 655                              (propertize tls-string 'face 'bold))))
 656         (setq header-line-format header))))
 657
 658 (defmacro elpher-with-clean-buffer (&rest args)
 659   "Evaluate ARGS with a clean *elpher* buffer as current."
 660   (declare (debug (body))) ;; Allow edebug to step through body
 661   `(with-current-buffer elpher-buffer-name
 662      (unless (eq major-mode 'elpher-mode)
 663        ;; avoid resetting buffer-local variables
 664        (elpher-mode))
 665      (let ((inhibit-read-only t)
 666            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 667        (setq-local xterm-color--current-fg nil)
 668        (setq-local xterm-color--current-bg nil)
 669        (setq-local network-security-level
 670                    (default-value 'network-security-level))
 671        (erase-buffer)
 672        (elpher-update-header)
 673        ,@args)))
 674
 675 (defun elpher-buffer-message (string &optional line)
 676   "Replace first line in elpher buffer with STRING.
 677 If LINE is non-nil, replace that line instead."
 678   (with-current-buffer elpher-buffer-name
 679     (let ((inhibit-read-only t))
 680       (goto-char (point-min))
 681       (if line
 682           (forward-line line))
 683       (let ((data (match-data)))
 684         (unwind-protect
 685             (progn
 686               (re-search-forward "^.*$")
 687               (replace-match string))
 688           (set-match-data data))))))
 689
 690
 691 ;;; Text Processing
 692 ;;
 693
 694 (defvar elpher-user-coding-system nil
 695   "User-specified coding system to use for decoding text responses.")
 696
 697 (defun elpher-decode (string)
 698   "Decode STRING using autodetected or user-specified coding system."
 699   (decode-coding-string string
 700                         (if elpher-user-coding-system
 701                             elpher-user-coding-system
 702                           (detect-coding-string string t))))
 703
 704 (defun elpher-preprocess-text-response (string)
 705   "Preprocess text selector response contained in STRING.
 706 This involes decoding the character representation, and clearing
 707 away CRs and any terminating period."
 708   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 709                                            (replace-regexp-in-string "\r" "" string))))
 710
 711 ;;; Buttonify urls
 712
 713 (defconst elpher-url-regex
 714   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 715   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 716
 717 (defun elpher-buttonify-urls (string)
 718   "Turn substrings which look like urls in STRING into clickable buttons."
 719   (with-temp-buffer
 720     (insert string)
 721     (goto-char (point-min))
 722     (while (re-search-forward elpher-url-regex nil t)
 723       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 724         (make-text-button (match-beginning 0)
 725                           (match-end 0)
 726                           'elpher-page  page
 727                           'action #'elpher-click-link
 728                           'follow-link t
 729                           'help-echo #'elpher--page-button-help
 730                           'face 'button)))
 731     (buffer-string)))
 732
 733 ;;; ANSI colors or XTerm colors (application and filtering)
 734
 735 (or (require 'xterm-color nil t)
 736     (require 'ansi-color))
 737
 738 (defalias 'elpher-color-filter-apply
 739   (if (fboundp 'xterm-color-filter)
 740       (lambda (s)
 741         (let ((_xterm-color-render nil))
 742           (xterm-color-filter s)))
 743     #'ansi-color-filter-apply)
 744   "A function to filter out ANSI escape sequences.")
 745
 746 (defalias 'elpher-color-apply
 747   (if (fboundp 'xterm-color-filter)
 748       #'xterm-color-filter
 749     #'ansi-color-apply)
 750   "A function to apply ANSI escape sequences.")
 751
 752 ;;; Processing text for display
 753
 754 (defun elpher-process-text-for-display (string)
 755   "Perform any desired processing of STRING prior to display as text.
 756 Currently includes buttonifying URLs and processing ANSI escape codes."
 757   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 758                              (elpher-color-filter-apply string)
 759                            (elpher-color-apply string))))
 760
 761
 762 ;;; Network error reporting
 763 ;;
 764
 765 (defun elpher-network-error (address error)
 766   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 767 ERROR can be either an error object or a string."
 768   (elpher-with-clean-buffer
 769    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 770            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 771            (if (stringp error) error (error-message-string error)) "\n"
 772            (propertize "\n----------------\n\n" 'face 'error)
 773            "Press 'u' to return to the previous page.")))
 774
 775
 776 ;;; General network communication
 777 ;;
 778
 779 (defvar elpher-network-timer nil
 780   "Timer used for network connections.")
 781
 782 (defvar elpher-use-tls nil
 783   "If non-nil, use TLS to communicate with gopher servers.")
 784
 785 (defvar elpher-client-certificate nil
 786   "If non-nil, contains client certificate details to use for TLS connections.")
 787
 788 (defun elpher-process-cleanup ()
 789   "Immediately shut down any extant elpher process and timers."
 790   (let ((p (get-process "elpher-process")))
 791     (if p (delete-process p)))
 792   (if (timerp elpher-network-timer)
 793       (cancel-timer elpher-network-timer)))
 794
 795 (defun elpher-make-network-timer (thunk)
 796   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 797 This is just a wraper around `run-at-time' which additionally sets the
 798 buffer-local variable `elpher-network-timer' to allow
 799 `elpher-process-cleanup' to also clear the timer."
 800   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 801     (setq-local elpher-network-timer timer)
 802     timer))
 803
 804 (defun elpher-get-host-response (address default-port query-string response-processor
 805                                          &optional use-tls force-ipv4)
 806   "Generic function for retrieving data from ADDRESS.
 807
 808 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 809 QUERY-STRING is a string sent to the host specified by ADDRESS to
 810 illicet a response.  This response is passed as an argument to the
 811 function RESPONSE-PROCESSOR.
 812
 813 If non-nil, USE-TLS specifies that the connection is to be made over
 814 TLS.  If set to gemini, the certificate verification will be disabled
 815 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 816
 817 If non-nil, FORCE-IPV4 causes the network connection to be made over
 818 ipv4 only.  (The default behaviour when this is not set depends on
 819 the host operating system and the local network capabilities.)"
 820   (if (and use-tls (not (gnutls-available-p)))
 821       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 822     (unless (< (elpher-address-port address) 65536)
 823       (error "Cannot establish network connection: port number > 65536"))
 824     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 825       (setq-local network-security-level 'low)
 826       (setq-local gnutls-verify-error nil))
 827     (condition-case nil
 828         (let* ((kill-buffer-query-functions nil)
 829                (port (elpher-address-port address))
 830                (host (elpher-address-host address))
 831                (service (if (> port 0) port default-port))
 832                (response-string-parts nil)
 833                (bytes-received 0)
 834                (hkbytes-received 0)
 835                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 836                (gnutls-params (list :type 'gnutls-x509pki
 837                                     :hostname host
 838                                     :keylist
 839                                     (elpher-get-current-keylist address)))
 840                (timer (elpher-make-network-timer
 841                                    (lambda ()
 842                                      (elpher-process-cleanup)
 843                                      (cond
 844                                         ; Try again with IPv4
 845                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 846                                        (message "Connection timed out.  Retrying with IPv4.")
 847                                        (elpher-get-host-response address default-port
 848                                                                  query-string
 849                                                                  response-processor
 850                                                                  use-tls t))
 851                                       ((and use-tls
 852                                             (not (eq use-tls 'gemini))
 853                                             (or elpher-auto-disengage-TLS
 854                                                 (y-or-n-p
 855                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 856                                        (setq elpher-use-tls nil)
 857                                        (elpher-get-host-response address default-port
 858                                                                  query-string
 859                                                                  response-processor
 860                                                                  nil force-ipv4))
 861                                       (t
 862                                        (elpher-network-error address "Connection time-out."))))))
 863                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 864                        (make-network-process :name "elpher-process"
 865                                              :host host
 866                                              :family (and (or force-ipv4
 867                                                               elpher-ipv4-always)
 868                                                           'ipv4)
 869                                              :service service
 870                                              :buffer nil
 871                                              :nowait t
 872                                              :tls-parameters
 873                                              (and use-tls
 874                                                   (cons 'gnutls-x509pki
 875                                                         (apply #'gnutls-boot-parameters
 876                                                                gnutls-params)))))))
 877           (setq elpher-network-timer timer)
 878           (set-process-coding-system proc 'binary 'binary)
 879           (set-process-query-on-exit-flag proc nil)
 880           (elpher-buffer-message (concat "Connecting to " host "..."
 881                                          " (press 'u' to abort)"))
 882           (set-process-filter proc
 883                               (lambda (_proc string)
 884                                 (when timer
 885                                   (cancel-timer timer)
 886                                   (setq timer nil))
 887                                 (setq bytes-received (+ bytes-received (length string)))
 888                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 889                                   (when (> new-hkbytes-received hkbytes-received)
 890                                     (setq hkbytes-received new-hkbytes-received)
 891                                     (elpher-buffer-message
 892                                      (concat "("
 893                                              (number-to-string (/ hkbytes-received 10.0))
 894                                              " MB read)")
 895                                      1)))
 896                                 (setq response-string-parts
 897                                       (cons string response-string-parts))))
 898           (set-process-sentinel proc
 899                                 (lambda (proc event)
 900                                   (when timer
 901                                     (cancel-timer timer))
 902                                   (condition-case the-error
 903                                       (cond
 904                                        ((string-prefix-p "open" event)    ; request URL
 905                                         (elpher-buffer-message
 906                                          (concat "Connected to " host ". Receiving data..."
 907                                                  " (press 'u' to abort)"))
 908                                         (let ((inhibit-eol-conversion t))
 909                                           (process-send-string proc query-string)))
 910                                        ((string-prefix-p "deleted" event)) ; do nothing
 911                                        ((and (not response-string-parts)
 912                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 913                                         ; Try again with IPv4
 914                                         (message "Connection failed. Retrying with IPv4.")
 915                                         (elpher-get-host-response address default-port
 916                                                                   query-string
 917                                                                   response-processor
 918                                                                   use-tls t))
 919                                        (response-string-parts
 920                                         (elpher-with-clean-buffer
 921                                          (insert "Data received.  Rendering..."))
 922                                         (funcall response-processor
 923                                                  (apply #'concat (reverse response-string-parts)))
 924                                         (elpher-restore-pos))
 925                                        (t
 926                                         (error "No response from server")))
 927                                     (error
 928                                      (elpher-network-error address the-error)))))
 929           (when socks
 930             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 931             (funcall (process-sentinel proc) proc "open\n")))
 932       (error
 933        (elpher-process-cleanup)
 934        (error "Error initiating connection to server")))))
 935
 936
 937 ;;; Client-side TLS Certificate Management
 938 ;;
 939
 940 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 941   "Generate a key and a self-signed client TLS certificate using openssl.
 942
 943 The Common Name field of the certificate is set to COMMON-NAME.  The
 944 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 945 the key and certificate files to write.
 946
 947 If TEMPORARY is non-nil, the certificate will be given an exporation
 948 period of one day, and the key and certificate files will be deleted
 949 when the certificate is no longer needed for the current session.
 950
 951 Otherwise, the certificate will be given a 100 year expiration period
 952 and the files will not be deleted.
 953
 954 The function returns a list containing the current host name, the
 955 temporary flag, and the key and cert file names in the form required
 956 by `gnutls-boot-parameters`."
 957   (let ((exp-key-file (expand-file-name key-file))
 958         (exp-cert-file (expand-file-name cert-file)))
 959     (condition-case nil
 960         (progn
 961           (call-process elpher-openssl-command nil nil nil
 962                         "req" "-x509" "-newkey" "rsa:2048"
 963                         "-days" (if temporary "1" "36500")
 964                         "-nodes"
 965                         "-subj" (concat "/CN=" common-name)
 966                         "-keyout" exp-key-file
 967                         "-out" exp-cert-file)
 968           (list (elpher-address-host (elpher-page-address elpher-current-page))
 969                 temporary exp-key-file exp-cert-file))
 970       (error
 971        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 972        (error "Program 'openssl', required for certificate generation, not found")))))
 973
 974 (defun elpher-generate-throwaway-certificate ()
 975   "Generate and return details of a throwaway certificate.
 976 The key and certificate files will be deleted when they are no
 977 longer needed for this session."
 978   (let* ((file-base (make-temp-name "elpher"))
 979          (key-file (concat temporary-file-directory file-base ".key"))
 980          (cert-file (concat temporary-file-directory file-base ".crt")))
 981     (elpher-generate-certificate file-base key-file cert-file t)))
 982
 983 (defun elpher-generate-persistent-certificate (file-base common-name)
 984   "Generate and return details of a persistent certificate.
 985 The argument FILE-BASE is used as the base for the key and certificate
 986 files, while COMMON-NAME specifies the common name field of the
 987 certificate.
 988
 989 The key and certificate files are written to in `elpher-certificate-directory'."
 990   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 991          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 992     (elpher-generate-certificate common-name key-file cert-file)))
 993
 994 (defun elpher-get-existing-certificate (file-base)
 995   "Return a certificate object corresponding to an existing certificate.
 996 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 997 the directory `elpher-certificate-directory'."
 998   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 999          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1000     (list (elpher-address-host (elpher-page-address elpher-current-page))
1001           nil
1002           (expand-file-name key-file)
1003           (expand-file-name cert-file))))
1004
1005 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1006   "Install a key+certificate file pair in `elpher-certificate-directory'.
1007 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1008 certificate files to install.  The argument FILE-BASE is used as the
1009 base for the installed key and certificate files."
1010   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1011          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1012     (if (or (file-exists-p key-file)
1013             (file-exists-p cert-file))
1014         (error "A certificate with base name %s is already installed" file-base))
1015     (copy-file key-file-src key-file)
1016     (copy-file cert-file-src cert-file)
1017     (list (elpher-address-host (elpher-page-address elpher-current-page))
1018           nil
1019           (expand-file-name key-file)
1020           (expand-file-name cert-file))))
1021
1022 (defun elpher-list-existing-certificates ()
1023   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1024   (unless (file-directory-p elpher-certificate-directory)
1025     (make-directory elpher-certificate-directory))
1026   (mapcar
1027    (lambda (file)
1028      (file-name-sans-extension file))
1029    (directory-files elpher-certificate-directory nil "\\.key$")))
1030
1031 (defun elpher-forget-current-certificate ()
1032   "Causes any current certificate to be forgotten.)
1033 In the case of throwaway certificates, the key and certificate files
1034 are also deleted."
1035   (interactive)
1036   (when elpher-client-certificate
1037     (unless (and (called-interactively-p 'any)
1038                  (not (y-or-n-p (concat "Really forget client certificate? "
1039                                         "(Throwaway certificates will be deleted.)"))))
1040       (when (cadr elpher-client-certificate)
1041         (delete-file (elt elpher-client-certificate 2))
1042         (delete-file (elt elpher-client-certificate 3)))
1043       (setq elpher-client-certificate nil)
1044       (if (called-interactively-p 'any)
1045           (message "Client certificate forgotten.")))))
1046
1047 (defun elpher-get-current-keylist (address)
1048   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1049
1050 This is obtained from the client certificate described by
1051 `elpher-current-certificate', if one is available and the host for
1052 that certificate matches the host in ADDRESS.
1053
1054 If `elpher-current-certificate' is non-nil, and its host name doesn't
1055 match that of ADDRESS, the certificate is forgotten."
1056   (if elpher-client-certificate
1057       (if (string= (car elpher-client-certificate)
1058                    (elpher-address-host address))
1059           (list (cddr elpher-client-certificate))
1060         (elpher-forget-current-certificate)
1061         (message "Disabling client certificate for new host")
1062         nil)
1063     nil))
1064
1065
1066 ;;; Gopher selector retrieval
1067 ;;
1068
1069 (defun elpher-get-gopher-response (address renderer)
1070   "Get response string from gopher server at ADDRESS and render using RENDERER."
1071   (elpher-get-host-response address 70
1072                             (concat (elpher-gopher-address-selector address) "\r\n")
1073                             renderer
1074                             (or (string= (elpher-address-protocol address) "gophers")
1075                                 elpher-use-tls)))
1076
1077 (defun elpher-get-gopher-page (renderer)
1078   "Getter function for gopher pages.
1079 The RENDERER procedure is used to display the contents of the page
1080 once they are retrieved from the gopher server."
1081   (let* ((address (elpher-page-address elpher-current-page))
1082          (content (elpher-get-cached-content address)))
1083     (if (and content (funcall renderer nil))
1084         (elpher-with-clean-buffer
1085          (insert content)
1086          (elpher-restore-pos))
1087       (elpher-with-clean-buffer
1088        (insert "LOADING... (use 'u' to cancel)\n"))
1089       (condition-case the-error
1090           (elpher-get-gopher-response address renderer)
1091         (error
1092          (elpher-network-error address the-error))))))
1093
1094 ;; Index rendering
1095
1096 (defun elpher-insert-margin (&optional type-name)
1097   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1098   (if type-name
1099       (progn
1100         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1101                         (concat
1102                          (propertize "[" 'face 'elpher-margin-brackets)
1103                          (propertize type-name 'face 'elpher-margin-key)
1104                          (propertize "]" 'face 'elpher-margin-brackets))))
1105         (insert " "))
1106     (insert (make-string elpher-margin-width ?\s))))
1107
1108 (defun elpher--page-button-help (_window buffer pos)
1109   "Function called by Emacs to generate mouse-over text.
1110 The arguments specify the BUFFER and the POS within the buffer of the item
1111 for which help is required.  The function returns the help to be
1112 displayed.  The _WINDOW argument is currently unused."
1113   (with-current-buffer buffer
1114     (let ((button (button-at pos)))
1115       (when button
1116         (let* ((page (button-get button 'elpher-page))
1117                (address (elpher-page-address page)))
1118           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1119
1120 (defun elpher-insert-index-record (display-string &optional address)
1121   "Function to insert an index record into the current buffer.
1122 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1123 If ADDRESS is not supplied or nil the record is rendered as an
1124 'information' line."
1125   (let* ((type (if address (elpher-address-type address) nil))
1126          (type-map-entry (cdr (assoc type elpher-type-map))))
1127     (if type-map-entry
1128         (let* ((margin-code (elt type-map-entry 2))
1129                (face (elt type-map-entry 3))
1130                (filtered-display-string (elpher-color-filter-apply display-string))
1131                (page (elpher-make-page filtered-display-string address)))
1132           (elpher-insert-margin margin-code)
1133           (insert-text-button filtered-display-string
1134                               'face face
1135                               'elpher-page page
1136                               'action #'elpher-click-link
1137                               'follow-link t
1138                               'help-echo #'elpher--page-button-help))
1139       (pcase type
1140         ('nil ;; Information
1141          (elpher-insert-margin)
1142          (let ((propertized-display-string
1143                 (propertize display-string 'face 'elpher-info)))
1144            (insert (elpher-process-text-for-display propertized-display-string))))
1145         (`(gopher ,selector-type) ;; Unknown
1146          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1147          (insert (propertize display-string
1148                              'face 'elpher-unknown)))))
1149     (insert "\n")))
1150
1151 (defun elpher-click-link (button)
1152   "Function called when the gopher link BUTTON is activated."
1153   (let ((page (button-get button 'elpher-page)))
1154     (elpher-visit-page page)))
1155
1156 (defun elpher-render-index (data &optional _mime-type-string)
1157   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1158   (elpher-with-clean-buffer
1159    (if (not data)
1160        t
1161      (let ((data-processed (elpher-preprocess-text-response data)))
1162        (dolist (line (split-string data-processed "\n"))
1163          (ignore-errors
1164            (unless (= (length line) 0)
1165              (let* ((type (elt line 0))
1166                     (fields (split-string (substring line 1) "\t"))
1167                     (display-string (elt fields 0))
1168                     (selector (elt fields 1))
1169                     (host (elt fields 2))
1170                     (port (if (elt fields 3)
1171                               (string-to-number (elt fields 3))
1172                             nil))
1173                     (address (elpher-make-gopher-address type selector host port)))
1174                (elpher-insert-index-record display-string address))))))
1175      (elpher-cache-content (elpher-page-address elpher-current-page)
1176                            (buffer-string)))))
1177
1178 ;; Text rendering
1179
1180 (defun elpher-render-text (data &optional _mime-type-string)
1181   "Render DATA as text.  MIME-TYPE-STRING is unused."
1182   (elpher-with-clean-buffer
1183    (if (not data)
1184        t
1185      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1186      (elpher-cache-content
1187       (elpher-page-address elpher-current-page)
1188       (buffer-string)))))
1189
1190 ;; Image retrieval
1191
1192 (defun elpher-render-image (data &optional _mime-type-string)
1193   "Display DATA as image.  MIME-TYPE-STRING is unused."
1194   (if (not data)
1195       nil
1196     (if (display-images-p)
1197         (let* ((image (create-image
1198                        data
1199                        nil t)))
1200           (if (not image)
1201               (error "Unsupported image format")
1202             (let ((window (get-buffer-window elpher-buffer-name)))
1203               (when window
1204                 (setf (image-property image :max-width) (window-body-width window t))
1205                 (setf (image-property image :max-height) (window-body-height window t))))
1206             (elpher-with-clean-buffer
1207              (insert-image image)
1208              (elpher-restore-pos))))
1209       (elpher-render-download data))))
1210
1211 ;; Search retrieval and rendering
1212
1213 (defun elpher-get-gopher-query-page (renderer)
1214   "Getter for gopher addresses requiring input.
1215 The response is rendered using the rendering function RENDERER."
1216   (let* ((address (elpher-page-address elpher-current-page))
1217          (content (elpher-get-cached-content address))
1218          (aborted t))
1219     (if (and content (funcall renderer nil))
1220         (elpher-with-clean-buffer
1221          (insert content)
1222          (elpher-restore-pos)
1223          (message "Displaying cached search results.  Reload to perform a new search."))
1224       (unwind-protect
1225           (let* ((query-string (read-string "Query: "))
1226                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1227                  (search-address (elpher-make-gopher-address ?1
1228                                                              query-selector
1229                                                              (elpher-address-host address)
1230                                                              (elpher-address-port address)
1231                                                              (equal (elpher-address-type address) "gophers"))))
1232             (setq aborted nil)
1233
1234             (elpher-with-clean-buffer
1235              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1236             (elpher-get-gopher-response search-address renderer))
1237         (if aborted
1238             (elpher-visit-previous-page))))))
1239
1240 ;; Raw server response rendering
1241
1242 (defun elpher-render-raw (data &optional mime-type-string)
1243   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1244   (if (not data)
1245       nil
1246     (elpher-with-clean-buffer
1247      (when mime-type-string
1248        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1249      (insert data)
1250      (goto-char (point-min)))
1251     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1252
1253 ;; File save "rendering"
1254
1255 (defun elpher-render-download (data &optional _mime-type-string)
1256   "Save DATA to file.  MIME-TYPE-STRING is unused."
1257   (if (not data)
1258       nil
1259     (let* ((address (elpher-page-address elpher-current-page))
1260            (selector (if (elpher-address-gopher-p address)
1261                          (elpher-gopher-address-selector address)
1262                        (elpher-address-filename address))))
1263       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1264       (let* ((filename-proposal (file-name-nondirectory selector))
1265              (filename (read-file-name "Download complete. Save file as: "
1266                                        nil nil nil
1267                                        (if (> (length filename-proposal) 0)
1268                                            filename-proposal
1269                                          "download.file"))))
1270         (let ((coding-system-for-write 'binary))
1271           (with-temp-file filename
1272             (insert data)))
1273         (message (format "Saved to file %s." filename))))))
1274
1275 ;; HTML rendering
1276
1277 (defun elpher-render-html (data &optional _mime-type-string)
1278   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1279   (elpher-with-clean-buffer
1280    (if (not data)
1281        t
1282      (let ((dom (with-temp-buffer
1283                   (insert data)
1284                   (libxml-parse-html-region (point-min) (point-max)))))
1285        (shr-insert-document dom)))))
1286
1287 ;; Gemini page retrieval
1288
1289 (defvar elpher-gemini-redirect-chain)
1290
1291 (defun elpher-get-gemini-response (address renderer)
1292   "Get response string from gemini server at ADDRESS and render using RENDERER."
1293   (elpher-get-host-response address 1965
1294                             (concat (elpher-address-to-url address) "\r\n")
1295                             (lambda (response-string)
1296                               (elpher-process-gemini-response response-string renderer))
1297                             'gemini))
1298
1299 (defun elpher-parse-gemini-response (response)
1300   "Parse the RESPONSE string and return a list of components.
1301 The list is of the form (code meta body).  A response of nil implies
1302 that the response was malformed."
1303   (let ((header-end-idx (string-match "\r\n" response)))
1304     (if header-end-idx
1305         (let ((header (string-trim (substring response 0 header-end-idx)))
1306               (body (substring response (+ header-end-idx 2))))
1307           (if (>= (length header) 2)
1308               (let ((code (substring header 0 2))
1309                     (meta (string-trim (substring header 2))))
1310                 (list code meta body))
1311             (error "Malformed response: No response status found in header %s" header)))
1312       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1313
1314 (defun elpher-process-gemini-response (response-string renderer)
1315   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1316   (let ((response-components (elpher-parse-gemini-response response-string)))
1317     (let ((response-code (elt response-components 0))
1318           (response-meta (elt response-components 1))
1319           (response-body (elt response-components 2)))
1320       (pcase (elt response-code 0)
1321         (?1 ; Input required
1322          (elpher-with-clean-buffer
1323           (insert "Gemini server is requesting input."))
1324          (let* ((query-string
1325                  (if (eq (elt response-code 1) ?1)
1326                      (read-passwd (concat response-meta ": "))
1327                    (read-string (concat response-meta ": "))))
1328                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1329                 (old-fname (url-filename query-address)))
1330            (setf (url-filename query-address)
1331                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1332            (elpher-get-gemini-response query-address renderer)))
1333         (?2 ; Normal response
1334          (funcall renderer response-body response-meta))
1335         (?3 ; Redirect
1336          (message "Following redirect to %s" response-meta)
1337          (if (>= (length elpher-gemini-redirect-chain) 5)
1338              (error "More than 5 consecutive redirects followed"))
1339          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1340            (if (member redirect-address elpher-gemini-redirect-chain)
1341                (error "Redirect loop detected"))
1342            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1343                (error "Server tried to automatically redirect to non-gemini URL: %s"
1344                       response-meta))
1345            (elpher-page-set-address elpher-current-page redirect-address)
1346            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1347            (elpher-get-gemini-response redirect-address renderer)))
1348         (?4 ; Temporary failure
1349          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1350                 response-code response-meta))
1351         (?5 ; Permanent failure
1352          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1353                 response-code response-meta))
1354         (?6 ; Client certificate required
1355          (elpher-with-clean-buffer
1356           (if elpher-client-certificate
1357               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1358             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1359           (auto-fill-mode 1)
1360           (elpher-gemini-insert-text response-meta))
1361          (let ((chosen-certificate (elpher-choose-client-certificate)))
1362            (unless chosen-certificate
1363              (error "Gemini server requires a client certificate and none was provided"))
1364            (setq elpher-client-certificate chosen-certificate))
1365          (elpher-with-clean-buffer)
1366          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1367         (_other
1368          (error "Gemini server response unknown: %s %s"
1369                 response-code response-meta))))))
1370
1371 (defun elpher--read-answer-polyfill (question answers)
1372   "Polyfill for `read-answer' in Emacs 26.1.
1373 QUESTION is a string containing a question, and ANSWERS
1374 is a list of possible answers."
1375     (completing-read question (mapcar 'identity answers)))
1376
1377 (if (fboundp 'read-answer)
1378     (defalias 'elpher-read-answer 'read-answer)
1379   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1380
1381 (defun elpher-choose-client-certificate ()
1382   "Prompt for a client certificate to use to establish a TLS connection."
1383   (let* ((read-answer-short t))
1384     (pcase (read-answer "What do you want to do? "
1385                         '(("throwaway" ?t
1386                            "generate and use throw-away certificate")
1387                           ("persistent" ?p
1388                            "generate new or use existing persistent certificate")
1389                           ("abort" ?a
1390                            "stop immediately")))
1391       ("throwaway"
1392        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1393       ("persistent"
1394        (let* ((existing-certificates (elpher-list-existing-certificates))
1395               (file-base (completing-read
1396                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1397                           existing-certificates)))
1398          (if (string-empty-p (string-trim file-base))
1399              nil
1400            (if (member file-base existing-certificates)
1401                (setq elpher-client-certificate
1402                      (elpher-get-existing-certificate file-base))
1403              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1404                                  '(("new" ?n
1405                                     "generate new certificate")
1406                                    ("install" ?i
1407                                     "install existing certificate")
1408                                    ("abort" ?a
1409                                     "stop immediately")))
1410                ("new"
1411                 (let ((common-name (read-string "Common Name field for new certificate: "
1412                                                 file-base)))
1413                   (message "New key and self-signed certificate written to %s"
1414                            elpher-certificate-directory)
1415                   (elpher-generate-persistent-certificate file-base common-name)))
1416                ("install"
1417                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1418                        (key-file (read-file-name "Key file: " nil nil t)))
1419                   (message "Key and certificate installed in %s for future use"
1420                            elpher-certificate-directory)
1421                   (elpher-install-and-use-existing-certificate key-file
1422                                                                cert-file
1423                                                                file-base)))
1424                ("abort" nil))))))
1425       ("abort" nil))))
1426
1427 (defun elpher-get-gemini-page (renderer)
1428   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1429   (let* ((address (elpher-page-address elpher-current-page))
1430          (content (elpher-get-cached-content address)))
1431     (condition-case the-error
1432         (if (and content (funcall renderer nil))
1433             (elpher-with-clean-buffer
1434              (insert content)
1435              (elpher-restore-pos))
1436           (elpher-with-clean-buffer
1437            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1438           (setq elpher-gemini-redirect-chain nil)
1439           (elpher-get-gemini-response address renderer))
1440       (error
1441        (elpher-network-error address the-error)))))
1442
1443 (defun elpher-render-gemini (body &optional mime-type-string)
1444   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1445   (if (not body)
1446       t
1447     (let* ((mime-type-string* (if (or (not mime-type-string)
1448                                       (string-empty-p mime-type-string))
1449                                   "text/gemini; charset=utf-8"
1450                                 mime-type-string))
1451            (mime-type-split (split-string mime-type-string* ";" t))
1452            (mime-type (string-trim (car mime-type-split)))
1453            (parameters (mapcar (lambda (s)
1454                                  (let ((key-val (split-string s "=")))
1455                                    (list (downcase (string-trim (car key-val)))
1456                                          (downcase (string-trim (cadr key-val))))))
1457                                (cdr mime-type-split))))
1458       (when (string-prefix-p "text/" mime-type)
1459         (setq body (decode-coding-string
1460                     body
1461                     (if (assoc "charset" parameters)
1462                         (intern (cadr (assoc "charset" parameters)))
1463                       'utf-8)))
1464         (setq body (replace-regexp-in-string "\r" "" body)))
1465       (pcase mime-type
1466         ((or "text/gemini" "")
1467          (elpher-render-gemini-map body parameters))
1468         ("text/html"
1469          (elpher-render-html body))
1470         ((pred (string-prefix-p "text/"))
1471          (elpher-render-gemini-plain-text body parameters))
1472         ((pred (string-prefix-p "image/"))
1473          (elpher-render-image body))
1474         (_other
1475          (elpher-render-download body))))))
1476
1477 (defun elpher-gemini-get-link-url (link-line)
1478   "Extract the url portion of LINK-LINE, a gemini map file link line.
1479 Returns nil in the event that the contents of the line following the
1480 => prefix are empty."
1481   (let ((l (split-string (substring link-line 2))))
1482     (if l
1483         (string-trim (elt l 0))
1484       nil)))
1485
1486 (defun elpher-gemini-get-link-display-string (link-line)
1487   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1488 Return nil if this portion is not provided."
1489   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1490          (idx (string-match "[ \t]" rest)))
1491     (and idx
1492          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1493
1494 (defun elpher-collapse-dot-sequences (filename)
1495   "Collapse dot sequences in the (absolute) FILENAME.
1496 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1497   (let* ((path (split-string filename "/" t))
1498          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1499          (path-reversed-normalized
1500           (seq-reduce (lambda (a b)
1501                         (cond ((equal b "..") (cdr a))
1502                               ((equal b ".") a)
1503                               (t (cons b a))))
1504                       path nil))
1505          (path-normalized (reverse path-reversed-normalized)))
1506     (if path-normalized
1507         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1508       "/")))
1509
1510 (defun elpher-address-from-gemini-url (url)
1511   "Extract address from URL with defaults as per gemini map files.
1512 While there's obviously some redundancy here between this function and
1513 `elpher-address-from-url', gemini map file URLs require enough special
1514 treatment that a separate function is warranted."
1515   (let ((address (url-generic-parse-url url))
1516         (current-address (elpher-page-address elpher-current-page)))
1517     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1518       (if (url-host address) ;if there is an explicit host, filenames are absolute
1519           (if (string-empty-p (url-filename address))
1520               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1521         (setf (url-host address) (url-host current-address))
1522         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1523         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1524         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1525           (setf (url-filename address)
1526                 (concat (file-name-directory (url-filename current-address))
1527                         (url-filename address)))))
1528       (when (url-host address)
1529         (setf (url-host address) (puny-encode-domain (url-host address))))
1530       (unless (url-type address)
1531         (setf (url-type address) (url-type current-address)))
1532       (when (equal (url-type address) "gemini")
1533         (setf (url-filename address)
1534               (elpher-collapse-dot-sequences (url-filename address)))))
1535     (elpher-remove-redundant-ports address)))
1536
1537 (defun elpher-gemini-insert-link (link-line)
1538   "Insert link described by LINK-LINE into a text/gemini document."
1539   (let ((url (elpher-gemini-get-link-url link-line)))
1540     (when url
1541       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1542              (address (elpher-address-from-gemini-url url))
1543              (type (if address (elpher-address-type address) nil))
1544              (type-map-entry (cdr (assoc type elpher-type-map)))
1545              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1546         (when type-map-entry
1547           (insert elpher-gemini-link-string)
1548           (let* ((face (elt type-map-entry 3))
1549                  (display-string (or given-display-string
1550                                      (elpher-address-to-iri address)))
1551                  (page (elpher-make-page display-string
1552                                          address)))
1553             (insert-text-button display-string
1554                                 'face face
1555                                 'elpher-page page
1556                                 'action #'elpher-click-link
1557                                 'follow-link t
1558                                 'help-echo #'elpher--page-button-help))
1559           (newline))))))
1560
1561 (defun elpher-gemini-insert-header (header-line)
1562   "Insert header described by HEADER-LINE into a text/gemini document.
1563 The gemini map file line describing the header is given
1564 by HEADER-LINE."
1565   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1566     (let* ((level (length (match-string 1 header-line)))
1567            (header (substring header-line (match-end 0)))
1568            (face (pcase level
1569                    (1 'elpher-gemini-heading1)
1570                    (2 'elpher-gemini-heading2)
1571                    (3 'elpher-gemini-heading3)
1572                    (_ 'default)))
1573            (fill-column (if (display-graphic-p)
1574                             (/ (* fill-column
1575                                   (font-get (font-spec :name (face-font 'default)) :size))
1576                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1577       (unless (display-graphic-p)
1578         (insert (make-string level ?#) " "))
1579       (insert (propertize header
1580                           'face face
1581                           'gemini-heading t
1582                           'rear-nonsticky t))
1583       (newline))))
1584
1585 (defun elpher-gemini-insert-text (text-line)
1586   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1587 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1588 width defined by `elpher-gemini-max-fill-width'."
1589   (string-match
1590    (rx (: line-start
1591           (optional
1592            (group (or (: "*" (+ (any " \t")))
1593                       (: ">" (* (any " \t"))))))))
1594    text-line)
1595   (let* ((line-prefix (match-string 1 text-line))
1596          (processed-text-line
1597           (if line-prefix
1598               (cond ((string-prefix-p "*" line-prefix)
1599                      (concat
1600                       (replace-regexp-in-string "\\*"
1601                                                 elpher-gemini-bullet-string
1602                                                 (match-string 0 text-line))
1603                       (substring text-line (match-end 0))))
1604                     ((string-prefix-p ">" line-prefix)
1605                      (propertize text-line 'face 'elpher-gemini-quoted))
1606                     (t text-line))
1607             text-line))
1608          (fill-prefix (if line-prefix
1609                           (make-string (length (match-string 0 text-line)) ?\s)
1610                         "")))
1611     (insert (elpher-process-text-for-display processed-text-line))
1612     (newline)))
1613
1614 (defun elpher-gemini-pref-expand-collapse (button)
1615   "Function called when the preformatted text toggle BUTTON is activated."
1616   (let ((id (button-get button 'pref-id)))
1617     (if (invisible-p id)
1618         (remove-from-invisibility-spec id)
1619       (add-to-invisibility-spec id))
1620     (redraw-display)))
1621
1622 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1623   "Insert a button for toggling the visibility of preformatted text.
1624 If non-nil, ALT-TEXT is displayed alongside the button."
1625   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1626          (pref-id (intern (concat "pref-"
1627                                   (number-to-string (point))
1628                                   "-"
1629                                   url-string))))
1630     (insert elpher-gemini-preformatted-toggle-bullet)
1631     (when alt-text
1632       (insert (propertize (concat alt-text " ")
1633                           'face 'elpher-gemin-preformatted)))
1634     (insert-text-button elpher-gemini-preformatted-toggle-label
1635                         'action #'elpher-gemini-pref-expand-collapse
1636                         'pref-id pref-id
1637                         'face 'elpher-gemini-preformatted-toggle)
1638     (add-to-invisibility-spec pref-id)
1639     (newline)
1640     pref-id))
1641
1642 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1643   "Insert a LINE of preformatted text.
1644 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1645 can be used to toggle the display of the preformatted text."
1646   (insert (propertize (concat (elpher-process-text-for-display line) "\n")
1647                       'invisible pref-id
1648                       'rear-nonsticky t)))
1649
1650 (defun elpher-render-gemini-map (data _parameters)
1651   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1652   (elpher-with-clean-buffer
1653    (auto-fill-mode 1)
1654    (setq-local buffer-invisibility-spec nil)
1655    (let ((preformatted nil)
1656          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1657      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1658      (dolist (line (split-string data "\n"))
1659        (pcase line
1660          ((rx (: "```" (opt (let alt-text (+ any)))))
1661           (setq preformatted
1662                 (if preformatted
1663                     nil
1664                   (if elpher-gemini-hide-preformatted
1665                       (elpher-gemini-insert-preformatted-toggler alt-text)
1666                     t))))
1667          ((guard  preformatted)
1668           (elpher-gemini-insert-preformatted-line line preformatted))
1669          ((pred (string-prefix-p "=>"))
1670           (elpher-gemini-insert-link line))
1671          ((pred (string-prefix-p "#"))
1672           (elpher-gemini-insert-header line))
1673          (_ (elpher-gemini-insert-text line))))
1674    (elpher-cache-content
1675     (elpher-page-address elpher-current-page)
1676     (buffer-string)))))
1677
1678 (defun elpher-render-gemini-plain-text (data _parameters)
1679   "Render DATA as plain text file.  PARAMETERS is currently unused."
1680   (elpher-with-clean-buffer
1681    (insert (elpher-process-text-for-display data))
1682    (elpher-cache-content
1683     (elpher-page-address elpher-current-page)
1684     (buffer-string))))
1685
1686 (defun elpher-build-current-imenu-index ()
1687   "Build imenu index for current elpher buffer."
1688   (save-excursion
1689     (goto-char (point-min))
1690     (let ((match nil)
1691           (headers nil))
1692       (while (setq match (text-property-search-forward 'gemini-heading t t))
1693         (push (cons
1694                (buffer-substring-no-properties (prop-match-beginning match)
1695                                                (prop-match-end match))
1696                (prop-match-beginning match))
1697               headers))
1698       (reverse headers))))
1699
1700 ;; Spartan page retrieval
1701
1702 (defvar elpher-spartan-redirect-chain)
1703
1704 (defun elpher-get-spartan-page (renderer)
1705   "Getter which retrieves and renders a Spartan page and renders it using RENDERER."
1706   (let* ((address (elpher-page-address elpher-current-page))
1707          (content (elpher-get-cached-content address)))
1708     (condition-case the-error
1709         (if (and content (funcall renderer nil))
1710             (elpher-with-clean-buffer
1711              (insert content)
1712              (elpher-restore-pos))
1713           (elpher-with-clean-buffer
1714            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1715           (setq elpher-spartan-redirect-chain nil)
1716           (elpher-get-spartan-response address renderer))
1717       (error
1718        (elpher-network-error address the-error)))))
1719
1720 (defun elpher-get-spartan-response (address renderer)
1721   "Get response string from spartan server at ADDRESS and render using RENDERER."
1722   (elpher-get-host-response address 300
1723                             (concat (elpher-address-host address) " "
1724                                     (elpher-address-filename address) " "
1725                                     "0\r\n") ; No uploads for now
1726                             (lambda (response-string)
1727                               (elpher-process-spartan-response response-string renderer))))
1728
1729 (defun elpher-parse-spartan-response (response)
1730   "Parse the RESPONSE string and return a list of components.
1731 The list is of the form (code meta body).  A response of nil implies
1732 that the response was malformed."
1733   (let ((header-end-idx (string-match "\r\n" response)))
1734     (if header-end-idx
1735         (let ((header (string-trim (substring response 0 header-end-idx)))
1736               (body (substring response (+ header-end-idx 2))))
1737           (if (>= (length header) 2)
1738               (let ((code (substring header 0 1))
1739                     (meta (string-trim (substring header 1))))
1740                 (list code meta body))
1741             (error "Malformed response: No response status found in header %s" header)))
1742       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1743
1744 (defun elpher-process-spartan-response (response-string renderer)
1745   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1746   (let ((response-components (elpher-parse-gemini-response response-string)))
1747     (let ((response-code (elt response-components 0))
1748           (response-meta (elt response-components 1))
1749           (response-body (elt response-components 2)))
1750       (pcase (elt response-code 0)
1751         (?2 ; Normal response
1752          (funcall renderer response-body response-meta))
1753         (?3 ; Redirect
1754          (message "Following redirect to %s" response-meta)
1755          (if (>= (length elpher-spartan-redirect-chain) 5)
1756              (error "More than 5 consecutive redirects followed"))
1757          (let* ((current-address (elpher-page-address current-page))
1758                 (redirect-address (elpher-address-from-url
1759                                    (concat "spartan://"
1760                                            (elpher-address-host current-address)
1761                                            ":"
1762                                            (elpher-address-port current-address)
1763                                            "/"
1764                                            response-meta))))
1765            (if (member redirect-address elpher-spartan-redirect-chain)
1766                (error "Redirect loop detected"))
1767            (elpher-page-set-address elpher-current-page redirect-address)
1768            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1769            (elpher-get-spartan-response redirect-address renderer)))
1770         (?4 ; Temporary failure
1771          (error "Spartan server reports CLIENT ERROR for this request: %s %s"
1772                 response-code response-meta))
1773         (?5 ; Permanent failure
1774          (error "Spartan server reports SERVER ERROR for this request: %s %s"
1775                 response-code response-meta))
1776         (_other
1777          (error "Spartan server response unknown: %s %s"
1778                 response-code response-meta))))))
1779
1780 ;; Finger page connection
1781
1782 (defun elpher-get-finger-page (renderer)
1783   "Opens a finger connection to the current page address.
1784 The result is rendered using RENDERER."
1785   (let* ((address (elpher-page-address elpher-current-page))
1786          (content (elpher-get-cached-content address)))
1787     (if (and content (funcall renderer nil))
1788         (elpher-with-clean-buffer
1789          (insert content)
1790          (elpher-restore-pos))
1791       (elpher-with-clean-buffer
1792        (insert "LOADING... (use 'u' to cancel)\n"))
1793       (condition-case the-error
1794           (let* ((kill-buffer-query-functions nil)
1795                  (user (let ((filename (elpher-address-filename address)))
1796                          (if (> (length filename) 1)
1797                              (substring filename 1)
1798                            (elpher-address-user address)))))
1799             (elpher-get-host-response address 79
1800                                       (concat user "\r\n")
1801                                       renderer))
1802         (error
1803          (elpher-network-error address the-error))))))
1804
1805
1806 ;; Telnet page connection
1807
1808 (defun elpher-get-telnet-page (renderer)
1809   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1810   (when renderer
1811     (elpher-visit-previous-page)
1812     (error "Command not supported for telnet URLs"))
1813   (let* ((address (elpher-page-address elpher-current-page))
1814          (host (elpher-address-host address))
1815          (port (elpher-address-port address)))
1816     (elpher-visit-previous-page)
1817     (if (> port 0)
1818         (telnet host port)
1819       (telnet host))))
1820
1821
1822 ;; Other URL page opening
1823
1824 (defun elpher-get-other-url-page (renderer)
1825   "Getter which attempts to open the URL specified by the current page.
1826 The RENDERER argument to this getter must be nil."
1827   (when renderer
1828     (elpher-visit-previous-page)
1829     (error "Command not supported for general URLs"))
1830   (let* ((address (elpher-page-address elpher-current-page))
1831          (url (elpher-address-to-url address)))
1832     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1833     (message "Opening URL...")
1834     (if elpher-open-urls-with-eww
1835         (browse-web url)
1836       (browse-url url))))
1837
1838
1839 ;; File page
1840
1841 (defun elpher-get-file-page (renderer)
1842   "Getter which renders a local file using RENDERER.
1843 Assumes UTF-8 encoding for all text files."
1844   (let* ((address (elpher-page-address elpher-current-page))
1845          (filename (elpher-address-filename address)))
1846     (unless (file-exists-p filename)
1847       (elpher-visit-previous-page)
1848         (error "File not found"))
1849     (unless (file-readable-p filename)
1850       (elpher-visit-previous-page)
1851         (error "Could not read from file"))
1852     (let ((body (with-temp-buffer
1853        (let ((coding-system-for-read 'binary)
1854              (coding-system-for-write 'binary))
1855          (insert-file-contents-literally filename)
1856          (encode-coding-string (buffer-string) 'raw-text)))))
1857        (if renderer
1858            (funcall renderer body nil)
1859          (pcase (file-name-extension filename)
1860            ((or  "gmi" "gemini")
1861             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1862            ((or "htm" "html")
1863             (elpher-render-html (decode-coding-string body 'utf-8)))
1864            ((or "txt" "")
1865             (elpher-render-text (decode-coding-string body 'utf-8)))
1866            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1867             (elpher-render-image body))
1868            ((or "gopher" "gophermap")
1869             (elpher-render-index (elpher-decode body)))
1870            (_
1871             (elpher-render-download body))))
1872        (elpher-restore-pos))))
1873
1874
1875 ;; Welcome page retrieval
1876
1877 (defun elpher-get-welcome-page (renderer)
1878   "Getter which displays the welcome page (RENDERER must be nil)."
1879   (when renderer
1880     (elpher-visit-previous-page)
1881     (error "Command not supported for welcome page"))
1882   (elpher-with-clean-buffer
1883    (insert "     --------------------------------------------\n"
1884            "           Elpher Gopher and Gemini Client       \n"
1885            "                   version " elpher-version "\n"
1886            "     --------------------------------------------\n"
1887            "\n"
1888            "Default bindings:\n"
1889            "\n"
1890            " - TAB/Shift-TAB: next/prev item on current page\n"
1891            " - RET/mouse-1: open item under cursor\n"
1892            " - m: select an item on current page by name (autocompletes)\n"
1893            " - u/mouse-3/U: return to previous page or to the start page\n"
1894            " - g: go to a particular address (gopher, gemini, finger)\n"
1895            " - o/O: open a different address selector or the root menu of the current server\n"
1896            " - d/D: download item under cursor or current page\n"
1897            " - i/I: info on item under cursor or current page\n"
1898            " - c/C: copy URL representation of item under cursor or current page\n"
1899            " - a/A: bookmark the item under cursor or current page\n"
1900            " - B: list all bookmarks\n"
1901            " - s/S: show current history stack or all previously visted pages\n"
1902            " - r: redraw current page (using cached contents if available)\n"
1903            " - R: reload current page (regenerates cache)\n"
1904            " - !: set character coding system for gopher (default is to autodetect)\n"
1905            " - T: toggle TLS gopher mode\n"
1906            " - F: forget/discard current TLS client certificate\n"
1907            " - .: display the raw server response for the current page\n"
1908            "\n"
1909            "Start your exploration of gopher space and gemini:\n")
1910    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1911                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1912    (elpher-insert-index-record "Project Gemini home page"
1913                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1914    (insert "\n"
1915            "Alternatively, select a search engine and enter some search terms:\n")
1916    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1917                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1918    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1919                                (elpher-address-from-url "gemini://geminispace.info/search"))
1920    (insert "\n"
1921            "Your bookmarks are stored in your ")
1922    (insert-text-button "bookmark list"
1923                        'face 'link
1924                        'action #'elpher-click-link
1925                        'follow-link t
1926                        'help-echo #'elpher--page-button-help
1927                        'elpher-page
1928                        (elpher-make-page "Elpher Bookmarks"
1929                                          (elpher-make-about-address 'bookmarks)))
1930    (insert ".\n")
1931    (insert (propertize
1932             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1933             'face 'shadow))
1934    (insert "\n"
1935            "The gopher home of the Elpher project is here:\n")
1936    (elpher-insert-index-record "The Elpher Project Page"
1937                                (elpher-make-gopher-address ?1
1938                                                            "/projects/elpher/"
1939                                                            "thelambdalab.xyz"
1940                                                            70))
1941    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1942      (insert "\n"
1943              "The following info documentation is available:\n"
1944              "   - ")
1945      (insert-text-button "Elpher Manual"
1946                          'face 'link
1947                          'action (lambda (_)
1948                                    (interactive)
1949                                    (info "(elpher)"))
1950                          'follow-link t
1951                          'help-echo help-string)
1952      (insert "\n   - ")
1953      (insert-text-button "Changes introduced by the latest release"
1954                        'face 'link
1955                        'action (lambda (_)
1956                                  (interactive)
1957                                  (info "(elpher)News"))
1958                        'follow-link t
1959                        'help-echo help-string))
1960    (insert "\n")
1961    (insert (propertize
1962             (concat "(These documents should be available if you have installed Elpher\n"
1963                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1964                     " manual yourself.)\n")
1965             'face 'shadow))
1966    (elpher-restore-pos)))
1967
1968
1969 ;; History page retrieval
1970
1971 (defun elpher-show-history ()
1972   "Show the current contents of elpher's history stack.
1973 Use \\[elpher-show-visited-pages] to see the entire history.
1974 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1975   (interactive)
1976   (elpher-visit-page
1977    (elpher-make-page "Current History Stack"
1978                      (elpher-make-about-address 'history))))
1979
1980 (defun elpher-show-visited-pages ()
1981   "Show the all the pages you've visited using Elpher.
1982 Use \\[elpher-show-history] to see just the current history stack.
1983 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1984   (interactive)
1985   (elpher-visit-page
1986    (elpher-make-page "Elpher Visted Pages"
1987                      (elpher-make-about-address 'visited-pages))))
1988
1989 (defun elpher-get-history-page (renderer)
1990   "Getter which displays the history page (RENDERER must be nil)."
1991   (when renderer
1992     (elpher-visit-previous-page)
1993     (error "Command not supported for history page"))
1994   (elpher-display-history-links elpher-history "Current history stack"))
1995
1996 (defun elpher-get-visited-pages-page (renderer)
1997   "Getter which displays the list of visited pages (RENDERER must be nil)."
1998   (when renderer
1999     (elpher-visit-previous-page)
2000     (error "Command not supported for history page"))
2001   (elpher-display-history-links
2002    (seq-filter (lambda (page)
2003                  (not (elpher-address-about-p (elpher-page-address page))))
2004                elpher-visited-pages)
2005    "All visited pages"))
2006
2007 (defun elpher-display-history-links (pages title)
2008   "Show all PAGES in an Elpher buffer with a given TITLE."
2009   (let* ((title-line (concat " ---- " title " ----"))
2010          (footer-line (make-string (length title-line) ?-)))
2011     (elpher-with-clean-buffer
2012      (insert title-line "\n\n")
2013      (if pages
2014          (dolist (page pages)
2015            (when page
2016              (let ((display-string (elpher-page-display-string page))
2017                    (address (elpher-page-address page)))
2018                (elpher-insert-index-record display-string address))))
2019        (insert "No history items found.\n"))
2020      (insert "\n " footer-line "\n"
2021              "Select an entry or press 'u' to return to the previous page.")
2022      (elpher-restore-pos))))
2023
2024
2025 ;;; Bookmarks
2026
2027 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2028 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2029 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2030 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2031
2032 (defvar elpher-bookmark-link nil
2033   "Prefer bookmarking a link or the current page.
2034 Bind this variable dynamically, or set it to t.
2035 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2036 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2037
2038 (defun elpher-bookmark-make-record ()
2039   "Return a bookmark record.
2040 If `elpher-bookmark-link' is non-nil and point is on a link button,
2041 return a bookmark record for that link.  Otherwise, return a bookmark
2042 record for the current elpher page."
2043   (let* ((button (and elpher-bookmark-link (button-at (point))))
2044          (page (if button
2045                    (button-get button 'elpher-page)
2046                  elpher-current-page)))
2047     (unless page
2048       (error "Cannot bookmark this link"))
2049     (let* ((address (elpher-page-address page))
2050            (url (elpher-address-to-url address))
2051            (display-string (elpher-page-display-string page))
2052            (pos (if button nil (point))))
2053       (if (elpher-address-about-p address)
2054           (error "Cannot bookmark %s" display-string)
2055         `(,display-string
2056           (defaults . (,display-string))
2057           (position . ,pos)
2058           (location . ,url)
2059           (handler . elpher-bookmark-jump))))))
2060
2061 ;;;###autoload
2062 (defun elpher-bookmark-jump (bookmark)
2063   "Handler used to open a bookmark using elpher.
2064 The argument BOOKMARK is a bookmark record passed to the function.
2065 This handler is responsible for loading the bookmark in some buffer,
2066 then making that buffer the current buffer.  It should not switch
2067 to the buffer."
2068   (let* ((url (cdr (assq 'location bookmark)))
2069          (cleaned-url (string-trim url))
2070          (page (elpher-page-from-url cleaned-url))
2071          (buffer (get-buffer-create elpher-buffer-name)))
2072     (elpher-with-clean-buffer
2073      (elpher-visit-page page))
2074     (set-buffer buffer)
2075     nil))
2076
2077 (defun elpher-bookmark-link ()
2078   "Bookmark the link at point.
2079 To bookmark the current page, use \\[elpher-bookmark-current]."
2080   (interactive)
2081   (let ((elpher-bookmark-link t))
2082     (bookmark-set-no-overwrite)))
2083
2084 (defun elpher-bookmark-current ()
2085   "Bookmark the current page.
2086 To bookmark the link at point use \\[elpher-bookmark-link]."
2087   (interactive)
2088   (call-interactively #'bookmark-set-no-overwrite))
2089
2090 (defun elpher-bookmark-import (file)
2091   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2092   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2093                               (file-readable-p elpher-bookmarks-file))
2094                          elpher-bookmarks-file
2095                        (read-file-name "Old Elpher bookmarks: "
2096                                        user-emacs-directory nil t
2097                                        "elpher-bookmarks"))))
2098   (dolist (bookmark (with-temp-buffer
2099                       (insert-file-contents file)
2100                       (read (current-buffer))))
2101     (let* ((display-string (car bookmark))
2102            (url (cadr bookmark))
2103            (record `(,display-string
2104                      (location . ,url)
2105                      (handler . elpher-bookmark-jump))))
2106       (bookmark-store display-string (cdr record) t)))
2107   (bookmark-save))
2108
2109 (defun elpher-get-bookmarks-page (renderer)
2110   "Getter which displays the bookmarks (RENDERER must be nil)."
2111   (when renderer
2112     (elpher-visit-previous-page)
2113     (error "Command not supported for bookmarks page"))
2114
2115   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2116                                      elpher-bookmarks-file)
2117                                 (locate-user-emacs-file "elpher-bookmarks"))))
2118     (when (and (file-readable-p old-bookmarks-file)
2119                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2120                                  old-bookmarks-file
2121                                  "\" found. Import now?")))
2122       (elpher-bookmark-import old-bookmarks-file)
2123       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2124
2125   (if (and elpher-use-emacs-bookmark-menu
2126            elpher-history)
2127       (progn
2128         (elpher-visit-previous-page)
2129         (call-interactively #'bookmark-bmenu-list))
2130     (elpher-with-clean-buffer
2131      (insert " ---- Elpher Bookmarks ---- \n\n")
2132      (bookmark-maybe-load-default-file)
2133      (dolist (bookmark (bookmark-maybe-sort-alist))
2134        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2135          (let* ((name (car bookmark))
2136                 (url (alist-get 'location (cdr bookmark)))
2137                 (address (elpher-address-from-url url)))
2138            (elpher-insert-index-record name address))))
2139      (when (<= (line-number-at-pos) 3)
2140        (insert "No bookmarked pages found.\n"))
2141      (insert "\n --------------------------\n\n"
2142              "Select an entry or press 'u' to return to the previous page.\n\n"
2143              "Bookmarks can be renamed or deleted via the ")
2144      (insert-text-button "Emacs bookmark menu"
2145                          'action (lambda (_)
2146                                    (interactive)
2147                                    (call-interactively #'bookmark-bmenu-list))
2148                          'follow-link t
2149                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2150      (insert (substitute-command-keys
2151               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2152      (elpher-restore-pos))))
2153
2154 (defun elpher-show-bookmarks ()
2155   "Interactive function to display the current list of elpher bookmarks."
2156   (interactive)
2157   (elpher-visit-page
2158    (elpher-make-page "Elpher Bookmarks"
2159                      (elpher-make-about-address 'bookmarks))))
2160
2161
2162 ;;; Integrations
2163 ;;
2164
2165 ;;; Org
2166
2167 (defun elpher-org-export-link (link description format protocol)
2168   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2169
2170 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2171 of gemini, gopher or finger."
2172   (let* ((url (if (equal protocol "elpher")
2173                   (string-remove-prefix "elpher:" link)
2174                 (format "%s:%s" protocol link)))
2175          (desc (or description url)))
2176     (pcase format
2177       (`gemini (format "=> %s %s" url desc))
2178       (`html (format "<a href=\"%s\">%s</a>" url desc))
2179       (`latex (format "\\href{%s}{%s}" url desc))
2180       (_ (if (not description)
2181              url
2182            (format "%s (%s)" desc url))))))
2183
2184 (defun elpher-org-store-link ()
2185   "Store link to an `elpher' page in Org."
2186   (when (eq major-mode 'elpher-mode)
2187     (let* ((url (elpher-info-current))
2188            (desc (car elpher-current-page))
2189            (protocol (cond
2190                       ((string-prefix-p "gemini:" url) "gemini")
2191                       ((string-prefix-p "gopher:" url) "gopher")
2192                       ((string-prefix-p "finger:" url) "finger")
2193                       (t "elpher"))))
2194       (when (equal "elpher" protocol)
2195         ;; Weird link. Or special inner link?
2196         (setq url (concat "elpher:" url)))
2197       (org-link-store-props :type protocol :link url :description desc)
2198       t)))
2199
2200 (defun elpher-org-follow-link (link protocol)
2201   "Visit a LINK for the given PROTOCOL.
2202
2203 PROTOCOL may be one of gemini, gopher or finger.  This method also
2204 supports the old protocol elpher, where the link is self-contained."
2205   (let ((url (if (equal protocol "elpher")
2206                  (string-remove-prefix "elpher:" link)
2207                (format "%s:%s" protocol link))))
2208     (elpher-go url)))
2209
2210 (defun elpher-org-mode-integration ()
2211   "Set up `elpher' integration for `org-mode'."
2212   (org-link-set-parameters
2213    "elpher"
2214    :store #'elpher-org-store-link
2215    :export (lambda (link description format _plist)
2216              (elpher-org-export-link link description format "elpher"))
2217    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2218   (org-link-set-parameters
2219    "gemini"
2220    :export (lambda (link description format _plist)
2221              (elpher-org-export-link link description format "gemini"))
2222    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2223   (org-link-set-parameters
2224    "gopher"
2225    :export (lambda (link description format _plist)
2226              (elpher-org-export-link link description format "gopher"))
2227    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2228   (org-link-set-parameters
2229    "finger"
2230    :export (lambda (link description format _plist)
2231              (elpher-org-export-link link description format "finger"))
2232    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2233
2234 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2235
2236 ;;; Browse URL
2237
2238 ;;;###autoload
2239 (defun elpher-browse-url-elpher (url &rest _args)
2240   "Browse URL using Elpher.  This function is used by `browse-url'."
2241   (interactive (browse-url-interactive-arg "Elpher URL: "))
2242   (elpher-go url))
2243
2244 ;; Use elpher to open gopher, finger and gemini links
2245 ;; For recent version of `browse-url' package
2246 (if (boundp 'browse-url-default-handlers)
2247     (add-to-list
2248      'browse-url-default-handlers
2249      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2250   ;; Patch `browse-url-browser-function' for older ones. The value of
2251   ;; that variable is `browse-url-default-browser' by default, so
2252   ;; that's the function that gets advised. If the value is an alist,
2253   ;; however, we don't know what to do. Better not interfere?
2254   (when (and (symbolp browse-url-browser-function)
2255              (fboundp browse-url-browser-function))
2256     (advice-add browse-url-browser-function :before-while
2257                 (lambda (url &rest _args)
2258                   "Handle gemini, gopher, and finger schemes using Elpher."
2259                   (let ((scheme (downcase (car (split-string url ":" t)))))
2260                     (if (member scheme '("gemini" "gopher" "finger"))
2261                         ;; `elpher-go' always returns nil, which will stop the
2262                         ;; advice chain here in a before-while
2263                         (elpher-go url)
2264                       ;; chain must continue, then return t.
2265                       t))))))
2266
2267 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2268 (with-eval-after-load 'thingatpt
2269   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2270
2271 ;;; Mu4e:
2272
2273 ;; Make mu4e aware of the gemini world
2274 (setq mu4e~view-beginning-of-url-regexp
2275       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2276
2277 ;;; eww:
2278
2279 ;; Let elpher handle gemini, gopher links in eww buffer.
2280 (setq eww-use-browse-url
2281       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2282
2283
2284 ;;; Interactive procedures
2285 ;;
2286
2287 (defun elpher-next-link ()
2288   "Move point to the next link on the current page."
2289   (interactive)
2290   (forward-button 1))
2291
2292 (defun elpher-prev-link ()
2293   "Move point to the previous link on the current page."
2294   (interactive)
2295   (backward-button 1))
2296
2297 (defun elpher-follow-current-link ()
2298   "Open the link or url at point."
2299   (interactive)
2300   (push-button))
2301
2302 ;;;###autoload
2303 (defun elpher-go (host-or-url)
2304   "Go to a particular gopher site HOST-OR-URL.
2305 When run interactively HOST-OR-URL is read from the minibuffer."
2306   (interactive (list
2307                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2308   (let ((trimmed-host-or-url (string-trim host-or-url)))
2309     (unless (string-empty-p trimmed-host-or-url)
2310       (let ((page (elpher-page-from-url trimmed-host-or-url
2311                                         (elpher-get-default-url-scheme))))
2312         (unless (get-buffer-window elpher-buffer-name t)
2313           (switch-to-buffer elpher-buffer-name))
2314         (elpher-with-clean-buffer
2315          (elpher-visit-page page))
2316         nil)))) ; non-nil value is displayed by eshell
2317
2318 (defun elpher-go-current ()
2319   "Go to a particular URL which is read from the minibuffer.
2320 Unlike `elpher-go', the reader is initialized with the URL of the
2321 current page."
2322   (interactive)
2323   (let* ((address (elpher-page-address elpher-current-page))
2324          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2325                            (elpher-address-to-url address))))
2326     (unless (string-empty-p (string-trim url))
2327       (elpher-visit-page (elpher-page-from-url url)))))
2328
2329 (defun elpher-redraw ()
2330   "Redraw current page."
2331   (interactive)
2332   (elpher-visit-page elpher-current-page))
2333
2334 (defun elpher-reload ()
2335   "Reload current page."
2336   (interactive)
2337   (elpher-reload-current-page))
2338
2339 (defun elpher-toggle-tls ()
2340   "Toggle TLS encryption mode for gopher."
2341   (interactive)
2342   (setq elpher-use-tls (not elpher-use-tls))
2343   (if elpher-use-tls
2344       (if (gnutls-available-p)
2345           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2346         (setq elpher-use-tls nil)
2347         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2348     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2349
2350 (defun elpher-view-raw ()
2351   "View raw server response for current page."
2352   (interactive)
2353   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2354       (error "This page was not generated by a server")
2355     (elpher-visit-page elpher-current-page
2356                        #'elpher-render-raw)))
2357
2358 (defun elpher-back ()
2359   "Go to previous site."
2360   (interactive)
2361   (elpher-visit-previous-page))
2362
2363 (defun elpher-back-to-start ()
2364   "Go all the way back to the start page."
2365   (interactive)
2366   (setq-local elpher-current-page nil)
2367   (setq-local elpher-history nil)
2368   (elpher-visit-page (elpher-make-start-page)))
2369
2370 (defun elpher-download ()
2371   "Download the link at point."
2372   (interactive)
2373   (let ((button (button-at (point))))
2374     (if button
2375         (let ((page (button-get button 'elpher-page)))
2376           (unless page
2377             (error "Not an elpher page"))
2378           (when (elpher-address-about-p (elpher-page-address page))
2379             (error "Cannot download %s" (elpher-page-display-string page)))
2380           (elpher-visit-page (button-get button 'elpher-page)
2381                              #'elpher-render-download))
2382       (error "No link selected"))))
2383
2384 (defun elpher-download-current ()
2385   "Download the current page."
2386   (interactive)
2387   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2388       (error "Cannot download %s"
2389              (elpher-page-display-string elpher-current-page))
2390     (elpher-visit-page (elpher-make-page
2391                         (elpher-page-display-string elpher-current-page)
2392                         (elpher-page-address elpher-current-page))
2393                        #'elpher-render-download
2394                        t)))
2395
2396 (defun elpher--build-link-map ()
2397   "Build alist mapping link names to destination pages in current buffer."
2398   (let ((link-map nil)
2399         (b (next-button (point-min) t)))
2400     (while b
2401       (push (cons (button-label b) b) link-map)
2402       (setq b (next-button (button-start b))))
2403     link-map))
2404
2405 (defun elpher-jump ()
2406   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2407   (interactive)
2408   (let* ((link-map (elpher--build-link-map)))
2409     (if link-map
2410         (let ((key (let ((completion-ignore-case t))
2411                      (completing-read "Directory item/link: "
2412                                       link-map nil t))))
2413           (if (and key (> (length key) 0))
2414               (let ((b (cdr (assoc key link-map))))
2415                 (goto-char (button-start b))
2416                 (button-activate b)))))))
2417
2418 (defun elpher-root-dir ()
2419   "Visit root of current server."
2420   (interactive)
2421   (let ((address (elpher-page-address elpher-current-page)))
2422     (if (not (elpher-address-about-p address))
2423         (if (or (member (url-filename address) '("/" ""))
2424                 (and (elpher-address-gopher-p address)
2425                      (= (length (elpher-gopher-address-selector address)) 0)))
2426             (error "Already at root directory of current server")
2427           (let ((address-copy (elpher-address-from-url
2428                                (elpher-address-to-url address))))
2429             (setf (url-filename address-copy) "")
2430             (elpher-go (elpher-address-to-url address-copy))))
2431       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2432
2433 (defun elpher-info-page (page)
2434   "Display URL of PAGE in minibuffer."
2435   (let* ((address (elpher-page-address page))
2436          (url (elpher-address-to-url address))
2437          (iri (elpher-address-to-iri address)))
2438     (if (equal url iri)
2439         (message "%s" url)
2440       (message "%s (Raw: %s)" iri url))))
2441
2442 (defun elpher-info-link ()
2443   "Display information on page corresponding to link at point."
2444   (interactive)
2445   (let ((button (button-at (point))))
2446     (unless button
2447       (error "No item selected"))
2448     (let ((page (button-get button 'elpher-page)))
2449       (unless page
2450         (error "Not an elpher page"))
2451       (elpher-info-page page))))
2452
2453 (defun elpher-info-current ()
2454   "Display information on current page."
2455   (interactive)
2456   (elpher-info-page elpher-current-page))
2457
2458 (defun elpher-copy-page-url (page)
2459   "Copy URL representation of address of PAGE to `kill-ring'."
2460   (let* ((address (elpher-page-address page))
2461          (url (elpher-address-to-url address)))
2462     (message "Copied \"%s\" to kill-ring/clipboard." url)
2463     (kill-new url)))
2464
2465 (defun elpher-copy-link-url ()
2466   "Copy URL of item at point to `kill-ring'."
2467   (interactive)
2468   (let ((button (button-at (point))))
2469     (unless button
2470       (error "No item selected"))
2471     (let ((page (button-get button 'elpher-page)))
2472       (unless page
2473         (error "Not an elpher page"))
2474       (elpher-copy-page-url page))))
2475
2476 (defun elpher-copy-current-url ()
2477   "Copy URL of current page to `kill-ring'."
2478   (interactive)
2479   (elpher-copy-page-url elpher-current-page))
2480
2481 (defun elpher-set-gopher-coding-system ()
2482   "Specify an explicit character coding system for gopher selectors."
2483   (interactive)
2484   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2485     (setq elpher-user-coding-system system)
2486     (if system
2487         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2488       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2489
2490
2491 ;;; Mode and keymap
2492 ;;
2493
2494 (defvar elpher-mode-map
2495   (let ((map (make-sparse-keymap)))
2496     (define-key map (kbd "TAB") 'elpher-next-link)
2497     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2498     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2499     (define-key map (kbd "u") 'elpher-back)
2500     (define-key map (kbd "-") 'elpher-back)
2501     (define-key map (kbd "^") 'elpher-back)
2502     (define-key map [mouse-3] 'elpher-back)
2503     (define-key map (kbd "U") 'elpher-back-to-start)
2504     (define-key map (kbd "g") 'elpher-go)
2505     (define-key map (kbd "o") 'elpher-go-current)
2506     (define-key map (kbd "O") 'elpher-root-dir)
2507     (define-key map (kbd "s") 'elpher-show-history)
2508     (define-key map (kbd "S") 'elpher-show-visited-pages)
2509     (define-key map (kbd "r") 'elpher-redraw)
2510     (define-key map (kbd "R") 'elpher-reload)
2511     (define-key map (kbd "T") 'elpher-toggle-tls)
2512     (define-key map (kbd ".") 'elpher-view-raw)
2513     (define-key map (kbd "d") 'elpher-download)
2514     (define-key map (kbd "D") 'elpher-download-current)
2515     (define-key map (kbd "m") 'elpher-jump)
2516     (define-key map (kbd "i") 'elpher-info-link)
2517     (define-key map (kbd "I") 'elpher-info-current)
2518     (define-key map (kbd "c") 'elpher-copy-link-url)
2519     (define-key map (kbd "C") 'elpher-copy-current-url)
2520     (define-key map (kbd "a") 'elpher-bookmark-link)
2521     (define-key map (kbd "A") 'elpher-bookmark-current)
2522     (define-key map (kbd "B") 'elpher-show-bookmarks)
2523     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2524     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2525     (when (fboundp 'evil-define-key*)
2526       (evil-define-key*
2527        'motion map
2528        (kbd "TAB") 'elpher-next-link
2529        (kbd "C-") 'elpher-follow-current-link
2530        (kbd "C-t") 'elpher-back
2531        (kbd "u") 'elpher-back
2532        (kbd "-") 'elpher-back
2533        (kbd "^") 'elpher-back
2534        [mouse-3] 'elpher-back
2535        (kbd "U") 'elpher-back-to-start
2536        (kbd "g") 'elpher-go
2537        (kbd "o") 'elpher-go-current
2538        (kbd "O") 'elpher-root-dir
2539        (kbd "s") 'elpher-show-history
2540        (kbd "S") 'elpher-show-visited-pages
2541        (kbd "r") 'elpher-redraw
2542        (kbd "R") 'elpher-reload
2543        (kbd "T") 'elpher-toggle-tls
2544        (kbd ".") 'elpher-view-raw
2545        (kbd "d") 'elpher-download
2546        (kbd "D") 'elpher-download-current
2547        (kbd "m") 'elpher-jump
2548        (kbd "i") 'elpher-info-link
2549        (kbd "I") 'elpher-info-current
2550        (kbd "c") 'elpher-copy-link-url
2551        (kbd "C") 'elpher-copy-current-url
2552        (kbd "a") 'elpher-bookmark-link
2553        (kbd "A") 'elpher-bookmark-current
2554        (kbd "B") 'elpher-show-bookmarks
2555        (kbd "!") 'elpher-set-gopher-coding-system
2556        (kbd "F") 'elpher-forget-current-certificate))
2557     map)
2558   "Keymap for gopher client.")
2559
2560 (define-derived-mode elpher-mode special-mode "elpher"
2561   "Major mode for elpher, an elisp gopher client.
2562
2563 This mode is automatically enabled by the interactive
2564 functions which initialize the client, namely
2565 `elpher', and `elpher-go'."
2566   (setq-local elpher-current-page nil)
2567   (setq-local elpher-history nil)
2568   (setq-local elpher-buffer-name (buffer-name))
2569   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2570   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2571
2572 (when (fboundp 'evil-set-initial-state)
2573   (evil-set-initial-state 'elpher-mode 'motion))
2574
2575
2576 ;;; Main start procedure
2577 ;;
2578
2579 ;;;###autoload
2580 (defun elpher (&optional arg)
2581   "Start elpher with default landing page.
2582 The buffer used for Elpher sessions is determined by the value of
2583 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2584 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2585 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2586 \\[execute-extended-command] elpher RET’) switches to the session with
2587 that number, creating it if necessary.  A non numeric prefix ARG means
2588 to create a new session.  Returns the buffer selected (or created)."
2589   (interactive "P")
2590   (let* ((name (default-value 'elpher-buffer-name))
2591          (buf (cond ((numberp arg)
2592                      (get-buffer-create (format "%s<%d>" name arg)))
2593                     (arg
2594                      (generate-new-buffer name))
2595                     (t
2596                      (get-buffer-create name)))))
2597     (pop-to-buffer-same-window buf)
2598     (unless (buffer-modified-p)
2599       (elpher-mode)
2600       (elpher-visit-page (elpher-make-start-page))
2601       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2602
2603 ;;; elpher.el ends here