elpher.el

   1 ;;; elpher.el --- Full-featured gopher client.
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 1.1.1
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "25"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a full-featured gopher client for GNU Emacs.
  30 ;; It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - caching of visited sites (both content and cursor position),
  34 ;; - pleasant and configurable colouring of Gopher directories,
  35 ;; - direct visualisation of image files,
  36 ;; - (m)enu key support, similar to Emacs' info browser,
  37 ;; - clickable web and gopher links in plain text.
  38
  39 ;; Visited pages are stored as a hierarchy rather than a linear history,
  40 ;; meaning that navigation between these pages is quick and easy.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Faces, caching options and start page can be configured via
  47 ;; the Elpher customization group in Applications.
  48
  49 ;;; Code:
  50
  51 (provide 'elpher)
  52
  53 ;;; Global constants
  54 ;;
  55
  56 (defconst elpher-version "1.1.1"
  57   "Current version of elpher.")
  58
  59 (defconst elpher-margin-width 6
  60   "Width of left-hand margin used when rendering indicies.")
  61
  62 (defconst elpher-start-index
  63   (mapconcat
  64    'identity
  65    (list "i\tfake\tfake\t1"
  66          "i     --------------------------------------------\tfake\tfake\t1"
  67          "i                Elpher Gopher Client             \tfake\tfake\t1"
  68          (format "i                   version %s\tfake\tfake\t1" elpher-version)
  69          "i     --------------------------------------------\tfake\tfake\t1"
  70          "i\tfake\tfake\t1"
  71          "iUsage:\tfake\tfake\t1"
  72          "i\tfake\tfake\t1"
  73          "i - tab/shift-tab: next/prev directory entry on current page\tfake\tfake\t1"
  74          "i - RET/mouse-1: open directory entry under cursor\tfake\tfake\t1"
  75          "i - m: select a directory entry by name (autocompletes)\tfake\tfake\t1"
  76          "i - u: return to parent directory entry\tfake\tfake\t1"
  77          "i - O: visit the root directory of the current server\tfake\tfake\t1"
  78          "i - g: go to a particular page\tfake\tfake\t1"
  79          "i - r: redraw current page (using cached contents if available)\tfake\tfake\t1"
  80          "i - R: reload current page (regenerates cache)\tfake\tfake\t1"
  81          "i - d: download directory entry under cursor\tfake\tfake\t1"
  82          "i - w: display the raw server response for the current page\tfake\tfake\t1"
  83          "i\tfake\tfake\t1"
  84          "iPlaces to start exploring Gopherspace:\tfake\tfake\t1"
  85          "i\tfake\tfake\t1"
  86          "1Floodgap Systems Gopher Server\t\tgopher.floodgap.com\t70"
  87          "i\tfake\tfake\t1"
  88          "iAlternatively, select the following item and enter some\tfake\tfake\t1"
  89          "isearch terms:\tfake\tfake\t1"
  90          "i\tfake\tfake\t1"
  91          "7Veronica-2 Gopher Search Engine\t/v2/vs\tgopher.floodgap.com\t70"
  92          ".\r\n")
  93    "\r\n")
  94   "Source for elpher start page.")
  95
  96 (defconst elpher-type-map
  97   '((?0 elpher-get-text-node "T" elpher-text)
  98     (?1 elpher-get-index-node "/" elpher-index)
  99     (?g elpher-get-image-node "im" elpher-image)
 100     (?p elpher-get-image-node "im" elpher-image)
 101     (?I elpher-get-image-node "im" elpher-image)
 102     (?4 elpher-get-node-download "B" elpher-binary)
 103     (?5 elpher-get-node-download "B" elpher-binary)
 104     (?9 elpher-get-node-download "B" elpher-binary)
 105     (?7 elpher-get-search-node "?" elpher-search))
 106   "Association list from types to getters, margin codes and index faces.")
 107
 108
 109 ;;; Customization group
 110 ;;
 111
 112 (defgroup elpher nil
 113   "A gopher client."
 114   :group 'applications)
 115
 116 ;; Face customizations
 117
 118 (defface elpher-index
 119   '((t :inherit org-drawer))
 120   "Face used for directory type directory records.")
 121
 122 (defface elpher-text
 123   '((t :inherit org-tag))
 124   "Face used for text type directory records.")
 125
 126 (defface elpher-info
 127   '((t :inherit org-default))
 128   "Face used for info type directory records.")
 129
 130 (defface elpher-image
 131   '((t :inherit org-level-4))
 132   "Face used for image type directory records.")
 133
 134 (defface elpher-search
 135   '((t :inherit org-level-5))
 136   "Face used for search type directory records.")
 137
 138 (defface elpher-url
 139   '((t :inherit org-level-6))
 140   "Face used for url type directory records.")
 141
 142 (defface elpher-binary
 143   '((t :inherit org-level-7))
 144   "Face used for binary type directory records.")
 145
 146 (defface elpher-unknown
 147   '((t :inherit org-warning))
 148   "Face used for directory records with unknown/unsupported types.")
 149
 150 (defface elpher-margin-key
 151   '((t :inherit org-tag))
 152   "Face used for directory margin key.")
 153
 154 (defface elpher-margin-brackets
 155   '((t :inherit org-special-keyword))
 156   "Face used for brackets around directory margin key.")
 157
 158 ;; Other customizations
 159
 160 (defcustom elpher-open-urls-with-eww nil
 161   "If non-nil, open URL selectors using eww.
 162 Otherwise, use the system browser via the BROWSE-URL function."
 163   :type '(boolean))
 164
 165 (defcustom elpher-buttonify-urls-in-directories nil
 166   "If non-nil, turns URLs matched in directories into clickable buttons."
 167   :type '(boolean))
 168
 169 (defcustom elpher-cache-images nil
 170   "If non-nil, cache images in memory in the same way as other content."
 171   :type '(boolean))
 172
 173 (defcustom elpher-start-address nil
 174   "If nil, the default start directory is shown when Elpher is started.
 175 Otherwise, a list containing the selector, host and port of a directory to
 176 use as the start page."
 177   :type '(list string string integer))
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 (defun elpher-make-address (selector host port)
 185   "Create an address of a gopher object with SELECTOR, HOST and PORT."
 186   (list selector host port))
 187
 188 (defun elpher-address-selector (address)
 189   "Retrieve selector from ADDRESS."
 190   (elt address 0))
 191
 192 (defun elpher-address-host (address)
 193   "Retrieve host from ADDRESS."
 194   (elt address 1))
 195
 196 (defun elpher-address-port (address)
 197   "Retrieve port from ADDRESS."
 198   (elt address 2))
 199
 200 ;; Node
 201
 202 (defun elpher-make-node (parent address getter &optional content pos)
 203   "Create a node in the gopher page hierarchy.
 204
 205 PARENT specifies the parent of the node, ADDRESS specifies the address of
 206 the gopher page, GETTER provides the getter function used to obtain this
 207 page.
 208
 209 The optional arguments CONTENT and POS can be used to fill the cached
 210 content and cursor position fields of the node."
 211   (list parent address getter content pos))
 212
 213 (defun elpher-node-parent (node)
 214   "Retrieve the parent node of NODE."
 215   (elt node 0))
 216
 217 (defun elpher-node-address (node)
 218   "Retrieve the address of NODE."
 219   (elt node 1))
 220
 221 (defun elpher-node-getter (node)
 222   "Retrieve the preferred getter function of NODE."
 223   (elt node 2))
 224
 225 (defun elpher-node-content (node)
 226   "Retrieve the cached content of NODE, or nil if none exists."
 227   (elt node 3))
 228
 229 (defun elpher-node-pos (node)
 230   "Retrieve the cached cursor position for NODE, or nil if none exists."
 231   (elt node 4))
 232
 233 (defun elpher-set-node-content (node content)
 234   "Set the content cache of NODE to CONTENT."
 235   (setcar (nthcdr 3 node) content))
 236
 237 (defun elpher-set-node-pos (node pos)
 238   "Set the cursor position cache of NODE to POS."
 239   (setcar (nthcdr 4 node) pos))
 240
 241 ;; Node graph traversal
 242
 243 (defvar elpher-current-node nil)
 244
 245 (defun elpher-visit-node (node &optional getter)
 246   "Visit NODE using its own getter or GETTER, if non-nil."
 247   (elpher-save-pos)
 248   (elpher-process-cleanup)
 249   (setq elpher-current-node node)
 250   (if getter
 251       (funcall getter)
 252     (funcall (elpher-node-getter node))))
 253
 254 (defun elpher-visit-parent-node ()
 255   "Visit the parent of the current node."
 256   (let ((parent-node (elpher-node-parent elpher-current-node)))
 257     (when parent-node
 258       (elpher-visit-node parent-node))))
 259
 260 (defun elpher-reload-current-node ()
 261   "Reload the current node, discarding any existing cached content."
 262   (elpher-set-node-content elpher-current-node nil)
 263   (elpher-visit-node elpher-current-node))
 264
 265 (defun elpher-save-pos ()
 266   "Save the current position of point to the current node."
 267   (when elpher-current-node
 268     (elpher-set-node-pos elpher-current-node (point))))
 269
 270 (defun elpher-restore-pos ()
 271   "Restore the position of point to that cached in the current node."
 272   (let ((pos (elpher-node-pos elpher-current-node)))
 273     (if pos
 274         (goto-char pos)
 275       (goto-char (point-min)))))
 276
 277 ;;; Buffer preparation
 278 ;;
 279
 280 (defmacro elpher-with-clean-buffer (&rest args)
 281   "Evaluate ARGS with a clean *elpher* buffer as current."
 282   (list 'with-current-buffer "*elpher*"
 283         '(elpher-mode)
 284         (append (list 'let '((inhibit-read-only t))
 285                       '(erase-buffer))
 286                 args)))
 287
 288 ;;; Index rendering
 289 ;;
 290
 291 (defun elpher-insert-index (string)
 292   "Insert the index corresponding to STRING into the current buffer."
 293   ;; Should be able to split directly on CRLF, but some non-conformant
 294   ;; LF-only servers sadly exist, hence the following.
 295   (let* ((str-no-period (replace-regexp-in-string "\r\n\.\r\n$" "\r\n" string))
 296          (str-no-cr (replace-regexp-in-string "\r" "" str-no-period)))
 297     (dolist (line (split-string str-no-cr "\n"))
 298       (unless (= (length line) 0)
 299         (elpher-insert-index-record line)))))
 300
 301 (defun elpher-insert-margin (&optional type-name)
 302   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 303   (if type-name
 304       (progn
 305         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 306                         (concat
 307                          (propertize "[" 'face 'elpher-margin-brackets)
 308                          (propertize type-name 'face 'elpher-margin-key)
 309                          (propertize "]" 'face 'elpher-margin-brackets))))
 310         (insert " "))
 311     (insert (make-string elpher-margin-width ?\s))))
 312
 313 (defun elpher-insert-index-record (line)
 314   "Insert the index record corresponding to LINE into the current buffer."
 315   (let* ((type (elt line 0))
 316          (fields (split-string (substring line 1) "\t"))
 317          (display-string (elt fields 0))
 318          (selector (elt fields 1))
 319          (host (elt fields 2))
 320          (port (elt fields 3))
 321          (address (elpher-make-address selector host port))
 322          (type-map-entry (alist-get type elpher-type-map)))
 323     (if type-map-entry
 324         (let ((getter (car type-map-entry))
 325               (margin-code (cadr type-map-entry))
 326               (face (elt type-map-entry 2)))
 327           (elpher-insert-margin margin-code)
 328           (insert-text-button display-string
 329                               'face face
 330                               'elpher-node (elpher-make-node elpher-current-node
 331                                                                address
 332                                                                getter)
 333                               'action #'elpher-click-link
 334                               'follow-link t
 335                               'help-echo (format "mouse-1, RET: open '%s' on %s port %s"
 336                                                  selector host port)))
 337       (pcase type
 338         (?i (elpher-insert-margin) ;; Information
 339             (insert (propertize
 340                      (if elpher-buttonify-urls-in-directories
 341                          (elpher-buttonify-urls display-string)
 342                        display-string)
 343                      'face 'elpher-info)))
 344         (?h (elpher-insert-margin "W") ;; Web link
 345             (let ((url (elt (split-string selector "URL:") 1)))
 346               (insert-text-button display-string
 347                                   'face 'elpher-url
 348                                   'elpher-url url
 349                                   'action #'elpher-click-url
 350                                   'follow-link t
 351                                   'help-echo (format "mouse-1, RET: open url %s" url))))
 352         (tp (elpher-insert-margin (concat (char-to-string tp) "?"))
 353             (insert (propertize display-string
 354                                 'face 'elpher-unknown-face)))))
 355     (insert "\n")))
 356
 357
 358 ;;; Selector retrieval (all kinds)
 359 ;;
 360
 361 (defun elpher-process-cleanup ()
 362   "Immediately shut down any extant elpher process."
 363   (let ((p (get-process "elpher-process")))
 364     (if p (delete-process p))))
 365
 366 (defvar elpher-selector-string)
 367
 368 (defun elpher-get-selector (address after)
 369   "Retrieve selector specified by ADDRESS, then execute AFTER.
 370 The result is stored as a string in the variable ‘elpher-selector-string’."
 371   (setq elpher-selector-string "")
 372   (make-network-process
 373    :name "elpher-process"
 374    :host (elpher-address-host address)
 375    :service (elpher-address-port address)
 376    :filter (lambda (proc string)
 377              (setq elpher-selector-string (concat elpher-selector-string string)))
 378    :sentinel after)
 379   (process-send-string "elpher-process"
 380                        (concat (elpher-address-selector address) "\n")))
 381
 382 ;; Index retrieval
 383
 384 (defun elpher-get-index-node ()
 385   "Getter which retrieves the current node contents as an index."
 386   (let ((content (elpher-node-content elpher-current-node))
 387         (address (elpher-node-address elpher-current-node)))
 388     (if content
 389         (progn
 390           (elpher-with-clean-buffer
 391            (insert content)
 392            (elpher-restore-pos)))
 393       (if address
 394           (progn
 395             (elpher-with-clean-buffer
 396              (insert "LOADING DIRECTORY..."))
 397             (elpher-get-selector address
 398                                   (lambda (proc event)
 399                                     (unless (string-prefix-p "deleted" event)
 400                                       (elpher-with-clean-buffer
 401                                        (elpher-insert-index elpher-selector-string)
 402                                        (elpher-restore-pos)
 403                                        (elpher-set-node-content elpher-current-node
 404                                                                 (buffer-string)))))))
 405         (progn
 406           (elpher-with-clean-buffer
 407            (elpher-insert-index elpher-start-index)
 408            (elpher-restore-pos)
 409            (elpher-set-node-content elpher-current-node
 410                                     (buffer-string))))))))
 411
 412 ;; Text retrieval
 413
 414 (defconst elpher-url-regex
 415   "\\(https?\\|gopher\\)://\\([a-zA-Z0-9.\-]+\\)\\(?3::[0-9]+\\)?\\(?4:/[^ \r\n\t(),]*\\)?"
 416   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 417
 418 (defun elpher-buttonify-urls (string)
 419   "Turn substrings which look like urls in STRING into clickable buttons."
 420   (with-temp-buffer
 421     (insert string)
 422     (goto-char (point-min))
 423     (while (re-search-forward elpher-url-regex nil t)
 424       (let ((url (match-string 0))
 425             (protocol (downcase (match-string 1))))
 426         (if (string= protocol "gopher")
 427             (let* ((host (match-string 2))
 428                    (port (if (match-string 3)
 429                              (string-to-number (substring (match-string 3) 1))
 430                            70))
 431                    (type-and-selector (match-string 4))
 432                    (type (if (> (length type-and-selector) 1)
 433                              (elt type-and-selector 1)
 434                            ?1))
 435                    (selector (if (> (length type-and-selector) 1)
 436                                  (substring type-and-selector 2)
 437                                ""))
 438                    (address (elpher-make-address selector host port))
 439                    (getter (car (alist-get type elpher-type-map))))
 440               (make-text-button (match-beginning 0)
 441                                 (match-end 0)
 442                                 'elpher-node (elpher-make-node elpher-current-node
 443                                                                  address
 444                                                                  getter)
 445                                 'action #'elpher-click-link
 446                                 'follow-link t
 447                                 'help-echo (format "mouse-1, RET: open '%s' on %s port %s"
 448                                                    selector host port)))
 449           (make-text-button (match-beginning 0)
 450                             (match-end 0)
 451                             'elpher-url url
 452                             'action #'elpher-click-url
 453                             'follow-link t
 454                             'help-echo (format "mouse-1, RET: open url %s" url)))))
 455     (buffer-string)))
 456
 457 (defun elpher-process-text (string)
 458   "Remove CRs and trailing period from the gopher text document STRING."
 459   (let* ((chopped-str (replace-regexp-in-string "\r\n\.\r\n$" "\r\n" string))
 460          (cleaned-str (replace-regexp-in-string "\r" "" chopped-str)))
 461     (elpher-buttonify-urls cleaned-str)))
 462
 463 (defun elpher-get-text-node ()
 464   "Getter which retrieves the current node contents as a text document."
 465   (let ((content (elpher-node-content elpher-current-node))
 466         (address (elpher-node-address elpher-current-node)))
 467     (if content
 468         (progn
 469           (elpher-with-clean-buffer
 470            (insert content)
 471            (elpher-restore-pos)))
 472       (progn
 473         (elpher-with-clean-buffer
 474          (insert "LOADING TEXT..."))
 475         (elpher-get-selector address
 476                               (lambda (proc event)
 477                                 (unless (string-prefix-p "deleted" event)
 478                                   (elpher-with-clean-buffer
 479                                    (insert (elpher-process-text elpher-selector-string))
 480                                    (elpher-restore-pos)
 481                                    (elpher-set-node-content elpher-current-node
 482                                                             (buffer-string))))))))))
 483
 484 ;; Image retrieval
 485
 486 (defun elpher-get-image-node ()
 487   "Getter which retrieves the current node contents as an image to view."
 488   (let ((content (elpher-node-content elpher-current-node))
 489         (address (elpher-node-address elpher-current-node)))
 490     (if content
 491         (progn
 492           (elpher-with-clean-buffer
 493            (insert-image content)
 494            (elpher-restore-pos)))
 495       (if (display-images-p)
 496           (progn
 497             (elpher-with-clean-buffer
 498              (insert "LOADING IMAGE..."))
 499             (elpher-get-selector address
 500                                  (lambda (proc event)
 501                                    (unless (string-prefix-p "deleted" event)
 502                                      (let ((image (create-image
 503                                                    (encode-coding-string elpher-selector-string
 504                                                                          'no-conversion)
 505                                                    nil t)))
 506                                        (elpher-with-clean-buffer
 507                                         (insert-image image)
 508                                         (elpher-restore-pos))
 509                                        (if elpher-cache-images
 510                                            (elpher-set-node-content elpher-current-node
 511                                                                     image)))))))
 512         (elpher-get-node-download)))))
 513
 514 ;; Search retrieval
 515
 516 (defun elpher-get-search-node ()
 517   "Getter which submits a search query to the address of the current node."
 518   (let ((content (elpher-node-content elpher-current-node))
 519         (address (elpher-node-address elpher-current-node))
 520         (aborted t))
 521     (if content
 522         (progn
 523           (elpher-with-clean-buffer
 524            (insert content)
 525            (elpher-restore-pos))
 526           (message "Displaying cached search results.  Reload to perform a new search."))
 527       (unwind-protect
 528           (let* ((query-string (read-string "Query: "))
 529                  (query-selector (concat (elpher-address-selector address) "\t" query-string))
 530                  (search-address (elpher-make-address query-selector
 531                                                        (elpher-address-host address)
 532                                                        (elpher-address-port address))))
 533             (setq aborted nil)
 534             (elpher-with-clean-buffer
 535              (insert "LOADING RESULTS..."))
 536             (elpher-get-selector search-address
 537                                   (lambda (proc event)
 538                                     (unless (string-prefix-p "deleted" event)
 539                                       (elpher-with-clean-buffer
 540                                        (elpher-insert-index elpher-selector-string))
 541                                       (goto-char (point-min))
 542                                       (elpher-set-node-content elpher-current-node
 543                                                                 (buffer-string))))))
 544         (if aborted
 545             (elpher-visit-parent-node))))))
 546
 547 ;; Raw server response retrieval
 548
 549 (defun elpher-get-node-raw ()
 550   "Getter which retrieves the raw server response for the current node."
 551   (let* ((content (elpher-node-content elpher-current-node))
 552          (address (elpher-node-address elpher-current-node)))
 553     (elpher-with-clean-buffer
 554      (insert "LOADING RAW SERVER RESPONSE..."))
 555     (if address
 556         (elpher-get-selector address
 557                               (lambda (proc event)
 558                                 (unless (string-prefix-p "deleted" event)
 559                                   (elpher-with-clean-buffer
 560                                    (insert elpher-selector-string)
 561                                    (goto-char (point-min))))))
 562       (progn
 563         (elpher-with-clean-buffer
 564          (insert elpher-start-index))
 565         (goto-char (point-min)))))
 566   (message "Displaying raw server response.  Reload or redraw to return to standard view."))
 567
 568 ;; File export retrieval
 569
 570 (defvar elpher-download-filename)
 571
 572 (defun elpher-get-node-download ()
 573   "Getter which retrieves the current node and writes the result to a file."
 574   (let* ((address (elpher-node-address elpher-current-node))
 575          (selector (elpher-address-selector address)))
 576     (elpher-visit-parent-node) ; Do first in case of non-local exits.
 577     (let* ((filename-proposal (file-name-nondirectory selector))
 578            (filename (read-file-name "Save file as: "
 579                                      nil nil nil
 580                                      (if (> (length filename-proposal) 0)
 581                                          filename-proposal
 582                                        "gopher.file"))))
 583       (message "Downloading...")
 584       (setq elpher-download-filename filename)
 585       (elpher-get-selector address
 586                             (lambda (proc event)
 587                               (let ((coding-system-for-write 'binary))
 588                                 (with-temp-file elpher-download-filename
 589                                   (insert elpher-selector-string)
 590                                   (message (format "Download complate, saved to file %s."
 591                                                    elpher-download-filename)))))))))
 592
 593
 594 ;;; Navigation procedures
 595 ;;
 596
 597 (defun elpher-next-link ()
 598   "Move point to the next link on the current page."
 599   (interactive)
 600   (forward-button 1))
 601
 602 (defun elpher-prev-link ()
 603   "Move point to the previous link on the current page."
 604   (interactive)
 605   (backward-button 1))
 606
 607 (defun elpher-click-link (button)
 608   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 609   (let ((node (button-get button 'elpher-node)))
 610     (elpher-visit-node node)))
 611
 612 (defun elpher-click-url (button)
 613   "Function called when the url link BUTTON is activated (via mouse or keypress)."
 614   (let ((url (button-get button 'elpher-url)))
 615     (if elpher-open-urls-with-eww
 616         (browse-web url)
 617       (browse-url url))))
 618
 619 (defun elpher-follow-current-link ()
 620   "Open the link or url at point."
 621   (interactive)
 622   (push-button))
 623
 624 (defun elpher-go ()
 625   "Go to a particular gopher site read from the minibuffer.
 626 The site may be specified via a URL or explicitly in terms of
 627 host, selector and port."
 628   (interactive)
 629   (let ((node
 630          (let ((host-or-url (read-string "Gopher host or URL: ")))
 631            (if (string-match elpher-url-regex host-or-url)
 632                (if (not (string= (downcase (match-string 1 host-or-url)) "gopher"))
 633                    (error "Only gopher URLs acceptable")
 634                  (let* ((host (match-string 2 host-or-url))
 635                         (port (if (match-string 3 host-or-url)
 636                                   (string-to-number (substring (match-string 3 host-or-url) 1))
 637                                 70))
 638                         (type-and-selector (match-string 4 host-or-url))
 639                         (type (if (> (length type-and-selector) 1)
 640                                   (elt type-and-selector 1)
 641                                 ?1))
 642                         (selector (if (> (length type-and-selector) 1)
 643                                       (substring type-and-selector 2)
 644                                     ""))
 645                         (address (elpher-make-address selector host port))
 646                         (getter (car (alist-get type elpher-type-map))))
 647                    (elpher-make-node elpher-current-node
 648                                      address
 649                                      getter)))
 650              (let* ((selector (read-string "Selector (default none): " nil nil ""))
 651                     (port (read-string "Port (default 70): " nil nil 70))
 652                     (address (list selector host-or-url port)))
 653                (elpher-make-node elpher-current-node
 654                                  address
 655                                  #'elpher-get-index-node))))))
 656     (switch-to-buffer "*elpher*")
 657     (elpher-visit-node node)))
 658
 659 (defun  elpher-redraw ()
 660   "Redraw current page."
 661   (interactive)
 662   (if elpher-current-node
 663       (elpher-visit-node elpher-current-node)
 664     (message "No current site.")))
 665
 666 (defun  elpher-reload ()
 667   "Reload current page."
 668   (interactive)
 669   (if elpher-current-node
 670       (elpher-reload-current-node)
 671     (message "No current site.")))
 672
 673 (defun elpher-view-raw ()
 674   "View current page as plain text."
 675   (interactive)
 676   (if elpher-current-node
 677       (elpher-visit-node elpher-current-node
 678                          #'elpher-get-node-raw)
 679     (message "No current site.")))
 680
 681 (defun elpher-back ()
 682   "Go to previous site."
 683   (interactive)
 684   (if (elpher-node-parent elpher-current-node)
 685       (elpher-visit-parent-node)
 686     (message "No previous site.")))
 687
 688 (defun elpher-download ()
 689   "Download the link at point."
 690   (interactive)
 691   (let ((button (button-at (point))))
 692     (if button
 693         (let ((node (button-get button 'elpher-node)))
 694           (if node
 695               (elpher-visit-node (button-get button 'elpher-node)
 696                                  #'elpher-get-node-download)
 697             (message "Can only download gopher links, not general URLs.")))
 698       (message "No link selected."))))
 699
 700 (defun elpher-build-link-map ()
 701   "Build alist mapping link names to destination nodes in current buffer."
 702   (let ((link-map nil)
 703         (b (next-button (point-min) t)))
 704     (while b
 705       (add-to-list 'link-map (cons (button-label b) b))
 706       (setq b (next-button (button-start b))))
 707     link-map))
 708
 709 (defun elpher-menu ()
 710   "Select a directory entry by name.  Similar to the info browser (m)enu command."
 711   (interactive)
 712   (let* ((link-map (elpher-build-link-map)))
 713     (if link-map
 714         (let ((key (let ((completion-ignore-case t))
 715                      (completing-read "Directory item/link: "
 716                                       link-map nil t))))
 717           (if (and key (> (length key) 0))
 718               (let ((b (cdr (assoc key link-map))))
 719                 (goto-char (button-start b))
 720                 (button-activate b)))))))
 721
 722 (defun elpher-root-dir ()
 723   "Visit root of current server."
 724   (interactive)
 725   (let ((address (elpher-node-address elpher-current-node)))
 726     (if address
 727         (let ((host (elpher-address-host address))
 728               (selector (elpher-address-selector address))
 729               (port (elpher-address-port address)))
 730           (if (> (length selector) 0)
 731               (let ((root-address (elpher-make-address "" host port)))
 732                 (elpher-visit-node (elpher-make-node elpher-current-node
 733                                                      root-address
 734                                                      #'elpher-get-index-node)))
 735             (message "Already at root directory of current server.")))
 736       (message "Command invalid for Elpher start page."))))
 737
 738 ;;; Mode and keymap
 739 ;;
 740
 741 (defvar elpher-mode-map
 742   (let ((map (make-sparse-keymap)))
 743     (define-key map (kbd "TAB") 'elpher-next-link)
 744     (define-key map (kbd "<backtab>") 'elpher-prev-link)
 745     (define-key map (kbd "u") 'elpher-back)
 746     (define-key map (kbd "O") 'elpher-root-dir)
 747     (define-key map (kbd "g") 'elpher-go)
 748     (define-key map (kbd "r") 'elpher-redraw)
 749     (define-key map (kbd "R") 'elpher-reload)
 750     (define-key map (kbd "w") 'elpher-view-raw)
 751     (define-key map (kbd "d") 'elpher-download)
 752     (define-key map (kbd "m") 'elpher-menu)
 753     (when (fboundp 'evil-define-key)
 754       (evil-define-key 'normal map
 755         (kbd "TAB") 'elpher-next-link
 756         (kbd "C-]") 'elpher-follow-current-link
 757         (kbd "C-t") 'elpher-back
 758         (kbd "u") 'elpher-back
 759         (kbd "O") 'elpher-root-dir
 760         (kbd "g") 'elpher-go
 761         (kbd "r") 'elpher-redraw
 762         (kbd "R") 'elpher-reload
 763         (kbd "w") 'elpher-view-raw
 764         (kbd "d") 'elpher-download
 765         (kbd "m") 'elpher-menu))
 766     map)
 767   "Keymap for gopher client.")
 768
 769 (define-derived-mode elpher-mode special-mode "elpher"
 770   "Major mode for elpher, an elisp gopher client.")
 771
 772
 773 ;;; Main start procedure
 774 ;;
 775
 776 ;;;###autoload
 777 (defun elpher ()
 778   "Start elpher with default landing page."
 779   (interactive)
 780   (if (get-buffer "*elpher*")
 781       (switch-to-buffer "*elpher*")
 782     (switch-to-buffer "*elpher*")
 783     (setq elpher-current-node nil)
 784     (let ((start-node (elpher-make-node nil
 785                                         elpher-start-address
 786                                         #'elpher-get-index-node)))
 787       (elpher-visit-node start-node)))
 788   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
 789
 790 ;;; elpher.el ends here