elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.3.6
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63 (require 'dns)
  64
  65
  66 ;;; Global constants
  67 ;;
  68
  69 (defconst elpher-version "2.3.6"
  70   "Current version of elpher.")
  71
  72 (defconst elpher-margin-width 6
  73   "Width of left-hand margin used when rendering indicies.")
  74
  75 (defconst elpher-type-map
  76   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  77     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  78     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  80     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  81     ((gopher ?9) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  82     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  85     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  87     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  88     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  89     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  90     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  91     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  92     ((special bookmarks) elpher-get-bookmarks-node nil "/" elpher-index)
  93     ((special start) elpher-get-start-node nil))
  94   "Association list from types to getters, renderers, margin codes and index faces.")
  95
  96
  97 ;;; Customization group
  98 ;;
  99
 100 (defgroup elpher nil
 101   "A gopher client."
 102   :group 'applications)
 103
 104 ;; Face customizations
 105
 106 (defface elpher-index
 107   '((t :inherit font-lock-keyword-face))
 108   "Face used for directory type directory records.")
 109
 110 (defface elpher-text
 111   '((t :inherit bold))
 112   "Face used for text type directory records.")
 113
 114 (defface elpher-info
 115   '((t :inherit default))
 116   "Face used for info type directory records.")
 117
 118 (defface elpher-image
 119   '((t :inherit font-lock-string-face))
 120   "Face used for image type directory records.")
 121
 122 (defface elpher-search
 123   '((t :inherit warning))
 124   "Face used for search type directory records.")
 125
 126 (defface elpher-html
 127   '((t :inherit font-lock-comment-face))
 128   "Face used for html type directory records.")
 129
 130 (defface elpher-gemini
 131   '((t :inherit font-lock-regexp-grouping-backslash))
 132   "Face used for html type directory records.")
 133
 134 (defface elpher-other-url
 135   '((t :inherit font-lock-comment-face))
 136   "Face used for other URL type links records.")
 137
 138 (defface elpher-telnet
 139   '((t :inherit font-lock-function-name-face))
 140   "Face used for telnet type directory records.")
 141
 142 (defface elpher-binary
 143   '((t :inherit font-lock-doc-face))
 144   "Face used for binary type directory records.")
 145
 146 (defface elpher-unknown
 147   '((t :inherit error))
 148   "Face used for directory records with unknown/unsupported types.")
 149
 150 (defface elpher-margin-key
 151   '((t :inherit bold))
 152   "Face used for directory margin key.")
 153
 154 (defface elpher-margin-brackets
 155   '((t :inherit shadow))
 156   "Face used for brackets around directory margin key.")
 157
 158 ;; Other customizations
 159
 160 (defcustom elpher-open-urls-with-eww nil
 161   "If non-nil, open URL selectors using eww.
 162 Otherwise, use the system browser via the BROWSE-URL function."
 163   :type '(boolean))
 164
 165 (defcustom elpher-buttonify-urls-in-directories t
 166   "If non-nil, turns URLs matched in directories into clickable buttons."
 167   :type '(boolean))
 168
 169 (defcustom elpher-use-header t
 170   "If non-nil, display current node information in buffer header."
 171   :type '(boolean))
 172
 173 (defcustom elpher-auto-disengage-TLS nil
 174   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 175 While enabling this may seem convenient, it is also potentially dangerous as it
 176 allows switching from an encrypted channel back to plain text without user input."
 177   :type '(boolean))
 178
 179
 180 ;;; Model
 181 ;;
 182
 183 ;; Address
 184
 185 ;; An elpher "address" object is either a url object or a symbol.
 186 ;; Symbol addresses are "special", corresponding to pages generated
 187 ;; dynamically for and by elpher.  All others represent pages which
 188 ;; rely on content retrieved over the network.
 189
 190 (defun elpher-address-from-url (url-string)
 191   "Create a ADDRESS object corresponding to the given URL-STRING."
 192   (let ((data (match-data))) ; Prevent parsing clobbering match data
 193     (unwind-protect
 194         (let ((url (url-generic-parse-url url-string)))
 195           (unless (and (not (url-fullness url)) (url-type url))
 196             (setf (url-fullness url) t)
 197             (setf (url-filename url)
 198                   (url-unhex-string (url-filename url)))
 199             (unless (url-type url)
 200               (setf (url-type url) "gopher"))
 201             (when (or (equal "gopher" (url-type url))
 202                       (equal "gophers" (url-type url)))
 203               ;; Gopher defaults
 204               (unless (url-host url)
 205                 (setf (url-host url) (url-filename url))
 206                 (setf (url-filename url) ""))
 207               (when (or (equal (url-filename url) "")
 208                         (equal (url-filename url) "/"))
 209                 (setf (url-filename url) "/1")))
 210             (when (equal "gemini" (url-type url))
 211               ;; Gemini defaults
 212               (if (equal (url-filename url) "")
 213                   (setf (url-filename url) "/"))))
 214           url)
 215       (set-match-data data))))
 216
 217 (defun elpher-make-gopher-address (type selector host port &optional tls)
 218   "Create an ADDRESS object using gopher directory record attributes.
 219 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 220 If the optional attribute TLS is non-nil, the address will be marked as
 221 requiring gopher-over-TLS."
 222   (cond
 223    ((and (equal type ?h)
 224          (string-prefix-p "URL:" selector))
 225     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 226    ((equal type ?8)
 227     (elpher-address-from-url
 228      (concat "telnet"
 229              "://" host
 230              ":" (number-to-string port))))
 231    (t
 232     (elpher-address-from-url
 233      (concat "gopher" (if tls "s" "")
 234              "://" host
 235              ":" (number-to-string port)
 236              "/" (string type)
 237              selector)))))
 238
 239 (defun elpher-make-special-address (type)
 240   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 241   type)
 242
 243 (defun elpher-address-to-url (address)
 244   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 245   (if (not (elpher-address-special-p address))
 246       (url-encode-url (url-recreate-url address))
 247     nil))
 248
 249 (defun elpher-address-type (address)
 250   "Retrieve type of ADDRESS object.
 251 This is used to determine how to retrieve and render the document the
 252 address refers to, via the table `elpher-type-map'."
 253   (if (symbolp address)
 254       (list 'special address)
 255     (let ((protocol (url-type address)))
 256       (cond ((or (equal protocol "gopher")
 257                  (equal protocol "gophers"))
 258              (list 'gopher
 259                    (if (member (url-filename address) '("" "/"))
 260                        ?1
 261                      (string-to-char (substring (url-filename address) 1)))))
 262             ((equal protocol "gemini")
 263              'gemini)
 264             ((equal protocol "telnet")
 265              'telnet)
 266             (t 'other-url)))))
 267
 268 (defun elpher-address-protocol (address)
 269   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 270   (if (symbolp address)
 271       nil
 272     (url-type address)))
 273
 274 (defun elpher-address-filename (address)
 275   "Retrieve the filename component of ADDRESS.
 276 For gopher addresses this is a combination of the selector type and selector."
 277   (if (symbolp address)
 278       nil
 279     (url-filename address)))
 280
 281 (defun elpher-address-host (address)
 282   "Retrieve host from ADDRESS object."
 283   (url-host address))
 284
 285 (defun elpher-address-port (address)
 286   "Retrieve port from ADDRESS object.
 287 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 288   (if (symbolp address)
 289       0
 290     (url-port address)))
 291
 292 (defun elpher-address-special-p (address)
 293   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 294   (symbolp address))
 295
 296 (defun elpher-address-gopher-p (address)
 297   "Return non-nill if ADDRESS object is a gopher address."
 298   (and (not (elpher-address-special-p address))
 299        (member (elpher-address-protocol address) '("gopher gophers"))))
 300
 301 (defun elpher-gopher-address-selector (address)
 302   "Retrieve gopher selector from ADDRESS object."
 303   (if (member (url-filename address) '("" "/"))
 304       ""
 305     (substring (url-filename address) 2)))
 306
 307 ;; Node
 308
 309 (defun elpher-make-node (display-string address &optional parent)
 310   "Create a node in the page hierarchy.
 311
 312 DISPLAY-STRING records the display string used for the page.
 313
 314 ADDRESS specifies the address object of the page.
 315
 316 The optional PARENT specifies the parent node in the hierarchy.
 317 This is set every time the node is visited, so while it forms
 318 an important part of the node data there is no need to set it
 319 initially."
 320   (list display-string address parent))
 321
 322 (defun elpher-node-display-string (node)
 323   "Retrieve the display string of NODE."
 324   (elt node 0))
 325
 326 (defun elpher-node-address (node)
 327   "Retrieve the ADDRESS object of NODE."
 328   (elt node 1))
 329
 330 (defun elpher-node-parent (node)
 331   "Retrieve the parent node of NODE."
 332   (elt node 2))
 333
 334 (defun elpher-set-node-parent (node parent)
 335   "Set the parent node of NODE to be PARENT."
 336   (setcar (cdr (cdr node)) parent))
 337
 338 ;; Cache
 339
 340 (defvar elpher-content-cache (make-hash-table :test 'equal))
 341 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 342
 343 (defun elpher-get-cached-content (address)
 344   "Retrieve the cached content for ADDRESS, or nil if none exists."
 345   (gethash address elpher-content-cache))
 346
 347 (defun elpher-cache-content (address content)
 348   "Set the content cache for ADDRESS to CONTENT."
 349   (puthash address content elpher-content-cache))
 350
 351 (defun elpher-get-cached-pos (address)
 352   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 353   (gethash address elpher-pos-cache))
 354
 355 (defun elpher-cache-pos (address pos)
 356   "Set the cursor position cache for ADDRESS to POS."
 357   (puthash address pos elpher-pos-cache))
 358
 359 ;; Node graph traversal
 360
 361 (defvar elpher-current-node nil)
 362
 363 (defun elpher-visit-node (node &optional renderer preserve-parent)
 364   "Visit NODE using its own renderer or RENDERER, if non-nil.
 365 Additionally, set the parent of NODE to `elpher-current-node',
 366 unless PRESERVE-PARENT is non-nil."
 367   (elpher-save-pos)
 368   (elpher-process-cleanup)
 369   (unless preserve-parent
 370     (if (and (elpher-node-parent elpher-current-node)
 371              (equal (elpher-node-address elpher-current-node)
 372                     (elpher-node-address node)))
 373         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 374       (elpher-set-node-parent node elpher-current-node)))
 375   (setq elpher-current-node node)
 376   (let* ((address (elpher-node-address node))
 377          (type (elpher-address-type address))
 378          (type-record (cdr (assoc type elpher-type-map))))
 379     (if type-record
 380         (funcall (car type-record)
 381                  (if renderer
 382                      renderer
 383                    (cadr type-record)))
 384       (elpher-visit-parent-node)
 385       (pcase type
 386         (`(gopher ,type-char)
 387          (error "Unsupported gopher selector type '%c' for '%s'"
 388                 type-char (elpher-address-to-url address)))
 389         (other
 390          (error "Unsupported address type '%S' for '%s'"
 391                 other (elpher-address-to-url address)))))))
 392
 393 (defun elpher-visit-parent-node ()
 394   "Visit the parent of the current node."
 395   (let ((parent-node (elpher-node-parent elpher-current-node)))
 396     (when parent-node
 397       (elpher-visit-node parent-node nil t))))
 398
 399 (defun elpher-reload-current-node ()
 400   "Reload the current node, discarding any existing cached content."
 401   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 402   (elpher-visit-node elpher-current-node))
 403
 404 (defun elpher-save-pos ()
 405   "Save the current position of point to the current node."
 406   (when elpher-current-node
 407     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 408
 409 (defun elpher-restore-pos ()
 410   "Restore the position of point to that cached in the current node."
 411   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 412     (if pos
 413         (goto-char pos)
 414       (goto-char (point-min)))))
 415
 416
 417 ;;; Buffer preparation
 418 ;;
 419
 420 (defun elpher-update-header ()
 421   "If `elpher-use-header' is true, display current node info in window header."
 422   (if elpher-use-header
 423       (let* ((display-string (elpher-node-display-string elpher-current-node))
 424              (address (elpher-node-address elpher-current-node))
 425              (tls-string (if (and (not (elpher-address-special-p address))
 426                                   (member (elpher-address-protocol address)
 427                                           '("gophers" "gemini")))
 428                              " [TLS encryption]"
 429                            ""))
 430              (header (concat display-string
 431                              (propertize tls-string 'face 'bold))))
 432         (setq header-line-format header))))
 433
 434 (defmacro elpher-with-clean-buffer (&rest args)
 435   "Evaluate ARGS with a clean *elpher* buffer as current."
 436   (list 'with-current-buffer "*elpher*"
 437         '(elpher-mode)
 438         (append (list 'let '((inhibit-read-only t))
 439                       '(erase-buffer)
 440                       '(elpher-update-header))
 441                 args)))
 442
 443
 444 ;;; Text Processing
 445 ;;
 446
 447 (defvar elpher-user-coding-system nil
 448   "User-specified coding system to use for decoding text responses.")
 449
 450 (defun elpher-decode (string)
 451   "Decode STRING using autodetected or user-specified coding system."
 452   (decode-coding-string string
 453                         (if elpher-user-coding-system
 454                             elpher-user-coding-system
 455                           (detect-coding-string string t))))
 456
 457 (defun elpher-preprocess-text-response (string)
 458   "Preprocess text selector response contained in STRING.
 459 This involes decoding the character representation, and clearing
 460 away CRs and any terminating period."
 461   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 462                                            (replace-regexp-in-string "\r" "" string))))
 463
 464
 465 ;;; Network error reporting
 466 ;;
 467
 468 (defun elpher-network-error (address error)
 469   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 470   (elpher-with-clean-buffer
 471    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 472            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 473            (error-message-string error) "\n"
 474            (propertize "\n----------------\n\n" 'face 'error)
 475            "Press 'u' to return to the previous page.")))
 476
 477
 478 ;;; Gopher selector retrieval
 479 ;;
 480
 481 (defun elpher-process-cleanup ()
 482   "Immediately shut down any extant elpher process."
 483   (let ((p (get-process "elpher-process")))
 484     (if p (delete-process p))))
 485
 486 (defvar elpher-use-tls nil
 487   "If non-nil, use TLS to communicate with gopher servers.")
 488
 489 (defvar elpher-selector-string)
 490
 491 (defun elpher-get-selector (address after &optional propagate-error)
 492   "Retrieve selector specified by ADDRESS, then execute AFTER.
 493 The result is stored as a string in the variable ‘elpher-selector-string’.
 494
 495 Usually errors result in an error page being displayed.  This is only
 496 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 497 is non-nil, this message is not displayed.  Instead, the error propagates
 498 up to the calling function."
 499   (setq elpher-selector-string "")
 500   (when (equal (elpher-address-protocol address) "gophers")
 501       (if (gnutls-available-p)
 502           (when (not elpher-use-tls)
 503             (setq elpher-use-tls t)
 504             (message "Engaging TLS gopher mode."))
 505         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 506   (condition-case the-error
 507       (let* ((kill-buffer-query-functions nil)
 508              (port (elpher-address-port address))
 509              (host (elpher-address-host address))
 510              (proc (open-network-stream "elpher-process"
 511                                        nil
 512                                        host
 513                                        (if (> port 0) port 70)
 514                                        :type (if elpher-use-tls 'tls 'plain)
 515                                        :nowait t)))
 516         (set-process-coding-system proc 'binary)
 517         (set-process-filter proc
 518                             (lambda (_proc string)
 519                               (setq elpher-selector-string
 520                                     (concat elpher-selector-string string))))
 521         (set-process-sentinel proc after)
 522         (let ((inhibit-eol-conversion t))
 523           (process-send-string proc
 524                                (concat (elpher-gopher-address-selector address) "\r\n"))))
 525     (error
 526      (if (and (consp the-error)
 527               (eq (car the-error) 'gnutls-error)
 528               (not (equal (elpher-address-protocol address) "gophers"))
 529               (or elpher-auto-disengage-TLS
 530                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 531          (progn
 532            (message "Disengaging TLS gopher mode.")
 533            (setq elpher-use-tls nil)
 534            (elpher-get-selector address after))
 535        (elpher-process-cleanup)
 536        (if propagate-error
 537            (error the-error)
 538          (elpher-with-clean-buffer
 539           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 540                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 541                   (propertize "\n----------------\n\n" 'face 'error)
 542                   "Press 'u' to return to the previous page.")))))))
 543
 544 (defun elpher-get-gopher-node (renderer)
 545   "Getter function for gopher nodes.
 546 The RENDERER procedure is used to display the contents of the node
 547 once they are retrieved from the gopher server."
 548   (let* ((address (elpher-node-address elpher-current-node))
 549          (content (elpher-get-cached-content address)))
 550     (if (and content (funcall renderer nil))
 551         (elpher-with-clean-buffer
 552          (insert content)
 553          (elpher-restore-pos))
 554       (elpher-with-clean-buffer
 555        (insert "LOADING... (use 'u' to cancel)"))
 556       (elpher-get-selector address
 557                            (lambda (_proc event)
 558                              (unless (or (string-prefix-p "deleted" event)
 559                                          (string-prefix-p "open" event))
 560                                (funcall renderer elpher-selector-string)
 561                                (elpher-restore-pos)))))))
 562
 563 ;; Index rendering
 564
 565 (defun elpher-insert-index (string)
 566   "Insert the index corresponding to STRING into the current buffer."
 567   ;; Should be able to split directly on CRLF, but some non-conformant
 568   ;; LF-only servers sadly exist, hence the following.
 569   (let ((str-processed (elpher-preprocess-text-response string)))
 570     (dolist (line (split-string str-processed "\n"))
 571       (ignore-errors
 572         (unless (= (length line) 0)
 573           (let* ((type (elt line 0))
 574                  (fields (split-string (substring line 1) "\t"))
 575                  (display-string (elt fields 0))
 576                  (selector (elt fields 1))
 577                  (host (elt fields 2))
 578                  (port (if (elt fields 3)
 579                            (string-to-number (elt fields 3))
 580                          nil))
 581                  (address (elpher-make-gopher-address type selector host port)))
 582             (elpher-insert-index-record display-string address)))))))
 583
 584 (defun elpher-insert-margin (&optional type-name)
 585   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 586   (if type-name
 587       (progn
 588         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 589                         (concat
 590                          (propertize "[" 'face 'elpher-margin-brackets)
 591                          (propertize type-name 'face 'elpher-margin-key)
 592                          (propertize "]" 'face 'elpher-margin-brackets))))
 593         (insert " "))
 594     (insert (make-string elpher-margin-width ?\s))))
 595
 596 (defun elpher-node-button-help (node)
 597   "Return a string containing the help text for a button corresponding to NODE."
 598   (let ((address (elpher-node-address node)))
 599     (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 600                                           address
 601                                         (elpher-address-to-url address)))))
 602
 603 (defun elpher-insert-index-record (display-string &optional address)
 604   "Function to insert an index record into the current buffer.
 605 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 606 If ADDRESS is not supplied or nil the record is rendered as an
 607 'information' line."
 608   (let* ((type (if address (elpher-address-type address) nil))
 609          (type-map-entry (cdr (assoc type elpher-type-map))))
 610     (if type-map-entry
 611         (let* ((margin-code (elt type-map-entry 2))
 612                (face (elt type-map-entry 3))
 613                (node (elpher-make-node display-string address)))
 614           (elpher-insert-margin margin-code)
 615           (insert-text-button display-string
 616                               'face face
 617                               'elpher-node node
 618                               'action #'elpher-click-link
 619                               'follow-link t
 620                               'help-echo (elpher-node-button-help node)))
 621       (pcase type
 622         ((or '(gopher ?i) 'nil) ;; Information
 623          (elpher-insert-margin)
 624          (let ((propertized-display-string
 625                 (propertize display-string 'face 'elpher-info)))
 626            (insert (if elpher-buttonify-urls-in-directories
 627                        (elpher-buttonify-urls propertized-display-string)
 628                      propertized-display-string))))
 629         (`(gopher ,selector-type) ;; Unknown
 630          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 631          (insert (propertize display-string
 632                              'face 'elpher-unknown)))))
 633     (insert "\n")))
 634
 635 (defun elpher-click-link (button)
 636   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 637   (let ((node (button-get button 'elpher-node)))
 638     (elpher-visit-node node)))
 639
 640 (defun elpher-render-index (data &optional _mime-type-string)
 641   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 642   (elpher-with-clean-buffer
 643    (if (not data)
 644        t
 645      (elpher-insert-index data)
 646      (elpher-cache-content (elpher-node-address elpher-current-node)
 647                            (buffer-string)))))
 648
 649 ;; Text rendering
 650
 651 (defconst elpher-url-regex
 652   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.]*[0-9a-zA-Z\-_~?/@|]\\)?\\)?"
 653   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 654
 655 (defun elpher-buttonify-urls (string)
 656   "Turn substrings which look like urls in STRING into clickable buttons."
 657   (with-temp-buffer
 658     (insert string)
 659     (goto-char (point-min))
 660     (while (re-search-forward elpher-url-regex nil t)
 661       (let ((node (elpher-make-node (substring-no-properties (match-string 0))
 662                                     (elpher-address-from-url (match-string 0)))))
 663           (make-text-button (match-beginning 0)
 664                             (match-end 0)
 665                             'elpher-node  node
 666                             'action #'elpher-click-link
 667                             'follow-link t
 668                             'help-echo (elpher-node-button-help node)
 669                             'face 'button)))
 670     (buffer-string)))
 671
 672 (defun elpher-render-text (data &optional _mime-type-string)
 673   "Render DATA as text.  MIME-TYPE-STRING is unused."
 674   (elpher-with-clean-buffer
 675    (if (not data)
 676        t
 677      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 678      (elpher-cache-content
 679       (elpher-node-address elpher-current-node)
 680       (buffer-string)))))
 681
 682 ;; Image retrieval
 683
 684 (defun elpher-render-image (data &optional _mime-type-string)
 685   "Display DATA as image.  MIME-TYPE-STRING is unused."
 686   (if (not data)
 687       nil
 688     (if (display-images-p)
 689         (progn
 690           (let ((image (create-image
 691                         data
 692                         nil t)))
 693             (elpher-with-clean-buffer
 694              (insert-image image)
 695              (elpher-restore-pos))))
 696       (elpher-render-download data))))
 697
 698 ;; Search retrieval and rendering
 699
 700 (defun elpher-get-gopher-query-node (renderer)
 701   "Getter for gopher addresses requiring input.
 702 The response is rendered using the rendering function RENDERER."
 703    (let* ((address (elpher-node-address elpher-current-node))
 704           (content (elpher-get-cached-content address))
 705           (aborted t))
 706     (if (and content (funcall renderer nil))
 707         (elpher-with-clean-buffer
 708          (insert content)
 709          (elpher-restore-pos)
 710          (message "Displaying cached search results.  Reload to perform a new search."))
 711       (unwind-protect
 712           (let* ((query-string (read-string "Query: "))
 713                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 714                  (search-address (elpher-make-gopher-address ?1
 715                                                              query-selector
 716                                                              (elpher-address-host address)
 717                                                              (elpher-address-port address)
 718                                                              (equal (elpher-address-type address) "gophers"))))
 719             (setq aborted nil)
 720
 721             (elpher-with-clean-buffer
 722              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 723             (elpher-get-selector search-address
 724                                  (lambda (_proc event)
 725                                    (unless (string-prefix-p "deleted" event)
 726                                      (funcall renderer elpher-selector-string)
 727                                      (elpher-restore-pos)))))
 728         (if aborted
 729             (elpher-visit-parent-node))))))
 730
 731 ;; Raw server response rendering
 732
 733 (defun elpher-render-raw (data &optional _mime-type-string)
 734   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 735   (if (not data)
 736       nil
 737     (elpher-with-clean-buffer
 738      (insert data)
 739      (goto-char (point-min)))
 740     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 741
 742 ;; File save "rendering"
 743
 744 (defun elpher-render-download (data &optional _mime-type-string)
 745   "Save DATA to file.  MIME-TYPE-STRING is unused."
 746   (if (not data)
 747       nil
 748     (let* ((address (elpher-node-address elpher-current-node))
 749            (selector (elpher-gopher-address-selector address)))
 750       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 751       (let* ((filename-proposal (file-name-nondirectory selector))
 752              (filename (read-file-name "Download complete. Save file as: "
 753                                        nil nil nil
 754                                        (if (> (length filename-proposal) 0)
 755                                            filename-proposal
 756                                          "download.file"))))
 757         (let ((coding-system-for-write 'binary))
 758           (with-temp-file filename
 759             (insert data)))
 760         (message (format "Saved to file %s." filename))))))
 761
 762 ;; HTML rendering
 763
 764 (defun elpher-render-html (data &optional _mime-type-string)
 765   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 766   (elpher-with-clean-buffer
 767    (if (not data)
 768        t
 769      (let ((dom (with-temp-buffer
 770                   (insert data)
 771                   (libxml-parse-html-region (point-min) (point-max)))))
 772        (shr-insert-document dom)))))
 773
 774 ;; Gemini node retrieval
 775
 776 (defvar elpher-gemini-response)
 777 (defvar elpher-gemini-redirect-chain)
 778
 779 (defun elpher-get-gemini-response (address after)
 780   "Retrieve gemini ADDRESS, then execute AFTER.
 781 The response is stored in the variable ‘elpher-gemini-response’."
 782   (setq elpher-gemini-response "")
 783   (if (not (gnutls-available-p))
 784       (error "Cannot establish gemini connection: GnuTLS not available")
 785     (condition-case the-error
 786         (let* ((kill-buffer-query-functions nil)
 787                (network-security-level 'medium)
 788                (port (elpher-address-port address))
 789                (host (elpher-address-host address))
 790                (proc (open-network-stream "elpher-process"
 791                                           nil
 792                                           host
 793                                           (if (> port 0) port 1965)
 794                                           :type 'tls
 795                                           :nowait t)))
 796           (set-process-coding-system proc 'binary)
 797           (set-process-filter proc
 798                               (lambda (_proc string)
 799                                 (setq elpher-gemini-response
 800                                       (concat elpher-gemini-response string))))
 801           (set-process-sentinel proc after)
 802           (let ((inhibit-eol-conversion t))
 803             (process-send-string proc
 804                                  (concat (elpher-address-to-url address) "\r\n"))))
 805       (error
 806        (error "Error initiating connection to server")))))
 807
 808 (defun elpher-parse-gemini-response (response)
 809   "Parse the RESPONSE string and return a list of components
 810 The list is of the form (code meta body). A response of nil implies
 811 that the response was malformed."
 812   (let ((header-end-idx (string-match "\r\n" response)))
 813     (if header-end-idx
 814         (let ((header (string-trim (substring response 0 header-end-idx)))
 815               (body (substring response (+ header-end-idx 2))))
 816           (if (>= (length header) 2)
 817               (let ((code (substring header 0 2))
 818                     (meta (string-trim (substring header 2))))
 819                 (list code meta body))
 820             (error "Malformed response: No response status found in header %s" header)))
 821       (error "Malformed response: No CRLF-delimited header found"))))
 822
 823
 824 (defun elpher-process-gemini-response (renderer)
 825   "Process the gemini response and pass the result to RENDERER.
 826 The response is assumed to be in the variable `elpher-gemini-response'."
 827   (condition-case the-error
 828       (let ((response-components (elpher-parse-gemini-response elpher-gemini-response)))
 829         (let ((response-code (elt response-components 0))
 830               (response-meta (elt response-components 1))
 831               (response-body (elt response-components 2)))
 832           (pcase (elt response-code 0)
 833             (?1 ; Input required
 834              (elpher-with-clean-buffer
 835               (insert "Gemini server is requesting input."))
 836              (let* ((query-string (read-string (concat response-meta ": ")))
 837                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 838                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 839                (elpher-get-gemini-response query-address
 840                                            (lambda (_proc event)
 841                                              (unless (or (string-prefix-p "deleted" event)
 842                                                          (string-prefix-p "open" event))
 843                                                (funcall #'elpher-process-gemini-response
 844                                                         renderer)
 845                                                (elpher-restore-pos))))))
 846             (?2 ; Normal response
 847              ;; (message response-header)
 848              (funcall renderer response-body response-meta))
 849             (?3 ; Redirect
 850              (message "Following redirect to %s" response-meta)
 851              (if (>= (length elpher-gemini-redirect-chain) 5)
 852                  (error "More than 5 consecutive redirects followed"))
 853              (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 854                (if (member redirect-address elpher-gemini-redirect-chain)
 855                    (error "Redirect loop detected"))
 856                (if (not (string= (elpher-address-protocol redirect-address)
 857                                  "gemini"))
 858                    (error "Server tried to automatically redirect to non-gemini URL: %s"
 859                           response-meta))
 860                (add-to-list 'elpher-gemini-redirect-chain redirect-address)
 861                (elpher-get-gemini-response redirect-address
 862                                            (lambda (_proc event)
 863                                              (unless (or (string-prefix-p "deleted" event)
 864                                                          (string-prefix-p "open" event))
 865                                                (funcall #'elpher-process-gemini-response
 866                                                         renderer)
 867                                                (elpher-restore-pos))))))
 868             (?4 ; Temporary failure
 869              (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
 870                     response-code response-meta))
 871             (?5 ; Permanent failure
 872              (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
 873                     response-code response-meta))
 874             (?6 ; Client certificate required
 875              (error "Gemini server requires client certificate (unsupported at this time)"))
 876             (_other
 877              (error "Gemini server response unknown: %s %s"
 878                     response-code response-meta)))))
 879     (error
 880      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 881
 882 (defun elpher-get-gemini-node (renderer)
 883   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 884   (let* ((address (elpher-node-address elpher-current-node))
 885          (content (elpher-get-cached-content address)))
 886     (condition-case the-error
 887         (if (and content (funcall renderer nil))
 888             (elpher-with-clean-buffer
 889               (insert content)
 890               (elpher-restore-pos))
 891           (elpher-with-clean-buffer
 892            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 893           (setq elpher-gemini-redirect-chain nil)
 894           (elpher-get-gemini-response address
 895                                       (lambda (_proc event)
 896                                         (unless (or (string-prefix-p "deleted" event)
 897                                                     (string-prefix-p "open" event))
 898                                           (funcall #'elpher-process-gemini-response
 899                                                    renderer)
 900                                           (elpher-restore-pos)))))
 901       (error
 902        (elpher-network-error address the-error)))))
 903
 904
 905 (defun elpher-render-gemini (body &optional mime-type-string)
 906   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 907   (if (not body)
 908       t
 909     (let* ((mime-type-string* (if (or (not mime-type-string)
 910                                       (string-empty-p mime-type-string))
 911                                   "text/gemini; charset=utf-8"
 912                                 mime-type-string))
 913            (mime-type-split (split-string mime-type-string* ";" t))
 914            (mime-type (string-trim (car mime-type-split)))
 915            (parameters (mapcar (lambda (s)
 916                                  (let ((key-val (split-string s "=")))
 917                                    (list (downcase (string-trim (car key-val)))
 918                                          (downcase (string-trim (cadr key-val))))))
 919                                (cdr mime-type-split))))
 920       (when (string-prefix-p "text/" mime-type)
 921         (setq body (decode-coding-string
 922                     body
 923                     (if (assoc "charset" parameters)
 924                         (intern (cadr (assoc "charset" parameters)))
 925                       'utf-8)))
 926         (setq body (replace-regexp-in-string "\r" "" body)))
 927       (pcase mime-type
 928         ((or "text/gemini" "")
 929          (elpher-render-gemini-map body parameters))
 930         ((pred (string-prefix-p "text/"))
 931          (elpher-render-gemini-plain-text body parameters))
 932         ((pred (string-prefix-p "image/"))
 933          (elpher-render-image body))
 934         (_other
 935          (error "Unsupported MIME type %S" mime-type))))))
 936
 937 (defun elpher-gemini-get-link-url (line)
 938   "Extract the url portion of LINE, a gemini map file link line."
 939   (string-trim (elt (split-string (substring line 2)) 0)))
 940
 941 (defun elpher-gemini-get-link-display-string (line)
 942   "Extract the display string portion of LINE, a gemini map file link line."
 943   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 944          (idx (string-match "[ \t]" rest)))
 945     (if idx
 946         (string-trim (substring rest (+ idx 1)))
 947       "")))
 948
 949 (defun elpher-collapse-dot-sequences (filename)
 950   "Collapse dot sequences in FILENAME.
 951 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
 952   (let* ((path (split-string filename "/"))
 953          (path-reversed-normalized
 954           (seq-reduce (lambda (a b)
 955                         (cond ((and a (equal b "..") (cdr a)))
 956                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
 957                               ((equal b ".") a)
 958                               (t (cons b a))))
 959                       path nil)))
 960     (string-join (reverse path-reversed-normalized) "/")))
 961
 962 (defun elpher-address-from-gemini-url (url)
 963   "Extract address from URL with defaults as per gemini map files."
 964   (let ((address (url-generic-parse-url url)))
 965     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 966       (setf (url-fullness address) t)
 967       (unless (url-host address) ;if there is an explicit host, filenames are absolute
 968         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 969         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 970           (setf (url-filename address)
 971                 (concat (file-name-directory
 972                          (url-filename (elpher-node-address elpher-current-node)))
 973                         (url-filename address)))))
 974       (unless (url-type address)
 975         (setf (url-type address) "gemini"))
 976       (if (equal (url-type address) "gemini")
 977           (setf (url-filename address)
 978                 (elpher-collapse-dot-sequences (url-filename address)))))
 979     address))
 980
 981 (defun elpher-render-gemini-map (data _parameters)
 982   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 983   (elpher-with-clean-buffer
 984    (dolist (line (split-string data "\n"))
 985      (if (string-prefix-p "=>" line)
 986          (let* ((url (elpher-gemini-get-link-url line))
 987                 (display-string (elpher-gemini-get-link-display-string line))
 988                 (address (elpher-address-from-gemini-url url)))
 989            (if (> (length display-string) 0)
 990                (elpher-insert-index-record display-string address)
 991              (elpher-insert-index-record url address)))
 992        (elpher-insert-index-record line)))
 993    (elpher-cache-content
 994     (elpher-node-address elpher-current-node)
 995     (buffer-string))))
 996
 997 (defun elpher-render-gemini-plain-text (data _parameters)
 998   "Render DATA as plain text file.  PARAMETERS is currently unused."
 999   (elpher-with-clean-buffer
1000    (insert (elpher-buttonify-urls data))
1001    (elpher-cache-content
1002     (elpher-node-address elpher-current-node)
1003     (buffer-string))))
1004
1005 ;; Other URL node opening
1006
1007 (defun elpher-get-other-url-node (renderer)
1008   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
1009   (when renderer
1010     (elpher-visit-parent-node)
1011     (error "Command not supported for general URLs"))
1012   (let* ((address (elpher-node-address elpher-current-node))
1013          (url (elpher-address-to-url address)))
1014     (progn
1015       (elpher-visit-parent-node) ; Do first in case of non-local exits.
1016       (message "Opening URL...")
1017       (if elpher-open-urls-with-eww
1018           (browse-web url)
1019         (browse-url url)))))
1020
1021 ;; Telnet node connection
1022
1023 (defun elpher-get-telnet-node (renderer)
1024   "Opens a telnet connection to the current node address (RENDERER must be nil)."
1025   (when renderer
1026     (elpher-visit-parent-node)
1027     (error "Command not supported for telnet URLs"))
1028   (let* ((address (elpher-node-address elpher-current-node))
1029          (host (elpher-address-host address))
1030          (port (elpher-address-port address)))
1031     (elpher-visit-parent-node)
1032     (if (> port 0)
1033         (telnet host port)
1034       (telnet host))))
1035
1036 ;; Start page node retrieval
1037
1038 (defun elpher-get-start-node (renderer)
1039   "Getter which displays the start page (RENDERER must be nil)."
1040   (when renderer
1041     (elpher-visit-parent-node)
1042     (error "Command not supported for start page"))
1043   (elpher-with-clean-buffer
1044    (insert "     --------------------------------------------\n"
1045            "                Elpher Gopher Client             \n"
1046            "                   version " elpher-version "\n"
1047            "     --------------------------------------------\n"
1048            "\n"
1049            "Default bindings:\n"
1050            "\n"
1051            " - TAB/Shift-TAB: next/prev item on current page\n"
1052            " - RET/mouse-1: open item under cursor\n"
1053            " - m: select an item on current page by name (autocompletes)\n"
1054            " - u/mouse-3: return to previous page\n"
1055            " - o/O: visit different selector or the root menu of the current server\n"
1056            " - g: go to a particular gopher address\n"
1057            " - d/D: download item under cursor or current page\n"
1058            " - i/I: info on item under cursor or current page\n"
1059            " - c/C: copy URL representation of item under cursor or current page\n"
1060            " - a/A: bookmark the item under cursor or current page\n"
1061            " - x/X: remove bookmark for item under cursor or current page\n"
1062            " - B: visit the bookmarks page\n"
1063            " - r: redraw current page (using cached contents if available)\n"
1064            " - R: reload current page (regenerates cache)\n"
1065            " - S: set character coding system for gopher (default is to autodetect)\n"
1066            " - T: toggle TLS gopher mode\n"
1067            " - .: display the raw server response for the current page\n"
1068            "\n"
1069            "Start your exploration of gopher space:\n")
1070    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1071                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1072    (insert "\n"
1073            "Alternatively, select the following item and enter some search terms:\n")
1074    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1075                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1076    (insert "\n"
1077            "This page contains your bookmarked sites (also visit with B):\n")
1078    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1079    (insert "\n"
1080            "** Refer to the ")
1081    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1082      (insert-text-button "Elpher info manual"
1083                          'face 'link
1084                          'action (lambda (_)
1085                                    (interactive)
1086                                    (info "(elpher)"))
1087                          'follow-link t
1088                          'help-echo help-string))
1089    (insert " for the full documentation. **\n")
1090    (insert (propertize
1091             (concat "  (This should be available if you have installed Elpher using\n"
1092                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1093             'face 'shadow))
1094    (elpher-restore-pos)))
1095
1096 ;; Bookmarks page node retrieval
1097
1098 (defun elpher-get-bookmarks-node (renderer)
1099   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1100   (when renderer
1101     (elpher-visit-parent-node)
1102     (error "Command not supported for bookmarks page"))
1103   (elpher-with-clean-buffer
1104    (insert "---- Bookmark list ----\n\n")
1105    (let ((bookmarks (elpher-load-bookmarks)))
1106      (if bookmarks
1107          (dolist (bookmark bookmarks)
1108            (let ((display-string (elpher-bookmark-display-string bookmark))
1109                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1110              (elpher-insert-index-record display-string address)))
1111        (insert "No bookmarks found.\n")))
1112    (insert "\n-----------------------\n\n"
1113            "- u: return to previous page\n"
1114            "- x: delete selected bookmark\n"
1115            "- a: rename selected bookmark\n\n"
1116            "Bookmarks are stored in the file "
1117            (locate-user-emacs-file "elpher-bookmarks"))
1118    (elpher-restore-pos)))
1119
1120
1121 ;;; Bookmarks
1122 ;;
1123
1124 (defun elpher-make-bookmark (display-string url)
1125   "Make an elpher bookmark.
1126 DISPLAY-STRING determines how the bookmark will appear in the
1127 bookmark list, while URL is the url of the entry."
1128   (list display-string url))
1129
1130 (defun elpher-bookmark-display-string (bookmark)
1131   "Get the display string of BOOKMARK."
1132   (elt bookmark 0))
1133
1134 (defun elpher-set-bookmark-display-string (bookmark display-string)
1135   "Set the display string of BOOKMARK to DISPLAY-STRING."
1136   (setcar bookmark display-string))
1137
1138 (defun elpher-bookmark-url (bookmark)
1139   "Get the address for BOOKMARK."
1140   (elt bookmark 1))
1141
1142 (defun elpher-save-bookmarks (bookmarks)
1143   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1144 Beware that this completely replaces the existing contents of the file."
1145   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1146     (erase-buffer)
1147     (insert "; Elpher bookmarks file\n\n"
1148             "; Bookmarks are stored as a list of (label URL) items.\n"
1149             "; Feel free to edit by hand, but take care to ensure\n"
1150             "; the list structure remains intact.\n\n")
1151     (pp bookmarks (current-buffer))))
1152
1153 (defun elpher-load-bookmarks ()
1154   "Get the list of bookmarks from the users's bookmark file."
1155   (let ((bookmarks
1156          (with-temp-buffer
1157            (ignore-errors
1158              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1159              (goto-char (point-min))
1160              (read (current-buffer))))))
1161     (if (and bookmarks (listp (cadar bookmarks)))
1162         (progn
1163           (message "Reading old bookmark file. (Will be updated on write.)")
1164           (mapcar (lambda (old-bm)
1165                     (list (car old-bm)
1166                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1167                                                         (cadr old-bm)))))
1168                   bookmarks))
1169       bookmarks)))
1170
1171 (defun elpher-add-address-bookmark (address display-string)
1172   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1173 If ADDRESS is already bookmarked, update the label only."
1174   (let ((bookmarks (elpher-load-bookmarks))
1175         (url (elpher-address-to-url address)))
1176     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1177       (if existing-bookmark
1178           (elpher-set-bookmark-display-string existing-bookmark display-string)
1179         (push (elpher-make-bookmark display-string url) bookmarks)))
1180     (elpher-save-bookmarks bookmarks)))
1181
1182 (defun elpher-remove-address-bookmark (address)
1183   "Remove any bookmark to ADDRESS."
1184   (let ((url (elpher-address-to-url address)))
1185     (elpher-save-bookmarks
1186      (seq-filter (lambda (bookmark)
1187                    (not (equal (elpher-bookmark-url bookmark) url)))
1188                  (elpher-load-bookmarks)))))
1189
1190 ;;; Interactive procedures
1191 ;;
1192
1193 (defun elpher-next-link ()
1194   "Move point to the next link on the current page."
1195   (interactive)
1196   (forward-button 1))
1197
1198 (defun elpher-prev-link ()
1199   "Move point to the previous link on the current page."
1200   (interactive)
1201   (backward-button 1))
1202
1203 (defun elpher-follow-current-link ()
1204   "Open the link or url at point."
1205   (interactive)
1206   (push-button))
1207
1208 (defun elpher-go ()
1209   "Go to a particular gopher site read from the minibuffer."
1210   (interactive)
1211   (let ((node
1212          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1213            (elpher-make-node host-or-url
1214                              (elpher-address-from-url host-or-url)))))
1215     (switch-to-buffer "*elpher*")
1216     (elpher-visit-node node)))
1217
1218 (defun elpher-go-current ()
1219   "Go to a particular site read from the minibuffer, initialized with the current URL."
1220   (interactive)
1221   (let ((address (elpher-node-address elpher-current-node)))
1222     (if (elpher-address-special-p address)
1223         (error "Command invalid for this page")
1224       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1225         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1226
1227 (defun elpher-redraw ()
1228   "Redraw current page."
1229   (interactive)
1230   (if elpher-current-node
1231       (elpher-visit-node elpher-current-node)
1232     (message "No current site.")))
1233
1234 (defun elpher-reload ()
1235   "Reload current page."
1236   (interactive)
1237   (if elpher-current-node
1238       (elpher-reload-current-node)
1239     (message "No current site.")))
1240
1241 (defun elpher-toggle-tls ()
1242   "Toggle TLS encryption mode for gopher."
1243   (interactive)
1244   (setq elpher-use-tls (not elpher-use-tls))
1245   (if elpher-use-tls
1246       (if (gnutls-available-p)
1247           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1248         (setq elpher-use-tls nil)
1249         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1250     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1251
1252 (defun elpher-view-raw ()
1253   "View raw server response for current page."
1254   (interactive)
1255   (if elpher-current-node
1256       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1257           (error "This page was not generated by a server")
1258         (elpher-visit-node elpher-current-node
1259                            #'elpher-render-raw))
1260     (message "No current site.")))
1261
1262 (defun elpher-back ()
1263   "Go to previous site."
1264   (interactive)
1265   (if (elpher-node-parent elpher-current-node)
1266       (elpher-visit-parent-node)
1267     (error "No previous site")))
1268
1269 (defun elpher-download ()
1270   "Download the link at point."
1271   (interactive)
1272   (let ((button (button-at (point))))
1273     (if button
1274         (let ((node (button-get button 'elpher-node)))
1275           (if (elpher-address-special-p (elpher-node-address node))
1276               (error "Cannot download %s"
1277                      (elpher-node-display-string node))
1278             (elpher-visit-node (button-get button 'elpher-node)
1279                                #'elpher-render-download)))
1280       (error "No link selected"))))
1281
1282 (defun elpher-download-current ()
1283   "Download the current page."
1284   (interactive)
1285   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1286       (error "Cannot download %s"
1287              (elpher-node-display-string elpher-current-node))
1288     (elpher-visit-node (elpher-make-node
1289                         (elpher-node-display-string elpher-current-node)
1290                         (elpher-node-address elpher-current-node)
1291                         elpher-current-node)
1292                        #'elpher-render-download
1293                        t)))
1294
1295 (defun elpher-build-link-map ()
1296   "Build alist mapping link names to destination nodes in current buffer."
1297   (let ((link-map nil)
1298         (b (next-button (point-min) t)))
1299     (while b
1300       (push (cons (button-label b) b) link-map)
1301       (setq b (next-button (button-start b))))
1302     link-map))
1303
1304 (defun elpher-jump ()
1305   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1306   (interactive)
1307   (let* ((link-map (elpher-build-link-map)))
1308     (if link-map
1309         (let ((key (let ((completion-ignore-case t))
1310                      (completing-read "Directory item/link: "
1311                                       link-map nil t))))
1312           (if (and key (> (length key) 0))
1313               (let ((b (cdr (assoc key link-map))))
1314                 (goto-char (button-start b))
1315                 (button-activate b)))))))
1316
1317 (defun elpher-root-dir ()
1318   "Visit root of current server."
1319   (interactive)
1320   (let ((address (elpher-node-address elpher-current-node)))
1321     (if (not (elpher-address-special-p address))
1322         (if (or (member (url-filename address) '("/" ""))
1323                 (and (elpher-address-gopher-p address)
1324                      (= (length (elpher-gopher-address-selector address)) 0)))
1325             (error "Already at root directory of current server")
1326           (let ((address-copy (elpher-address-from-url
1327                                (elpher-address-to-url address))))
1328             (setf (url-filename address-copy) "")
1329             (elpher-visit-node
1330              (elpher-make-node (elpher-address-to-url address-copy)
1331                                address-copy))))
1332       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1333
1334 (defun elpher-bookmarks-current-p ()
1335   "Return non-nil if current node is a bookmarks page."
1336   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1337          '(special bookmarks)))
1338
1339 (defun elpher-reload-bookmarks ()
1340   "Reload bookmarks if current node is a bookmarks page."
1341   (if (elpher-bookmarks-current-p)
1342       (elpher-reload-current-node)))
1343
1344 (defun elpher-bookmark-current ()
1345   "Bookmark the current node."
1346   (interactive)
1347   (let ((address (elpher-node-address elpher-current-node))
1348         (display-string (elpher-node-display-string elpher-current-node)))
1349     (if (not (elpher-address-special-p address))
1350         (let ((bookmark-display-string (read-string "Bookmark display string: "
1351                                                     display-string)))
1352           (elpher-add-address-bookmark address bookmark-display-string)
1353           (message "Bookmark added."))
1354       (error "Cannot bookmark %s" display-string))))
1355
1356 (defun elpher-bookmark-link ()
1357   "Bookmark the link at point."
1358   (interactive)
1359   (let ((button (button-at (point))))
1360     (if button
1361         (let* ((node (button-get button 'elpher-node))
1362                (address (elpher-node-address node))
1363                (display-string (elpher-node-display-string node)))
1364           (if (not (elpher-address-special-p address))
1365               (let ((bookmark-display-string (read-string "Bookmark display string: "
1366                                                           display-string)))
1367                 (elpher-add-address-bookmark address bookmark-display-string)
1368                 (elpher-reload-bookmarks)
1369                 (message "Bookmark added."))
1370             (error "Cannot bookmark %s" display-string)))
1371       (error "No link selected"))))
1372
1373 (defun elpher-unbookmark-current ()
1374   "Remove bookmark for the current node."
1375   (interactive)
1376   (let ((address (elpher-node-address elpher-current-node)))
1377     (unless (elpher-address-special-p address)
1378       (elpher-remove-address-bookmark address)
1379       (message "Bookmark removed."))))
1380
1381 (defun elpher-unbookmark-link ()
1382   "Remove bookmark for the link at point."
1383   (interactive)
1384   (let ((button (button-at (point))))
1385     (if button
1386         (let ((node (button-get button 'elpher-node)))
1387           (elpher-remove-address-bookmark (elpher-node-address node))
1388           (elpher-reload-bookmarks)
1389           (message "Bookmark removed."))
1390       (error "No link selected"))))
1391
1392 (defun elpher-bookmarks ()
1393   "Visit bookmarks page."
1394   (interactive)
1395   (switch-to-buffer "*elpher*")
1396   (elpher-visit-node
1397    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1398
1399 (defun elpher-info-node (node)
1400   "Display information on NODE."
1401   (let ((display-string (elpher-node-display-string node))
1402         (address (elpher-node-address node)))
1403     (if (elpher-address-special-p address)
1404         (message "Special page: %s" display-string)
1405       (message "%s" (elpher-address-to-url address)))))
1406
1407 (defun elpher-info-link ()
1408   "Display information on node corresponding to link at point."
1409   (interactive)
1410   (let ((button (button-at (point))))
1411     (if button
1412         (elpher-info-node (button-get button 'elpher-node))
1413       (error "No item selected"))))
1414
1415 (defun elpher-info-current ()
1416   "Display information on current node."
1417   (interactive)
1418   (elpher-info-node elpher-current-node))
1419
1420 (defun elpher-copy-node-url (node)
1421   "Copy URL representation of address of NODE to `kill-ring'."
1422   (let ((address (elpher-node-address node)))
1423     (if (elpher-address-special-p address)
1424         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1425       (let ((url (elpher-address-to-url address)))
1426         (message "Copied \"%s\" to kill-ring/clipboard." url)
1427         (kill-new url)))))
1428
1429 (defun elpher-copy-link-url ()
1430   "Copy URL of item at point to `kill-ring'."
1431   (interactive)
1432   (let ((button (button-at (point))))
1433     (if button
1434         (elpher-copy-node-url (button-get button 'elpher-node))
1435       (error "No item selected"))))
1436
1437 (defun elpher-copy-current-url ()
1438   "Copy URL of current node to `kill-ring'."
1439   (interactive)
1440   (elpher-copy-node-url elpher-current-node))
1441
1442 (defun elpher-set-gopher-coding-system ()
1443   "Specify an explicit character coding system for gopher selectors."
1444   (interactive)
1445   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1446     (setq elpher-user-coding-system system)
1447     (if system
1448         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1449       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1450
1451
1452 ;;; Mode and keymap
1453 ;;
1454
1455 (defvar elpher-mode-map
1456   (let ((map (make-sparse-keymap)))
1457     (define-key map (kbd "TAB") 'elpher-next-link)
1458     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1459     (define-key map (kbd "u") 'elpher-back)
1460     (define-key map [mouse-3] 'elpher-back)
1461     (define-key map (kbd "O") 'elpher-root-dir)
1462     (define-key map (kbd "g") 'elpher-go)
1463     (define-key map (kbd "o") 'elpher-go-current)
1464     (define-key map (kbd "r") 'elpher-redraw)
1465     (define-key map (kbd "R") 'elpher-reload)
1466     (define-key map (kbd "T") 'elpher-toggle-tls)
1467     (define-key map (kbd ".") 'elpher-view-raw)
1468     (define-key map (kbd "d") 'elpher-download)
1469     (define-key map (kbd "D") 'elpher-download-current)
1470     (define-key map (kbd "m") 'elpher-jump)
1471     (define-key map (kbd "i") 'elpher-info-link)
1472     (define-key map (kbd "I") 'elpher-info-current)
1473     (define-key map (kbd "c") 'elpher-copy-link-url)
1474     (define-key map (kbd "C") 'elpher-copy-current-url)
1475     (define-key map (kbd "a") 'elpher-bookmark-link)
1476     (define-key map (kbd "A") 'elpher-bookmark-current)
1477     (define-key map (kbd "x") 'elpher-unbookmark-link)
1478     (define-key map (kbd "X") 'elpher-unbookmark-current)
1479     (define-key map (kbd "B") 'elpher-bookmarks)
1480     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1481     (when (fboundp 'evil-define-key*)
1482       (evil-define-key* 'motion map
1483         (kbd "TAB") 'elpher-next-link
1484         (kbd "C-") 'elpher-follow-current-link
1485         (kbd "C-t") 'elpher-back
1486         (kbd "u") 'elpher-back
1487         [mouse-3] 'elpher-back
1488         (kbd "g") 'elpher-go
1489         (kbd "o") 'elpher-go-current
1490         (kbd "r") 'elpher-redraw
1491         (kbd "R") 'elpher-reload
1492         (kbd "T") 'elpher-toggle-tls
1493         (kbd ".") 'elpher-view-raw
1494         (kbd "d") 'elpher-download
1495         (kbd "D") 'elpher-download-current
1496         (kbd "m") 'elpher-jump
1497         (kbd "i") 'elpher-info-link
1498         (kbd "I") 'elpher-info-current
1499         (kbd "c") 'elpher-copy-link-url
1500         (kbd "C") 'elpher-copy-current-url
1501         (kbd "a") 'elpher-bookmark-link
1502         (kbd "A") 'elpher-bookmark-current
1503         (kbd "x") 'elpher-unbookmark-link
1504         (kbd "X") 'elpher-unbookmark-current
1505         (kbd "B") 'elpher-bookmarks
1506         (kbd "S") 'elpher-set-gopher-coding-system))
1507     map)
1508   "Keymap for gopher client.")
1509
1510 (define-derived-mode elpher-mode special-mode "elpher"
1511   "Major mode for elpher, an elisp gopher client.
1512
1513 This mode is automatically enabled by the interactive
1514 functions which initialize the gopher client, namely
1515 `elpher', `elpher-go' and `elpher-bookmarks'.")
1516
1517 (when (fboundp 'evil-set-initial-state)
1518   (evil-set-initial-state 'elpher-mode 'motion))
1519
1520
1521 ;;; Main start procedure
1522 ;;
1523
1524 ;;;###autoload
1525 (defun elpher ()
1526   "Start elpher with default landing page."
1527   (interactive)
1528   (if (get-buffer "*elpher*")
1529       (switch-to-buffer "*elpher*")
1530     (switch-to-buffer "*elpher*")
1531     (setq elpher-current-node nil)
1532     (let ((start-node (elpher-make-node "Elpher Start Page"
1533                                         (elpher-make-special-address 'start))))
1534       (elpher-visit-node start-node)))
1535   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1536
1537 ;;; elpher.el ends here