elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2023 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.5.0
   9 ;; Keywords: comm gopher gemini
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69 (require 'rx)
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "3.5.0"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 (defcustom elpher-certificate-map nil
 245   "Register client certificates to be used for gemini URLs.
 246 This variable contains an alist representing a mapping between gemini
 247 URLs and the names of client certificates which will be automatically
 248 activated for those URLs.  Beware that the certificates will also be
 249 active for all subdirectories of the given URLs."
 250   :type '(alist :key-type string :value-type string))
 251
 252 ;; Face customizations
 253
 254 (defgroup elpher-faces nil
 255   "Elpher face customizations."
 256   :group 'elpher)
 257
 258 (defface elpher-index
 259   '((t :inherit font-lock-keyword-face))
 260   "Face used for directory type directory records.")
 261
 262 (defface elpher-text
 263   '((t :inherit bold))
 264   "Face used for text type directory records.")
 265
 266 (defface elpher-info
 267   '((t :inherit default))
 268   "Face used for info type directory records.")
 269
 270 (defface elpher-image
 271   '((t :inherit font-lock-string-face))
 272   "Face used for image type directory records.")
 273
 274 (defface elpher-search
 275   '((t :inherit warning))
 276   "Face used for search type directory records.")
 277
 278 (defface elpher-html
 279   '((t :inherit font-lock-comment-face))
 280   "Face used for html type directory records.")
 281
 282 (defface elpher-gemini
 283   '((t :inherit font-lock-constant-face))
 284   "Face used for Gemini type directory records.")
 285
 286 (defface elpher-other-url
 287   '((t :inherit font-lock-comment-face))
 288   "Face used for other URL type links records.")
 289
 290 (defface elpher-telnet
 291   '((t :inherit font-lock-function-name-face))
 292   "Face used for telnet type directory records.")
 293
 294 (defface elpher-binary
 295   '((t :inherit font-lock-doc-face))
 296   "Face used for binary type directory records.")
 297
 298 (defface elpher-unknown
 299   '((t :inherit error))
 300   "Face used for directory records with unknown/unsupported types.")
 301
 302 (defface elpher-margin-key
 303   '((t :inherit bold))
 304   "Face used for directory margin key.")
 305
 306 (defface elpher-margin-brackets
 307   '((t :inherit shadow))
 308   "Face used for brackets around directory margin key.")
 309
 310 (defface elpher-gemini-heading1
 311   '((t :inherit bold :height 1.8))
 312   "Face used for gemini heading level 1.")
 313
 314 (defface elpher-gemini-heading2
 315   '((t :inherit bold :height 1.5))
 316   "Face used for gemini heading level 2.")
 317
 318 (defface elpher-gemini-heading3
 319   '((t :inherit bold :height 1.2))
 320   "Face used for gemini heading level 3.")
 321
 322 (defface elpher-gemini-quoted
 323   '((t :inherit font-lock-doc-face))
 324   "Face used for gemini quoted texts.")
 325
 326 (defface elpher-gemini-preformatted
 327   '((t :inherit default))
 328   "Face used for gemini preformatted text.")
 329
 330 (defface elpher-gemini-preformatted-toggle
 331   '((t :inherit button))
 332   "Face used for buttons used to toggle display of preformatted text.")
 333
 334 ;;; Model
 335 ;;
 336
 337 ;; Address
 338
 339 ;; An elpher "address" object is either a url object or a symbol.
 340 ;; Addresses with the "about" type, corresponding to pages generated
 341 ;; dynamically for and by elpher.  All others represent pages which
 342 ;; rely on content retrieved over the network.
 343
 344 (defun elpher-address-from-url (url-string &optional default-scheme)
 345   "Create a ADDRESS object corresponding to the given URL-STRING.
 346 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 347 is not explicitly given."
 348   (let ((data (match-data))) ; Prevent parsing clobbering match data
 349     (unwind-protect
 350         (let ((url (url-generic-parse-url url-string)))
 351           (unless (and (not (url-fullness url)) (url-type url))
 352             (unless (url-type url)
 353               (setf (url-type url) default-scheme))
 354             (unless (url-host url)
 355               (let ((p (split-string (url-filename url) "/" nil nil)))
 356                 (setf (url-host url) (car p))
 357                 (setf (url-filename url)
 358                       (if (cdr p)
 359                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 360                         ""))))
 361             (when (not (string-empty-p (url-host url)))
 362               (setf (url-fullness url) t)
 363               (setf (url-host url) (puny-encode-domain (url-host url))))
 364             (when (or (equal "gopher" (url-type url))
 365                       (equal "gophers" (url-type url)))
 366               ;; Gopher defaults
 367               (when (or (equal (url-filename url) "")
 368                         (equal (url-filename url) "/"))
 369                 (setf (url-filename url) "/1")))
 370             (when (equal "gemini" (url-type url))
 371               ;; Gemini defaults
 372               (if (equal (url-filename url) "")
 373                   (setf (url-filename url) "/"))))
 374           (elpher-remove-redundant-ports url))
 375       (set-match-data data))))
 376
 377 (defun elpher-remove-redundant-ports (address)
 378   "Remove redundant port specifiers from ADDRESS.
 379 Here 'redundant' means that the specified port matches the default
 380 for that protocol, eg 70 for gopher."
 381   (if (and (not (elpher-address-about-p address))
 382            (eq (url-portspec address) ; (url-port) is too slow!
 383                (pcase (url-type address)
 384                  ("gemini" 1965)
 385                  ((or "gopher" "gophers") 70)
 386                  ("finger" 79)
 387                  (_ -1))))
 388       (setf (url-portspec address) nil))
 389   address)
 390
 391 (defun elpher-make-gopher-address (type selector host port &optional tls)
 392   "Create an ADDRESS object using gopher directory record attributes.
 393 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 394 If the optional attribute TLS is non-nil, the address will be marked as
 395 requiring gopher-over-TLS."
 396   (cond
 397    ((equal type ?i) nil)
 398    ((and (equal type ?h)
 399          (string-prefix-p "URL:" selector))
 400     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 401    ((equal type ?8)
 402     (elpher-address-from-url
 403      (concat "telnet"
 404              "://" host
 405              ":" (number-to-string port))))
 406    (t
 407     (elpher-address-from-url
 408      (concat "gopher" (if tls "s" "")
 409              "://" host
 410              ":" (number-to-string port)
 411              "/" (string type)
 412              selector)))))
 413
 414 (defun elpher-make-about-address (type)
 415   "Create an ADDRESS object corresponding to the given about address TYPE."
 416   (elpher-address-from-url (concat "about:" (symbol-name type))))
 417
 418 (defun elpher-address-to-url (address)
 419   "Get string representation of ADDRESS."
 420   (url-encode-url (url-recreate-url address)))
 421
 422 (defun elpher-address-type (address)
 423   "Retrieve type of ADDRESS object.
 424 This is used to determine how to retrieve and render the document the
 425 address refers to, via the table `elpher-type-map'."
 426   (pcase (url-type address)
 427     ("about"
 428      (list 'about (intern (url-filename address))))
 429     ((or "gopher" "gophers")
 430      (list 'gopher
 431            (if (member (url-filename address) '("" "/"))
 432                ?1
 433              (string-to-char (substring (url-filename address) 1)))))
 434     ("gemini" 'gemini)
 435     ("telnet" 'telnet)
 436     ("finger" 'finger)
 437     ("file" 'file)
 438     (_ 'other-url)))
 439
 440 (defun elpher-address-about-p (address)
 441   "Return non-nil if ADDRESS is an about address."
 442   (pcase (elpher-address-type address) (`(about ,_) t)))
 443
 444 (defun elpher-address-gopher-p (address)
 445   "Return non-nil if ADDRESS object is a gopher address."
 446   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 447
 448 (defun elpher-address-protocol (address)
 449   "Retrieve the transport protocol for ADDRESS."
 450   (url-type address))
 451
 452 (defun elpher-address-filename (address)
 453   "Retrieve the filename component of ADDRESS.
 454 For gopher addresses this is a combination of the selector type and selector."
 455   (url-unhex-string (url-filename address)))
 456
 457 (defun elpher-address-host (address)
 458   "Retrieve host from ADDRESS object."
 459   (pcase (url-host address)
 460     ;; The following strips out square brackets which sometimes enclose IPv6
 461     ;; addresses.  Doing this here rather than at the parsing stage may seem
 462     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 463     ;; and reconstruction.  It's also more efficient, as this method is not
 464     ;; called during page rendering.
 465     ((rx (: "[" (let ipv6 (* (not "]"))) "]"))
 466      ipv6)
 467     ;; The following is a work-around for a parsing bug that causes
 468     ;; URLs with empty (but not absent, see RFC 1738) usernames to have
 469     ;; @ prepended to the hostname.
 470     ((rx (: "@" (let rest (+ anything))))
 471      rest)
 472     (addr
 473      addr)))
 474
 475 (defun elpher-address-user (address)
 476   "Retrieve user from ADDRESS object."
 477   (url-user address))
 478
 479 (defun elpher-address-port (address)
 480   "Retrieve port from ADDRESS object.
 481 If no address is defined, returns 0.  (This is for compatibility with
 482 the URL library.)"
 483   (let ((port (url-portspec address))) ; (url-port) is too slow!
 484     (if port port 0)))
 485
 486 (defun elpher-gopher-address-selector (address)
 487   "Retrieve gopher selector from ADDRESS object."
 488   (if (member (url-filename address) '("" "/"))
 489       ""
 490     (url-unhex-string (substring (url-filename address) 2))))
 491
 492
 493 ;; Cache
 494
 495 (defvar elpher-content-cache (make-hash-table :test 'equal))
 496 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 497
 498 (defun elpher-get-cached-content (address)
 499   "Retrieve the cached content for ADDRESS, or nil if none exists."
 500   (gethash address elpher-content-cache))
 501
 502 (defun elpher-cache-content (address content)
 503   "Set the content cache for ADDRESS to CONTENT."
 504   (puthash address content elpher-content-cache))
 505
 506 (defun elpher-get-cached-pos (address)
 507   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 508   (gethash address elpher-pos-cache))
 509
 510 (defun elpher-cache-pos (address pos)
 511   "Set the cursor position cache for ADDRESS to POS."
 512   (puthash address pos elpher-pos-cache))
 513
 514
 515 ;; Page
 516
 517 (defun elpher-make-page (display-string address)
 518   "Create a page with DISPLAY-STRING and ADDRESS."
 519   (list display-string address))
 520
 521 (defun elpher-make-start-page ()
 522   "Create the start page."
 523   (elpher-make-page "Start Page"
 524                     (elpher-address-from-url elpher-start-page-url)))
 525
 526 (defun elpher-page-display-string (page)
 527   "Retrieve the display string corresponding to PAGE."
 528   (elt page 0))
 529
 530 (defun elpher-page-address (page)
 531   "Retrieve the address corresponding to PAGE."
 532   (elt page 1))
 533
 534 (defun elpher-page-set-address (page new-address)
 535   "Set the address corresponding to PAGE to NEW-ADDRESS."
 536   (setcar (cdr page) new-address))
 537
 538 (defun elpher-page-from-url (url &optional default-scheme)
 539   "Create a page with address and display string defined by URL.
 540 The URL is unhexed prior to its use as a display string to improve
 541 readability.
 542
 543 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 544 in the instance that URL itself doesn't specify one."
 545   (let ((address (elpher-address-from-url url default-scheme)))
 546     (elpher-make-page (elpher-address-to-iri address) address)))
 547
 548 (defun elpher-address-to-iri (address)
 549   "Return an IRI for ADDRESS.
 550 Decode percent-escapes and handle punycode in the domain name.
 551 Drop the password, if any."
 552   (let ((data (match-data)) ; Prevent parsing clobbering match data
 553         (host (url-host address))
 554         (pass (url-password address)))
 555     (unwind-protect
 556         (let* ((host (url-host address))
 557                (pass (url-password address)))
 558           (when host
 559             (setf (url-host address) (puny-decode-domain host)))
 560           (when pass                             ; RFC 3986 says we should not render
 561             (setf (url-password address) nil)) ; the password as clear text
 562           (elpher-decode (url-unhex-string (url-recreate-url address))))
 563       (setf (url-host address) host)
 564       (setf (url-password address) pass)
 565       (set-match-data data))))
 566
 567 (defvar elpher-current-page nil
 568   "The current page for this Elpher buffer.")
 569
 570 (defvar elpher-history nil
 571   "The local history stack for this Elpher buffer.
 572 This variable is used by `elpher-back' and
 573 `elpher-show-history'.")
 574
 575 (defvar elpher-visited-pages nil
 576   "The global history for all Elpher buffers.
 577 This variable is used by `elpher-show-visited-pages'.")
 578
 579 (defun elpher-visit-page (page &optional renderer no-history)
 580   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 581 Additionally, push PAGE onto the history stack and the list of
 582 previously-visited pages, unless NO-HISTORY is non-nil."
 583   (elpher-save-pos)
 584   (elpher-process-cleanup)
 585   (unless no-history
 586     (unless (or (not elpher-current-page)
 587                  (equal (elpher-page-address elpher-current-page)
 588                         (elpher-page-address page)))
 589       (push elpher-current-page elpher-history)
 590       (unless (or (elpher-address-about-p (elpher-page-address page))
 591                   (and elpher-visited-pages
 592                        (equal page (car elpher-visited-pages))))
 593         (push page elpher-visited-pages))))
 594   (setq-local elpher-current-page page)
 595   (let* ((address (elpher-page-address page))
 596          (type (elpher-address-type address))
 597          (type-record (cdr (assoc type elpher-type-map))))
 598     (if type-record
 599         (funcall (car type-record)
 600                  (if renderer
 601                      renderer
 602                    (cadr type-record)))
 603       (elpher-visit-previous-page)
 604       (pcase type
 605         (`(gopher ,type-char)
 606          (error "Unsupported gopher selector type '%c' for '%s'"
 607                 type-char (elpher-address-to-url address)))
 608         (other
 609          (error "Unsupported address type '%S' for '%s'"
 610                 other (elpher-address-to-url address)))))))
 611
 612 (defun elpher-visit-previous-page ()
 613   "Visit the previous page in the history."
 614   (if elpher-history
 615       (elpher-visit-page (pop elpher-history) nil t)
 616     (error "No previous page")))
 617
 618 (defun elpher-reload-current-page ()
 619   "Reload the current page, discarding any existing cached content."
 620   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 621   (elpher-visit-page elpher-current-page))
 622
 623 (defun elpher-save-pos ()
 624   "Save the current position of point to the current page."
 625   (when elpher-current-page
 626     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 627
 628 (defun elpher-restore-pos ()
 629   "Restore the position of point to that cached in the current page."
 630   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 631     (if pos
 632         (goto-char pos)
 633       (goto-char (point-min)))))
 634
 635 (defun elpher-get-default-url-scheme ()
 636   "Suggest default URL scheme for visiting addresses based on the current page."
 637   (if elpher-current-page
 638       (let* ((address (elpher-page-address elpher-current-page))
 639              (current-type (elpher-address-type address)))
 640         (pcase current-type
 641           ((or (and 'file (guard (not elpher-history)))
 642                `(about ,_))
 643            elpher-default-url-type)
 644           (_
 645            (url-type address))))
 646       elpher-default-url-type))
 647
 648
 649 ;;; Buffer preparation
 650 ;;
 651
 652 (defvar elpher-buffer-name "*elpher*"
 653   "The default name of the Elpher buffer.")
 654
 655 (defun elpher-update-header ()
 656   "If `elpher-use-header' is true, display current page info in window header."
 657   (if (and elpher-use-header elpher-current-page)
 658       (let* ((display-string (elpher-page-display-string elpher-current-page))
 659              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 660              (address (elpher-page-address elpher-current-page))
 661              (tls-string (if (and (not (elpher-address-about-p address))
 662                                   (member (elpher-address-protocol address)
 663                                           '("gophers" "gemini")))
 664                              " [TLS encryption]"
 665                            ""))
 666              (header (concat sanitized-display-string
 667                              (propertize tls-string 'face 'bold))))
 668         (setq header-line-format header))))
 669
 670 (defmacro elpher-with-clean-buffer (&rest args)
 671   "Evaluate ARGS with a clean *elpher* buffer as current."
 672   (declare (debug (body))) ;; Allow edebug to step through body
 673   `(with-current-buffer elpher-buffer-name
 674      (unless (eq major-mode 'elpher-mode)
 675        ;; avoid resetting buffer-local variables
 676        (elpher-mode))
 677      (let ((inhibit-read-only t)
 678            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 679        (setq-local xterm-color--current-fg nil)
 680        (setq-local xterm-color--current-bg nil)
 681        (setq-local network-security-level
 682                    (default-value 'network-security-level))
 683        (erase-buffer)
 684        (elpher-update-header)
 685        ,@args)))
 686
 687 (defun elpher-buffer-message (string &optional line)
 688   "Replace first line in elpher buffer with STRING.
 689 If LINE is non-nil, replace that line instead."
 690   (with-current-buffer elpher-buffer-name
 691     (let ((inhibit-read-only t))
 692       (goto-char (point-min))
 693       (if line
 694           (forward-line line))
 695       (let ((data (match-data)))
 696         (unwind-protect
 697             (progn
 698               (re-search-forward "^.*$")
 699               (replace-match string))
 700           (set-match-data data))))))
 701
 702
 703 ;;; Text Processing
 704 ;;
 705
 706 (defvar elpher-user-coding-system nil
 707   "User-specified coding system to use for decoding text responses.")
 708
 709 (defun elpher-decode (string)
 710   "Decode STRING using autodetected or user-specified coding system."
 711   (decode-coding-string string
 712                         (if elpher-user-coding-system
 713                             elpher-user-coding-system
 714                           (detect-coding-string string t))))
 715
 716 (defun elpher-preprocess-text-response (string)
 717   "Preprocess text selector response contained in STRING.
 718 This involes decoding the character representation, and clearing
 719 away CRs and any terminating period."
 720   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 721                                            (replace-regexp-in-string "\r" "" string))))
 722
 723 ;;; Buttonify urls
 724
 725 (defconst elpher-url-regex
 726   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 727   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 728
 729 (defun elpher-buttonify-urls (string)
 730   "Turn substrings which look like urls in STRING into clickable buttons."
 731   (with-temp-buffer
 732     (insert string)
 733     (goto-char (point-min))
 734     (while (re-search-forward elpher-url-regex nil t)
 735       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 736         (make-text-button (match-beginning 0)
 737                           (match-end 0)
 738                           'elpher-page  page
 739                           'action #'elpher-click-link
 740                           'follow-link t
 741                           'help-echo #'elpher--page-button-help
 742                           'face 'button)))
 743     (buffer-string)))
 744
 745
 746 ;; ANSI colors or XTerm colors (application and filtering)
 747
 748 (or (require 'xterm-color nil t)
 749     (require 'ansi-color))
 750
 751 (defalias 'elpher-color-filter-apply
 752   (if (fboundp 'xterm-color-filter)
 753       (lambda (s)
 754         (let ((_xterm-color-render nil))
 755           (xterm-color-filter s)))
 756     #'ansi-color-filter-apply)
 757   "A function to filter out ANSI escape sequences.")
 758
 759 (defalias 'elpher-color-apply
 760   (if (fboundp 'xterm-color-filter)
 761       #'xterm-color-filter
 762     #'ansi-color-apply)
 763   "A function to apply ANSI escape sequences.")
 764
 765 (defun elpher-text-has-ansi-escapes-p (string)
 766   "Return non-nil if STRING includes an ANSI escape code."
 767   (save-match-data
 768     (string-match "\x1b\\[" string)))
 769
 770
 771 ;; Processing text for display
 772
 773 (defun elpher-process-text-for-display (string)
 774   "Perform any desired processing of STRING prior to display as text.
 775 Currently includes buttonifying URLs and processing ANSI escape codes."
 776   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 777                              (if elpher-filter-ansi-from-text
 778                                  (elpher-color-filter-apply string)
 779                                (elpher-color-apply string))
 780                            string)))
 781
 782
 783 ;;; General network communication
 784 ;;
 785
 786 (defun elpher-network-error (address error)
 787   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 788 ERROR can be either an error object or a string."
 789   (elpher-with-clean-buffer
 790    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 791            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 792            (if (stringp error) error (error-message-string error)) "\n"
 793            (propertize "\n----------------\n\n" 'face 'error)
 794            "Press 'u' to return to the previous page.")))
 795
 796
 797 (defvar elpher-network-timer nil
 798   "Timer used for network connections.")
 799
 800 (defvar elpher-use-tls nil
 801   "If non-nil, use TLS to communicate with gopher servers.")
 802
 803 (defvar elpher-client-certificate nil
 804   "If non-nil, contains details of client certificate to use for TLS connections.
 805 See `elpher-generate-certificate' for further info.")
 806
 807 (defun elpher-process-cleanup ()
 808   "Immediately shut down any extant elpher process and timers."
 809   (let ((p (get-process "elpher-process")))
 810     (if p (delete-process p)))
 811   (if (timerp elpher-network-timer)
 812       (cancel-timer elpher-network-timer)))
 813
 814 (defun elpher-make-network-timer (thunk)
 815   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 816 This is just a wraper around `run-at-time' which additionally sets the
 817 buffer-local variable `elpher-network-timer' to allow
 818 `elpher-process-cleanup' to also clear the timer."
 819   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 820     (setq-local elpher-network-timer timer)
 821     timer))
 822
 823 (defun elpher-get-host-response (address default-port query-string response-processor
 824                                          &optional use-tls force-ipv4)
 825   "Generic function for retrieving data from ADDRESS.
 826
 827 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 828 QUERY-STRING is a string sent to the host specified by ADDRESS to
 829 illicet a response.  This response is passed as an argument to the
 830 function RESPONSE-PROCESSOR.
 831
 832 If non-nil, USE-TLS specifies that the connection is to be made over
 833 TLS.  If set to gemini, the certificate verification will be disabled
 834 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 835
 836 If non-nil, FORCE-IPV4 causes the network connection to be made over
 837 ipv4 only.  (The default behaviour when this is not set depends on
 838 the host operating system and the local network capabilities.)"
 839   (if (and use-tls (not (gnutls-available-p)))
 840       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 841     (unless (< (elpher-address-port address) 65536)
 842       (error "Cannot establish network connection: port number > 65536"))
 843     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 844       (setq-local network-security-level 'low)
 845       (setq-local gnutls-verify-error nil))
 846     (condition-case nil
 847         (let* ((kill-buffer-query-functions nil)
 848                (port (elpher-address-port address))
 849                (host (elpher-address-host address))
 850                (service (if (> port 0) port default-port))
 851                (response-string-parts nil)
 852                (bytes-received 0)
 853                (hkbytes-received 0)
 854                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 855                (gnutls-params (list :type 'gnutls-x509pki
 856                                     :hostname host
 857                                     :keylist
 858                                     (elpher-get-current-keylist address)))
 859                (timer (elpher-make-network-timer
 860                                    (lambda ()
 861                                      (elpher-process-cleanup)
 862                                      (cond
 863                                         ; Try again with IPv4
 864                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 865                                        (message "Connection timed out.  Retrying with IPv4.")
 866                                        (elpher-get-host-response address default-port
 867                                                                  query-string
 868                                                                  response-processor
 869                                                                  use-tls t))
 870                                       ((and use-tls
 871                                             (not (eq use-tls 'gemini))
 872                                             (or elpher-auto-disengage-TLS
 873                                                 (y-or-n-p
 874                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 875                                        (setq elpher-use-tls nil)
 876                                        (elpher-get-host-response address default-port
 877                                                                  query-string
 878                                                                  response-processor
 879                                                                  nil force-ipv4))
 880                                       (t
 881                                        (elpher-network-error address "Connection time-out."))))))
 882                (proc (if socks
 883                          (socks-open-network-stream "elpher-process" nil host service)
 884                        (make-network-process :name "elpher-process"
 885                                              :host host
 886                                              :family (and (or force-ipv4
 887                                                               elpher-ipv4-always)
 888                                                           'ipv4)
 889                                              :service service
 890                                              :buffer nil
 891                                              :nowait t
 892                                              :tls-parameters
 893                                              (and use-tls
 894                                                   (cons 'gnutls-x509pki
 895                                                         (apply #'gnutls-boot-parameters
 896                                                                gnutls-params)))))))
 897           (process-put proc 'elpher-buffer (current-buffer))
 898           (setq elpher-network-timer timer)
 899           (set-process-coding-system proc 'binary 'binary)
 900           (set-process-query-on-exit-flag proc nil)
 901           (elpher-buffer-message (concat "Connecting to " host "..."
 902                                          " (press 'u' to abort)"))
 903           (set-process-filter proc
 904                               (lambda (_proc string)
 905                                 (when timer
 906                                   (cancel-timer timer)
 907                                   (setq timer nil))
 908                                 (setq bytes-received (+ bytes-received (length string)))
 909                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 910                                   (when (> new-hkbytes-received hkbytes-received)
 911                                     (setq hkbytes-received new-hkbytes-received)
 912                                     (elpher-buffer-message
 913                                      (concat "("
 914                                              (number-to-string (/ hkbytes-received 10.0))
 915                                              " MB read)")
 916                                      1)))
 917                                 (setq response-string-parts
 918                                       (cons string response-string-parts))))
 919           (set-process-sentinel proc
 920                                 (lambda (proc event)
 921                                   (when timer
 922                                     (cancel-timer timer))
 923                                   (condition-case the-error
 924                                       (cond
 925                                        ((string-prefix-p "open" event)    ; request URL
 926                                         (elpher-buffer-message
 927                                          (concat "Connected to " host ". Receiving data..."
 928                                                  " (press 'u' to abort)"))
 929                                         (let ((inhibit-eol-conversion t))
 930                                           (process-send-string proc query-string)))
 931                                        ((string-prefix-p "deleted" event)) ; do nothing
 932                                        ((and (not response-string-parts)
 933                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 934                                         ; Try again with IPv4
 935                                         (message "Connection failed. Retrying with IPv4.")
 936                                         (elpher-get-host-response address default-port
 937                                                                   query-string
 938                                                                   response-processor
 939                                                                   use-tls t))
 940                                        (response-string-parts
 941                                         (with-current-buffer (process-get proc 'elpher-buffer)
 942                                           (elpher-with-clean-buffer
 943                                            (insert "Data received.  Rendering..."))
 944                                           (funcall response-processor
 945                                                    (apply #'concat (reverse response-string-parts)))
 946                                           (elpher-restore-pos)))
 947                                        (t
 948                                         (error "No response from server")))
 949                                     (error
 950                                      (elpher-network-error address the-error)))))
 951           (when socks
 952             (if use-tls
 953                 (apply #'gnutls-negotiate :process proc gnutls-params))
 954             (funcall (process-sentinel proc) proc "open\n")))
 955       (error
 956        (elpher-process-cleanup)
 957        (error "Error initiating connection to server")))))
 958
 959
 960 ;;; Client-side TLS Certificate Management
 961 ;;
 962
 963 (defun elpher-generate-certificate (common-name key-file cert-file url-prefix
 964                                                 &optional temporary)
 965   "Generate a key and a self-signed client TLS certificate using openssl.
 966
 967 The Common Name field of the certificate is set to COMMON-NAME.  The
 968 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 969 the key and certificate files to write.
 970
 971 If TEMPORARY is non-nil, the certificate will be given an exporation
 972 period of one day, and the key and certificate files will be deleted
 973 when the certificate is no longer needed for the current session.
 974
 975 Otherwise, the certificate will be given a 100 year expiration period
 976 and the files will not be deleted.
 977
 978 The function returns a list containing the URL-PREFIX of addresses
 979 for which the certificate should be used in this session, the
 980 temporary flag, and the key and cert file names in the form required
 981 by `gnutls-boot-parameters`."
 982   (let ((exp-key-file (expand-file-name key-file))
 983         (exp-cert-file (expand-file-name cert-file)))
 984     (condition-case nil
 985         (progn
 986           (call-process elpher-openssl-command nil nil nil
 987                         "req" "-x509" "-newkey" "rsa:2048"
 988                         "-days" (if temporary "1" "36500")
 989                         "-nodes"
 990                         "-subj" (concat "/CN=" common-name)
 991                         "-keyout" exp-key-file
 992                         "-out" exp-cert-file)
 993           (list url-prefix temporary exp-key-file exp-cert-file))
 994       (error
 995        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 996        (error "Program 'openssl', required for certificate generation, not found")))))
 997
 998 (defun elpher-generate-throwaway-certificate (url-prefix)
 999   "Generate and return details of a throwaway certificate.
1000 The key and certificate files will be deleted when they are no
1001 longer needed for this session.
1002
1003 The certificate will be marked as applying to all addresses with URLs
1004 starting with URL-PREFIX."
1005   (let* ((file-base (make-temp-name "elpher"))
1006          (key-file (concat temporary-file-directory file-base ".key"))
1007          (cert-file (concat temporary-file-directory file-base ".crt")))
1008     (elpher-generate-certificate file-base key-file cert-file url-prefix t)))
1009
1010 (defun elpher-generate-persistent-certificate (file-base common-name url-prefix)
1011   "Generate and return details of a persistent certificate.
1012 The argument FILE-BASE is used as the base for the key and certificate
1013 files, while COMMON-NAME specifies the common name field of the
1014 certificate.
1015
1016 The key and certificate files are written to in `elpher-certificate-directory'.
1017
1018 In this session, the certificate will remain active for all addresses
1019 having URLs starting with URL-PREFIX."
1020   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1021          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1022     (elpher-generate-certificate common-name key-file cert-file url-prefix)))
1023
1024 (defun elpher-get-existing-certificate (file-base url-prefix)
1025   "Return a certificate object corresponding to an existing certificate.
1026 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1027 the directory `elpher-certificate-directory'.
1028
1029 In this session, the certificate will remain active for all addresses
1030 having URLs starting with URL-PREFIX."
1031   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1032          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1033     (list url-prefix
1034           nil
1035           (expand-file-name key-file)
1036           (expand-file-name cert-file))))
1037
1038 (defun elpher-install-certificate (key-file-src cert-file-src file-base url-prefix)
1039   "Install a key+certificate file pair in `elpher-certificate-directory'.
1040 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1041 certificate files to install.  The argument FILE-BASE is used as the
1042 base for the installed key and certificate files.
1043
1044 In this session, the certificate will remain active for all addresses
1045 having URLs starting with URL-PREFIX."
1046   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1047          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1048     (if (or (file-exists-p key-file)
1049             (file-exists-p cert-file))
1050         (error "A certificate with base name %s is already installed" file-base))
1051     (unless (and (file-exists-p key-file-src)
1052                  (file-exists-p cert-file-src))
1053       (error "Either of the key or certificate files do not exist"))
1054     (copy-file key-file-src key-file)
1055     (copy-file cert-file-src cert-file)
1056     (list url-prefix
1057           nil
1058           (expand-file-name key-file)
1059           (expand-file-name cert-file))))
1060
1061 (defun elpher-list-existing-certificates ()
1062   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1063   (unless (file-directory-p elpher-certificate-directory)
1064     (make-directory elpher-certificate-directory))
1065   (mapcar
1066    (lambda (file)
1067      (file-name-sans-extension file))
1068    (directory-files elpher-certificate-directory nil "\\.key$")))
1069
1070 (defun elpher-forget-current-certificate ()
1071   "Causes any current certificate to be forgotten.)
1072 In the case of throwaway certificates, the key and certificate files
1073 are also deleted."
1074   (interactive)
1075   (when elpher-client-certificate
1076     (unless (and (called-interactively-p 'any)
1077                  (not (y-or-n-p (concat "Really forget client certificate? "
1078                                         "(Throwaway certificates will be deleted.)"))))
1079       (when (cadr elpher-client-certificate)
1080         (delete-file (elt elpher-client-certificate 2))
1081         (delete-file (elt elpher-client-certificate 3)))
1082       (setq-local elpher-client-certificate nil)
1083       (if (called-interactively-p 'any)
1084           (message "Client certificate forgotten.")))))
1085
1086 (defun elpher-get-current-keylist (address)
1087   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1088
1089 This is obtained from the client certificate described by
1090 `elpher-current-certificate', if one is available and the
1091 URL prefix for that certificate matches ADDRESS.
1092
1093 If `elpher-current-certificate' is non-nil, and its URL prefix doesn't
1094 match that of ADDRESS, the certificate is forgotten."
1095   (if elpher-client-certificate
1096       (if (string-prefix-p (car elpher-client-certificate)
1097                            (elpher-address-to-url address))
1098           (list (cddr elpher-client-certificate))
1099         (elpher-forget-current-certificate)
1100         (message "Disabling client certificate for new host")
1101         nil)
1102     nil))
1103
1104
1105 ;;; Gopher selector retrieval
1106 ;;
1107
1108 (defun elpher-get-gopher-response (address renderer)
1109   "Get response string from gopher server at ADDRESS and render using RENDERER."
1110   (elpher-get-host-response address 70
1111                             (concat (elpher-gopher-address-selector address) "\r\n")
1112                             renderer
1113                             (or (string= (elpher-address-protocol address) "gophers")
1114                                 elpher-use-tls)))
1115
1116 (defun elpher-get-gopher-page (renderer)
1117   "Getter function for gopher pages.
1118 The RENDERER procedure is used to display the contents of the page
1119 once they are retrieved from the gopher server."
1120   (let* ((address (elpher-page-address elpher-current-page))
1121          (content (elpher-get-cached-content address)))
1122     (if (and content (funcall renderer nil))
1123         (elpher-with-clean-buffer
1124          (insert content)
1125          (elpher-restore-pos))
1126       (elpher-with-clean-buffer
1127        (insert "LOADING... (use 'u' to cancel)\n"))
1128       (condition-case the-error
1129           (elpher-get-gopher-response address renderer)
1130         (error
1131          (elpher-network-error address the-error))))))
1132
1133
1134 ;;; Gopher index rendering
1135 ;;
1136
1137 (defun elpher-insert-margin (&optional type-name)
1138   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1139   (if type-name
1140       (progn
1141         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1142                         (concat
1143                          (propertize "[" 'face 'elpher-margin-brackets)
1144                          (propertize type-name 'face 'elpher-margin-key)
1145                          (propertize "]" 'face 'elpher-margin-brackets))))
1146         (insert " "))
1147     (insert (make-string elpher-margin-width ?\s))))
1148
1149 (defun elpher--page-button-help (_window buffer pos)
1150   "Function called by Emacs to generate mouse-over text.
1151 The arguments specify the BUFFER and the POS within the buffer of the item
1152 for which help is required.  The function returns the help to be
1153 displayed.  The _WINDOW argument is currently unused."
1154   (with-current-buffer buffer
1155     (let ((button (button-at pos)))
1156       (when button
1157         (let* ((page (button-get button 'elpher-page))
1158                (address (elpher-page-address page)))
1159           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1160
1161 (defun elpher-insert-index-record (display-string &optional address)
1162   "Function to insert an index record into the current buffer.
1163 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1164 If ADDRESS is not supplied or nil the record is rendered as an
1165 'information' line."
1166   (let* ((type (if address (elpher-address-type address) nil))
1167          (type-map-entry (cdr (assoc type elpher-type-map))))
1168     (if type-map-entry
1169         (let* ((margin-code (elt type-map-entry 2))
1170                (face (elt type-map-entry 3))
1171                (filtered-display-string (elpher-color-filter-apply display-string))
1172                (page (elpher-make-page filtered-display-string address)))
1173           (elpher-insert-margin margin-code)
1174           (insert-text-button filtered-display-string
1175                               'face face
1176                               'elpher-page page
1177                               'action #'elpher-click-link
1178                               'follow-link t
1179                               'help-echo #'elpher--page-button-help))
1180       (pcase type
1181         ('nil ;; Information
1182          (elpher-insert-margin)
1183          (let ((propertized-display-string
1184                 (propertize display-string 'face 'elpher-info)))
1185            (insert (elpher-process-text-for-display propertized-display-string))))
1186         (`(gopher ,selector-type) ;; Unknown
1187          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1188          (insert (propertize display-string
1189                              'face 'elpher-unknown)))))
1190     (insert "\n")))
1191
1192 (defun elpher-click-link (button)
1193   "Function called when the gopher link BUTTON is activated."
1194   (let ((page (button-get button 'elpher-page)))
1195     (elpher-visit-page page)))
1196
1197 (defun elpher-render-index (data &optional _mime-type-string)
1198   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1199   (elpher-with-clean-buffer
1200    (if (not data)
1201        t
1202      (let ((data-processed (elpher-preprocess-text-response data)))
1203        (dolist (line (split-string data-processed "\n"))
1204          (ignore-errors
1205            (unless (= (length line) 0)
1206              (let* ((type (elt line 0))
1207                     (fields (split-string (substring line 1) "\t"))
1208                     (display-string (elt fields 0))
1209                     (selector (elt fields 1))
1210                     (host (elt fields 2))
1211                     (port (if (elt fields 3)
1212                               (string-to-number (elt fields 3))
1213                             nil))
1214                     (address (elpher-make-gopher-address type selector host port)))
1215                (elpher-insert-index-record display-string address))))))
1216      (elpher-cache-content (elpher-page-address elpher-current-page)
1217                            (buffer-string)))))
1218
1219
1220 ;;; Gopher text rendering
1221 ;;
1222
1223 (defun elpher-render-text (data &optional _mime-type-string)
1224   "Render DATA as text.  MIME-TYPE-STRING is unused."
1225   (elpher-with-clean-buffer
1226    (if (not data)
1227        t
1228      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1229      (elpher-cache-content
1230       (elpher-page-address elpher-current-page)
1231       (buffer-string)))))
1232
1233
1234 ;;; Image retrieval
1235 ;;
1236
1237 (defun elpher-render-image (data &optional _mime-type-string)
1238   "Display DATA as image.  MIME-TYPE-STRING is unused."
1239   (if (not data)
1240       nil
1241     (if (display-images-p)
1242         (let* ((image (create-image
1243                        data
1244                        nil t)))
1245           (if (not image)
1246               (error "Unsupported image format")
1247             (let ((window (get-buffer-window elpher-buffer-name)))
1248               (when window
1249                 (setf (image-property image :max-width) (window-body-width window t))
1250                 (setf (image-property image :max-height) (window-body-height window t))))
1251             (elpher-with-clean-buffer
1252              (insert-image image)
1253              (elpher-restore-pos))))
1254       (elpher-render-download data))))
1255
1256
1257 ;;; Gopher search retrieval and rendering
1258 ;;
1259
1260 (defun elpher-get-gopher-query-page (renderer)
1261   "Getter for gopher addresses requiring input.
1262 The response is rendered using the rendering function RENDERER."
1263   (let* ((address (elpher-page-address elpher-current-page))
1264          (content (elpher-get-cached-content address))
1265          (aborted t))
1266     (if (and content (funcall renderer nil))
1267         (elpher-with-clean-buffer
1268          (insert content)
1269          (elpher-restore-pos)
1270          (message "Displaying cached search results.  Reload to perform a new search."))
1271       (unwind-protect
1272           (let* ((query-string (read-string "Query: "))
1273                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1274                  (search-address (elpher-make-gopher-address ?1
1275                                                              query-selector
1276                                                              (elpher-address-host address)
1277                                                              (elpher-address-port address)
1278                                                              (equal (elpher-address-type address) "gophers"))))
1279             (setq aborted nil)
1280
1281             (elpher-with-clean-buffer
1282              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1283             (elpher-get-gopher-response search-address renderer))
1284         (if aborted
1285             (elpher-visit-previous-page))))))
1286
1287
1288 ;;; Raw server response rendering
1289 ;;
1290
1291 (defun elpher-render-raw (data &optional mime-type-string)
1292   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1293   (if (not data)
1294       nil
1295     (elpher-with-clean-buffer
1296      (when mime-type-string
1297        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1298      (insert data)
1299      (goto-char (point-min)))
1300     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1301
1302
1303 ;;; File save "rendering"
1304 ;;
1305
1306 (defun elpher-render-download (data &optional _mime-type-string)
1307   "Save DATA to file.  MIME-TYPE-STRING is unused."
1308   (if (not data)
1309       nil
1310     (let* ((address (elpher-page-address elpher-current-page))
1311            (selector (if (elpher-address-gopher-p address)
1312                          (elpher-gopher-address-selector address)
1313                        (elpher-address-filename address))))
1314       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1315       (let* ((filename-proposal (file-name-nondirectory selector))
1316              (filename (read-file-name "Download complete. Save file as: "
1317                                        nil nil nil
1318                                        (if (> (length filename-proposal) 0)
1319                                            filename-proposal
1320                                          "download.file"))))
1321         (let ((coding-system-for-write 'binary))
1322           (with-temp-file filename
1323             (insert data)))
1324         (message (format "Saved to file %s." filename))))))
1325
1326
1327 ;;; HTML rendering
1328 ;;
1329
1330 (defun elpher-render-html (data &optional _mime-type-string)
1331   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1332   (elpher-with-clean-buffer
1333    (if (not data)
1334        t
1335      (let ((dom (with-temp-buffer
1336                   (insert data)
1337                   (libxml-parse-html-region (point-min) (point-max)))))
1338        (shr-insert-document dom)))))
1339
1340
1341 ;;; Gemini page retrieval
1342 ;;
1343
1344 (defvar elpher-gemini-redirect-chain)
1345
1346 (defun elpher-get-gemini-response (address renderer)
1347   "Get response string from gemini server at ADDRESS and render using RENDERER."
1348   (elpher-get-host-response address 1965
1349                             (concat (elpher-address-to-url address) "\r\n")
1350                             (lambda (response-string)
1351                               (elpher-process-gemini-response response-string renderer))
1352                             'gemini))
1353
1354 (defun elpher-parse-gemini-response (response)
1355   "Parse the RESPONSE string and return a list of components.
1356 The list is of the form (code meta body).  A response of nil implies
1357 that the response was malformed."
1358   (let ((header-end-idx (string-match "\r\n" response)))
1359     (if header-end-idx
1360         (let ((header (string-trim (substring response 0 header-end-idx)))
1361               (body (substring response (+ header-end-idx 2))))
1362           (if (>= (length header) 2)
1363               (let ((code (substring header 0 2))
1364                     (meta (string-trim (substring header 2))))
1365                 (list code meta body))
1366             (error "Malformed response: No response status found in header %s" header)))
1367       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1368
1369 (defun elpher-process-gemini-response (response-string renderer)
1370   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1371   (let ((response-components (elpher-parse-gemini-response response-string)))
1372     (let ((response-code (elt response-components 0))
1373           (response-meta (elt response-components 1))
1374           (response-body (elt response-components 2)))
1375       (pcase (elt response-code 0)
1376         (?1 ; Input required
1377          (elpher-with-clean-buffer
1378           (insert "Gemini server is requesting input."))
1379          (let* ((query-string
1380                  (with-local-quit
1381                    (if (eq (elt response-code 1) ?1)
1382                        (read-passwd (concat response-meta ": "))
1383                      (read-string (concat response-meta ": ")))))
1384                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1385                 (old-fname (url-filename query-address)))
1386            (if (not query-string)
1387                (elpher-visit-previous-page)
1388              (setf (url-filename query-address)
1389                    (concat old-fname "?" (url-build-query-string `((,query-string)))))
1390              (elpher-get-gemini-response query-address renderer))))
1391         (?2 ; Normal response
1392          (funcall renderer response-body response-meta))
1393         (?3 ; Redirect
1394          (message "Following redirect to %s" response-meta)
1395          (if (>= (length elpher-gemini-redirect-chain) 5)
1396              (error "More than 5 consecutive redirects followed"))
1397          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1398            (if (member redirect-address elpher-gemini-redirect-chain)
1399                (error "Redirect loop detected"))
1400            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1401                (error "Server tried to automatically redirect to non-gemini URL: %s"
1402                       response-meta))
1403            (elpher-page-set-address elpher-current-page redirect-address)
1404            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1405            (elpher-get-gemini-response redirect-address renderer)))
1406         (?4 ; Temporary failure
1407          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1408                 response-code response-meta))
1409         (?5 ; Permanent failure
1410          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1411                 response-code response-meta))
1412         (?6 ; Client certificate required
1413          (elpher-with-clean-buffer
1414           (if elpher-client-certificate
1415               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1416             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1417           (auto-fill-mode 1)
1418           (elpher-gemini-insert-text response-meta))
1419          (let ((chosen-certificate
1420                 (with-local-quit
1421                   (elpher-acquire-client-certificate))))
1422            (unless chosen-certificate
1423              (error "Gemini server requires a client certificate and none was provided"))
1424            (setq-local elpher-client-certificate chosen-certificate))
1425          (elpher-with-clean-buffer)
1426          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1427         (_other
1428          (error "Gemini server response unknown: %s %s"
1429                 response-code response-meta))))))
1430
1431 (defun elpher-acquire-client-certificate ()
1432   "Select and activate a pre-defined client certificate or prompt for one.
1433 In this case, \"pre-defined\" means a certificate provided by
1434 the `elpher-certificate-map' variable."
1435   (let* ((current-url (elpher-address-to-url (elpher-page-address elpher-current-page)))
1436          (entry (assoc current-url
1437                        elpher-certificate-map
1438                        #'string-prefix-p)))
1439     (if entry
1440         (let ((cert-url-regex (car entry))
1441               (cert-name (cadr entry)))
1442           (message "Using certificate \"%s\" specified in elpher-certificate-map with prefix \"%s\""
1443                    cert-name cert-url-regex)
1444           (elpher-get-existing-certificate cert-name cert-url-regex))
1445       (elpher-prompt-for-client-certificate current-url))))
1446
1447 (defun elpher--read-answer-polyfill (question answers)
1448   "Polyfill for `read-answer' in Emacs 26.1.
1449 QUESTION is a string containing a question, and ANSWERS
1450 is a list of possible answers, or an alist whose keys
1451 are the possible answers."
1452     (completing-read question answers))
1453
1454 (if (fboundp 'read-answer)
1455     (defalias 'elpher-read-answer 'read-answer)
1456   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1457
1458
1459
1460 (defun elpher-prompt-for-client-certificate (url-prefix)
1461   "Prompt for a client certificate to use to establish a TLS connection.
1462
1463 In this session, the chosen certificate will remain active for all
1464 addresses with URLs matching URL-PREFIX."
1465   (let* ((read-answer-short t))
1466     (pcase (read-answer "What do you want to do? "
1467                         '(("throwaway" ?t
1468                            "generate and use throw-away certificate")
1469                           ("persistent" ?p
1470                            "generate new or use existing persistent certificate")
1471                           ("abort" ?a
1472                            "stop immediately")))
1473       ("throwaway"
1474        (setq-local elpher-client-certificate (elpher-generate-throwaway-certificate url-prefix)))
1475       ("persistent"
1476        (let* ((existing-certificates (elpher-list-existing-certificates))
1477               (file-base (completing-read
1478                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1479                           existing-certificates)))
1480          (if (string-empty-p (string-trim file-base))
1481              nil
1482            (if (member file-base existing-certificates)
1483                (setq-local elpher-client-certificate
1484                      (elpher-get-existing-certificate file-base url-prefix))
1485              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1486                                  '(("new" ?n
1487                                     "generate new certificate")
1488                                    ("install" ?i
1489                                     "install existing certificate")
1490                                    ("abort" ?a
1491                                     "stop immediately")))
1492                ("new"
1493                 (let ((common-name (read-string "Common Name field for new certificate: "
1494                                                 file-base)))
1495                   (message "New key and self-signed certificate written to %s"
1496                            elpher-certificate-directory)
1497                   (elpher-generate-persistent-certificate file-base
1498                                                           common-name
1499                                                           url-prefix)))
1500                ("install"
1501                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1502                        (key-file (read-file-name "Key file: " nil nil t)))
1503                   (message "Key and certificate installed in %s for future use"
1504                            elpher-certificate-directory)
1505                   (elpher-install-certificate key-file cert-file file-base
1506                                               url-prefix)))
1507                ("abort" nil))))))
1508       ("abort" nil))))
1509
1510 (defun elpher-get-gemini-page (renderer)
1511   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1512   (let* ((address (elpher-page-address elpher-current-page))
1513          (content (elpher-get-cached-content address)))
1514     (condition-case the-error
1515         (if (and content (funcall renderer nil))
1516             (elpher-with-clean-buffer
1517              (insert content)
1518              (elpher-restore-pos))
1519           (elpher-with-clean-buffer
1520            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1521           (setq elpher-gemini-redirect-chain nil)
1522           (elpher-get-gemini-response address renderer))
1523       (error
1524        (elpher-network-error address the-error)))))
1525
1526 ;;; Gemini page rendering
1527 ;;
1528
1529 (defun elpher-render-gemini (body &optional mime-type-string)
1530   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1531   (if (not body)
1532       t
1533     (let* ((mime-type-string* (if (or (not mime-type-string)
1534                                       (string-empty-p mime-type-string))
1535                                   "text/gemini; charset=utf-8"
1536                                 mime-type-string))
1537            (mime-type-split (split-string mime-type-string* ";" t))
1538            (mime-type (string-trim (car mime-type-split)))
1539            (parameters (mapcar (lambda (s)
1540                                  (let ((key-val (split-string s "=")))
1541                                    (list (downcase (string-trim (car key-val)))
1542                                          (downcase (string-trim (cadr key-val))))))
1543                                (cdr mime-type-split))))
1544       (when (string-prefix-p "text/" mime-type)
1545         (setq body (decode-coding-string
1546                     body
1547                     (if (assoc "charset" parameters)
1548                         (intern (cadr (assoc "charset" parameters)))
1549                       'utf-8)))
1550         (setq body (replace-regexp-in-string "\r" "" body)))
1551       (pcase mime-type
1552         ((or "text/gemini" "")
1553          (elpher-render-gemini-map body parameters))
1554         ("text/html"
1555          (elpher-render-html body))
1556         ((pred (string-prefix-p "text/"))
1557          (elpher-render-gemini-plain-text body parameters))
1558         ((pred (string-prefix-p "image/"))
1559          (elpher-render-image body))
1560         (_other
1561          (elpher-render-download body))))))
1562
1563 (defun elpher-gemini-get-link-url (link-line)
1564   "Extract the url portion of LINK-LINE, a gemini map file link line.
1565 Returns nil in the event that the contents of the line following the
1566 => prefix are empty."
1567   (let ((l (split-string (substring link-line 2))))
1568     (if l
1569         (string-trim (elt l 0))
1570       nil)))
1571
1572 (defun elpher-gemini-get-link-display-string (link-line)
1573   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1574 Return nil if this portion is not provided."
1575   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1576          (idx (string-match "[ \t]" rest)))
1577     (and idx
1578          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1579
1580 (defun elpher-collapse-dot-sequences (filename)
1581   "Collapse dot sequences in the (absolute) FILENAME.
1582 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1583   (let* ((path (split-string filename "/" t))
1584          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1585          (path-reversed-normalized
1586           (seq-reduce (lambda (a b)
1587                         (cond ((equal b "..") (cdr a))
1588                               ((equal b ".") a)
1589                               (t (cons b a))))
1590                       path nil))
1591          (path-normalized (reverse path-reversed-normalized)))
1592     (if path-normalized
1593         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1594       "/")))
1595
1596 (defun elpher-address-from-gemini-url (url)
1597   "Extract address from URL with defaults as per gemini map files.
1598 While there's obviously some redundancy here between this function and
1599 `elpher-address-from-url', gemini map file URLs require enough special
1600 treatment that a separate function is warranted."
1601   (let ((address (url-generic-parse-url url))
1602         (current-address (elpher-page-address elpher-current-page)))
1603     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1604       (if (url-host address) ;if there is an explicit host, filenames are absolute
1605           (if (string-empty-p (url-filename address))
1606               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1607         (setf (url-host address) (url-host current-address))
1608         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1609         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1610         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1611           (setf (url-filename address)
1612                 (concat (file-name-directory (url-filename current-address))
1613                         (url-filename address)))))
1614       (when (url-host address)
1615         (setf (url-host address) (puny-encode-domain (url-host address))))
1616       (unless (url-type address)
1617         (setf (url-type address) (url-type current-address)))
1618       (when (equal (url-type address) "gemini")
1619         (setf (url-filename address)
1620               (elpher-collapse-dot-sequences (url-filename address)))))
1621     (elpher-remove-redundant-ports address)))
1622
1623 (defun elpher-gemini-insert-link (link-line)
1624   "Insert link described by LINK-LINE into a text/gemini document."
1625   (let ((url (elpher-gemini-get-link-url link-line)))
1626     (when url
1627       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1628              (address (elpher-address-from-gemini-url url))
1629              (type (if address (elpher-address-type address) nil))
1630              (type-map-entry (cdr (assoc type elpher-type-map)))
1631              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1632         (when type-map-entry
1633           (insert elpher-gemini-link-string)
1634           (let* ((face (elt type-map-entry 3))
1635                  (display-string (or given-display-string
1636                                      (elpher-address-to-iri address)))
1637                  (page (elpher-make-page display-string
1638                                          address)))
1639             (insert-text-button display-string
1640                                 'face face
1641                                 'elpher-page page
1642                                 'action #'elpher-click-link
1643                                 'follow-link t
1644                                 'help-echo #'elpher--page-button-help))
1645           (newline))))))
1646
1647 (defun elpher-gemini-insert-header (header-line)
1648   "Insert header described by HEADER-LINE into a text/gemini document.
1649 The gemini map file line describing the header is given
1650 by HEADER-LINE."
1651   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1652     (let* ((level (length (match-string 1 header-line)))
1653            (header (substring header-line (match-end 0)))
1654            (face (pcase level
1655                    (1 'elpher-gemini-heading1)
1656                    (2 'elpher-gemini-heading2)
1657                    (3 'elpher-gemini-heading3)
1658                    (_ 'default)))
1659            (fill-column (if (display-graphic-p)
1660                             (/ (* fill-column
1661                                   (font-get (font-spec :name (face-font 'default)) :size))
1662                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1663       (unless (display-graphic-p)
1664         (insert (make-string level ?#) " "))
1665       (insert (propertize header
1666                           'face face
1667                           'gemini-heading t
1668                           'rear-nonsticky t))
1669       (newline))))
1670
1671 (defun elpher-gemini-insert-text (text-line)
1672   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1673 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1674 width defined by `elpher-gemini-max-fill-width'."
1675   (string-match
1676    (rx (: line-start
1677           (optional
1678            (group (or (: "*" (+ (any " \t")))
1679                       (: ">" (* (any " \t"))))))))
1680    text-line)
1681   (let* ((line-prefix (match-string 1 text-line))
1682          (processed-text-line
1683           (if line-prefix
1684               (cond ((string-prefix-p "*" line-prefix)
1685                      (concat
1686                       (replace-regexp-in-string "\\*"
1687                                                 elpher-gemini-bullet-string
1688                                                 (match-string 0 text-line))
1689                       (substring text-line (match-end 0))))
1690                     ((string-prefix-p ">" line-prefix)
1691                      (propertize text-line 'face 'elpher-gemini-quoted))
1692                     (t text-line))
1693             text-line))
1694          (fill-prefix (if line-prefix
1695                           (make-string (length (match-string 0 text-line)) ?\s)
1696                         "")))
1697     (insert (elpher-process-text-for-display processed-text-line))
1698     (newline)))
1699
1700 (defun elpher-gemini-pref-expand-collapse (button)
1701   "Function called when the preformatted text toggle BUTTON is activated."
1702   (let ((id (button-get button 'pref-id)))
1703     (if (invisible-p id)
1704         (remove-from-invisibility-spec id)
1705       (add-to-invisibility-spec id))
1706     (redraw-display)))
1707
1708 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1709   "Insert a button for toggling the visibility of preformatted text.
1710 If non-nil, ALT-TEXT is displayed alongside the button."
1711   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1712          (pref-id (intern (concat "pref-"
1713                                   (number-to-string (point))
1714                                   "-"
1715                                   url-string))))
1716     (insert elpher-gemini-preformatted-toggle-bullet)
1717     (when alt-text
1718       (insert (propertize (concat alt-text " ")
1719                           'face 'elpher-gemin-preformatted)))
1720     (insert-text-button elpher-gemini-preformatted-toggle-label
1721                         'action #'elpher-gemini-pref-expand-collapse
1722                         'pref-id pref-id
1723                         'face 'elpher-gemini-preformatted-toggle)
1724     (add-to-invisibility-spec pref-id)
1725     (newline)
1726     pref-id))
1727
1728 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1729   "Insert a LINE of preformatted text.
1730 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1731 can be used to toggle the display of the preformatted text."
1732   (insert (propertize (concat (elpher-process-text-for-display
1733                                (propertize line 'face 'elpher-gemini-preformatted))
1734                               "\n")
1735                       'invisible pref-id
1736                       'rear-nonsticky t)))
1737
1738 (defun elpher-render-gemini-map (data _parameters)
1739   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1740   (elpher-with-clean-buffer
1741    (auto-fill-mode 1)
1742    (setq-local buffer-invisibility-spec nil)
1743    (let ((preformatted nil)
1744          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1745      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1746      (dolist (line (split-string data "\n"))
1747        (pcase line
1748          ((rx (: string-start "```" (opt (let alt-text (+ any)))))
1749           (setq preformatted
1750                 (if preformatted
1751                     nil
1752                   (if elpher-gemini-hide-preformatted
1753                       (elpher-gemini-insert-preformatted-toggler alt-text)
1754                     t))))
1755          ((guard  preformatted)
1756           (elpher-gemini-insert-preformatted-line line preformatted))
1757          ((pred (string-prefix-p "=>"))
1758           (elpher-gemini-insert-link line))
1759          ((pred (string-prefix-p "#"))
1760           (elpher-gemini-insert-header line))
1761          (_ (elpher-gemini-insert-text line))))
1762    (elpher-cache-content
1763     (elpher-page-address elpher-current-page)
1764     (buffer-string)))))
1765
1766 (defun elpher-render-gemini-plain-text (data _parameters)
1767   "Render DATA as plain text file.  PARAMETERS is currently unused."
1768   (elpher-with-clean-buffer
1769    (insert (elpher-process-text-for-display data))
1770    (elpher-cache-content
1771     (elpher-page-address elpher-current-page)
1772     (buffer-string))))
1773
1774 (defun elpher-build-current-imenu-index ()
1775   "Build imenu index for current elpher buffer."
1776   (save-excursion
1777     (goto-char (point-min))
1778     (let ((match nil)
1779           (headers nil))
1780       (while (setq match (text-property-search-forward 'gemini-heading t t))
1781         (push (cons
1782                (buffer-substring-no-properties (prop-match-beginning match)
1783                                                (prop-match-end match))
1784                (prop-match-beginning match))
1785               headers))
1786       (reverse headers))))
1787
1788
1789 ;;; Finger page connection
1790 ;;
1791
1792 (defun elpher-get-finger-page (renderer)
1793   "Opens a finger connection to the current page address.
1794 The result is rendered using RENDERER."
1795   (let* ((address (elpher-page-address elpher-current-page))
1796          (content (elpher-get-cached-content address)))
1797     (if (and content (funcall renderer nil))
1798         (elpher-with-clean-buffer
1799          (insert content)
1800          (elpher-restore-pos))
1801       (elpher-with-clean-buffer
1802        (insert "LOADING... (use 'u' to cancel)\n"))
1803       (condition-case the-error
1804           (let* ((kill-buffer-query-functions nil)
1805                  (user (let ((filename (elpher-address-filename address)))
1806                          (if (> (length filename) 1)
1807                              (substring filename 1)
1808                            (elpher-address-user address)))))
1809             (elpher-get-host-response address 79
1810                                       (concat user "\r\n")
1811                                       renderer))
1812         (error
1813          (elpher-network-error address the-error))))))
1814
1815
1816 ;;; Telnet page connection
1817 ;;
1818
1819 (defun elpher-get-telnet-page (renderer)
1820   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1821   (when renderer
1822     (elpher-visit-previous-page)
1823     (error "Command not supported for telnet URLs"))
1824   (let* ((address (elpher-page-address elpher-current-page))
1825          (host (elpher-address-host address))
1826          (port (elpher-address-port address)))
1827     (elpher-visit-previous-page)
1828     (if (> port 0)
1829         (telnet host port)
1830       (telnet host))))
1831
1832
1833 ;;; Other URL page opening
1834 ;;
1835
1836 (defun elpher-get-other-url-page (renderer)
1837   "Getter which attempts to open the URL specified by the current page.
1838 The RENDERER argument to this getter must be nil."
1839   (when renderer
1840     (elpher-visit-previous-page)
1841     (error "Command not supported for general URLs"))
1842   (let* ((address (elpher-page-address elpher-current-page))
1843          (url (elpher-address-to-url address)))
1844     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1845     (message "Opening URL...")
1846     (if elpher-open-urls-with-eww
1847         (browse-web url)
1848       (browse-url url))))
1849
1850
1851 ;;; File page
1852 ;;
1853
1854 (defun elpher-get-file-page (renderer)
1855   "Getter which renders a local file using RENDERER.
1856 Assumes UTF-8 encoding for all text files."
1857   (let* ((address (elpher-page-address elpher-current-page))
1858          (filename (elpher-address-filename address)))
1859     (unless (file-exists-p filename)
1860       (elpher-visit-previous-page)
1861       (error "File not found"))
1862     (unless (file-readable-p filename)
1863       (elpher-visit-previous-page)
1864       (error "Could not read from file"))
1865     (let ((body (with-temp-buffer
1866        (let ((coding-system-for-read 'binary)
1867              (coding-system-for-write 'binary))
1868          (insert-file-contents-literally filename)
1869          (encode-coding-string (buffer-string) 'raw-text)))))
1870        (if renderer
1871            (funcall renderer body nil)
1872          (pcase (file-name-extension filename)
1873            ((or  "gmi" "gemini")
1874             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1875            ((or "htm" "html")
1876             (elpher-render-html (decode-coding-string body 'utf-8)))
1877            ((or "txt" "")
1878             (elpher-render-text (decode-coding-string body 'utf-8)))
1879            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1880             (elpher-render-image body))
1881            ((or "gopher" "gophermap")
1882             (elpher-render-index (elpher-decode body)))
1883            (_
1884             (elpher-render-download body))))
1885        (elpher-restore-pos))))
1886
1887
1888 ;;; Welcome page retrieval
1889 ;;
1890
1891 (defun elpher-get-welcome-page (renderer)
1892   "Getter which displays the welcome page (RENDERER must be nil)."
1893   (when renderer
1894     (elpher-visit-previous-page)
1895     (error "Command not supported for welcome page"))
1896   (elpher-with-clean-buffer
1897    (insert "     --------------------------------------------\n"
1898            "           Elpher Gopher and Gemini Client       \n"
1899            "                   version " elpher-version "\n"
1900            "     --------------------------------------------\n"
1901            "\n"
1902            "Default bindings:\n"
1903            "\n"
1904            " - TAB/Shift-TAB: next/prev item on current page\n"
1905            " - RET/mouse-1: open item under cursor\n"
1906            " - m: select an item on current page by name (autocompletes)\n"
1907            " - u/mouse-3/U: return to previous page or to the start page\n"
1908            " - g: go to a particular address (gopher, gemini, finger)\n"
1909            " - o/O: open a different address selector or the root menu of the current server\n"
1910            " - d/D: download item under cursor or current page\n"
1911            " - i/I: info on item under cursor or current page\n"
1912            " - c/C: copy URL representation of item under cursor or current page\n"
1913            " - a/A: bookmark the item under cursor or current page\n"
1914            " - B: list all bookmarks\n"
1915            " - s/S: show current history stack or all previously visted pages\n"
1916            " - r: redraw current page (using cached contents if available)\n"
1917            " - R: reload current page (regenerates cache)\n"
1918            " - !: set character coding system for gopher (default is to autodetect)\n"
1919            " - T: toggle TLS gopher mode\n"
1920            " - F: forget/discard current TLS client certificate\n"
1921            " - .: display the raw server response for the current page\n"
1922            "\n"
1923            "Start your exploration of gopher space and gemini:\n")
1924    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1925                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1926    (elpher-insert-index-record "Project Gemini home page"
1927                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1928    (insert "\n"
1929            "Alternatively, select a search engine and enter some search terms:\n")
1930    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1931                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1932    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1933                                (elpher-address-from-url "gemini://geminispace.info/search"))
1934    (insert "\n"
1935            "Your bookmarks are stored in your ")
1936    (insert-text-button "bookmark list"
1937                        'face 'link
1938                        'action #'elpher-click-link
1939                        'follow-link t
1940                        'help-echo #'elpher--page-button-help
1941                        'elpher-page
1942                        (elpher-make-page "Elpher Bookmarks"
1943                                          (elpher-make-about-address 'bookmarks)))
1944    (insert ".\n")
1945    (insert (propertize
1946             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1947             'face 'shadow))
1948    (insert "\n"
1949            "The gopher home of the Elpher project is here:\n")
1950    (elpher-insert-index-record "The Elpher Project Page"
1951                                (elpher-make-gopher-address ?1
1952                                                            "/projects/elpher/"
1953                                                            "thelambdalab.xyz"
1954                                                            70))
1955    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1956      (insert "\n"
1957              "The following info documentation is available:\n"
1958              "   - ")
1959      (insert-text-button "Elpher Manual"
1960                          'face 'link
1961                          'action (lambda (_)
1962                                    (interactive)
1963                                    (info "(elpher)"))
1964                          'follow-link t
1965                          'help-echo help-string)
1966      (insert "\n   - ")
1967      (insert-text-button "Changes introduced by the latest release"
1968                        'face 'link
1969                        'action (lambda (_)
1970                                  (interactive)
1971                                  (info "(elpher)News"))
1972                        'follow-link t
1973                        'help-echo help-string))
1974    (insert "\n")
1975    (insert (propertize
1976             (concat "(These documents should be available if you have installed Elpher\n"
1977                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1978                     " manual yourself.)\n")
1979             'face 'shadow))
1980    (elpher-restore-pos)))
1981
1982
1983 ;;; History page retrieval
1984 ;;
1985
1986 (defun elpher-show-history ()
1987   "Show the current contents of elpher's history stack.
1988 Use \\[elpher-show-visited-pages] to see the entire history.
1989 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1990   (interactive)
1991   (elpher-visit-page
1992    (elpher-make-page "Current History Stack"
1993                      (elpher-make-about-address 'history))))
1994
1995 (defun elpher-show-visited-pages ()
1996   "Show the all the pages you've visited using Elpher.
1997 Use \\[elpher-show-history] to see just the current history stack.
1998 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1999   (interactive)
2000   (elpher-visit-page
2001    (elpher-make-page "Elpher Visted Pages"
2002                      (elpher-make-about-address 'visited-pages))))
2003
2004 (defun elpher-get-history-page (renderer)
2005   "Getter which displays the history page (RENDERER must be nil)."
2006   (when renderer
2007     (elpher-visit-previous-page)
2008     (error "Command not supported for history page"))
2009   (elpher-display-history-links elpher-history "Current history stack"))
2010
2011 (defun elpher-get-visited-pages-page (renderer)
2012   "Getter which displays the list of visited pages (RENDERER must be nil)."
2013   (when renderer
2014     (elpher-visit-previous-page)
2015     (error "Command not supported for history page"))
2016   (elpher-display-history-links
2017    (seq-filter (lambda (page)
2018                  (not (elpher-address-about-p (elpher-page-address page))))
2019                elpher-visited-pages)
2020    "All visited pages"))
2021
2022 (defun elpher-display-history-links (pages title)
2023   "Show all PAGES in an Elpher buffer with a given TITLE."
2024   (let* ((title-line (concat " ---- " title " ----"))
2025          (footer-line (make-string (length title-line) ?-)))
2026     (elpher-with-clean-buffer
2027      (insert title-line "\n\n")
2028      (if pages
2029          (dolist (page pages)
2030            (when page
2031              (let ((display-string (elpher-page-display-string page))
2032                    (address (elpher-page-address page)))
2033                (elpher-insert-index-record display-string address))))
2034        (insert "No history items found.\n"))
2035      (insert "\n " footer-line "\n"
2036              "Select an entry or press 'u' to return to the previous page.")
2037      (elpher-restore-pos))))
2038
2039
2040 ;;; Bookmarks
2041 ;;
2042
2043 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2044 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2045 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2046 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2047
2048 (defvar elpher-bookmark-link nil
2049   "Prefer bookmarking a link or the current page.
2050 Bind this variable dynamically, or set it to t.
2051 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2052 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2053
2054 (defun elpher-bookmark-make-record ()
2055   "Return a bookmark record.
2056 If `elpher-bookmark-link' is non-nil and point is on a link button,
2057 return a bookmark record for that link.  Otherwise, return a bookmark
2058 record for the current elpher page."
2059   (let* ((button (and elpher-bookmark-link (button-at (point))))
2060          (page (if button
2061                    (button-get button 'elpher-page)
2062                  elpher-current-page)))
2063     (unless page
2064       (error "Cannot bookmark this link"))
2065     (let* ((address (elpher-page-address page))
2066            (url (elpher-address-to-url address))
2067            (display-string (elpher-page-display-string page))
2068            (pos (if button nil (point))))
2069       (if (elpher-address-about-p address)
2070           (error "Cannot bookmark %s" display-string)
2071         `(,display-string
2072           (defaults . (,display-string))
2073           (position . ,pos)
2074           (location . ,url)
2075           (handler . elpher-bookmark-jump))))))
2076
2077 ;;;###autoload
2078 (defun elpher-bookmark-jump (bookmark)
2079   "Handler used to open a bookmark using elpher.
2080 The argument BOOKMARK is a bookmark record passed to the function.
2081 This handler is responsible for loading the bookmark in some buffer,
2082 then making that buffer the current buffer.  It should not switch
2083 to the buffer."
2084   (let* ((url (cdr (assq 'location bookmark)))
2085          (cleaned-url (string-trim url))
2086          (page (elpher-page-from-url cleaned-url))
2087          (buffer (get-buffer-create elpher-buffer-name)))
2088     (elpher-with-clean-buffer
2089      (elpher-visit-page page))
2090     (set-buffer buffer)
2091     nil))
2092
2093 (defun elpher-bookmark-link ()
2094   "Bookmark the link at point.
2095 To bookmark the current page, use \\[elpher-bookmark-current]."
2096   (interactive)
2097   (let ((elpher-bookmark-link t))
2098     (bookmark-set-no-overwrite)))
2099
2100 (defun elpher-bookmark-current ()
2101   "Bookmark the current page.
2102 To bookmark the link at point use \\[elpher-bookmark-link]."
2103   (interactive)
2104   (call-interactively #'bookmark-set-no-overwrite))
2105
2106 (defun elpher-bookmark-import (file)
2107   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2108   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2109                               (file-readable-p elpher-bookmarks-file))
2110                          elpher-bookmarks-file
2111                        (read-file-name "Old Elpher bookmarks: "
2112                                        user-emacs-directory nil t
2113                                        "elpher-bookmarks"))))
2114   (dolist (bookmark (with-temp-buffer
2115                       (insert-file-contents file)
2116                       (read (current-buffer))))
2117     (let* ((display-string (car bookmark))
2118            (url (cadr bookmark))
2119            (record `(,display-string
2120                      (location . ,url)
2121                      (handler . elpher-bookmark-jump))))
2122       (bookmark-store display-string (cdr record) t)))
2123   (bookmark-save))
2124
2125 (defun elpher-get-bookmarks-page (renderer)
2126   "Getter which displays the bookmarks (RENDERER must be nil)."
2127   (when renderer
2128     (elpher-visit-previous-page)
2129     (error "Command not supported for bookmarks page"))
2130
2131   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2132                                      elpher-bookmarks-file)
2133                                 (locate-user-emacs-file "elpher-bookmarks"))))
2134     (when (and (file-readable-p old-bookmarks-file)
2135                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2136                                  old-bookmarks-file
2137                                  "\" found. Import now?")))
2138       (elpher-bookmark-import old-bookmarks-file)
2139       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2140
2141   (if (and elpher-use-emacs-bookmark-menu
2142            elpher-history)
2143       (progn
2144         (elpher-visit-previous-page)
2145         (call-interactively #'bookmark-bmenu-list))
2146     (elpher-with-clean-buffer
2147      (insert " ---- Elpher Bookmarks ---- \n\n")
2148      (bookmark-maybe-load-default-file)
2149      (dolist (bookmark (bookmark-maybe-sort-alist))
2150        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2151          (let* ((name (car bookmark))
2152                 (url (alist-get 'location (cdr bookmark)))
2153                 (address (elpher-address-from-url url)))
2154            (elpher-insert-index-record name address))))
2155      (when (<= (line-number-at-pos) 3)
2156        (insert "No bookmarked pages found.\n"))
2157      (insert "\n --------------------------\n\n"
2158              "Select an entry or press 'u' to return to the previous page.\n\n"
2159              "Bookmarks can be renamed or deleted via the ")
2160      (insert-text-button "Emacs bookmark menu"
2161                          'action (lambda (_)
2162                                    (interactive)
2163                                    (call-interactively #'bookmark-bmenu-list))
2164                          'follow-link t
2165                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2166      (insert (substitute-command-keys
2167               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2168      (elpher-restore-pos))))
2169
2170 (defun elpher-show-bookmarks ()
2171   "Interactive function to display the current list of elpher bookmarks."
2172   (interactive)
2173   (elpher-visit-page
2174    (elpher-make-page "Elpher Bookmarks"
2175                      (elpher-make-about-address 'bookmarks))))
2176
2177
2178 ;;; Integrations
2179 ;;
2180
2181 ;;; Org
2182
2183 (defun elpher-org-export-link (link description format protocol)
2184   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2185
2186 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2187 of gemini, gopher or finger."
2188   (let* ((url (if (equal protocol "elpher")
2189                   (string-remove-prefix "elpher:" link)
2190                 (format "%s:%s" protocol link)))
2191          (desc (or description url)))
2192     (pcase format
2193       (`gemini (format "=> %s %s" url desc))
2194       (`html (format "<a href=\"%s\">%s</a>" url desc))
2195       (`latex (format "\\href{%s}{%s}" url desc))
2196       (_ (if (not description)
2197              url
2198            (format "%s (%s)" desc url))))))
2199
2200 (defun elpher-org-store-link ()
2201   "Store link to an `elpher' page in Org."
2202   (when (eq major-mode 'elpher-mode)
2203     (let* ((url (elpher-info-current))
2204            (desc (car elpher-current-page))
2205            (protocol (cond
2206                       ((string-prefix-p "gemini:" url) "gemini")
2207                       ((string-prefix-p "gopher:" url) "gopher")
2208                       ((string-prefix-p "finger:" url) "finger")
2209                       (t "elpher"))))
2210       (when (equal "elpher" protocol)
2211         ;; Weird link. Or special inner link?
2212         (setq url (concat "elpher:" url)))
2213       (org-link-store-props :type protocol :link url :description desc)
2214       t)))
2215
2216 (defun elpher-org-follow-link (link protocol)
2217   "Visit a LINK for the given PROTOCOL.
2218
2219 PROTOCOL may be one of gemini, gopher or finger.  This method also
2220 supports the old protocol elpher, where the link is self-contained."
2221   (let ((url (if (equal protocol "elpher")
2222                  (string-remove-prefix "elpher:" link)
2223                (format "%s:%s" protocol link))))
2224     (elpher-go url)))
2225
2226 (defun elpher-org-mode-integration ()
2227   "Set up `elpher' integration for `org-mode'."
2228   (org-link-set-parameters
2229    "elpher"
2230    :store #'elpher-org-store-link
2231    :export (lambda (link description format _plist)
2232              (elpher-org-export-link link description format "elpher"))
2233    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2234   (org-link-set-parameters
2235    "gemini"
2236    :export (lambda (link description format _plist)
2237              (elpher-org-export-link link description format "gemini"))
2238    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2239   (org-link-set-parameters
2240    "gopher"
2241    :export (lambda (link description format _plist)
2242              (elpher-org-export-link link description format "gopher"))
2243    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2244   (org-link-set-parameters
2245    "gophers"
2246    :export (lambda (link description format _plist)
2247              (elpher-org-export-link link description format "gophers"))
2248    :follow (lambda (link _arg) (elpher-org-follow-link link "gophers")))
2249   (org-link-set-parameters
2250    "finger"
2251    :export (lambda (link description format _plist)
2252              (elpher-org-export-link link description format "finger"))
2253    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2254
2255 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2256
2257 ;; Browse URL
2258
2259 ;;;###autoload
2260 (defun elpher-browse-url-elpher (url &rest _args)
2261   "Browse URL using Elpher.  This function is used by `browse-url'."
2262   (interactive (browse-url-interactive-arg "Elpher URL: "))
2263   (elpher-go url))
2264
2265 ;; Use elpher to open gopher, finger and gemini links
2266 ;; For recent version of `browse-url' package
2267 (if (boundp 'browse-url-default-handlers)
2268     (add-to-list
2269      'browse-url-default-handlers
2270      '("^\\(gopher\\|gophers\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2271   ;; Patch `browse-url-browser-function' for older ones. The value of
2272   ;; that variable is `browse-url-default-browser' by default, so
2273   ;; that's the function that gets advised. If the value is an alist,
2274   ;; however, we don't know what to do. Better not interfere?
2275   (when (and (symbolp browse-url-browser-function)
2276              (fboundp browse-url-browser-function))
2277     (advice-add browse-url-browser-function :before-while
2278                 (lambda (url &rest _args)
2279                   "Handle gemini, gopher, and finger schemes using Elpher."
2280                   (let ((scheme (downcase (car (split-string url ":" t)))))
2281                     (if (member scheme '("gemini" "gopher" "gophers" "finger"))
2282                         ;; `elpher-go' always returns nil, which will stop the
2283                         ;; advice chain here in a before-while
2284                         (elpher-go url)
2285                       ;; chain must continue, then return t.
2286                       t))))))
2287
2288 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2289 (with-eval-after-load 'thingatpt
2290   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2291
2292 ;; Mu4e:
2293
2294 ;; Make mu4e aware of the gemini world
2295 (setq mu4e~view-beginning-of-url-regexp
2296       "\\(?:https?\\|gopher\\|gophers\\|finger\\|gemini\\)://\\|mailto:")
2297
2298 ;; eww:
2299
2300 ;; Let elpher handle gemini, gopher links in eww buffer.
2301 (setq eww-use-browse-url
2302       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`gophers\\|\\`finger\\)://")
2303
2304
2305 ;;; Interactive procedures
2306 ;;
2307
2308 (defun elpher-next-link ()
2309   "Move point to the next link on the current page."
2310   (interactive)
2311   (forward-button 1))
2312
2313 (defun elpher-prev-link ()
2314   "Move point to the previous link on the current page."
2315   (interactive)
2316   (backward-button 1))
2317
2318 (defun elpher-follow-current-link ()
2319   "Open the link or url at point."
2320   (interactive)
2321   (push-button))
2322
2323 ;;;###autoload
2324 (defun elpher-go (host-or-url)
2325   "Go to a particular gopher site HOST-OR-URL.
2326 When run interactively HOST-OR-URL is read from the minibuffer."
2327   (interactive (list
2328                 (read-string (format "Visit URL (default scheme %s): "
2329                                      (elpher-get-default-url-scheme)))))
2330   (let ((trimmed-host-or-url (string-trim host-or-url)))
2331     (unless (string-empty-p trimmed-host-or-url)
2332       (let ((page (elpher-page-from-url trimmed-host-or-url
2333                                         (elpher-get-default-url-scheme))))
2334         (unless (get-buffer-window elpher-buffer-name t)
2335           (switch-to-buffer elpher-buffer-name))
2336         (elpher-with-clean-buffer
2337          (elpher-visit-page page))
2338         nil)))) ; non-nil value is displayed by eshell
2339
2340 (defun elpher-go-current ()
2341   "Go to a particular URL which is read from the minibuffer.
2342 Unlike `elpher-go', the reader is initialized with the URL of the
2343 current page."
2344   (interactive)
2345   (let* ((address (elpher-page-address elpher-current-page))
2346          (url (read-string (format "Visit URL (default scheme %s): "
2347                                    (elpher-get-default-url-scheme))
2348                            (elpher-address-to-url address))))
2349     (let ((trimmed-url (string-trim url)))
2350       (unless (string-empty-p trimmed-url)
2351         (elpher-with-clean-buffer
2352          (elpher-visit-page
2353           (elpher-page-from-url trimmed-url (elpher-get-default-url-scheme))))))))
2354
2355 (defun elpher-redraw ()
2356   "Redraw current page."
2357   (interactive)
2358   (elpher-visit-page elpher-current-page))
2359
2360 (defun elpher-reload ()
2361   "Reload current page."
2362   (interactive)
2363   (elpher-reload-current-page))
2364
2365 (defun elpher-toggle-tls ()
2366   "Toggle TLS encryption mode for gopher."
2367   (interactive)
2368   (setq elpher-use-tls (not elpher-use-tls))
2369   (if elpher-use-tls
2370       (if (gnutls-available-p)
2371           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2372         (setq elpher-use-tls nil)
2373         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2374     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2375
2376 (defun elpher-view-raw ()
2377   "View raw server response for current page."
2378   (interactive)
2379   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2380       (error "This page was not generated by a server")
2381     (elpher-visit-page elpher-current-page
2382                        #'elpher-render-raw)))
2383
2384 (defun elpher-back ()
2385   "Go to previous site."
2386   (interactive)
2387   (elpher-visit-previous-page))
2388
2389 (defun elpher-back-to-start ()
2390   "Go all the way back to the start page."
2391   (interactive)
2392   (setq-local elpher-current-page nil)
2393   (setq-local elpher-history nil)
2394   (elpher-visit-page (elpher-make-start-page)))
2395
2396 (defun elpher-download ()
2397   "Download the link at point."
2398   (interactive)
2399   (let ((button (button-at (point))))
2400     (if button
2401         (let ((page (button-get button 'elpher-page)))
2402           (unless page
2403             (error "Not an elpher page"))
2404           (when (elpher-address-about-p (elpher-page-address page))
2405             (error "Cannot download %s" (elpher-page-display-string page)))
2406           (elpher-visit-page (button-get button 'elpher-page)
2407                              #'elpher-render-download))
2408       (error "No link selected"))))
2409
2410 (defun elpher-download-current ()
2411   "Download the current page."
2412   (interactive)
2413   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2414       (error "Cannot download %s"
2415              (elpher-page-display-string elpher-current-page))
2416     (elpher-visit-page elpher-current-page
2417                        #'elpher-render-download
2418                        t)))
2419
2420 (defun elpher--build-link-map ()
2421   "Build alist mapping link names to destination pages in current buffer."
2422   (let ((link-map nil)
2423         (b (next-button (point-min) t)))
2424     (while b
2425       (push (cons (button-label b) b) link-map)
2426       (setq b (next-button (button-start b))))
2427     link-map))
2428
2429 (defun elpher-jump ()
2430   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2431   (interactive)
2432   (let* ((link-map (elpher--build-link-map)))
2433     (if link-map
2434         (let ((key (let ((completion-ignore-case t))
2435                      (completing-read "Directory item/link: "
2436                                       link-map nil t))))
2437           (if (and key (> (length key) 0))
2438               (let ((b (cdr (assoc key link-map))))
2439                 (goto-char (button-start b))
2440                 (button-activate b)))))))
2441
2442 (defun elpher-root-dir ()
2443   "Visit root of current server."
2444   (interactive)
2445   (let ((address (elpher-page-address elpher-current-page)))
2446     (if (not (elpher-address-about-p address))
2447         (if (or (member (url-filename address) '("/" ""))
2448                 (and (elpher-address-gopher-p address)
2449                      (= (length (elpher-gopher-address-selector address)) 0)))
2450             (error "Already at root directory of current server")
2451           (let ((address-copy (elpher-address-from-url
2452                                (elpher-address-to-url address))))
2453             (setf (url-filename address-copy) "")
2454             (elpher-go (elpher-address-to-url address-copy))))
2455       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2456
2457 (defun elpher-info-page (page)
2458   "Display URL of PAGE in minibuffer."
2459   (let* ((address (elpher-page-address page))
2460          (url (elpher-address-to-url address))
2461          (iri (elpher-address-to-iri address)))
2462     (if (equal url iri)
2463         (message "%s" url)
2464       (message "%s (Raw: %s)" iri url))))
2465
2466 (defun elpher-info-link ()
2467   "Display information on page corresponding to link at point."
2468   (interactive)
2469   (let ((button (button-at (point))))
2470     (unless button
2471       (error "No item selected"))
2472     (let ((page (button-get button 'elpher-page)))
2473       (unless page
2474         (error "Not an elpher page"))
2475       (elpher-info-page page))))
2476
2477 (defun elpher-info-current ()
2478   "Display information on current page."
2479   (interactive)
2480   (elpher-info-page elpher-current-page))
2481
2482 (defun elpher-copy-page-url (page)
2483   "Copy URL representation of address of PAGE to `kill-ring'."
2484   (let* ((address (elpher-page-address page))
2485          (url (elpher-address-to-url address)))
2486     (message "Copied \"%s\" to kill-ring/clipboard." url)
2487     (kill-new url)))
2488
2489 (defun elpher-copy-link-url ()
2490   "Copy URL of item at point to `kill-ring'."
2491   (interactive)
2492   (let ((button (button-at (point))))
2493     (unless button
2494       (error "No item selected"))
2495     (let ((page (button-get button 'elpher-page)))
2496       (unless page
2497         (error "Not an elpher page"))
2498       (elpher-copy-page-url page))))
2499
2500 (defun elpher-copy-current-url ()
2501   "Copy URL of current page to `kill-ring'."
2502   (interactive)
2503   (elpher-copy-page-url elpher-current-page))
2504
2505 (defun elpher-set-gopher-coding-system ()
2506   "Specify an explicit character coding system for gopher selectors."
2507   (interactive)
2508   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2509     (setq elpher-user-coding-system system)
2510     (if system
2511         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2512       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2513
2514
2515 ;;; Mode and keymap
2516 ;;
2517
2518 (defvar elpher-mode-map
2519   (let ((map (make-sparse-keymap)))
2520     (define-key map (kbd "TAB") 'elpher-next-link)
2521     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2522     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2523     (define-key map (kbd "u") 'elpher-back)
2524     (define-key map (kbd "-") 'elpher-back)
2525     (define-key map (kbd "^") 'elpher-back)
2526     (define-key map [mouse-3] 'elpher-back)
2527     (define-key map (kbd "U") 'elpher-back-to-start)
2528     (define-key map (kbd "g") 'elpher-go)
2529     (define-key map (kbd "o") 'elpher-go-current)
2530     (define-key map (kbd "O") 'elpher-root-dir)
2531     (define-key map (kbd "s") 'elpher-show-history)
2532     (define-key map (kbd "S") 'elpher-show-visited-pages)
2533     (define-key map (kbd "r") 'elpher-redraw)
2534     (define-key map (kbd "R") 'elpher-reload)
2535     (define-key map (kbd "T") 'elpher-toggle-tls)
2536     (define-key map (kbd ".") 'elpher-view-raw)
2537     (define-key map (kbd "d") 'elpher-download)
2538     (define-key map (kbd "D") 'elpher-download-current)
2539     (define-key map (kbd "m") 'elpher-jump)
2540     (define-key map (kbd "i") 'elpher-info-link)
2541     (define-key map (kbd "I") 'elpher-info-current)
2542     (define-key map (kbd "c") 'elpher-copy-link-url)
2543     (define-key map (kbd "C") 'elpher-copy-current-url)
2544     (define-key map (kbd "a") 'elpher-bookmark-link)
2545     (define-key map (kbd "A") 'elpher-bookmark-current)
2546     (define-key map (kbd "B") 'elpher-show-bookmarks)
2547     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2548     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2549     (when (fboundp 'evil-define-key*)
2550       (evil-define-key*
2551        'motion map
2552        (kbd "TAB") 'elpher-next-link
2553        (kbd "C-") 'elpher-follow-current-link
2554        (kbd "C-t") 'elpher-back
2555        (kbd "u") 'elpher-back
2556        (kbd "-") 'elpher-back
2557        (kbd "^") 'elpher-back
2558        [mouse-3] 'elpher-back
2559        (kbd "U") 'elpher-back-to-start
2560        (kbd "g") 'elpher-go
2561        (kbd "o") 'elpher-go-current
2562        (kbd "O") 'elpher-root-dir
2563        (kbd "s") 'elpher-show-history
2564        (kbd "S") 'elpher-show-visited-pages
2565        (kbd "r") 'elpher-redraw
2566        (kbd "R") 'elpher-reload
2567        (kbd "T") 'elpher-toggle-tls
2568        (kbd ".") 'elpher-view-raw
2569        (kbd "d") 'elpher-download
2570        (kbd "D") 'elpher-download-current
2571        (kbd "m") 'elpher-jump
2572        (kbd "i") 'elpher-info-link
2573        (kbd "I") 'elpher-info-current
2574        (kbd "c") 'elpher-copy-link-url
2575        (kbd "C") 'elpher-copy-current-url
2576        (kbd "a") 'elpher-bookmark-link
2577        (kbd "A") 'elpher-bookmark-current
2578        (kbd "B") 'elpher-show-bookmarks
2579        (kbd "!") 'elpher-set-gopher-coding-system
2580        (kbd "F") 'elpher-forget-current-certificate))
2581     map)
2582   "Keymap for gopher client.")
2583
2584 (define-derived-mode elpher-mode special-mode "elpher"
2585   "Major mode for elpher, an elisp gopher client.
2586
2587 This mode is automatically enabled by the interactive
2588 functions which initialize the client, namely
2589 `elpher', and `elpher-go'."
2590   (setq-local elpher-current-page nil)
2591   (setq-local elpher-history nil)
2592   (setq-local elpher-buffer-name (buffer-name))
2593   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2594   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2595
2596 (when (fboundp 'evil-set-initial-state)
2597   (evil-set-initial-state 'elpher-mode 'motion))
2598
2599
2600 ;;; Main start procedure
2601 ;;
2602
2603 ;;;###autoload
2604 (defun elpher (&optional arg)
2605   "Start elpher with default landing page.
2606 The buffer used for Elpher sessions is determined by the value of
2607 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2608 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2609 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2610 \\[execute-extended-command] elpher RET’) switches to the session with
2611 that number, creating it if necessary.  A non numeric prefix ARG means
2612 to create a new session.  Returns the buffer selected (or created)."
2613   (interactive "P")
2614   (let* ((name (default-value 'elpher-buffer-name))
2615          (buf (cond ((numberp arg)
2616                      (get-buffer-create (format "%s<%d>" name arg)))
2617                     (arg
2618                      (generate-new-buffer name))
2619                     (t
2620                      (get-buffer-create name)))))
2621     (pop-to-buffer-same-window buf)
2622     (unless (buffer-modified-p)
2623       (elpher-mode)
2624       (elpher-visit-page (elpher-make-start-page))
2625       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2626
2627 ;;; elpher.el ends here