elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2023 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.3
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69 (require 'rx)
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "3.4.3"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 ;; Face customizations
 245
 246 (defgroup elpher-faces nil
 247   "Elpher face customizations."
 248   :group 'elpher)
 249
 250 (defface elpher-index
 251   '((t :inherit font-lock-keyword-face))
 252   "Face used for directory type directory records.")
 253
 254 (defface elpher-text
 255   '((t :inherit bold))
 256   "Face used for text type directory records.")
 257
 258 (defface elpher-info
 259   '((t :inherit default))
 260   "Face used for info type directory records.")
 261
 262 (defface elpher-image
 263   '((t :inherit font-lock-string-face))
 264   "Face used for image type directory records.")
 265
 266 (defface elpher-search
 267   '((t :inherit warning))
 268   "Face used for search type directory records.")
 269
 270 (defface elpher-html
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for html type directory records.")
 273
 274 (defface elpher-gemini
 275   '((t :inherit font-lock-constant-face))
 276   "Face used for Gemini type directory records.")
 277
 278 (defface elpher-other-url
 279   '((t :inherit font-lock-comment-face))
 280   "Face used for other URL type links records.")
 281
 282 (defface elpher-telnet
 283   '((t :inherit font-lock-function-name-face))
 284   "Face used for telnet type directory records.")
 285
 286 (defface elpher-binary
 287   '((t :inherit font-lock-doc-face))
 288   "Face used for binary type directory records.")
 289
 290 (defface elpher-unknown
 291   '((t :inherit error))
 292   "Face used for directory records with unknown/unsupported types.")
 293
 294 (defface elpher-margin-key
 295   '((t :inherit bold))
 296   "Face used for directory margin key.")
 297
 298 (defface elpher-margin-brackets
 299   '((t :inherit shadow))
 300   "Face used for brackets around directory margin key.")
 301
 302 (defface elpher-gemini-heading1
 303   '((t :inherit bold :height 1.8))
 304   "Face used for gemini heading level 1.")
 305
 306 (defface elpher-gemini-heading2
 307   '((t :inherit bold :height 1.5))
 308   "Face used for gemini heading level 2.")
 309
 310 (defface elpher-gemini-heading3
 311   '((t :inherit bold :height 1.2))
 312   "Face used for gemini heading level 3.")
 313
 314 (defface elpher-gemini-quoted
 315   '((t :inherit font-lock-doc-face))
 316   "Face used for gemini quoted texts.")
 317
 318 (defface elpher-gemini-preformatted
 319   '((t :inherit default))
 320   "Face used for gemini preformatted text.")
 321
 322 (defface elpher-gemini-preformatted-toggle
 323   '((t :inherit button))
 324   "Face used for buttons used to toggle display of preformatted text.")
 325
 326 ;;; Model
 327 ;;
 328
 329 ;; Address
 330
 331 ;; An elpher "address" object is either a url object or a symbol.
 332 ;; Addresses with the "about" type, corresponding to pages generated
 333 ;; dynamically for and by elpher.  All others represent pages which
 334 ;; rely on content retrieved over the network.
 335
 336 (defun elpher-address-from-url (url-string &optional default-scheme)
 337   "Create a ADDRESS object corresponding to the given URL-STRING.
 338 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 339 is not explicitly given."
 340   (let ((data (match-data))) ; Prevent parsing clobbering match data
 341     (unwind-protect
 342         (let ((url (url-generic-parse-url url-string)))
 343           (unless (and (not (url-fullness url)) (url-type url))
 344             (unless (url-type url)
 345               (setf (url-type url) default-scheme))
 346             (unless (url-host url)
 347               (let ((p (split-string (url-filename url) "/" nil nil)))
 348                 (setf (url-host url) (car p))
 349                 (setf (url-filename url)
 350                       (if (cdr p)
 351                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 352                         ""))))
 353             (when (not (string-empty-p (url-host url)))
 354               (setf (url-fullness url) t)
 355               (setf (url-host url) (puny-encode-domain (url-host url))))
 356             (when (or (equal "gopher" (url-type url))
 357                       (equal "gophers" (url-type url)))
 358               ;; Gopher defaults
 359               (when (or (equal (url-filename url) "")
 360                         (equal (url-filename url) "/"))
 361                 (setf (url-filename url) "/1")))
 362             (when (equal "gemini" (url-type url))
 363               ;; Gemini defaults
 364               (if (equal (url-filename url) "")
 365                   (setf (url-filename url) "/"))))
 366           (elpher-remove-redundant-ports url))
 367       (set-match-data data))))
 368
 369 (defun elpher-remove-redundant-ports (address)
 370   "Remove redundant port specifiers from ADDRESS.
 371 Here 'redundant' means that the specified port matches the default
 372 for that protocol, eg 70 for gopher."
 373   (if (and (not (elpher-address-about-p address))
 374            (eq (url-portspec address) ; (url-port) is too slow!
 375                (pcase (url-type address)
 376                  ("gemini" 1965)
 377                  ((or "gopher" "gophers") 70)
 378                  ("finger" 79)
 379                  (_ -1))))
 380       (setf (url-portspec address) nil))
 381   address)
 382
 383 (defun elpher-make-gopher-address (type selector host port &optional tls)
 384   "Create an ADDRESS object using gopher directory record attributes.
 385 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 386 If the optional attribute TLS is non-nil, the address will be marked as
 387 requiring gopher-over-TLS."
 388   (cond
 389    ((equal type ?i) nil)
 390    ((and (equal type ?h)
 391          (string-prefix-p "URL:" selector))
 392     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 393    ((equal type ?8)
 394     (elpher-address-from-url
 395      (concat "telnet"
 396              "://" host
 397              ":" (number-to-string port))))
 398    (t
 399     (elpher-address-from-url
 400      (concat "gopher" (if tls "s" "")
 401              "://" host
 402              ":" (number-to-string port)
 403              "/" (string type)
 404              selector)))))
 405
 406 (defun elpher-make-about-address (type)
 407   "Create an ADDRESS object corresponding to the given about address TYPE."
 408   (elpher-address-from-url (concat "about:" (symbol-name type))))
 409
 410 (defun elpher-address-to-url (address)
 411   "Get string representation of ADDRESS."
 412   (url-encode-url (url-recreate-url address)))
 413
 414 (defun elpher-address-type (address)
 415   "Retrieve type of ADDRESS object.
 416 This is used to determine how to retrieve and render the document the
 417 address refers to, via the table `elpher-type-map'."
 418   (pcase (url-type address)
 419     ("about"
 420      (list 'about (intern (url-filename address))))
 421     ((or "gopher" "gophers")
 422      (list 'gopher
 423            (if (member (url-filename address) '("" "/"))
 424                ?1
 425              (string-to-char (substring (url-filename address) 1)))))
 426     ("gemini" 'gemini)
 427     ("telnet" 'telnet)
 428     ("finger" 'finger)
 429     ("file" 'file)
 430     (_ 'other-url)))
 431
 432 (defun elpher-address-about-p (address)
 433   "Return non-nil if ADDRESS is an about address."
 434   (pcase (elpher-address-type address) (`(about ,_) t)))
 435
 436 (defun elpher-address-gopher-p (address)
 437   "Return non-nil if ADDRESS object is a gopher address."
 438   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 439
 440 (defun elpher-address-protocol (address)
 441   "Retrieve the transport protocol for ADDRESS."
 442   (url-type address))
 443
 444 (defun elpher-address-filename (address)
 445   "Retrieve the filename component of ADDRESS.
 446 For gopher addresses this is a combination of the selector type and selector."
 447   (url-unhex-string (url-filename address)))
 448
 449 (defun elpher-address-host (address)
 450   "Retrieve host from ADDRESS object."
 451   (pcase (url-host address)
 452     ;; The following strips out square brackets which sometimes enclose IPv6
 453     ;; addresses.  Doing this here rather than at the parsing stage may seem
 454     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 455     ;; and reconstruction.  It's also more efficient, as this method is not
 456     ;; called during page rendering.
 457     ((rx (: "[" (let ipv6 (* (not "]"))) "]"))
 458      ipv6)
 459     ;; The following is a work-around for a parsing bug that causes
 460     ;; URLs with empty (but not absent, see RFC 1738) usernames to have
 461     ;; @ prepended to the hostname.
 462     ((rx (: "@" (let rest (+ anything))))
 463      rest)
 464     (addr
 465      addr)))
 466
 467 (defun elpher-address-user (address)
 468   "Retrieve user from ADDRESS object."
 469   (url-user address))
 470
 471 (defun elpher-address-port (address)
 472   "Retrieve port from ADDRESS object.
 473 If no address is defined, returns 0.  (This is for compatibility with
 474 the URL library.)"
 475   (let ((port (url-portspec address))) ; (url-port) is too slow!
 476     (if port port 0)))
 477
 478 (defun elpher-gopher-address-selector (address)
 479   "Retrieve gopher selector from ADDRESS object."
 480   (if (member (url-filename address) '("" "/"))
 481       ""
 482     (url-unhex-string (substring (url-filename address) 2))))
 483
 484
 485 ;; Cache
 486
 487 (defvar elpher-content-cache (make-hash-table :test 'equal))
 488 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 489
 490 (defun elpher-get-cached-content (address)
 491   "Retrieve the cached content for ADDRESS, or nil if none exists."
 492   (gethash address elpher-content-cache))
 493
 494 (defun elpher-cache-content (address content)
 495   "Set the content cache for ADDRESS to CONTENT."
 496   (puthash address content elpher-content-cache))
 497
 498 (defun elpher-get-cached-pos (address)
 499   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 500   (gethash address elpher-pos-cache))
 501
 502 (defun elpher-cache-pos (address pos)
 503   "Set the cursor position cache for ADDRESS to POS."
 504   (puthash address pos elpher-pos-cache))
 505
 506
 507 ;; Page
 508
 509 (defun elpher-make-page (display-string address)
 510   "Create a page with DISPLAY-STRING and ADDRESS."
 511   (list display-string address))
 512
 513 (defun elpher-make-start-page ()
 514   "Create the start page."
 515   (elpher-make-page "Start Page"
 516                     (elpher-address-from-url elpher-start-page-url)))
 517
 518 (defun elpher-page-display-string (page)
 519   "Retrieve the display string corresponding to PAGE."
 520   (elt page 0))
 521
 522 (defun elpher-page-address (page)
 523   "Retrieve the address corresponding to PAGE."
 524   (elt page 1))
 525
 526 (defun elpher-page-set-address (page new-address)
 527   "Set the address corresponding to PAGE to NEW-ADDRESS."
 528   (setcar (cdr page) new-address))
 529
 530 (defun elpher-page-from-url (url &optional default-scheme)
 531   "Create a page with address and display string defined by URL.
 532 The URL is unhexed prior to its use as a display string to improve
 533 readability.
 534
 535 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 536 in the instance that URL itself doesn't specify one."
 537   (let ((address (elpher-address-from-url url default-scheme)))
 538     (elpher-make-page (elpher-address-to-iri address) address)))
 539
 540 (defun elpher-address-to-iri (address)
 541   "Return an IRI for ADDRESS.
 542 Decode percent-escapes and handle punycode in the domain name.
 543 Drop the password, if any."
 544   (let ((data (match-data)) ; Prevent parsing clobbering match data
 545         (host (url-host address))
 546         (pass (url-password address)))
 547     (unwind-protect
 548         (let* ((host (url-host address))
 549                (pass (url-password address)))
 550           (when host
 551             (setf (url-host address) (puny-decode-domain host)))
 552           (when pass                             ; RFC 3986 says we should not render
 553             (setf (url-password address) nil)) ; the password as clear text
 554           (elpher-decode (url-unhex-string (url-recreate-url address))))
 555       (setf (url-host address) host)
 556       (setf (url-password address) pass)
 557       (set-match-data data))))
 558
 559 (defvar elpher-current-page nil
 560   "The current page for this Elpher buffer.")
 561
 562 (defvar elpher-history nil
 563   "The local history stack for this Elpher buffer.
 564 This variable is used by `elpher-back' and
 565 `elpher-show-history'.")
 566
 567 (defvar elpher-visited-pages nil
 568   "The global history for all Elpher buffers.
 569 This variable is used by `elpher-show-visited-pages'.")
 570
 571 (defun elpher-visit-page (page &optional renderer no-history)
 572   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 573 Additionally, push PAGE onto the history stack and the list of
 574 previously-visited pages, unless NO-HISTORY is non-nil."
 575   (elpher-save-pos)
 576   (elpher-process-cleanup)
 577   (unless no-history
 578     (unless (or (not elpher-current-page)
 579                  (equal (elpher-page-address elpher-current-page)
 580                         (elpher-page-address page)))
 581       (push elpher-current-page elpher-history)
 582       (unless (or (elpher-address-about-p (elpher-page-address page))
 583                   (and elpher-visited-pages
 584                        (equal page (car elpher-visited-pages))))
 585         (push page elpher-visited-pages))))
 586   (setq-local elpher-current-page page)
 587   (let* ((address (elpher-page-address page))
 588          (type (elpher-address-type address))
 589          (type-record (cdr (assoc type elpher-type-map))))
 590     (if type-record
 591         (funcall (car type-record)
 592                  (if renderer
 593                      renderer
 594                    (cadr type-record)))
 595       (elpher-visit-previous-page)
 596       (pcase type
 597         (`(gopher ,type-char)
 598          (error "Unsupported gopher selector type '%c' for '%s'"
 599                 type-char (elpher-address-to-url address)))
 600         (other
 601          (error "Unsupported address type '%S' for '%s'"
 602                 other (elpher-address-to-url address)))))))
 603
 604 (defun elpher-visit-previous-page ()
 605   "Visit the previous page in the history."
 606   (if elpher-history
 607       (elpher-visit-page (pop elpher-history) nil t)
 608     (error "No previous page")))
 609
 610 (defun elpher-reload-current-page ()
 611   "Reload the current page, discarding any existing cached content."
 612   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 613   (elpher-visit-page elpher-current-page))
 614
 615 (defun elpher-save-pos ()
 616   "Save the current position of point to the current page."
 617   (when elpher-current-page
 618     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 619
 620 (defun elpher-restore-pos ()
 621   "Restore the position of point to that cached in the current page."
 622   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 623     (if pos
 624         (goto-char pos)
 625       (goto-char (point-min)))))
 626
 627 (defun elpher-get-default-url-scheme ()
 628   "Suggest default URL scheme for visiting addresses based on the current page."
 629   (if elpher-current-page
 630       (let* ((address (elpher-page-address elpher-current-page))
 631              (current-type (elpher-address-type address)))
 632         (pcase current-type
 633           ((or (and 'file (guard (not elpher-history)))
 634                `(about ,_))
 635            elpher-default-url-type)
 636           (_
 637            (url-type address))))
 638       elpher-default-url-type))
 639
 640
 641 ;;; Buffer preparation
 642 ;;
 643
 644 (defvar elpher-buffer-name "*elpher*"
 645   "The default name of the Elpher buffer.")
 646
 647 (defun elpher-update-header ()
 648   "If `elpher-use-header' is true, display current page info in window header."
 649   (if (and elpher-use-header elpher-current-page)
 650       (let* ((display-string (elpher-page-display-string elpher-current-page))
 651              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 652              (address (elpher-page-address elpher-current-page))
 653              (tls-string (if (and (not (elpher-address-about-p address))
 654                                   (member (elpher-address-protocol address)
 655                                           '("gophers" "gemini")))
 656                              " [TLS encryption]"
 657                            ""))
 658              (header (concat sanitized-display-string
 659                              (propertize tls-string 'face 'bold))))
 660         (setq header-line-format header))))
 661
 662 (defmacro elpher-with-clean-buffer (&rest args)
 663   "Evaluate ARGS with a clean *elpher* buffer as current."
 664   (declare (debug (body))) ;; Allow edebug to step through body
 665   `(with-current-buffer elpher-buffer-name
 666      (unless (eq major-mode 'elpher-mode)
 667        ;; avoid resetting buffer-local variables
 668        (elpher-mode))
 669      (let ((inhibit-read-only t)
 670            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 671        (setq-local xterm-color--current-fg nil)
 672        (setq-local xterm-color--current-bg nil)
 673        (setq-local network-security-level
 674                    (default-value 'network-security-level))
 675        (erase-buffer)
 676        (elpher-update-header)
 677        ,@args)))
 678
 679 (defun elpher-buffer-message (string &optional line)
 680   "Replace first line in elpher buffer with STRING.
 681 If LINE is non-nil, replace that line instead."
 682   (with-current-buffer elpher-buffer-name
 683     (let ((inhibit-read-only t))
 684       (goto-char (point-min))
 685       (if line
 686           (forward-line line))
 687       (let ((data (match-data)))
 688         (unwind-protect
 689             (progn
 690               (re-search-forward "^.*$")
 691               (replace-match string))
 692           (set-match-data data))))))
 693
 694
 695 ;;; Text Processing
 696 ;;
 697
 698 (defvar elpher-user-coding-system nil
 699   "User-specified coding system to use for decoding text responses.")
 700
 701 (defun elpher-decode (string)
 702   "Decode STRING using autodetected or user-specified coding system."
 703   (decode-coding-string string
 704                         (if elpher-user-coding-system
 705                             elpher-user-coding-system
 706                           (detect-coding-string string t))))
 707
 708 (defun elpher-preprocess-text-response (string)
 709   "Preprocess text selector response contained in STRING.
 710 This involes decoding the character representation, and clearing
 711 away CRs and any terminating period."
 712   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 713                                            (replace-regexp-in-string "\r" "" string))))
 714
 715 ;;; Buttonify urls
 716
 717 (defconst elpher-url-regex
 718   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 719   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 720
 721 (defun elpher-buttonify-urls (string)
 722   "Turn substrings which look like urls in STRING into clickable buttons."
 723   (with-temp-buffer
 724     (insert string)
 725     (goto-char (point-min))
 726     (while (re-search-forward elpher-url-regex nil t)
 727       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 728         (make-text-button (match-beginning 0)
 729                           (match-end 0)
 730                           'elpher-page  page
 731                           'action #'elpher-click-link
 732                           'follow-link t
 733                           'help-echo #'elpher--page-button-help
 734                           'face 'button)))
 735     (buffer-string)))
 736
 737
 738 ;; ANSI colors or XTerm colors (application and filtering)
 739
 740 (or (require 'xterm-color nil t)
 741     (require 'ansi-color))
 742
 743 (defalias 'elpher-color-filter-apply
 744   (if (fboundp 'xterm-color-filter)
 745       (lambda (s)
 746         (let ((_xterm-color-render nil))
 747           (xterm-color-filter s)))
 748     #'ansi-color-filter-apply)
 749   "A function to filter out ANSI escape sequences.")
 750
 751 (defalias 'elpher-color-apply
 752   (if (fboundp 'xterm-color-filter)
 753       #'xterm-color-filter
 754     #'ansi-color-apply)
 755   "A function to apply ANSI escape sequences.")
 756
 757 (defun elpher-text-has-ansi-escapes-p (string)
 758   "Return non-nil if STRING includes an ANSI escape code."
 759   (save-match-data
 760     (string-match "\x1b\\[" string)))
 761
 762
 763 ;; Processing text for display
 764
 765 (defun elpher-process-text-for-display (string)
 766   "Perform any desired processing of STRING prior to display as text.
 767 Currently includes buttonifying URLs and processing ANSI escape codes."
 768   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 769                              (if elpher-filter-ansi-from-text
 770                                  (elpher-color-filter-apply string)
 771                                (elpher-color-apply string))
 772                            string)))
 773
 774
 775 ;;; General network communication
 776 ;;
 777
 778 (defun elpher-network-error (address error)
 779   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 780 ERROR can be either an error object or a string."
 781   (elpher-with-clean-buffer
 782    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 783            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 784            (if (stringp error) error (error-message-string error)) "\n"
 785            (propertize "\n----------------\n\n" 'face 'error)
 786            "Press 'u' to return to the previous page.")))
 787
 788
 789 (defvar elpher-network-timer nil
 790   "Timer used for network connections.")
 791
 792 (defvar elpher-use-tls nil
 793   "If non-nil, use TLS to communicate with gopher servers.")
 794
 795 (defvar elpher-client-certificate nil
 796   "If non-nil, contains client certificate details to use for TLS connections.")
 797
 798 (defun elpher-process-cleanup ()
 799   "Immediately shut down any extant elpher process and timers."
 800   (let ((p (get-process "elpher-process")))
 801     (if p (delete-process p)))
 802   (if (timerp elpher-network-timer)
 803       (cancel-timer elpher-network-timer)))
 804
 805 (defun elpher-make-network-timer (thunk)
 806   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 807 This is just a wraper around `run-at-time' which additionally sets the
 808 buffer-local variable `elpher-network-timer' to allow
 809 `elpher-process-cleanup' to also clear the timer."
 810   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 811     (setq-local elpher-network-timer timer)
 812     timer))
 813
 814 (defun elpher-get-host-response (address default-port query-string response-processor
 815                                          &optional use-tls force-ipv4)
 816   "Generic function for retrieving data from ADDRESS.
 817
 818 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 819 QUERY-STRING is a string sent to the host specified by ADDRESS to
 820 illicet a response.  This response is passed as an argument to the
 821 function RESPONSE-PROCESSOR.
 822
 823 If non-nil, USE-TLS specifies that the connection is to be made over
 824 TLS.  If set to gemini, the certificate verification will be disabled
 825 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 826
 827 If non-nil, FORCE-IPV4 causes the network connection to be made over
 828 ipv4 only.  (The default behaviour when this is not set depends on
 829 the host operating system and the local network capabilities.)"
 830   (if (and use-tls (not (gnutls-available-p)))
 831       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 832     (unless (< (elpher-address-port address) 65536)
 833       (error "Cannot establish network connection: port number > 65536"))
 834     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 835       (setq-local network-security-level 'low)
 836       (setq-local gnutls-verify-error nil))
 837     (condition-case nil
 838         (let* ((kill-buffer-query-functions nil)
 839                (port (elpher-address-port address))
 840                (host (elpher-address-host address))
 841                (service (if (> port 0) port default-port))
 842                (response-string-parts nil)
 843                (bytes-received 0)
 844                (hkbytes-received 0)
 845                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 846                (gnutls-params (list :type 'gnutls-x509pki
 847                                     :hostname host
 848                                     :keylist
 849                                     (elpher-get-current-keylist address)))
 850                (timer (elpher-make-network-timer
 851                                    (lambda ()
 852                                      (elpher-process-cleanup)
 853                                      (cond
 854                                         ; Try again with IPv4
 855                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 856                                        (message "Connection timed out.  Retrying with IPv4.")
 857                                        (elpher-get-host-response address default-port
 858                                                                  query-string
 859                                                                  response-processor
 860                                                                  use-tls t))
 861                                       ((and use-tls
 862                                             (not (eq use-tls 'gemini))
 863                                             (or elpher-auto-disengage-TLS
 864                                                 (y-or-n-p
 865                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 866                                        (setq elpher-use-tls nil)
 867                                        (elpher-get-host-response address default-port
 868                                                                  query-string
 869                                                                  response-processor
 870                                                                  nil force-ipv4))
 871                                       (t
 872                                        (elpher-network-error address "Connection time-out."))))))
 873                (proc (if socks
 874                          (socks-open-network-stream "elpher-process" nil host service)
 875                        (make-network-process :name "elpher-process"
 876                                              :host host
 877                                              :family (and (or force-ipv4
 878                                                               elpher-ipv4-always)
 879                                                           'ipv4)
 880                                              :service service
 881                                              :buffer nil
 882                                              :nowait t
 883                                              :tls-parameters
 884                                              (and use-tls
 885                                                   (cons 'gnutls-x509pki
 886                                                         (apply #'gnutls-boot-parameters
 887                                                                gnutls-params)))))))
 888           (process-put proc 'elpher-buffer (current-buffer))
 889           (setq elpher-network-timer timer)
 890           (set-process-coding-system proc 'binary 'binary)
 891           (set-process-query-on-exit-flag proc nil)
 892           (elpher-buffer-message (concat "Connecting to " host "..."
 893                                          " (press 'u' to abort)"))
 894           (set-process-filter proc
 895                               (lambda (_proc string)
 896                                 (when timer
 897                                   (cancel-timer timer)
 898                                   (setq timer nil))
 899                                 (setq bytes-received (+ bytes-received (length string)))
 900                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 901                                   (when (> new-hkbytes-received hkbytes-received)
 902                                     (setq hkbytes-received new-hkbytes-received)
 903                                     (elpher-buffer-message
 904                                      (concat "("
 905                                              (number-to-string (/ hkbytes-received 10.0))
 906                                              " MB read)")
 907                                      1)))
 908                                 (setq response-string-parts
 909                                       (cons string response-string-parts))))
 910           (set-process-sentinel proc
 911                                 (lambda (proc event)
 912                                   (when timer
 913                                     (cancel-timer timer))
 914                                   (condition-case the-error
 915                                       (cond
 916                                        ((string-prefix-p "open" event)    ; request URL
 917                                         (elpher-buffer-message
 918                                          (concat "Connected to " host ". Receiving data..."
 919                                                  " (press 'u' to abort)"))
 920                                         (let ((inhibit-eol-conversion t))
 921                                           (process-send-string proc query-string)))
 922                                        ((string-prefix-p "deleted" event)) ; do nothing
 923                                        ((and (not response-string-parts)
 924                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 925                                         ; Try again with IPv4
 926                                         (message "Connection failed. Retrying with IPv4.")
 927                                         (elpher-get-host-response address default-port
 928                                                                   query-string
 929                                                                   response-processor
 930                                                                   use-tls t))
 931                                        (response-string-parts
 932                                         (with-current-buffer (process-get proc 'elpher-buffer)
 933                                           (elpher-with-clean-buffer
 934                                            (insert "Data received.  Rendering..."))
 935                                           (funcall response-processor
 936                                                    (apply #'concat (reverse response-string-parts)))
 937                                           (elpher-restore-pos)))
 938                                        (t
 939                                         (error "No response from server")))
 940                                     (error
 941                                      (elpher-network-error address the-error)))))
 942           (when socks
 943             (if use-tls
 944                 (apply #'gnutls-negotiate :process proc gnutls-params))
 945             (funcall (process-sentinel proc) proc "open\n")))
 946       (error
 947        (elpher-process-cleanup)
 948        (error "Error initiating connection to server")))))
 949
 950
 951 ;;; Client-side TLS Certificate Management
 952 ;;
 953
 954 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 955   "Generate a key and a self-signed client TLS certificate using openssl.
 956
 957 The Common Name field of the certificate is set to COMMON-NAME.  The
 958 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 959 the key and certificate files to write.
 960
 961 If TEMPORARY is non-nil, the certificate will be given an exporation
 962 period of one day, and the key and certificate files will be deleted
 963 when the certificate is no longer needed for the current session.
 964
 965 Otherwise, the certificate will be given a 100 year expiration period
 966 and the files will not be deleted.
 967
 968 The function returns a list containing the current host name, the
 969 temporary flag, and the key and cert file names in the form required
 970 by `gnutls-boot-parameters`."
 971   (let ((exp-key-file (expand-file-name key-file))
 972         (exp-cert-file (expand-file-name cert-file)))
 973     (condition-case nil
 974         (progn
 975           (call-process elpher-openssl-command nil nil nil
 976                         "req" "-x509" "-newkey" "rsa:2048"
 977                         "-days" (if temporary "1" "36500")
 978                         "-nodes"
 979                         "-subj" (concat "/CN=" common-name)
 980                         "-keyout" exp-key-file
 981                         "-out" exp-cert-file)
 982           (list (elpher-address-host (elpher-page-address elpher-current-page))
 983                 temporary exp-key-file exp-cert-file))
 984       (error
 985        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 986        (error "Program 'openssl', required for certificate generation, not found")))))
 987
 988 (defun elpher-generate-throwaway-certificate ()
 989   "Generate and return details of a throwaway certificate.
 990 The key and certificate files will be deleted when they are no
 991 longer needed for this session."
 992   (let* ((file-base (make-temp-name "elpher"))
 993          (key-file (concat temporary-file-directory file-base ".key"))
 994          (cert-file (concat temporary-file-directory file-base ".crt")))
 995     (elpher-generate-certificate file-base key-file cert-file t)))
 996
 997 (defun elpher-generate-persistent-certificate (file-base common-name)
 998   "Generate and return details of a persistent certificate.
 999 The argument FILE-BASE is used as the base for the key and certificate
1000 files, while COMMON-NAME specifies the common name field of the
1001 certificate.
1002
1003 The key and certificate files are written to in `elpher-certificate-directory'."
1004   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1005          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1006     (elpher-generate-certificate common-name key-file cert-file)))
1007
1008 (defun elpher-get-existing-certificate (file-base)
1009   "Return a certificate object corresponding to an existing certificate.
1010 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1011 the directory `elpher-certificate-directory'."
1012   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1013          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1014     (list (elpher-address-host (elpher-page-address elpher-current-page))
1015           nil
1016           (expand-file-name key-file)
1017           (expand-file-name cert-file))))
1018
1019 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1020   "Install a key+certificate file pair in `elpher-certificate-directory'.
1021 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1022 certificate files to install.  The argument FILE-BASE is used as the
1023 base for the installed key and certificate files."
1024   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1025          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1026     (if (or (file-exists-p key-file)
1027             (file-exists-p cert-file))
1028         (error "A certificate with base name %s is already installed" file-base))
1029     (copy-file key-file-src key-file)
1030     (copy-file cert-file-src cert-file)
1031     (list (elpher-address-host (elpher-page-address elpher-current-page))
1032           nil
1033           (expand-file-name key-file)
1034           (expand-file-name cert-file))))
1035
1036 (defun elpher-list-existing-certificates ()
1037   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1038   (unless (file-directory-p elpher-certificate-directory)
1039     (make-directory elpher-certificate-directory))
1040   (mapcar
1041    (lambda (file)
1042      (file-name-sans-extension file))
1043    (directory-files elpher-certificate-directory nil "\\.key$")))
1044
1045 (defun elpher-forget-current-certificate ()
1046   "Causes any current certificate to be forgotten.)
1047 In the case of throwaway certificates, the key and certificate files
1048 are also deleted."
1049   (interactive)
1050   (when elpher-client-certificate
1051     (unless (and (called-interactively-p 'any)
1052                  (not (y-or-n-p (concat "Really forget client certificate? "
1053                                         "(Throwaway certificates will be deleted.)"))))
1054       (when (cadr elpher-client-certificate)
1055         (delete-file (elt elpher-client-certificate 2))
1056         (delete-file (elt elpher-client-certificate 3)))
1057       (setq elpher-client-certificate nil)
1058       (if (called-interactively-p 'any)
1059           (message "Client certificate forgotten.")))))
1060
1061 (defun elpher-get-current-keylist (address)
1062   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1063
1064 This is obtained from the client certificate described by
1065 `elpher-current-certificate', if one is available and the host for
1066 that certificate matches the host in ADDRESS.
1067
1068 If `elpher-current-certificate' is non-nil, and its host name doesn't
1069 match that of ADDRESS, the certificate is forgotten."
1070   (if elpher-client-certificate
1071       (if (string= (car elpher-client-certificate)
1072                    (elpher-address-host address))
1073           (list (cddr elpher-client-certificate))
1074         (elpher-forget-current-certificate)
1075         (message "Disabling client certificate for new host")
1076         nil)
1077     nil))
1078
1079
1080 ;;; Gopher selector retrieval
1081 ;;
1082
1083 (defun elpher-get-gopher-response (address renderer)
1084   "Get response string from gopher server at ADDRESS and render using RENDERER."
1085   (elpher-get-host-response address 70
1086                             (concat (elpher-gopher-address-selector address) "\r\n")
1087                             renderer
1088                             (or (string= (elpher-address-protocol address) "gophers")
1089                                 elpher-use-tls)))
1090
1091 (defun elpher-get-gopher-page (renderer)
1092   "Getter function for gopher pages.
1093 The RENDERER procedure is used to display the contents of the page
1094 once they are retrieved from the gopher server."
1095   (let* ((address (elpher-page-address elpher-current-page))
1096          (content (elpher-get-cached-content address)))
1097     (if (and content (funcall renderer nil))
1098         (elpher-with-clean-buffer
1099          (insert content)
1100          (elpher-restore-pos))
1101       (elpher-with-clean-buffer
1102        (insert "LOADING... (use 'u' to cancel)\n"))
1103       (condition-case the-error
1104           (elpher-get-gopher-response address renderer)
1105         (error
1106          (elpher-network-error address the-error))))))
1107
1108
1109 ;;; Gopher index rendering
1110 ;;
1111
1112 (defun elpher-insert-margin (&optional type-name)
1113   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1114   (if type-name
1115       (progn
1116         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1117                         (concat
1118                          (propertize "[" 'face 'elpher-margin-brackets)
1119                          (propertize type-name 'face 'elpher-margin-key)
1120                          (propertize "]" 'face 'elpher-margin-brackets))))
1121         (insert " "))
1122     (insert (make-string elpher-margin-width ?\s))))
1123
1124 (defun elpher--page-button-help (_window buffer pos)
1125   "Function called by Emacs to generate mouse-over text.
1126 The arguments specify the BUFFER and the POS within the buffer of the item
1127 for which help is required.  The function returns the help to be
1128 displayed.  The _WINDOW argument is currently unused."
1129   (with-current-buffer buffer
1130     (let ((button (button-at pos)))
1131       (when button
1132         (let* ((page (button-get button 'elpher-page))
1133                (address (elpher-page-address page)))
1134           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1135
1136 (defun elpher-insert-index-record (display-string &optional address)
1137   "Function to insert an index record into the current buffer.
1138 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1139 If ADDRESS is not supplied or nil the record is rendered as an
1140 'information' line."
1141   (let* ((type (if address (elpher-address-type address) nil))
1142          (type-map-entry (cdr (assoc type elpher-type-map))))
1143     (if type-map-entry
1144         (let* ((margin-code (elt type-map-entry 2))
1145                (face (elt type-map-entry 3))
1146                (filtered-display-string (elpher-color-filter-apply display-string))
1147                (page (elpher-make-page filtered-display-string address)))
1148           (elpher-insert-margin margin-code)
1149           (insert-text-button filtered-display-string
1150                               'face face
1151                               'elpher-page page
1152                               'action #'elpher-click-link
1153                               'follow-link t
1154                               'help-echo #'elpher--page-button-help))
1155       (pcase type
1156         ('nil ;; Information
1157          (elpher-insert-margin)
1158          (let ((propertized-display-string
1159                 (propertize display-string 'face 'elpher-info)))
1160            (insert (elpher-process-text-for-display propertized-display-string))))
1161         (`(gopher ,selector-type) ;; Unknown
1162          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1163          (insert (propertize display-string
1164                              'face 'elpher-unknown)))))
1165     (insert "\n")))
1166
1167 (defun elpher-click-link (button)
1168   "Function called when the gopher link BUTTON is activated."
1169   (let ((page (button-get button 'elpher-page)))
1170     (elpher-visit-page page)))
1171
1172 (defun elpher-render-index (data &optional _mime-type-string)
1173   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1174   (elpher-with-clean-buffer
1175    (if (not data)
1176        t
1177      (let ((data-processed (elpher-preprocess-text-response data)))
1178        (dolist (line (split-string data-processed "\n"))
1179          (ignore-errors
1180            (unless (= (length line) 0)
1181              (let* ((type (elt line 0))
1182                     (fields (split-string (substring line 1) "\t"))
1183                     (display-string (elt fields 0))
1184                     (selector (elt fields 1))
1185                     (host (elt fields 2))
1186                     (port (if (elt fields 3)
1187                               (string-to-number (elt fields 3))
1188                             nil))
1189                     (address (elpher-make-gopher-address type selector host port)))
1190                (elpher-insert-index-record display-string address))))))
1191      (elpher-cache-content (elpher-page-address elpher-current-page)
1192                            (buffer-string)))))
1193
1194
1195 ;;; Gopher text rendering
1196 ;;
1197
1198 (defun elpher-render-text (data &optional _mime-type-string)
1199   "Render DATA as text.  MIME-TYPE-STRING is unused."
1200   (elpher-with-clean-buffer
1201    (if (not data)
1202        t
1203      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1204      (elpher-cache-content
1205       (elpher-page-address elpher-current-page)
1206       (buffer-string)))))
1207
1208
1209 ;;; Image retrieval
1210 ;;
1211
1212 (defun elpher-render-image (data &optional _mime-type-string)
1213   "Display DATA as image.  MIME-TYPE-STRING is unused."
1214   (if (not data)
1215       nil
1216     (if (display-images-p)
1217         (let* ((image (create-image
1218                        data
1219                        nil t)))
1220           (if (not image)
1221               (error "Unsupported image format")
1222             (let ((window (get-buffer-window elpher-buffer-name)))
1223               (when window
1224                 (setf (image-property image :max-width) (window-body-width window t))
1225                 (setf (image-property image :max-height) (window-body-height window t))))
1226             (elpher-with-clean-buffer
1227              (insert-image image)
1228              (elpher-restore-pos))))
1229       (elpher-render-download data))))
1230
1231
1232 ;;; Gopher search retrieval and rendering
1233 ;;
1234
1235 (defun elpher-get-gopher-query-page (renderer)
1236   "Getter for gopher addresses requiring input.
1237 The response is rendered using the rendering function RENDERER."
1238   (let* ((address (elpher-page-address elpher-current-page))
1239          (content (elpher-get-cached-content address))
1240          (aborted t))
1241     (if (and content (funcall renderer nil))
1242         (elpher-with-clean-buffer
1243          (insert content)
1244          (elpher-restore-pos)
1245          (message "Displaying cached search results.  Reload to perform a new search."))
1246       (unwind-protect
1247           (let* ((query-string (read-string "Query: "))
1248                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1249                  (search-address (elpher-make-gopher-address ?1
1250                                                              query-selector
1251                                                              (elpher-address-host address)
1252                                                              (elpher-address-port address)
1253                                                              (equal (elpher-address-type address) "gophers"))))
1254             (setq aborted nil)
1255
1256             (elpher-with-clean-buffer
1257              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1258             (elpher-get-gopher-response search-address renderer))
1259         (if aborted
1260             (elpher-visit-previous-page))))))
1261
1262
1263 ;;; Raw server response rendering
1264 ;;
1265
1266 (defun elpher-render-raw (data &optional mime-type-string)
1267   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1268   (if (not data)
1269       nil
1270     (elpher-with-clean-buffer
1271      (when mime-type-string
1272        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1273      (insert data)
1274      (goto-char (point-min)))
1275     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1276
1277
1278 ;;; File save "rendering"
1279 ;;
1280
1281 (defun elpher-render-download (data &optional _mime-type-string)
1282   "Save DATA to file.  MIME-TYPE-STRING is unused."
1283   (if (not data)
1284       nil
1285     (let* ((address (elpher-page-address elpher-current-page))
1286            (selector (if (elpher-address-gopher-p address)
1287                          (elpher-gopher-address-selector address)
1288                        (elpher-address-filename address))))
1289       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1290       (let* ((filename-proposal (file-name-nondirectory selector))
1291              (filename (read-file-name "Download complete. Save file as: "
1292                                        nil nil nil
1293                                        (if (> (length filename-proposal) 0)
1294                                            filename-proposal
1295                                          "download.file"))))
1296         (let ((coding-system-for-write 'binary))
1297           (with-temp-file filename
1298             (insert data)))
1299         (message (format "Saved to file %s." filename))))))
1300
1301
1302 ;;; HTML rendering
1303 ;;
1304
1305 (defun elpher-render-html (data &optional _mime-type-string)
1306   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1307   (elpher-with-clean-buffer
1308    (if (not data)
1309        t
1310      (let ((dom (with-temp-buffer
1311                   (insert data)
1312                   (libxml-parse-html-region (point-min) (point-max)))))
1313        (shr-insert-document dom)))))
1314
1315
1316 ;;; Gemini page retrieval
1317 ;;
1318
1319 (defvar elpher-gemini-redirect-chain)
1320
1321 (defun elpher-get-gemini-response (address renderer)
1322   "Get response string from gemini server at ADDRESS and render using RENDERER."
1323   (elpher-get-host-response address 1965
1324                             (concat (elpher-address-to-url address) "\r\n")
1325                             (lambda (response-string)
1326                               (elpher-process-gemini-response response-string renderer))
1327                             'gemini))
1328
1329 (defun elpher-parse-gemini-response (response)
1330   "Parse the RESPONSE string and return a list of components.
1331 The list is of the form (code meta body).  A response of nil implies
1332 that the response was malformed."
1333   (let ((header-end-idx (string-match "\r\n" response)))
1334     (if header-end-idx
1335         (let ((header (string-trim (substring response 0 header-end-idx)))
1336               (body (substring response (+ header-end-idx 2))))
1337           (if (>= (length header) 2)
1338               (let ((code (substring header 0 2))
1339                     (meta (string-trim (substring header 2))))
1340                 (list code meta body))
1341             (error "Malformed response: No response status found in header %s" header)))
1342       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1343
1344 (defun elpher-process-gemini-response (response-string renderer)
1345   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1346   (let ((response-components (elpher-parse-gemini-response response-string)))
1347     (let ((response-code (elt response-components 0))
1348           (response-meta (elt response-components 1))
1349           (response-body (elt response-components 2)))
1350       (pcase (elt response-code 0)
1351         (?1 ; Input required
1352          (elpher-with-clean-buffer
1353           (insert "Gemini server is requesting input."))
1354          (let* ((query-string
1355                  (with-local-quit
1356                    (if (eq (elt response-code 1) ?1)
1357                        (read-passwd (concat response-meta ": "))
1358                      (read-string (concat response-meta ": ")))))
1359                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1360                 (old-fname (url-filename query-address)))
1361            (if (not query-string)
1362                (elpher-visit-previous-page)
1363              (setf (url-filename query-address)
1364                    (concat old-fname "?" (url-build-query-string `((,query-string)))))
1365              (elpher-get-gemini-response query-address renderer))))
1366         (?2 ; Normal response
1367          (funcall renderer response-body response-meta))
1368         (?3 ; Redirect
1369          (message "Following redirect to %s" response-meta)
1370          (if (>= (length elpher-gemini-redirect-chain) 5)
1371              (error "More than 5 consecutive redirects followed"))
1372          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1373            (if (member redirect-address elpher-gemini-redirect-chain)
1374                (error "Redirect loop detected"))
1375            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1376                (error "Server tried to automatically redirect to non-gemini URL: %s"
1377                       response-meta))
1378            (elpher-page-set-address elpher-current-page redirect-address)
1379            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1380            (elpher-get-gemini-response redirect-address renderer)))
1381         (?4 ; Temporary failure
1382          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1383                 response-code response-meta))
1384         (?5 ; Permanent failure
1385          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1386                 response-code response-meta))
1387         (?6 ; Client certificate required
1388          (elpher-with-clean-buffer
1389           (if elpher-client-certificate
1390               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1391             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1392           (auto-fill-mode 1)
1393           (elpher-gemini-insert-text response-meta))
1394          (let ((chosen-certificate
1395                 (with-local-quit (elpher-choose-client-certificate))))
1396            (unless chosen-certificate
1397              (error "Gemini server requires a client certificate and none was provided"))
1398            (setq elpher-client-certificate chosen-certificate))
1399          (elpher-with-clean-buffer)
1400          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1401         (_other
1402          (error "Gemini server response unknown: %s %s"
1403                 response-code response-meta))))))
1404
1405 (defun elpher--read-answer-polyfill (question answers)
1406   "Polyfill for `read-answer' in Emacs 26.1.
1407 QUESTION is a string containing a question, and ANSWERS
1408 is a list of possible answers."
1409     (completing-read question (mapcar 'identity answers)))
1410
1411 (if (fboundp 'read-answer)
1412     (defalias 'elpher-read-answer 'read-answer)
1413   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1414
1415 (defun elpher-choose-client-certificate ()
1416   "Prompt for a client certificate to use to establish a TLS connection."
1417   (let* ((read-answer-short t))
1418     (pcase (read-answer "What do you want to do? "
1419                         '(("throwaway" ?t
1420                            "generate and use throw-away certificate")
1421                           ("persistent" ?p
1422                            "generate new or use existing persistent certificate")
1423                           ("abort" ?a
1424                            "stop immediately")))
1425       ("throwaway"
1426        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1427       ("persistent"
1428        (let* ((existing-certificates (elpher-list-existing-certificates))
1429               (file-base (completing-read
1430                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1431                           existing-certificates)))
1432          (if (string-empty-p (string-trim file-base))
1433              nil
1434            (if (member file-base existing-certificates)
1435                (setq elpher-client-certificate
1436                      (elpher-get-existing-certificate file-base))
1437              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1438                                  '(("new" ?n
1439                                     "generate new certificate")
1440                                    ("install" ?i
1441                                     "install existing certificate")
1442                                    ("abort" ?a
1443                                     "stop immediately")))
1444                ("new"
1445                 (let ((common-name (read-string "Common Name field for new certificate: "
1446                                                 file-base)))
1447                   (message "New key and self-signed certificate written to %s"
1448                            elpher-certificate-directory)
1449                   (elpher-generate-persistent-certificate file-base common-name)))
1450                ("install"
1451                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1452                        (key-file (read-file-name "Key file: " nil nil t)))
1453                   (message "Key and certificate installed in %s for future use"
1454                            elpher-certificate-directory)
1455                   (elpher-install-and-use-existing-certificate key-file
1456                                                                cert-file
1457                                                                file-base)))
1458                ("abort" nil))))))
1459       ("abort" nil))))
1460
1461 (defun elpher-get-gemini-page (renderer)
1462   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1463   (let* ((address (elpher-page-address elpher-current-page))
1464          (content (elpher-get-cached-content address)))
1465     (condition-case the-error
1466         (if (and content (funcall renderer nil))
1467             (elpher-with-clean-buffer
1468              (insert content)
1469              (elpher-restore-pos))
1470           (elpher-with-clean-buffer
1471            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1472           (setq elpher-gemini-redirect-chain nil)
1473           (elpher-get-gemini-response address renderer))
1474       (error
1475        (elpher-network-error address the-error)))))
1476
1477 ;;; Gemini page rendering
1478 ;;
1479
1480 (defun elpher-render-gemini (body &optional mime-type-string)
1481   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1482   (if (not body)
1483       t
1484     (let* ((mime-type-string* (if (or (not mime-type-string)
1485                                       (string-empty-p mime-type-string))
1486                                   "text/gemini; charset=utf-8"
1487                                 mime-type-string))
1488            (mime-type-split (split-string mime-type-string* ";" t))
1489            (mime-type (string-trim (car mime-type-split)))
1490            (parameters (mapcar (lambda (s)
1491                                  (let ((key-val (split-string s "=")))
1492                                    (list (downcase (string-trim (car key-val)))
1493                                          (downcase (string-trim (cadr key-val))))))
1494                                (cdr mime-type-split))))
1495       (when (string-prefix-p "text/" mime-type)
1496         (setq body (decode-coding-string
1497                     body
1498                     (if (assoc "charset" parameters)
1499                         (intern (cadr (assoc "charset" parameters)))
1500                       'utf-8)))
1501         (setq body (replace-regexp-in-string "\r" "" body)))
1502       (pcase mime-type
1503         ((or "text/gemini" "")
1504          (elpher-render-gemini-map body parameters))
1505         ("text/html"
1506          (elpher-render-html body))
1507         ((pred (string-prefix-p "text/"))
1508          (elpher-render-gemini-plain-text body parameters))
1509         ((pred (string-prefix-p "image/"))
1510          (elpher-render-image body))
1511         (_other
1512          (elpher-render-download body))))))
1513
1514 (defun elpher-gemini-get-link-url (link-line)
1515   "Extract the url portion of LINK-LINE, a gemini map file link line.
1516 Returns nil in the event that the contents of the line following the
1517 => prefix are empty."
1518   (let ((l (split-string (substring link-line 2))))
1519     (if l
1520         (string-trim (elt l 0))
1521       nil)))
1522
1523 (defun elpher-gemini-get-link-display-string (link-line)
1524   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1525 Return nil if this portion is not provided."
1526   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1527          (idx (string-match "[ \t]" rest)))
1528     (and idx
1529          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1530
1531 (defun elpher-collapse-dot-sequences (filename)
1532   "Collapse dot sequences in the (absolute) FILENAME.
1533 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1534   (let* ((path (split-string filename "/" t))
1535          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1536          (path-reversed-normalized
1537           (seq-reduce (lambda (a b)
1538                         (cond ((equal b "..") (cdr a))
1539                               ((equal b ".") a)
1540                               (t (cons b a))))
1541                       path nil))
1542          (path-normalized (reverse path-reversed-normalized)))
1543     (if path-normalized
1544         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1545       "/")))
1546
1547 (defun elpher-address-from-gemini-url (url)
1548   "Extract address from URL with defaults as per gemini map files.
1549 While there's obviously some redundancy here between this function and
1550 `elpher-address-from-url', gemini map file URLs require enough special
1551 treatment that a separate function is warranted."
1552   (let ((address (url-generic-parse-url url))
1553         (current-address (elpher-page-address elpher-current-page)))
1554     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1555       (if (url-host address) ;if there is an explicit host, filenames are absolute
1556           (if (string-empty-p (url-filename address))
1557               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1558         (setf (url-host address) (url-host current-address))
1559         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1560         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1561         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1562           (setf (url-filename address)
1563                 (concat (file-name-directory (url-filename current-address))
1564                         (url-filename address)))))
1565       (when (url-host address)
1566         (setf (url-host address) (puny-encode-domain (url-host address))))
1567       (unless (url-type address)
1568         (setf (url-type address) (url-type current-address)))
1569       (when (equal (url-type address) "gemini")
1570         (setf (url-filename address)
1571               (elpher-collapse-dot-sequences (url-filename address)))))
1572     (elpher-remove-redundant-ports address)))
1573
1574 (defun elpher-gemini-insert-link (link-line)
1575   "Insert link described by LINK-LINE into a text/gemini document."
1576   (let ((url (elpher-gemini-get-link-url link-line)))
1577     (when url
1578       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1579              (address (elpher-address-from-gemini-url url))
1580              (type (if address (elpher-address-type address) nil))
1581              (type-map-entry (cdr (assoc type elpher-type-map)))
1582              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1583         (when type-map-entry
1584           (insert elpher-gemini-link-string)
1585           (let* ((face (elt type-map-entry 3))
1586                  (display-string (or given-display-string
1587                                      (elpher-address-to-iri address)))
1588                  (page (elpher-make-page display-string
1589                                          address)))
1590             (insert-text-button display-string
1591                                 'face face
1592                                 'elpher-page page
1593                                 'action #'elpher-click-link
1594                                 'follow-link t
1595                                 'help-echo #'elpher--page-button-help))
1596           (newline))))))
1597
1598 (defun elpher-gemini-insert-header (header-line)
1599   "Insert header described by HEADER-LINE into a text/gemini document.
1600 The gemini map file line describing the header is given
1601 by HEADER-LINE."
1602   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1603     (let* ((level (length (match-string 1 header-line)))
1604            (header (substring header-line (match-end 0)))
1605            (face (pcase level
1606                    (1 'elpher-gemini-heading1)
1607                    (2 'elpher-gemini-heading2)
1608                    (3 'elpher-gemini-heading3)
1609                    (_ 'default)))
1610            (fill-column (if (display-graphic-p)
1611                             (/ (* fill-column
1612                                   (font-get (font-spec :name (face-font 'default)) :size))
1613                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1614       (unless (display-graphic-p)
1615         (insert (make-string level ?#) " "))
1616       (insert (propertize header
1617                           'face face
1618                           'gemini-heading t
1619                           'rear-nonsticky t))
1620       (newline))))
1621
1622 (defun elpher-gemini-insert-text (text-line)
1623   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1624 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1625 width defined by `elpher-gemini-max-fill-width'."
1626   (string-match
1627    (rx (: line-start
1628           (optional
1629            (group (or (: "*" (+ (any " \t")))
1630                       (: ">" (* (any " \t"))))))))
1631    text-line)
1632   (let* ((line-prefix (match-string 1 text-line))
1633          (processed-text-line
1634           (if line-prefix
1635               (cond ((string-prefix-p "*" line-prefix)
1636                      (concat
1637                       (replace-regexp-in-string "\\*"
1638                                                 elpher-gemini-bullet-string
1639                                                 (match-string 0 text-line))
1640                       (substring text-line (match-end 0))))
1641                     ((string-prefix-p ">" line-prefix)
1642                      (propertize text-line 'face 'elpher-gemini-quoted))
1643                     (t text-line))
1644             text-line))
1645          (fill-prefix (if line-prefix
1646                           (make-string (length (match-string 0 text-line)) ?\s)
1647                         "")))
1648     (insert (elpher-process-text-for-display processed-text-line))
1649     (newline)))
1650
1651 (defun elpher-gemini-pref-expand-collapse (button)
1652   "Function called when the preformatted text toggle BUTTON is activated."
1653   (let ((id (button-get button 'pref-id)))
1654     (if (invisible-p id)
1655         (remove-from-invisibility-spec id)
1656       (add-to-invisibility-spec id))
1657     (redraw-display)))
1658
1659 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1660   "Insert a button for toggling the visibility of preformatted text.
1661 If non-nil, ALT-TEXT is displayed alongside the button."
1662   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1663          (pref-id (intern (concat "pref-"
1664                                   (number-to-string (point))
1665                                   "-"
1666                                   url-string))))
1667     (insert elpher-gemini-preformatted-toggle-bullet)
1668     (when alt-text
1669       (insert (propertize (concat alt-text " ")
1670                           'face 'elpher-gemin-preformatted)))
1671     (insert-text-button elpher-gemini-preformatted-toggle-label
1672                         'action #'elpher-gemini-pref-expand-collapse
1673                         'pref-id pref-id
1674                         'face 'elpher-gemini-preformatted-toggle)
1675     (add-to-invisibility-spec pref-id)
1676     (newline)
1677     pref-id))
1678
1679 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1680   "Insert a LINE of preformatted text.
1681 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1682 can be used to toggle the display of the preformatted text."
1683   (insert (propertize (concat (elpher-process-text-for-display
1684                                (propertize line 'face 'elpher-gemini-preformatted))
1685                               "\n")
1686                       'invisible pref-id
1687                       'rear-nonsticky t)))
1688
1689 (defun elpher-render-gemini-map (data _parameters)
1690   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1691   (elpher-with-clean-buffer
1692    (auto-fill-mode 1)
1693    (setq-local buffer-invisibility-spec nil)
1694    (let ((preformatted nil)
1695          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1696      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1697      (dolist (line (split-string data "\n"))
1698        (pcase line
1699          ((rx (: string-start "```" (opt (let alt-text (+ any)))))
1700           (setq preformatted
1701                 (if preformatted
1702                     nil
1703                   (if elpher-gemini-hide-preformatted
1704                       (elpher-gemini-insert-preformatted-toggler alt-text)
1705                     t))))
1706          ((guard  preformatted)
1707           (elpher-gemini-insert-preformatted-line line preformatted))
1708          ((pred (string-prefix-p "=>"))
1709           (elpher-gemini-insert-link line))
1710          ((pred (string-prefix-p "#"))
1711           (elpher-gemini-insert-header line))
1712          (_ (elpher-gemini-insert-text line))))
1713    (elpher-cache-content
1714     (elpher-page-address elpher-current-page)
1715     (buffer-string)))))
1716
1717 (defun elpher-render-gemini-plain-text (data _parameters)
1718   "Render DATA as plain text file.  PARAMETERS is currently unused."
1719   (elpher-with-clean-buffer
1720    (insert (elpher-process-text-for-display data))
1721    (elpher-cache-content
1722     (elpher-page-address elpher-current-page)
1723     (buffer-string))))
1724
1725 (defun elpher-build-current-imenu-index ()
1726   "Build imenu index for current elpher buffer."
1727   (save-excursion
1728     (goto-char (point-min))
1729     (let ((match nil)
1730           (headers nil))
1731       (while (setq match (text-property-search-forward 'gemini-heading t t))
1732         (push (cons
1733                (buffer-substring-no-properties (prop-match-beginning match)
1734                                                (prop-match-end match))
1735                (prop-match-beginning match))
1736               headers))
1737       (reverse headers))))
1738
1739
1740 ;;; Finger page connection
1741 ;;
1742
1743 (defun elpher-get-finger-page (renderer)
1744   "Opens a finger connection to the current page address.
1745 The result is rendered using RENDERER."
1746   (let* ((address (elpher-page-address elpher-current-page))
1747          (content (elpher-get-cached-content address)))
1748     (if (and content (funcall renderer nil))
1749         (elpher-with-clean-buffer
1750          (insert content)
1751          (elpher-restore-pos))
1752       (elpher-with-clean-buffer
1753        (insert "LOADING... (use 'u' to cancel)\n"))
1754       (condition-case the-error
1755           (let* ((kill-buffer-query-functions nil)
1756                  (user (let ((filename (elpher-address-filename address)))
1757                          (if (> (length filename) 1)
1758                              (substring filename 1)
1759                            (elpher-address-user address)))))
1760             (elpher-get-host-response address 79
1761                                       (concat user "\r\n")
1762                                       renderer))
1763         (error
1764          (elpher-network-error address the-error))))))
1765
1766
1767 ;;; Telnet page connection
1768 ;;
1769
1770 (defun elpher-get-telnet-page (renderer)
1771   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1772   (when renderer
1773     (elpher-visit-previous-page)
1774     (error "Command not supported for telnet URLs"))
1775   (let* ((address (elpher-page-address elpher-current-page))
1776          (host (elpher-address-host address))
1777          (port (elpher-address-port address)))
1778     (elpher-visit-previous-page)
1779     (if (> port 0)
1780         (telnet host port)
1781       (telnet host))))
1782
1783
1784 ;;; Other URL page opening
1785 ;;
1786
1787 (defun elpher-get-other-url-page (renderer)
1788   "Getter which attempts to open the URL specified by the current page.
1789 The RENDERER argument to this getter must be nil."
1790   (when renderer
1791     (elpher-visit-previous-page)
1792     (error "Command not supported for general URLs"))
1793   (let* ((address (elpher-page-address elpher-current-page))
1794          (url (elpher-address-to-url address)))
1795     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1796     (message "Opening URL...")
1797     (if elpher-open-urls-with-eww
1798         (browse-web url)
1799       (browse-url url))))
1800
1801
1802 ;;; File page
1803 ;;
1804
1805 (defun elpher-get-file-page (renderer)
1806   "Getter which renders a local file using RENDERER.
1807 Assumes UTF-8 encoding for all text files."
1808   (let* ((address (elpher-page-address elpher-current-page))
1809          (filename (elpher-address-filename address)))
1810     (unless (file-exists-p filename)
1811       (elpher-visit-previous-page)
1812       (error "File not found"))
1813     (unless (file-readable-p filename)
1814       (elpher-visit-previous-page)
1815       (error "Could not read from file"))
1816     (let ((body (with-temp-buffer
1817        (let ((coding-system-for-read 'binary)
1818              (coding-system-for-write 'binary))
1819          (insert-file-contents-literally filename)
1820          (encode-coding-string (buffer-string) 'raw-text)))))
1821        (if renderer
1822            (funcall renderer body nil)
1823          (pcase (file-name-extension filename)
1824            ((or  "gmi" "gemini")
1825             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1826            ((or "htm" "html")
1827             (elpher-render-html (decode-coding-string body 'utf-8)))
1828            ((or "txt" "")
1829             (elpher-render-text (decode-coding-string body 'utf-8)))
1830            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1831             (elpher-render-image body))
1832            ((or "gopher" "gophermap")
1833             (elpher-render-index (elpher-decode body)))
1834            (_
1835             (elpher-render-download body))))
1836        (elpher-restore-pos))))
1837
1838
1839 ;;; Welcome page retrieval
1840 ;;
1841
1842 (defun elpher-get-welcome-page (renderer)
1843   "Getter which displays the welcome page (RENDERER must be nil)."
1844   (when renderer
1845     (elpher-visit-previous-page)
1846     (error "Command not supported for welcome page"))
1847   (elpher-with-clean-buffer
1848    (insert "     --------------------------------------------\n"
1849            "           Elpher Gopher and Gemini Client       \n"
1850            "                   version " elpher-version "\n"
1851            "     --------------------------------------------\n"
1852            "\n"
1853            "Default bindings:\n"
1854            "\n"
1855            " - TAB/Shift-TAB: next/prev item on current page\n"
1856            " - RET/mouse-1: open item under cursor\n"
1857            " - m: select an item on current page by name (autocompletes)\n"
1858            " - u/mouse-3/U: return to previous page or to the start page\n"
1859            " - g: go to a particular address (gopher, gemini, finger)\n"
1860            " - o/O: open a different address selector or the root menu of the current server\n"
1861            " - d/D: download item under cursor or current page\n"
1862            " - i/I: info on item under cursor or current page\n"
1863            " - c/C: copy URL representation of item under cursor or current page\n"
1864            " - a/A: bookmark the item under cursor or current page\n"
1865            " - B: list all bookmarks\n"
1866            " - s/S: show current history stack or all previously visted pages\n"
1867            " - r: redraw current page (using cached contents if available)\n"
1868            " - R: reload current page (regenerates cache)\n"
1869            " - !: set character coding system for gopher (default is to autodetect)\n"
1870            " - T: toggle TLS gopher mode\n"
1871            " - F: forget/discard current TLS client certificate\n"
1872            " - .: display the raw server response for the current page\n"
1873            "\n"
1874            "Start your exploration of gopher space and gemini:\n")
1875    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1876                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1877    (elpher-insert-index-record "Project Gemini home page"
1878                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1879    (insert "\n"
1880            "Alternatively, select a search engine and enter some search terms:\n")
1881    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1882                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1883    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1884                                (elpher-address-from-url "gemini://geminispace.info/search"))
1885    (insert "\n"
1886            "Your bookmarks are stored in your ")
1887    (insert-text-button "bookmark list"
1888                        'face 'link
1889                        'action #'elpher-click-link
1890                        'follow-link t
1891                        'help-echo #'elpher--page-button-help
1892                        'elpher-page
1893                        (elpher-make-page "Elpher Bookmarks"
1894                                          (elpher-make-about-address 'bookmarks)))
1895    (insert ".\n")
1896    (insert (propertize
1897             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1898             'face 'shadow))
1899    (insert "\n"
1900            "The gopher home of the Elpher project is here:\n")
1901    (elpher-insert-index-record "The Elpher Project Page"
1902                                (elpher-make-gopher-address ?1
1903                                                            "/projects/elpher/"
1904                                                            "thelambdalab.xyz"
1905                                                            70))
1906    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1907      (insert "\n"
1908              "The following info documentation is available:\n"
1909              "   - ")
1910      (insert-text-button "Elpher Manual"
1911                          'face 'link
1912                          'action (lambda (_)
1913                                    (interactive)
1914                                    (info "(elpher)"))
1915                          'follow-link t
1916                          'help-echo help-string)
1917      (insert "\n   - ")
1918      (insert-text-button "Changes introduced by the latest release"
1919                        'face 'link
1920                        'action (lambda (_)
1921                                  (interactive)
1922                                  (info "(elpher)News"))
1923                        'follow-link t
1924                        'help-echo help-string))
1925    (insert "\n")
1926    (insert (propertize
1927             (concat "(These documents should be available if you have installed Elpher\n"
1928                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1929                     " manual yourself.)\n")
1930             'face 'shadow))
1931    (elpher-restore-pos)))
1932
1933
1934 ;;; History page retrieval
1935 ;;
1936
1937 (defun elpher-show-history ()
1938   "Show the current contents of elpher's history stack.
1939 Use \\[elpher-show-visited-pages] to see the entire history.
1940 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1941   (interactive)
1942   (elpher-visit-page
1943    (elpher-make-page "Current History Stack"
1944                      (elpher-make-about-address 'history))))
1945
1946 (defun elpher-show-visited-pages ()
1947   "Show the all the pages you've visited using Elpher.
1948 Use \\[elpher-show-history] to see just the current history stack.
1949 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1950   (interactive)
1951   (elpher-visit-page
1952    (elpher-make-page "Elpher Visted Pages"
1953                      (elpher-make-about-address 'visited-pages))))
1954
1955 (defun elpher-get-history-page (renderer)
1956   "Getter which displays the history page (RENDERER must be nil)."
1957   (when renderer
1958     (elpher-visit-previous-page)
1959     (error "Command not supported for history page"))
1960   (elpher-display-history-links elpher-history "Current history stack"))
1961
1962 (defun elpher-get-visited-pages-page (renderer)
1963   "Getter which displays the list of visited pages (RENDERER must be nil)."
1964   (when renderer
1965     (elpher-visit-previous-page)
1966     (error "Command not supported for history page"))
1967   (elpher-display-history-links
1968    (seq-filter (lambda (page)
1969                  (not (elpher-address-about-p (elpher-page-address page))))
1970                elpher-visited-pages)
1971    "All visited pages"))
1972
1973 (defun elpher-display-history-links (pages title)
1974   "Show all PAGES in an Elpher buffer with a given TITLE."
1975   (let* ((title-line (concat " ---- " title " ----"))
1976          (footer-line (make-string (length title-line) ?-)))
1977     (elpher-with-clean-buffer
1978      (insert title-line "\n\n")
1979      (if pages
1980          (dolist (page pages)
1981            (when page
1982              (let ((display-string (elpher-page-display-string page))
1983                    (address (elpher-page-address page)))
1984                (elpher-insert-index-record display-string address))))
1985        (insert "No history items found.\n"))
1986      (insert "\n " footer-line "\n"
1987              "Select an entry or press 'u' to return to the previous page.")
1988      (elpher-restore-pos))))
1989
1990
1991 ;;; Bookmarks
1992 ;;
1993
1994 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1995 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1996 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1997 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1998
1999 (defvar elpher-bookmark-link nil
2000   "Prefer bookmarking a link or the current page.
2001 Bind this variable dynamically, or set it to t.
2002 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2003 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2004
2005 (defun elpher-bookmark-make-record ()
2006   "Return a bookmark record.
2007 If `elpher-bookmark-link' is non-nil and point is on a link button,
2008 return a bookmark record for that link.  Otherwise, return a bookmark
2009 record for the current elpher page."
2010   (let* ((button (and elpher-bookmark-link (button-at (point))))
2011          (page (if button
2012                    (button-get button 'elpher-page)
2013                  elpher-current-page)))
2014     (unless page
2015       (error "Cannot bookmark this link"))
2016     (let* ((address (elpher-page-address page))
2017            (url (elpher-address-to-url address))
2018            (display-string (elpher-page-display-string page))
2019            (pos (if button nil (point))))
2020       (if (elpher-address-about-p address)
2021           (error "Cannot bookmark %s" display-string)
2022         `(,display-string
2023           (defaults . (,display-string))
2024           (position . ,pos)
2025           (location . ,url)
2026           (handler . elpher-bookmark-jump))))))
2027
2028 ;;;###autoload
2029 (defun elpher-bookmark-jump (bookmark)
2030   "Handler used to open a bookmark using elpher.
2031 The argument BOOKMARK is a bookmark record passed to the function.
2032 This handler is responsible for loading the bookmark in some buffer,
2033 then making that buffer the current buffer.  It should not switch
2034 to the buffer."
2035   (let* ((url (cdr (assq 'location bookmark)))
2036          (cleaned-url (string-trim url))
2037          (page (elpher-page-from-url cleaned-url))
2038          (buffer (get-buffer-create elpher-buffer-name)))
2039     (elpher-with-clean-buffer
2040      (elpher-visit-page page))
2041     (set-buffer buffer)
2042     nil))
2043
2044 (defun elpher-bookmark-link ()
2045   "Bookmark the link at point.
2046 To bookmark the current page, use \\[elpher-bookmark-current]."
2047   (interactive)
2048   (let ((elpher-bookmark-link t))
2049     (bookmark-set-no-overwrite)))
2050
2051 (defun elpher-bookmark-current ()
2052   "Bookmark the current page.
2053 To bookmark the link at point use \\[elpher-bookmark-link]."
2054   (interactive)
2055   (call-interactively #'bookmark-set-no-overwrite))
2056
2057 (defun elpher-bookmark-import (file)
2058   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2059   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2060                               (file-readable-p elpher-bookmarks-file))
2061                          elpher-bookmarks-file
2062                        (read-file-name "Old Elpher bookmarks: "
2063                                        user-emacs-directory nil t
2064                                        "elpher-bookmarks"))))
2065   (dolist (bookmark (with-temp-buffer
2066                       (insert-file-contents file)
2067                       (read (current-buffer))))
2068     (let* ((display-string (car bookmark))
2069            (url (cadr bookmark))
2070            (record `(,display-string
2071                      (location . ,url)
2072                      (handler . elpher-bookmark-jump))))
2073       (bookmark-store display-string (cdr record) t)))
2074   (bookmark-save))
2075
2076 (defun elpher-get-bookmarks-page (renderer)
2077   "Getter which displays the bookmarks (RENDERER must be nil)."
2078   (when renderer
2079     (elpher-visit-previous-page)
2080     (error "Command not supported for bookmarks page"))
2081
2082   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2083                                      elpher-bookmarks-file)
2084                                 (locate-user-emacs-file "elpher-bookmarks"))))
2085     (when (and (file-readable-p old-bookmarks-file)
2086                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2087                                  old-bookmarks-file
2088                                  "\" found. Import now?")))
2089       (elpher-bookmark-import old-bookmarks-file)
2090       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2091
2092   (if (and elpher-use-emacs-bookmark-menu
2093            elpher-history)
2094       (progn
2095         (elpher-visit-previous-page)
2096         (call-interactively #'bookmark-bmenu-list))
2097     (elpher-with-clean-buffer
2098      (insert " ---- Elpher Bookmarks ---- \n\n")
2099      (bookmark-maybe-load-default-file)
2100      (dolist (bookmark (bookmark-maybe-sort-alist))
2101        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2102          (let* ((name (car bookmark))
2103                 (url (alist-get 'location (cdr bookmark)))
2104                 (address (elpher-address-from-url url)))
2105            (elpher-insert-index-record name address))))
2106      (when (<= (line-number-at-pos) 3)
2107        (insert "No bookmarked pages found.\n"))
2108      (insert "\n --------------------------\n\n"
2109              "Select an entry or press 'u' to return to the previous page.\n\n"
2110              "Bookmarks can be renamed or deleted via the ")
2111      (insert-text-button "Emacs bookmark menu"
2112                          'action (lambda (_)
2113                                    (interactive)
2114                                    (call-interactively #'bookmark-bmenu-list))
2115                          'follow-link t
2116                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2117      (insert (substitute-command-keys
2118               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2119      (elpher-restore-pos))))
2120
2121 (defun elpher-show-bookmarks ()
2122   "Interactive function to display the current list of elpher bookmarks."
2123   (interactive)
2124   (elpher-visit-page
2125    (elpher-make-page "Elpher Bookmarks"
2126                      (elpher-make-about-address 'bookmarks))))
2127
2128
2129 ;;; Integrations
2130 ;;
2131
2132 ;;; Org
2133
2134 (defun elpher-org-export-link (link description format protocol)
2135   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2136
2137 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2138 of gemini, gopher or finger."
2139   (let* ((url (if (equal protocol "elpher")
2140                   (string-remove-prefix "elpher:" link)
2141                 (format "%s:%s" protocol link)))
2142          (desc (or description url)))
2143     (pcase format
2144       (`gemini (format "=> %s %s" url desc))
2145       (`html (format "<a href=\"%s\">%s</a>" url desc))
2146       (`latex (format "\\href{%s}{%s}" url desc))
2147       (_ (if (not description)
2148              url
2149            (format "%s (%s)" desc url))))))
2150
2151 (defun elpher-org-store-link ()
2152   "Store link to an `elpher' page in Org."
2153   (when (eq major-mode 'elpher-mode)
2154     (let* ((url (elpher-info-current))
2155            (desc (car elpher-current-page))
2156            (protocol (cond
2157                       ((string-prefix-p "gemini:" url) "gemini")
2158                       ((string-prefix-p "gopher:" url) "gopher")
2159                       ((string-prefix-p "finger:" url) "finger")
2160                       (t "elpher"))))
2161       (when (equal "elpher" protocol)
2162         ;; Weird link. Or special inner link?
2163         (setq url (concat "elpher:" url)))
2164       (org-link-store-props :type protocol :link url :description desc)
2165       t)))
2166
2167 (defun elpher-org-follow-link (link protocol)
2168   "Visit a LINK for the given PROTOCOL.
2169
2170 PROTOCOL may be one of gemini, gopher or finger.  This method also
2171 supports the old protocol elpher, where the link is self-contained."
2172   (let ((url (if (equal protocol "elpher")
2173                  (string-remove-prefix "elpher:" link)
2174                (format "%s:%s" protocol link))))
2175     (elpher-go url)))
2176
2177 (defun elpher-org-mode-integration ()
2178   "Set up `elpher' integration for `org-mode'."
2179   (org-link-set-parameters
2180    "elpher"
2181    :store #'elpher-org-store-link
2182    :export (lambda (link description format _plist)
2183              (elpher-org-export-link link description format "elpher"))
2184    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2185   (org-link-set-parameters
2186    "gemini"
2187    :export (lambda (link description format _plist)
2188              (elpher-org-export-link link description format "gemini"))
2189    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2190   (org-link-set-parameters
2191    "gopher"
2192    :export (lambda (link description format _plist)
2193              (elpher-org-export-link link description format "gopher"))
2194    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2195   (org-link-set-parameters
2196    "gophers"
2197    :export (lambda (link description format _plist)
2198              (elpher-org-export-link link description format "gophers"))
2199    :follow (lambda (link _arg) (elpher-org-follow-link link "gophers")))
2200   (org-link-set-parameters
2201    "finger"
2202    :export (lambda (link description format _plist)
2203              (elpher-org-export-link link description format "finger"))
2204    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2205
2206 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2207
2208 ;; Browse URL
2209
2210 ;;;###autoload
2211 (defun elpher-browse-url-elpher (url &rest _args)
2212   "Browse URL using Elpher.  This function is used by `browse-url'."
2213   (interactive (browse-url-interactive-arg "Elpher URL: "))
2214   (elpher-go url))
2215
2216 ;; Use elpher to open gopher, finger and gemini links
2217 ;; For recent version of `browse-url' package
2218 (if (boundp 'browse-url-default-handlers)
2219     (add-to-list
2220      'browse-url-default-handlers
2221      '("^\\(gopher\\|gophers\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2222   ;; Patch `browse-url-browser-function' for older ones. The value of
2223   ;; that variable is `browse-url-default-browser' by default, so
2224   ;; that's the function that gets advised. If the value is an alist,
2225   ;; however, we don't know what to do. Better not interfere?
2226   (when (and (symbolp browse-url-browser-function)
2227              (fboundp browse-url-browser-function))
2228     (advice-add browse-url-browser-function :before-while
2229                 (lambda (url &rest _args)
2230                   "Handle gemini, gopher, and finger schemes using Elpher."
2231                   (let ((scheme (downcase (car (split-string url ":" t)))))
2232                     (if (member scheme '("gemini" "gopher" "gophers" "finger"))
2233                         ;; `elpher-go' always returns nil, which will stop the
2234                         ;; advice chain here in a before-while
2235                         (elpher-go url)
2236                       ;; chain must continue, then return t.
2237                       t))))))
2238
2239 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2240 (with-eval-after-load 'thingatpt
2241   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2242
2243 ;; Mu4e:
2244
2245 ;; Make mu4e aware of the gemini world
2246 (setq mu4e~view-beginning-of-url-regexp
2247       "\\(?:https?\\|gopher\\|gophers\\|finger\\|gemini\\)://\\|mailto:")
2248
2249 ;; eww:
2250
2251 ;; Let elpher handle gemini, gopher links in eww buffer.
2252 (setq eww-use-browse-url
2253       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`gophers\\|\\`finger\\)://")
2254
2255
2256 ;;; Interactive procedures
2257 ;;
2258
2259 (defun elpher-next-link ()
2260   "Move point to the next link on the current page."
2261   (interactive)
2262   (forward-button 1))
2263
2264 (defun elpher-prev-link ()
2265   "Move point to the previous link on the current page."
2266   (interactive)
2267   (backward-button 1))
2268
2269 (defun elpher-follow-current-link ()
2270   "Open the link or url at point."
2271   (interactive)
2272   (push-button))
2273
2274 ;;;###autoload
2275 (defun elpher-go (host-or-url)
2276   "Go to a particular gopher site HOST-OR-URL.
2277 When run interactively HOST-OR-URL is read from the minibuffer."
2278   (interactive (list
2279                 (read-string (format "Visit URL (default scheme %s): "
2280                                      (elpher-get-default-url-scheme)))))
2281   (let ((trimmed-host-or-url (string-trim host-or-url)))
2282     (unless (string-empty-p trimmed-host-or-url)
2283       (let ((page (elpher-page-from-url trimmed-host-or-url
2284                                         (elpher-get-default-url-scheme))))
2285         (unless (get-buffer-window elpher-buffer-name t)
2286           (switch-to-buffer elpher-buffer-name))
2287         (elpher-with-clean-buffer
2288          (elpher-visit-page page))
2289         nil)))) ; non-nil value is displayed by eshell
2290
2291 (defun elpher-go-current ()
2292   "Go to a particular URL which is read from the minibuffer.
2293 Unlike `elpher-go', the reader is initialized with the URL of the
2294 current page."
2295   (interactive)
2296   (let* ((address (elpher-page-address elpher-current-page))
2297          (url (read-string (format "Visit URL (default scheme %s): "
2298                                    (elpher-get-default-url-scheme))
2299                            (elpher-address-to-url address))))
2300     (let ((trimmed-url (string-trim url)))
2301       (unless (string-empty-p trimmed-url)
2302         (elpher-with-clean-buffer
2303          (elpher-visit-page
2304           (elpher-page-from-url trimmed-url (elpher-get-default-url-scheme))))))))
2305
2306 (defun elpher-redraw ()
2307   "Redraw current page."
2308   (interactive)
2309   (elpher-visit-page elpher-current-page))
2310
2311 (defun elpher-reload ()
2312   "Reload current page."
2313   (interactive)
2314   (elpher-reload-current-page))
2315
2316 (defun elpher-toggle-tls ()
2317   "Toggle TLS encryption mode for gopher."
2318   (interactive)
2319   (setq elpher-use-tls (not elpher-use-tls))
2320   (if elpher-use-tls
2321       (if (gnutls-available-p)
2322           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2323         (setq elpher-use-tls nil)
2324         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2325     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2326
2327 (defun elpher-view-raw ()
2328   "View raw server response for current page."
2329   (interactive)
2330   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2331       (error "This page was not generated by a server")
2332     (elpher-visit-page elpher-current-page
2333                        #'elpher-render-raw)))
2334
2335 (defun elpher-back ()
2336   "Go to previous site."
2337   (interactive)
2338   (elpher-visit-previous-page))
2339
2340 (defun elpher-back-to-start ()
2341   "Go all the way back to the start page."
2342   (interactive)
2343   (setq-local elpher-current-page nil)
2344   (setq-local elpher-history nil)
2345   (elpher-visit-page (elpher-make-start-page)))
2346
2347 (defun elpher-download ()
2348   "Download the link at point."
2349   (interactive)
2350   (let ((button (button-at (point))))
2351     (if button
2352         (let ((page (button-get button 'elpher-page)))
2353           (unless page
2354             (error "Not an elpher page"))
2355           (when (elpher-address-about-p (elpher-page-address page))
2356             (error "Cannot download %s" (elpher-page-display-string page)))
2357           (elpher-visit-page (button-get button 'elpher-page)
2358                              #'elpher-render-download))
2359       (error "No link selected"))))
2360
2361 (defun elpher-download-current ()
2362   "Download the current page."
2363   (interactive)
2364   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2365       (error "Cannot download %s"
2366              (elpher-page-display-string elpher-current-page))
2367     (elpher-visit-page elpher-current-page
2368                        #'elpher-render-download
2369                        t)))
2370
2371 (defun elpher--build-link-map ()
2372   "Build alist mapping link names to destination pages in current buffer."
2373   (let ((link-map nil)
2374         (b (next-button (point-min) t)))
2375     (while b
2376       (push (cons (button-label b) b) link-map)
2377       (setq b (next-button (button-start b))))
2378     link-map))
2379
2380 (defun elpher-jump ()
2381   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2382   (interactive)
2383   (let* ((link-map (elpher--build-link-map)))
2384     (if link-map
2385         (let ((key (let ((completion-ignore-case t))
2386                      (completing-read "Directory item/link: "
2387                                       link-map nil t))))
2388           (if (and key (> (length key) 0))
2389               (let ((b (cdr (assoc key link-map))))
2390                 (goto-char (button-start b))
2391                 (button-activate b)))))))
2392
2393 (defun elpher-root-dir ()
2394   "Visit root of current server."
2395   (interactive)
2396   (let ((address (elpher-page-address elpher-current-page)))
2397     (if (not (elpher-address-about-p address))
2398         (if (or (member (url-filename address) '("/" ""))
2399                 (and (elpher-address-gopher-p address)
2400                      (= (length (elpher-gopher-address-selector address)) 0)))
2401             (error "Already at root directory of current server")
2402           (let ((address-copy (elpher-address-from-url
2403                                (elpher-address-to-url address))))
2404             (setf (url-filename address-copy) "")
2405             (elpher-go (elpher-address-to-url address-copy))))
2406       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2407
2408 (defun elpher-info-page (page)
2409   "Display URL of PAGE in minibuffer."
2410   (let* ((address (elpher-page-address page))
2411          (url (elpher-address-to-url address))
2412          (iri (elpher-address-to-iri address)))
2413     (if (equal url iri)
2414         (message "%s" url)
2415       (message "%s (Raw: %s)" iri url))))
2416
2417 (defun elpher-info-link ()
2418   "Display information on page corresponding to link at point."
2419   (interactive)
2420   (let ((button (button-at (point))))
2421     (unless button
2422       (error "No item selected"))
2423     (let ((page (button-get button 'elpher-page)))
2424       (unless page
2425         (error "Not an elpher page"))
2426       (elpher-info-page page))))
2427
2428 (defun elpher-info-current ()
2429   "Display information on current page."
2430   (interactive)
2431   (elpher-info-page elpher-current-page))
2432
2433 (defun elpher-copy-page-url (page)
2434   "Copy URL representation of address of PAGE to `kill-ring'."
2435   (let* ((address (elpher-page-address page))
2436          (url (elpher-address-to-url address)))
2437     (message "Copied \"%s\" to kill-ring/clipboard." url)
2438     (kill-new url)))
2439
2440 (defun elpher-copy-link-url ()
2441   "Copy URL of item at point to `kill-ring'."
2442   (interactive)
2443   (let ((button (button-at (point))))
2444     (unless button
2445       (error "No item selected"))
2446     (let ((page (button-get button 'elpher-page)))
2447       (unless page
2448         (error "Not an elpher page"))
2449       (elpher-copy-page-url page))))
2450
2451 (defun elpher-copy-current-url ()
2452   "Copy URL of current page to `kill-ring'."
2453   (interactive)
2454   (elpher-copy-page-url elpher-current-page))
2455
2456 (defun elpher-set-gopher-coding-system ()
2457   "Specify an explicit character coding system for gopher selectors."
2458   (interactive)
2459   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2460     (setq elpher-user-coding-system system)
2461     (if system
2462         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2463       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2464
2465
2466 ;;; Mode and keymap
2467 ;;
2468
2469 (defvar elpher-mode-map
2470   (let ((map (make-sparse-keymap)))
2471     (define-key map (kbd "TAB") 'elpher-next-link)
2472     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2473     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2474     (define-key map (kbd "u") 'elpher-back)
2475     (define-key map (kbd "-") 'elpher-back)
2476     (define-key map (kbd "^") 'elpher-back)
2477     (define-key map [mouse-3] 'elpher-back)
2478     (define-key map (kbd "U") 'elpher-back-to-start)
2479     (define-key map (kbd "g") 'elpher-go)
2480     (define-key map (kbd "o") 'elpher-go-current)
2481     (define-key map (kbd "O") 'elpher-root-dir)
2482     (define-key map (kbd "s") 'elpher-show-history)
2483     (define-key map (kbd "S") 'elpher-show-visited-pages)
2484     (define-key map (kbd "r") 'elpher-redraw)
2485     (define-key map (kbd "R") 'elpher-reload)
2486     (define-key map (kbd "T") 'elpher-toggle-tls)
2487     (define-key map (kbd ".") 'elpher-view-raw)
2488     (define-key map (kbd "d") 'elpher-download)
2489     (define-key map (kbd "D") 'elpher-download-current)
2490     (define-key map (kbd "m") 'elpher-jump)
2491     (define-key map (kbd "i") 'elpher-info-link)
2492     (define-key map (kbd "I") 'elpher-info-current)
2493     (define-key map (kbd "c") 'elpher-copy-link-url)
2494     (define-key map (kbd "C") 'elpher-copy-current-url)
2495     (define-key map (kbd "a") 'elpher-bookmark-link)
2496     (define-key map (kbd "A") 'elpher-bookmark-current)
2497     (define-key map (kbd "B") 'elpher-show-bookmarks)
2498     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2499     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2500     (when (fboundp 'evil-define-key*)
2501       (evil-define-key*
2502        'motion map
2503        (kbd "TAB") 'elpher-next-link
2504        (kbd "C-") 'elpher-follow-current-link
2505        (kbd "C-t") 'elpher-back
2506        (kbd "u") 'elpher-back
2507        (kbd "-") 'elpher-back
2508        (kbd "^") 'elpher-back
2509        [mouse-3] 'elpher-back
2510        (kbd "U") 'elpher-back-to-start
2511        (kbd "g") 'elpher-go
2512        (kbd "o") 'elpher-go-current
2513        (kbd "O") 'elpher-root-dir
2514        (kbd "s") 'elpher-show-history
2515        (kbd "S") 'elpher-show-visited-pages
2516        (kbd "r") 'elpher-redraw
2517        (kbd "R") 'elpher-reload
2518        (kbd "T") 'elpher-toggle-tls
2519        (kbd ".") 'elpher-view-raw
2520        (kbd "d") 'elpher-download
2521        (kbd "D") 'elpher-download-current
2522        (kbd "m") 'elpher-jump
2523        (kbd "i") 'elpher-info-link
2524        (kbd "I") 'elpher-info-current
2525        (kbd "c") 'elpher-copy-link-url
2526        (kbd "C") 'elpher-copy-current-url
2527        (kbd "a") 'elpher-bookmark-link
2528        (kbd "A") 'elpher-bookmark-current
2529        (kbd "B") 'elpher-show-bookmarks
2530        (kbd "!") 'elpher-set-gopher-coding-system
2531        (kbd "F") 'elpher-forget-current-certificate))
2532     map)
2533   "Keymap for gopher client.")
2534
2535 (define-derived-mode elpher-mode special-mode "elpher"
2536   "Major mode for elpher, an elisp gopher client.
2537
2538 This mode is automatically enabled by the interactive
2539 functions which initialize the client, namely
2540 `elpher', and `elpher-go'."
2541   (setq-local elpher-current-page nil)
2542   (setq-local elpher-history nil)
2543   (setq-local elpher-buffer-name (buffer-name))
2544   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2545   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2546
2547 (when (fboundp 'evil-set-initial-state)
2548   (evil-set-initial-state 'elpher-mode 'motion))
2549
2550
2551 ;;; Main start procedure
2552 ;;
2553
2554 ;;;###autoload
2555 (defun elpher (&optional arg)
2556   "Start elpher with default landing page.
2557 The buffer used for Elpher sessions is determined by the value of
2558 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2559 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2560 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2561 \\[execute-extended-command] elpher RET’) switches to the session with
2562 that number, creating it if necessary.  A non numeric prefix ARG means
2563 to create a new session.  Returns the buffer selected (or created)."
2564   (interactive "P")
2565   (let* ((name (default-value 'elpher-buffer-name))
2566          (buf (cond ((numberp arg)
2567                      (get-buffer-create (format "%s<%d>" name arg)))
2568                     (arg
2569                      (generate-new-buffer name))
2570                     (t
2571                      (get-buffer-create name)))))
2572     (pop-to-buffer-same-window buf)
2573     (unless (buffer-modified-p)
2574       (elpher-mode)
2575       (elpher-visit-page (elpher-make-start-page))
2576       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2577
2578 ;;; elpher.el ends here