elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.2
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.2"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     (file elpher-get-file-page nil "~" elpher-gemini)
  98     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
  99     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 100     ((about history) elpher-get-history-page nil "E" elpher-index)
 101     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 102   "Association list from types to getters, renderers, margin codes and index faces.")
 103
 104
 105 ;;; Declarations to avoid compiler warnings.
 106 ;;
 107
 108 (eval-when-compile
 109   (declare-function ansi-color-filter-apply "ansi-color")
 110   (declare-function ansi-color-apply "ansi-color")
 111   (declare-function bookmark-store "bookmark")
 112   (declare-function org-link-store-props "ol")
 113   (declare-function org-link-set-parameters "ol")
 114   (defvar ansi-color-context)
 115   (defvar xterm-color--current-fg)
 116   (defvar xterm-color--current-bg)
 117   (defvar bookmark-make-record-function)
 118   (defvar mu4e~view-beginning-of-url-regexp)
 119   (defvar eww-use-browse-url)
 120   (defvar thing-at-point-uri-schemes))
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher and gemini client."
 128   :group 'applications)
 129
 130 ;; General appearance and customizations
 131
 132 (defcustom elpher-open-urls-with-eww nil
 133   "If non-nil, open URL selectors using eww.
 134 Otherwise, use the system browser via the `browse-url' function."
 135   :type '(boolean))
 136
 137 (defcustom elpher-use-header t
 138   "If non-nil, display current page information in buffer header."
 139   :type '(boolean))
 140
 141 (defcustom elpher-auto-disengage-TLS nil
 142   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 143 While enabling this may seem convenient, it is also potentially
 144 dangerous as it allows switching from an encrypted channel back to
 145 plain text without user input."
 146   :type '(boolean))
 147
 148 (defcustom elpher-connection-timeout 5
 149   "Specifies the number of seconds to wait for a network connection to time out."
 150   :type '(integer))
 151
 152 (defcustom elpher-filter-ansi-from-text nil
 153   "If non-nil, filter ANSI escape sequences from text.
 154 The default behaviour is to use the ansi-color package (or xterm-color if it is
 155 available) to interpret these sequences."
 156   :type '(boolean))
 157
 158 (defcustom elpher-certificate-directory
 159   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 160   "Specify the name of the directory where client certificates will be stored.
 161 These certificates may be used for establishing authenticated TLS connections."
 162   :type '(directory))
 163
 164 (defcustom elpher-openssl-command "openssl"
 165   "The command used to launch openssl when generating TLS client certificates."
 166   :type '(file))
 167
 168 (defcustom elpher-default-url-type "gopher"
 169   "Default URL type (i.e. scheme) to assume if not explicitly given."
 170   :type '(choice (const "gopher")
 171                  (const "gemini")))
 172
 173 (defcustom elpher-gemini-TLS-cert-checks nil
 174   "If non-nil, verify gemini server TLS certs using the default security level.
 175 Otherwise, certificate verification is disabled.
 176
 177 This defaults to off because it is standard practice for Gemini servers
 178 to use self-signed certificates, meaning that most servers provide what
 179 EMACS considers to be an invalid certificate."
 180   :type '(boolean))
 181
 182 (defcustom elpher-gemini-max-fill-width 80
 183   "Specify the maximum default width (in columns) of text/gemini documents.
 184 The actual width used is the minimum of this value and the window width at
 185 the time when the text is rendered."
 186   :type '(integer))
 187
 188 (defcustom elpher-gemini-link-string "→ "
 189   "Specify the string used to indicate links when rendering gemini maps.
 190 May be empty."
 191   :type '(string))
 192
 193 (defcustom elpher-gemini-bullet-string "•"
 194   "Specify the string used for bullets when rendering gemini maps."
 195   :type '(string))
 196
 197 (defcustom elpher-ipv4-always nil
 198   "If non-nil, elpher will always use IPv4 to establish network connections.
 199 This can be useful when browsing from a computer that supports IPv6, because
 200 some servers which do not support IPv6 can take a long time to time-out."
 201   :type '(boolean))
 202
 203 (defcustom elpher-socks-always nil
 204   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 205 Otherwise, the SOCKS proxy is only used for connections to onion services."
 206   :type '(boolean))
 207
 208 (defcustom elpher-use-emacs-bookmark-menu nil
 209   "If non-nil, elpher will only use the native Emacs bookmark menu.
 210 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 211 page within which all of the standard elpher keybindings are active."
 212   :type '(boolean))
 213
 214 (defcustom elpher-start-page-url "about:welcome"
 215   "Specify the page displayed initially by elpher.
 216 The default welcome screen is \"about:welcome\", while the bookmarks list
 217 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 218
 219 Beware that using \"about:bookmarks\" as a start page in combination with
 220 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 221 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 222 the start page."
 223   :type '(string))
 224
 225 (defcustom elpher-gemini-hide-preformatted nil
 226   "Cause elpher to hide preformatted gemini text by default.
 227 When this option is enabled, preformatted text in text/gemini documents
 228 is replaced with a button which can be used to toggle its display.
 229
 230 This is intended to improve accessibility, as preformatted text often
 231 includes art which can be difficult for screen readers to interpret
 232 meaningfully."
 233   :type '(boolean))
 234
 235 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 236   "Margin symbol used to distinguish the preformatted text toggle."
 237   :type '(string))
 238
 239 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 240   "Label of button used to toggle formatted text."
 241   :type '(string))
 242
 243 ;; Face customizations
 244
 245 (defgroup elpher-faces nil
 246   "Elpher face customizations."
 247   :group 'elpher)
 248
 249 (defface elpher-index
 250   '((t :inherit font-lock-keyword-face))
 251   "Face used for directory type directory records.")
 252
 253 (defface elpher-text
 254   '((t :inherit bold))
 255   "Face used for text type directory records.")
 256
 257 (defface elpher-info
 258   '((t :inherit default))
 259   "Face used for info type directory records.")
 260
 261 (defface elpher-image
 262   '((t :inherit font-lock-string-face))
 263   "Face used for image type directory records.")
 264
 265 (defface elpher-search
 266   '((t :inherit warning))
 267   "Face used for search type directory records.")
 268
 269 (defface elpher-html
 270   '((t :inherit font-lock-comment-face))
 271   "Face used for html type directory records.")
 272
 273 (defface elpher-gemini
 274   '((t :inherit font-lock-constant-face))
 275   "Face used for Gemini type directory records.")
 276
 277 (defface elpher-other-url
 278   '((t :inherit font-lock-comment-face))
 279   "Face used for other URL type links records.")
 280
 281 (defface elpher-telnet
 282   '((t :inherit font-lock-function-name-face))
 283   "Face used for telnet type directory records.")
 284
 285 (defface elpher-binary
 286   '((t :inherit font-lock-doc-face))
 287   "Face used for binary type directory records.")
 288
 289 (defface elpher-unknown
 290   '((t :inherit error))
 291   "Face used for directory records with unknown/unsupported types.")
 292
 293 (defface elpher-margin-key
 294   '((t :inherit bold))
 295   "Face used for directory margin key.")
 296
 297 (defface elpher-margin-brackets
 298   '((t :inherit shadow))
 299   "Face used for brackets around directory margin key.")
 300
 301 (defface elpher-gemini-heading1
 302   '((t :inherit bold :height 1.8))
 303   "Face used for gemini heading level 1.")
 304
 305 (defface elpher-gemini-heading2
 306   '((t :inherit bold :height 1.5))
 307   "Face used for gemini heading level 2.")
 308
 309 (defface elpher-gemini-heading3
 310   '((t :inherit bold :height 1.2))
 311   "Face used for gemini heading level 3.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 (defface elpher-gemini-preformatted
 318   '((t :inherit default))
 319   "Face used for gemini preformatted text.")
 320
 321 (defface elpher-gemini-preformatted-toggle
 322   '((t :inherit button))
 323   "Face used for buttons used to toggle display of preformatted text.")
 324
 325 ;;; Model
 326 ;;
 327
 328 ;; Address
 329
 330 ;; An elpher "address" object is either a url object or a symbol.
 331 ;; Addresses with the "about" type, corresponding to pages generated
 332 ;; dynamically for and by elpher.  All others represent pages which
 333 ;; rely on content retrieved over the network.
 334
 335 (defun elpher-address-from-url (url-string &optional default-scheme)
 336   "Create a ADDRESS object corresponding to the given URL-STRING.
 337 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 338 is not explicitly given."
 339   (let ((data (match-data))) ; Prevent parsing clobbering match data
 340     (unwind-protect
 341         (let ((url (url-generic-parse-url url-string)))
 342           (unless (and (not (url-fullness url)) (url-type url))
 343             (unless (url-type url)
 344               (setf (url-type url) default-scheme))
 345             (unless (url-host url)
 346               (let ((p (split-string (url-filename url) "/" nil nil)))
 347                 (setf (url-host url) (car p))
 348                 (setf (url-filename url)
 349                       (if (cdr p)
 350                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 351                         ""))))
 352             (when (not (string-empty-p (url-host url)))
 353               (setf (url-fullness url) t)
 354               (setf (url-host url) (puny-encode-domain (url-host url))))
 355             (when (or (equal "gopher" (url-type url))
 356                       (equal "gophers" (url-type url)))
 357               ;; Gopher defaults
 358               (when (or (equal (url-filename url) "")
 359                         (equal (url-filename url) "/"))
 360                 (setf (url-filename url) "/1")))
 361             (when (equal "gemini" (url-type url))
 362               ;; Gemini defaults
 363               (if (equal (url-filename url) "")
 364                   (setf (url-filename url) "/"))))
 365           (elpher-remove-redundant-ports url))
 366       (set-match-data data))))
 367
 368 (defun elpher-remove-redundant-ports (address)
 369   "Remove redundant port specifiers from ADDRESS.
 370 Here 'redundant' means that the specified port matches the default
 371 for that protocol, eg 70 for gopher."
 372   (if (and (not (elpher-address-about-p address))
 373            (eq (url-portspec address) ; (url-port) is too slow!
 374                (pcase (url-type address)
 375                  ("gemini" 1965)
 376                  ((or "gopher" "gophers") 70)
 377                  ("finger" 79)
 378                  (_ -1))))
 379       (setf (url-portspec address) nil))
 380   address)
 381
 382 (defun elpher-make-gopher-address (type selector host port &optional tls)
 383   "Create an ADDRESS object using gopher directory record attributes.
 384 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 385 If the optional attribute TLS is non-nil, the address will be marked as
 386 requiring gopher-over-TLS."
 387   (cond
 388    ((equal type ?i) nil)
 389    ((and (equal type ?h)
 390          (string-prefix-p "URL:" selector))
 391     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 392    ((equal type ?8)
 393     (elpher-address-from-url
 394      (concat "telnet"
 395              "://" host
 396              ":" (number-to-string port))))
 397    (t
 398     (elpher-address-from-url
 399      (concat "gopher" (if tls "s" "")
 400              "://" host
 401              ":" (number-to-string port)
 402              "/" (string type)
 403              selector)))))
 404
 405 (defun elpher-make-about-address (type)
 406   "Create an ADDRESS object corresponding to the given about address TYPE."
 407   (elpher-address-from-url (concat "about:" (symbol-name type))))
 408
 409 (defun elpher-address-to-url (address)
 410   "Get string representation of ADDRESS."
 411   (url-encode-url (url-recreate-url address)))
 412
 413 (defun elpher-address-type (address)
 414   "Retrieve type of ADDRESS object.
 415 This is used to determine how to retrieve and render the document the
 416 address refers to, via the table `elpher-type-map'."
 417   (pcase (url-type address)
 418     ("about"
 419      (list 'about (intern (url-filename address))))
 420     ((or "gopher" "gophers")
 421      (list 'gopher
 422            (if (member (url-filename address) '("" "/"))
 423                ?1
 424              (string-to-char (substring (url-filename address) 1)))))
 425     ("gemini" 'gemini)
 426     ("telnet" 'telnet)
 427     ("finger" 'finger)
 428     ("file" 'file)
 429     (_ 'other-url)))
 430
 431 (defun elpher-address-about-p (address)
 432   "Return non-nil if ADDRESS is an about address."
 433   (pcase (elpher-address-type address) (`(about ,_) t)))
 434
 435 (defun elpher-address-gopher-p (address)
 436   "Return non-nil if ADDRESS object is a gopher address."
 437   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 438
 439 (defun elpher-address-protocol (address)
 440   "Retrieve the transport protocol for ADDRESS."
 441   (url-type address))
 442
 443 (defun elpher-address-filename (address)
 444   "Retrieve the filename component of ADDRESS.
 445 For gopher addresses this is a combination of the selector type and selector."
 446   (url-unhex-string (url-filename address)))
 447
 448 (defun elpher-address-host (address)
 449   "Retrieve host from ADDRESS object."
 450   (pcase (url-host address)
 451     ;; The following strips out square brackets which sometimes enclose IPv6
 452     ;; addresses.  Doing this here rather than at the parsing stage may seem
 453     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 454     ;; and reconstruction.  It's also more efficient, as this method is not
 455     ;; called during page rendering.
 456     ((rx (: "[" (let ipv6 (* (not "]"))) "]"))
 457      ipv6)
 458     ;; The following is a work-around for a parsing bug that causes
 459     ;; URLs with empty (but not absent, see RFC 1738) usernames to have
 460     ;; @ prepended to the hostname.
 461     ((rx (: "@" (let rest (+ anything))))
 462      rest)
 463     (addr
 464      addr)))
 465
 466 (defun elpher-address-user (address)
 467   "Retrieve user from ADDRESS object."
 468   (url-user address))
 469
 470 (defun elpher-address-port (address)
 471   "Retrieve port from ADDRESS object.
 472 If no address is defined, returns 0.  (This is for compatibility with
 473 the URL library.)"
 474   (let ((port (url-portspec address))) ; (url-port) is too slow!
 475     (if port port 0)))
 476
 477 (defun elpher-gopher-address-selector (address)
 478   "Retrieve gopher selector from ADDRESS object."
 479   (if (member (url-filename address) '("" "/"))
 480       ""
 481     (url-unhex-string (substring (url-filename address) 2))))
 482
 483
 484 ;; Cache
 485
 486 (defvar elpher-content-cache (make-hash-table :test 'equal))
 487 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 488
 489 (defun elpher-get-cached-content (address)
 490   "Retrieve the cached content for ADDRESS, or nil if none exists."
 491   (gethash address elpher-content-cache))
 492
 493 (defun elpher-cache-content (address content)
 494   "Set the content cache for ADDRESS to CONTENT."
 495   (puthash address content elpher-content-cache))
 496
 497 (defun elpher-get-cached-pos (address)
 498   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 499   (gethash address elpher-pos-cache))
 500
 501 (defun elpher-cache-pos (address pos)
 502   "Set the cursor position cache for ADDRESS to POS."
 503   (puthash address pos elpher-pos-cache))
 504
 505
 506 ;; Page
 507
 508 (defun elpher-make-page (display-string address)
 509   "Create a page with DISPLAY-STRING and ADDRESS."
 510   (list display-string address))
 511
 512 (defun elpher-make-start-page ()
 513   "Create the start page."
 514   (elpher-make-page "Start Page"
 515                     (elpher-address-from-url elpher-start-page-url)))
 516
 517 (defun elpher-page-display-string (page)
 518   "Retrieve the display string corresponding to PAGE."
 519   (elt page 0))
 520
 521 (defun elpher-page-address (page)
 522   "Retrieve the address corresponding to PAGE."
 523   (elt page 1))
 524
 525 (defun elpher-page-set-address (page new-address)
 526   "Set the address corresponding to PAGE to NEW-ADDRESS."
 527   (setcar (cdr page) new-address))
 528
 529 (defun elpher-page-from-url (url &optional default-scheme)
 530   "Create a page with address and display string defined by URL.
 531 The URL is unhexed prior to its use as a display string to improve
 532 readability.
 533
 534 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 535 in the instance that URL itself doesn't specify one."
 536   (let ((address (elpher-address-from-url url default-scheme)))
 537     (elpher-make-page (elpher-address-to-iri address) address)))
 538
 539 (defun elpher-address-to-iri (address)
 540   "Return an IRI for ADDRESS.
 541 Decode percent-escapes and handle punycode in the domain name.
 542 Drop the password, if any."
 543   (let ((data (match-data)) ; Prevent parsing clobbering match data
 544         (host (url-host address))
 545         (pass (url-password address)))
 546     (unwind-protect
 547         (let* ((host (url-host address))
 548                (pass (url-password address)))
 549           (when host
 550             (setf (url-host address) (puny-decode-domain host)))
 551           (when pass                             ; RFC 3986 says we should not render
 552             (setf (url-password address) nil)) ; the password as clear text
 553           (elpher-decode (url-unhex-string (url-recreate-url address))))
 554       (setf (url-host address) host)
 555       (setf (url-password address) pass)
 556       (set-match-data data))))
 557
 558 (defvar elpher-current-page nil
 559   "The current page for this Elpher buffer.")
 560
 561 (defvar elpher-history nil
 562   "The local history stack for this Elpher buffer.
 563 This variable is used by `elpher-back' and
 564 `elpher-show-history'.")
 565
 566 (defvar elpher-visited-pages nil
 567   "The global history for all Elpher buffers.
 568 This variable is used by `elpher-show-visited-pages'.")
 569
 570 (defun elpher-visit-page (page &optional renderer no-history)
 571   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 572 Additionally, push PAGE onto the history stack and the list of
 573 previously-visited pages, unless NO-HISTORY is non-nil."
 574   (elpher-save-pos)
 575   (elpher-process-cleanup)
 576   (unless no-history
 577     (unless (or (not elpher-current-page)
 578                  (equal (elpher-page-address elpher-current-page)
 579                         (elpher-page-address page)))
 580       (push elpher-current-page elpher-history)
 581       (unless (or (elpher-address-about-p (elpher-page-address page))
 582                   (and elpher-visited-pages
 583                        (equal page (car elpher-visited-pages))))
 584         (push page elpher-visited-pages))))
 585   (setq-local elpher-current-page page)
 586   (let* ((address (elpher-page-address page))
 587          (type (elpher-address-type address))
 588          (type-record (cdr (assoc type elpher-type-map))))
 589     (if type-record
 590         (funcall (car type-record)
 591                  (if renderer
 592                      renderer
 593                    (cadr type-record)))
 594       (elpher-visit-previous-page)
 595       (pcase type
 596         (`(gopher ,type-char)
 597          (error "Unsupported gopher selector type '%c' for '%s'"
 598                 type-char (elpher-address-to-url address)))
 599         (other
 600          (error "Unsupported address type '%S' for '%s'"
 601                 other (elpher-address-to-url address)))))))
 602
 603 (defun elpher-visit-previous-page ()
 604   "Visit the previous page in the history."
 605   (if elpher-history
 606       (elpher-visit-page (pop elpher-history) nil t)
 607     (error "No previous page")))
 608
 609 (defun elpher-reload-current-page ()
 610   "Reload the current page, discarding any existing cached content."
 611   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 612   (elpher-visit-page elpher-current-page))
 613
 614 (defun elpher-save-pos ()
 615   "Save the current position of point to the current page."
 616   (when elpher-current-page
 617     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 618
 619 (defun elpher-restore-pos ()
 620   "Restore the position of point to that cached in the current page."
 621   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 622     (if pos
 623         (goto-char pos)
 624       (goto-char (point-min)))))
 625
 626 (defun elpher-get-default-url-scheme ()
 627   "Suggest default URL scheme for visiting addresses based on the current page."
 628   (if elpher-current-page
 629       (let* ((address (elpher-page-address elpher-current-page))
 630              (current-type (elpher-address-type address)))
 631         (pcase current-type
 632           ((or (and 'file (guard (not elpher-history)))
 633                `(about ,_))
 634            elpher-default-url-type)
 635           (_
 636            (url-type address))))
 637       elpher-default-url-type))
 638
 639
 640 ;;; Buffer preparation
 641 ;;
 642
 643 (defvar elpher-buffer-name "*elpher*"
 644   "The default name of the Elpher buffer.")
 645
 646 (defun elpher-update-header ()
 647   "If `elpher-use-header' is true, display current page info in window header."
 648   (if (and elpher-use-header elpher-current-page)
 649       (let* ((display-string (elpher-page-display-string elpher-current-page))
 650              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 651              (address (elpher-page-address elpher-current-page))
 652              (tls-string (if (and (not (elpher-address-about-p address))
 653                                   (member (elpher-address-protocol address)
 654                                           '("gophers" "gemini")))
 655                              " [TLS encryption]"
 656                            ""))
 657              (header (concat sanitized-display-string
 658                              (propertize tls-string 'face 'bold))))
 659         (setq header-line-format header))))
 660
 661 (defmacro elpher-with-clean-buffer (&rest args)
 662   "Evaluate ARGS with a clean *elpher* buffer as current."
 663   (declare (debug (body))) ;; Allow edebug to step through body
 664   `(with-current-buffer elpher-buffer-name
 665      (unless (eq major-mode 'elpher-mode)
 666        ;; avoid resetting buffer-local variables
 667        (elpher-mode))
 668      (let ((inhibit-read-only t)
 669            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 670        (setq-local xterm-color--current-fg nil)
 671        (setq-local xterm-color--current-bg nil)
 672        (setq-local network-security-level
 673                    (default-value 'network-security-level))
 674        (erase-buffer)
 675        (elpher-update-header)
 676        ,@args)))
 677
 678 (defun elpher-buffer-message (string &optional line)
 679   "Replace first line in elpher buffer with STRING.
 680 If LINE is non-nil, replace that line instead."
 681   (with-current-buffer elpher-buffer-name
 682     (let ((inhibit-read-only t))
 683       (goto-char (point-min))
 684       (if line
 685           (forward-line line))
 686       (let ((data (match-data)))
 687         (unwind-protect
 688             (progn
 689               (re-search-forward "^.*$")
 690               (replace-match string))
 691           (set-match-data data))))))
 692
 693
 694 ;;; Text Processing
 695 ;;
 696
 697 (defvar elpher-user-coding-system nil
 698   "User-specified coding system to use for decoding text responses.")
 699
 700 (defun elpher-decode (string)
 701   "Decode STRING using autodetected or user-specified coding system."
 702   (decode-coding-string string
 703                         (if elpher-user-coding-system
 704                             elpher-user-coding-system
 705                           (detect-coding-string string t))))
 706
 707 (defun elpher-preprocess-text-response (string)
 708   "Preprocess text selector response contained in STRING.
 709 This involes decoding the character representation, and clearing
 710 away CRs and any terminating period."
 711   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 712                                            (replace-regexp-in-string "\r" "" string))))
 713
 714 ;;; Buttonify urls
 715
 716 (defconst elpher-url-regex
 717   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 718   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 719
 720 (defun elpher-buttonify-urls (string)
 721   "Turn substrings which look like urls in STRING into clickable buttons."
 722   (with-temp-buffer
 723     (insert string)
 724     (goto-char (point-min))
 725     (while (re-search-forward elpher-url-regex nil t)
 726       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 727         (make-text-button (match-beginning 0)
 728                           (match-end 0)
 729                           'elpher-page  page
 730                           'action #'elpher-click-link
 731                           'follow-link t
 732                           'help-echo #'elpher--page-button-help
 733                           'face 'button)))
 734     (buffer-string)))
 735
 736
 737 ;; ANSI colors or XTerm colors (application and filtering)
 738
 739 (or (require 'xterm-color nil t)
 740     (require 'ansi-color))
 741
 742 (defalias 'elpher-color-filter-apply
 743   (if (fboundp 'xterm-color-filter)
 744       (lambda (s)
 745         (let ((_xterm-color-render nil))
 746           (xterm-color-filter s)))
 747     #'ansi-color-filter-apply)
 748   "A function to filter out ANSI escape sequences.")
 749
 750 (defalias 'elpher-color-apply
 751   (if (fboundp 'xterm-color-filter)
 752       #'xterm-color-filter
 753     #'ansi-color-apply)
 754   "A function to apply ANSI escape sequences.")
 755
 756 (defun elpher-text-has-ansi-escapes-p (string)
 757   "Return non-nil if STRING includes an ANSI escape code."
 758   (save-match-data
 759     (string-match "\x1b\\[" string)))
 760
 761
 762 ;; Processing text for display
 763
 764 (defun elpher-process-text-for-display (string)
 765   "Perform any desired processing of STRING prior to display as text.
 766 Currently includes buttonifying URLs and processing ANSI escape codes."
 767   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 768                              (if elpher-filter-ansi-from-text
 769                                  (elpher-color-filter-apply string)
 770                                (elpher-color-apply string))
 771                            string)))
 772
 773
 774 ;;; General network communication
 775 ;;
 776
 777 (defun elpher-network-error (address error)
 778   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 779 ERROR can be either an error object or a string."
 780   (elpher-with-clean-buffer
 781    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 782            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 783            (if (stringp error) error (error-message-string error)) "\n"
 784            (propertize "\n----------------\n\n" 'face 'error)
 785            "Press 'u' to return to the previous page.")))
 786
 787
 788 (defvar elpher-network-timer nil
 789   "Timer used for network connections.")
 790
 791 (defvar elpher-use-tls nil
 792   "If non-nil, use TLS to communicate with gopher servers.")
 793
 794 (defvar elpher-client-certificate nil
 795   "If non-nil, contains client certificate details to use for TLS connections.")
 796
 797 (defun elpher-process-cleanup ()
 798   "Immediately shut down any extant elpher process and timers."
 799   (let ((p (get-process "elpher-process")))
 800     (if p (delete-process p)))
 801   (if (timerp elpher-network-timer)
 802       (cancel-timer elpher-network-timer)))
 803
 804 (defun elpher-make-network-timer (thunk)
 805   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 806 This is just a wraper around `run-at-time' which additionally sets the
 807 buffer-local variable `elpher-network-timer' to allow
 808 `elpher-process-cleanup' to also clear the timer."
 809   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 810     (setq-local elpher-network-timer timer)
 811     timer))
 812
 813 (defun elpher-get-host-response (address default-port query-string response-processor
 814                                          &optional use-tls force-ipv4)
 815   "Generic function for retrieving data from ADDRESS.
 816
 817 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 818 QUERY-STRING is a string sent to the host specified by ADDRESS to
 819 illicet a response.  This response is passed as an argument to the
 820 function RESPONSE-PROCESSOR.
 821
 822 If non-nil, USE-TLS specifies that the connection is to be made over
 823 TLS.  If set to gemini, the certificate verification will be disabled
 824 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 825
 826 If non-nil, FORCE-IPV4 causes the network connection to be made over
 827 ipv4 only.  (The default behaviour when this is not set depends on
 828 the host operating system and the local network capabilities.)"
 829   (if (and use-tls (not (gnutls-available-p)))
 830       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 831     (unless (< (elpher-address-port address) 65536)
 832       (error "Cannot establish network connection: port number > 65536"))
 833     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 834       (setq-local network-security-level 'low)
 835       (setq-local gnutls-verify-error nil))
 836     (condition-case nil
 837         (let* ((kill-buffer-query-functions nil)
 838                (port (elpher-address-port address))
 839                (host (elpher-address-host address))
 840                (service (if (> port 0) port default-port))
 841                (response-string-parts nil)
 842                (bytes-received 0)
 843                (hkbytes-received 0)
 844                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 845                (gnutls-params (list :type 'gnutls-x509pki
 846                                     :hostname host
 847                                     :keylist
 848                                     (elpher-get-current-keylist address)))
 849                (timer (elpher-make-network-timer
 850                                    (lambda ()
 851                                      (elpher-process-cleanup)
 852                                      (cond
 853                                         ; Try again with IPv4
 854                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 855                                        (message "Connection timed out.  Retrying with IPv4.")
 856                                        (elpher-get-host-response address default-port
 857                                                                  query-string
 858                                                                  response-processor
 859                                                                  use-tls t))
 860                                       ((and use-tls
 861                                             (not (eq use-tls 'gemini))
 862                                             (or elpher-auto-disengage-TLS
 863                                                 (y-or-n-p
 864                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 865                                        (setq elpher-use-tls nil)
 866                                        (elpher-get-host-response address default-port
 867                                                                  query-string
 868                                                                  response-processor
 869                                                                  nil force-ipv4))
 870                                       (t
 871                                        (elpher-network-error address "Connection time-out."))))))
 872                (proc (if socks
 873                          (socks-open-network-stream "elpher-process" nil host service)
 874                        (make-network-process :name "elpher-process"
 875                                              :host host
 876                                              :family (and (or force-ipv4
 877                                                               elpher-ipv4-always)
 878                                                           'ipv4)
 879                                              :service service
 880                                              :buffer nil
 881                                              :nowait t
 882                                              :tls-parameters
 883                                              (and use-tls
 884                                                   (cons 'gnutls-x509pki
 885                                                         (apply #'gnutls-boot-parameters
 886                                                                gnutls-params)))))))
 887           (process-put proc 'elpher-buffer (current-buffer))
 888           (setq elpher-network-timer timer)
 889           (set-process-coding-system proc 'binary 'binary)
 890           (set-process-query-on-exit-flag proc nil)
 891           (elpher-buffer-message (concat "Connecting to " host "..."
 892                                          " (press 'u' to abort)"))
 893           (set-process-filter proc
 894                               (lambda (_proc string)
 895                                 (when timer
 896                                   (cancel-timer timer)
 897                                   (setq timer nil))
 898                                 (setq bytes-received (+ bytes-received (length string)))
 899                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 900                                   (when (> new-hkbytes-received hkbytes-received)
 901                                     (setq hkbytes-received new-hkbytes-received)
 902                                     (elpher-buffer-message
 903                                      (concat "("
 904                                              (number-to-string (/ hkbytes-received 10.0))
 905                                              " MB read)")
 906                                      1)))
 907                                 (setq response-string-parts
 908                                       (cons string response-string-parts))))
 909           (set-process-sentinel proc
 910                                 (lambda (proc event)
 911                                   (when timer
 912                                     (cancel-timer timer))
 913                                   (condition-case the-error
 914                                       (cond
 915                                        ((string-prefix-p "open" event)    ; request URL
 916                                         (elpher-buffer-message
 917                                          (concat "Connected to " host ". Receiving data..."
 918                                                  " (press 'u' to abort)"))
 919                                         (let ((inhibit-eol-conversion t))
 920                                           (process-send-string proc query-string)))
 921                                        ((string-prefix-p "deleted" event)) ; do nothing
 922                                        ((and (not response-string-parts)
 923                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 924                                         ; Try again with IPv4
 925                                         (message "Connection failed. Retrying with IPv4.")
 926                                         (elpher-get-host-response address default-port
 927                                                                   query-string
 928                                                                   response-processor
 929                                                                   use-tls t))
 930                                        (response-string-parts
 931                                         (with-current-buffer (process-get proc 'elpher-buffer)
 932                                           (elpher-with-clean-buffer
 933                                            (insert "Data received.  Rendering..."))
 934                                           (funcall response-processor
 935                                                    (apply #'concat (reverse response-string-parts)))
 936                                           (elpher-restore-pos)))
 937                                        (t
 938                                         (error "No response from server")))
 939                                     (error
 940                                      (elpher-network-error address the-error)))))
 941           (when socks
 942             (if use-tls
 943                 (apply #'gnutls-negotiate :process proc gnutls-params))
 944             (funcall (process-sentinel proc) proc "open\n")))
 945       (error
 946        (elpher-process-cleanup)
 947        (error "Error initiating connection to server")))))
 948
 949
 950 ;;; Client-side TLS Certificate Management
 951 ;;
 952
 953 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 954   "Generate a key and a self-signed client TLS certificate using openssl.
 955
 956 The Common Name field of the certificate is set to COMMON-NAME.  The
 957 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 958 the key and certificate files to write.
 959
 960 If TEMPORARY is non-nil, the certificate will be given an exporation
 961 period of one day, and the key and certificate files will be deleted
 962 when the certificate is no longer needed for the current session.
 963
 964 Otherwise, the certificate will be given a 100 year expiration period
 965 and the files will not be deleted.
 966
 967 The function returns a list containing the current host name, the
 968 temporary flag, and the key and cert file names in the form required
 969 by `gnutls-boot-parameters`."
 970   (let ((exp-key-file (expand-file-name key-file))
 971         (exp-cert-file (expand-file-name cert-file)))
 972     (condition-case nil
 973         (progn
 974           (call-process elpher-openssl-command nil nil nil
 975                         "req" "-x509" "-newkey" "rsa:2048"
 976                         "-days" (if temporary "1" "36500")
 977                         "-nodes"
 978                         "-subj" (concat "/CN=" common-name)
 979                         "-keyout" exp-key-file
 980                         "-out" exp-cert-file)
 981           (list (elpher-address-host (elpher-page-address elpher-current-page))
 982                 temporary exp-key-file exp-cert-file))
 983       (error
 984        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 985        (error "Program 'openssl', required for certificate generation, not found")))))
 986
 987 (defun elpher-generate-throwaway-certificate ()
 988   "Generate and return details of a throwaway certificate.
 989 The key and certificate files will be deleted when they are no
 990 longer needed for this session."
 991   (let* ((file-base (make-temp-name "elpher"))
 992          (key-file (concat temporary-file-directory file-base ".key"))
 993          (cert-file (concat temporary-file-directory file-base ".crt")))
 994     (elpher-generate-certificate file-base key-file cert-file t)))
 995
 996 (defun elpher-generate-persistent-certificate (file-base common-name)
 997   "Generate and return details of a persistent certificate.
 998 The argument FILE-BASE is used as the base for the key and certificate
 999 files, while COMMON-NAME specifies the common name field of the
1000 certificate.
1001
1002 The key and certificate files are written to in `elpher-certificate-directory'."
1003   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1004          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1005     (elpher-generate-certificate common-name key-file cert-file)))
1006
1007 (defun elpher-get-existing-certificate (file-base)
1008   "Return a certificate object corresponding to an existing certificate.
1009 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1010 the directory `elpher-certificate-directory'."
1011   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1012          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1013     (list (elpher-address-host (elpher-page-address elpher-current-page))
1014           nil
1015           (expand-file-name key-file)
1016           (expand-file-name cert-file))))
1017
1018 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1019   "Install a key+certificate file pair in `elpher-certificate-directory'.
1020 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1021 certificate files to install.  The argument FILE-BASE is used as the
1022 base for the installed key and certificate files."
1023   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1024          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1025     (if (or (file-exists-p key-file)
1026             (file-exists-p cert-file))
1027         (error "A certificate with base name %s is already installed" file-base))
1028     (copy-file key-file-src key-file)
1029     (copy-file cert-file-src cert-file)
1030     (list (elpher-address-host (elpher-page-address elpher-current-page))
1031           nil
1032           (expand-file-name key-file)
1033           (expand-file-name cert-file))))
1034
1035 (defun elpher-list-existing-certificates ()
1036   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1037   (unless (file-directory-p elpher-certificate-directory)
1038     (make-directory elpher-certificate-directory))
1039   (mapcar
1040    (lambda (file)
1041      (file-name-sans-extension file))
1042    (directory-files elpher-certificate-directory nil "\\.key$")))
1043
1044 (defun elpher-forget-current-certificate ()
1045   "Causes any current certificate to be forgotten.)
1046 In the case of throwaway certificates, the key and certificate files
1047 are also deleted."
1048   (interactive)
1049   (when elpher-client-certificate
1050     (unless (and (called-interactively-p 'any)
1051                  (not (y-or-n-p (concat "Really forget client certificate? "
1052                                         "(Throwaway certificates will be deleted.)"))))
1053       (when (cadr elpher-client-certificate)
1054         (delete-file (elt elpher-client-certificate 2))
1055         (delete-file (elt elpher-client-certificate 3)))
1056       (setq elpher-client-certificate nil)
1057       (if (called-interactively-p 'any)
1058           (message "Client certificate forgotten.")))))
1059
1060 (defun elpher-get-current-keylist (address)
1061   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1062
1063 This is obtained from the client certificate described by
1064 `elpher-current-certificate', if one is available and the host for
1065 that certificate matches the host in ADDRESS.
1066
1067 If `elpher-current-certificate' is non-nil, and its host name doesn't
1068 match that of ADDRESS, the certificate is forgotten."
1069   (if elpher-client-certificate
1070       (if (string= (car elpher-client-certificate)
1071                    (elpher-address-host address))
1072           (list (cddr elpher-client-certificate))
1073         (elpher-forget-current-certificate)
1074         (message "Disabling client certificate for new host")
1075         nil)
1076     nil))
1077
1078
1079 ;;; Gopher selector retrieval
1080 ;;
1081
1082 (defun elpher-get-gopher-response (address renderer)
1083   "Get response string from gopher server at ADDRESS and render using RENDERER."
1084   (elpher-get-host-response address 70
1085                             (concat (elpher-gopher-address-selector address) "\r\n")
1086                             renderer
1087                             (or (string= (elpher-address-protocol address) "gophers")
1088                                 elpher-use-tls)))
1089
1090 (defun elpher-get-gopher-page (renderer)
1091   "Getter function for gopher pages.
1092 The RENDERER procedure is used to display the contents of the page
1093 once they are retrieved from the gopher server."
1094   (let* ((address (elpher-page-address elpher-current-page))
1095          (content (elpher-get-cached-content address)))
1096     (if (and content (funcall renderer nil))
1097         (elpher-with-clean-buffer
1098          (insert content)
1099          (elpher-restore-pos))
1100       (elpher-with-clean-buffer
1101        (insert "LOADING... (use 'u' to cancel)\n"))
1102       (condition-case the-error
1103           (elpher-get-gopher-response address renderer)
1104         (error
1105          (elpher-network-error address the-error))))))
1106
1107
1108 ;;; Gopher index rendering
1109 ;;
1110
1111 (defun elpher-insert-margin (&optional type-name)
1112   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1113   (if type-name
1114       (progn
1115         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1116                         (concat
1117                          (propertize "[" 'face 'elpher-margin-brackets)
1118                          (propertize type-name 'face 'elpher-margin-key)
1119                          (propertize "]" 'face 'elpher-margin-brackets))))
1120         (insert " "))
1121     (insert (make-string elpher-margin-width ?\s))))
1122
1123 (defun elpher--page-button-help (_window buffer pos)
1124   "Function called by Emacs to generate mouse-over text.
1125 The arguments specify the BUFFER and the POS within the buffer of the item
1126 for which help is required.  The function returns the help to be
1127 displayed.  The _WINDOW argument is currently unused."
1128   (with-current-buffer buffer
1129     (let ((button (button-at pos)))
1130       (when button
1131         (let* ((page (button-get button 'elpher-page))
1132                (address (elpher-page-address page)))
1133           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1134
1135 (defun elpher-insert-index-record (display-string &optional address)
1136   "Function to insert an index record into the current buffer.
1137 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1138 If ADDRESS is not supplied or nil the record is rendered as an
1139 'information' line."
1140   (let* ((type (if address (elpher-address-type address) nil))
1141          (type-map-entry (cdr (assoc type elpher-type-map))))
1142     (if type-map-entry
1143         (let* ((margin-code (elt type-map-entry 2))
1144                (face (elt type-map-entry 3))
1145                (filtered-display-string (elpher-color-filter-apply display-string))
1146                (page (elpher-make-page filtered-display-string address)))
1147           (elpher-insert-margin margin-code)
1148           (insert-text-button filtered-display-string
1149                               'face face
1150                               'elpher-page page
1151                               'action #'elpher-click-link
1152                               'follow-link t
1153                               'help-echo #'elpher--page-button-help))
1154       (pcase type
1155         ('nil ;; Information
1156          (elpher-insert-margin)
1157          (let ((propertized-display-string
1158                 (propertize display-string 'face 'elpher-info)))
1159            (insert (elpher-process-text-for-display propertized-display-string))))
1160         (`(gopher ,selector-type) ;; Unknown
1161          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1162          (insert (propertize display-string
1163                              'face 'elpher-unknown)))))
1164     (insert "\n")))
1165
1166 (defun elpher-click-link (button)
1167   "Function called when the gopher link BUTTON is activated."
1168   (let ((page (button-get button 'elpher-page)))
1169     (elpher-visit-page page)))
1170
1171 (defun elpher-render-index (data &optional _mime-type-string)
1172   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1173   (elpher-with-clean-buffer
1174    (if (not data)
1175        t
1176      (let ((data-processed (elpher-preprocess-text-response data)))
1177        (dolist (line (split-string data-processed "\n"))
1178          (ignore-errors
1179            (unless (= (length line) 0)
1180              (let* ((type (elt line 0))
1181                     (fields (split-string (substring line 1) "\t"))
1182                     (display-string (elt fields 0))
1183                     (selector (elt fields 1))
1184                     (host (elt fields 2))
1185                     (port (if (elt fields 3)
1186                               (string-to-number (elt fields 3))
1187                             nil))
1188                     (address (elpher-make-gopher-address type selector host port)))
1189                (elpher-insert-index-record display-string address))))))
1190      (elpher-cache-content (elpher-page-address elpher-current-page)
1191                            (buffer-string)))))
1192
1193
1194 ;;; Gopher text rendering
1195 ;;
1196
1197 (defun elpher-render-text (data &optional _mime-type-string)
1198   "Render DATA as text.  MIME-TYPE-STRING is unused."
1199   (elpher-with-clean-buffer
1200    (if (not data)
1201        t
1202      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1203      (elpher-cache-content
1204       (elpher-page-address elpher-current-page)
1205       (buffer-string)))))
1206
1207
1208 ;;; Image retrieval
1209 ;;
1210
1211 (defun elpher-render-image (data &optional _mime-type-string)
1212   "Display DATA as image.  MIME-TYPE-STRING is unused."
1213   (if (not data)
1214       nil
1215     (if (display-images-p)
1216         (let* ((image (create-image
1217                        data
1218                        nil t)))
1219           (if (not image)
1220               (error "Unsupported image format")
1221             (let ((window (get-buffer-window elpher-buffer-name)))
1222               (when window
1223                 (setf (image-property image :max-width) (window-body-width window t))
1224                 (setf (image-property image :max-height) (window-body-height window t))))
1225             (elpher-with-clean-buffer
1226              (insert-image image)
1227              (elpher-restore-pos))))
1228       (elpher-render-download data))))
1229
1230
1231 ;;; Gopher search retrieval and rendering
1232 ;;
1233
1234 (defun elpher-get-gopher-query-page (renderer)
1235   "Getter for gopher addresses requiring input.
1236 The response is rendered using the rendering function RENDERER."
1237   (let* ((address (elpher-page-address elpher-current-page))
1238          (content (elpher-get-cached-content address))
1239          (aborted t))
1240     (if (and content (funcall renderer nil))
1241         (elpher-with-clean-buffer
1242          (insert content)
1243          (elpher-restore-pos)
1244          (message "Displaying cached search results.  Reload to perform a new search."))
1245       (unwind-protect
1246           (let* ((query-string (read-string "Query: "))
1247                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1248                  (search-address (elpher-make-gopher-address ?1
1249                                                              query-selector
1250                                                              (elpher-address-host address)
1251                                                              (elpher-address-port address)
1252                                                              (equal (elpher-address-type address) "gophers"))))
1253             (setq aborted nil)
1254
1255             (elpher-with-clean-buffer
1256              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1257             (elpher-get-gopher-response search-address renderer))
1258         (if aborted
1259             (elpher-visit-previous-page))))))
1260
1261
1262 ;;; Raw server response rendering
1263 ;;
1264
1265 (defun elpher-render-raw (data &optional mime-type-string)
1266   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1267   (if (not data)
1268       nil
1269     (elpher-with-clean-buffer
1270      (when mime-type-string
1271        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1272      (insert data)
1273      (goto-char (point-min)))
1274     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1275
1276
1277 ;;; File save "rendering"
1278 ;;
1279
1280 (defun elpher-render-download (data &optional _mime-type-string)
1281   "Save DATA to file.  MIME-TYPE-STRING is unused."
1282   (if (not data)
1283       nil
1284     (let* ((address (elpher-page-address elpher-current-page))
1285            (selector (if (elpher-address-gopher-p address)
1286                          (elpher-gopher-address-selector address)
1287                        (elpher-address-filename address))))
1288       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1289       (let* ((filename-proposal (file-name-nondirectory selector))
1290              (filename (read-file-name "Download complete. Save file as: "
1291                                        nil nil nil
1292                                        (if (> (length filename-proposal) 0)
1293                                            filename-proposal
1294                                          "download.file"))))
1295         (let ((coding-system-for-write 'binary))
1296           (with-temp-file filename
1297             (insert data)))
1298         (message (format "Saved to file %s." filename))))))
1299
1300
1301 ;;; HTML rendering
1302 ;;
1303
1304 (defun elpher-render-html (data &optional _mime-type-string)
1305   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1306   (elpher-with-clean-buffer
1307    (if (not data)
1308        t
1309      (let ((dom (with-temp-buffer
1310                   (insert data)
1311                   (libxml-parse-html-region (point-min) (point-max)))))
1312        (shr-insert-document dom)))))
1313
1314
1315 ;;; Gemini page retrieval
1316 ;;
1317
1318 (defvar elpher-gemini-redirect-chain)
1319
1320 (defun elpher-get-gemini-response (address renderer)
1321   "Get response string from gemini server at ADDRESS and render using RENDERER."
1322   (elpher-get-host-response address 1965
1323                             (concat (elpher-address-to-url address) "\r\n")
1324                             (lambda (response-string)
1325                               (elpher-process-gemini-response response-string renderer))
1326                             'gemini))
1327
1328 (defun elpher-parse-gemini-response (response)
1329   "Parse the RESPONSE string and return a list of components.
1330 The list is of the form (code meta body).  A response of nil implies
1331 that the response was malformed."
1332   (let ((header-end-idx (string-match "\r\n" response)))
1333     (if header-end-idx
1334         (let ((header (string-trim (substring response 0 header-end-idx)))
1335               (body (substring response (+ header-end-idx 2))))
1336           (if (>= (length header) 2)
1337               (let ((code (substring header 0 2))
1338                     (meta (string-trim (substring header 2))))
1339                 (list code meta body))
1340             (error "Malformed response: No response status found in header %s" header)))
1341       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1342
1343 (defun elpher-process-gemini-response (response-string renderer)
1344   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1345   (let ((response-components (elpher-parse-gemini-response response-string)))
1346     (let ((response-code (elt response-components 0))
1347           (response-meta (elt response-components 1))
1348           (response-body (elt response-components 2)))
1349       (pcase (elt response-code 0)
1350         (?1 ; Input required
1351          (elpher-with-clean-buffer
1352           (insert "Gemini server is requesting input."))
1353          (let* ((query-string
1354                  (if (eq (elt response-code 1) ?1)
1355                      (read-passwd (concat response-meta ": "))
1356                    (read-string (concat response-meta ": "))))
1357                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1358                 (old-fname (url-filename query-address)))
1359            (setf (url-filename query-address)
1360                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1361            (elpher-get-gemini-response query-address renderer)))
1362         (?2 ; Normal response
1363          (funcall renderer response-body response-meta))
1364         (?3 ; Redirect
1365          (message "Following redirect to %s" response-meta)
1366          (if (>= (length elpher-gemini-redirect-chain) 5)
1367              (error "More than 5 consecutive redirects followed"))
1368          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1369            (if (member redirect-address elpher-gemini-redirect-chain)
1370                (error "Redirect loop detected"))
1371            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1372                (error "Server tried to automatically redirect to non-gemini URL: %s"
1373                       response-meta))
1374            (elpher-page-set-address elpher-current-page redirect-address)
1375            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1376            (elpher-get-gemini-response redirect-address renderer)))
1377         (?4 ; Temporary failure
1378          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1379                 response-code response-meta))
1380         (?5 ; Permanent failure
1381          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1382                 response-code response-meta))
1383         (?6 ; Client certificate required
1384          (elpher-with-clean-buffer
1385           (if elpher-client-certificate
1386               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1387             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1388           (auto-fill-mode 1)
1389           (elpher-gemini-insert-text response-meta))
1390          (let ((chosen-certificate (elpher-choose-client-certificate)))
1391            (unless chosen-certificate
1392              (error "Gemini server requires a client certificate and none was provided"))
1393            (setq elpher-client-certificate chosen-certificate))
1394          (elpher-with-clean-buffer)
1395          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1396         (_other
1397          (error "Gemini server response unknown: %s %s"
1398                 response-code response-meta))))))
1399
1400 (defun elpher--read-answer-polyfill (question answers)
1401   "Polyfill for `read-answer' in Emacs 26.1.
1402 QUESTION is a string containing a question, and ANSWERS
1403 is a list of possible answers."
1404     (completing-read question (mapcar 'identity answers)))
1405
1406 (if (fboundp 'read-answer)
1407     (defalias 'elpher-read-answer 'read-answer)
1408   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1409
1410 (defun elpher-choose-client-certificate ()
1411   "Prompt for a client certificate to use to establish a TLS connection."
1412   (let* ((read-answer-short t))
1413     (pcase (read-answer "What do you want to do? "
1414                         '(("throwaway" ?t
1415                            "generate and use throw-away certificate")
1416                           ("persistent" ?p
1417                            "generate new or use existing persistent certificate")
1418                           ("abort" ?a
1419                            "stop immediately")))
1420       ("throwaway"
1421        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1422       ("persistent"
1423        (let* ((existing-certificates (elpher-list-existing-certificates))
1424               (file-base (completing-read
1425                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1426                           existing-certificates)))
1427          (if (string-empty-p (string-trim file-base))
1428              nil
1429            (if (member file-base existing-certificates)
1430                (setq elpher-client-certificate
1431                      (elpher-get-existing-certificate file-base))
1432              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1433                                  '(("new" ?n
1434                                     "generate new certificate")
1435                                    ("install" ?i
1436                                     "install existing certificate")
1437                                    ("abort" ?a
1438                                     "stop immediately")))
1439                ("new"
1440                 (let ((common-name (read-string "Common Name field for new certificate: "
1441                                                 file-base)))
1442                   (message "New key and self-signed certificate written to %s"
1443                            elpher-certificate-directory)
1444                   (elpher-generate-persistent-certificate file-base common-name)))
1445                ("install"
1446                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1447                        (key-file (read-file-name "Key file: " nil nil t)))
1448                   (message "Key and certificate installed in %s for future use"
1449                            elpher-certificate-directory)
1450                   (elpher-install-and-use-existing-certificate key-file
1451                                                                cert-file
1452                                                                file-base)))
1453                ("abort" nil))))))
1454       ("abort" nil))))
1455
1456 (defun elpher-get-gemini-page (renderer)
1457   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1458   (let* ((address (elpher-page-address elpher-current-page))
1459          (content (elpher-get-cached-content address)))
1460     (condition-case the-error
1461         (if (and content (funcall renderer nil))
1462             (elpher-with-clean-buffer
1463              (insert content)
1464              (elpher-restore-pos))
1465           (elpher-with-clean-buffer
1466            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1467           (setq elpher-gemini-redirect-chain nil)
1468           (elpher-get-gemini-response address renderer))
1469       (error
1470        (elpher-network-error address the-error)))))
1471
1472 ;;; Gemini page rendering
1473 ;;
1474
1475 (defun elpher-render-gemini (body &optional mime-type-string)
1476   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1477   (if (not body)
1478       t
1479     (let* ((mime-type-string* (if (or (not mime-type-string)
1480                                       (string-empty-p mime-type-string))
1481                                   "text/gemini; charset=utf-8"
1482                                 mime-type-string))
1483            (mime-type-split (split-string mime-type-string* ";" t))
1484            (mime-type (string-trim (car mime-type-split)))
1485            (parameters (mapcar (lambda (s)
1486                                  (let ((key-val (split-string s "=")))
1487                                    (list (downcase (string-trim (car key-val)))
1488                                          (downcase (string-trim (cadr key-val))))))
1489                                (cdr mime-type-split))))
1490       (when (string-prefix-p "text/" mime-type)
1491         (setq body (decode-coding-string
1492                     body
1493                     (if (assoc "charset" parameters)
1494                         (intern (cadr (assoc "charset" parameters)))
1495                       'utf-8)))
1496         (setq body (replace-regexp-in-string "\r" "" body)))
1497       (pcase mime-type
1498         ((or "text/gemini" "")
1499          (elpher-render-gemini-map body parameters))
1500         ("text/html"
1501          (elpher-render-html body))
1502         ((pred (string-prefix-p "text/"))
1503          (elpher-render-gemini-plain-text body parameters))
1504         ((pred (string-prefix-p "image/"))
1505          (elpher-render-image body))
1506         (_other
1507          (elpher-render-download body))))))
1508
1509 (defun elpher-gemini-get-link-url (link-line)
1510   "Extract the url portion of LINK-LINE, a gemini map file link line.
1511 Returns nil in the event that the contents of the line following the
1512 => prefix are empty."
1513   (let ((l (split-string (substring link-line 2))))
1514     (if l
1515         (string-trim (elt l 0))
1516       nil)))
1517
1518 (defun elpher-gemini-get-link-display-string (link-line)
1519   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1520 Return nil if this portion is not provided."
1521   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1522          (idx (string-match "[ \t]" rest)))
1523     (and idx
1524          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1525
1526 (defun elpher-collapse-dot-sequences (filename)
1527   "Collapse dot sequences in the (absolute) FILENAME.
1528 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1529   (let* ((path (split-string filename "/" t))
1530          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1531          (path-reversed-normalized
1532           (seq-reduce (lambda (a b)
1533                         (cond ((equal b "..") (cdr a))
1534                               ((equal b ".") a)
1535                               (t (cons b a))))
1536                       path nil))
1537          (path-normalized (reverse path-reversed-normalized)))
1538     (if path-normalized
1539         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1540       "/")))
1541
1542 (defun elpher-address-from-gemini-url (url)
1543   "Extract address from URL with defaults as per gemini map files.
1544 While there's obviously some redundancy here between this function and
1545 `elpher-address-from-url', gemini map file URLs require enough special
1546 treatment that a separate function is warranted."
1547   (let ((address (url-generic-parse-url url))
1548         (current-address (elpher-page-address elpher-current-page)))
1549     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1550       (if (url-host address) ;if there is an explicit host, filenames are absolute
1551           (if (string-empty-p (url-filename address))
1552               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1553         (setf (url-host address) (url-host current-address))
1554         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1555         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1556         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1557           (setf (url-filename address)
1558                 (concat (file-name-directory (url-filename current-address))
1559                         (url-filename address)))))
1560       (when (url-host address)
1561         (setf (url-host address) (puny-encode-domain (url-host address))))
1562       (unless (url-type address)
1563         (setf (url-type address) (url-type current-address)))
1564       (when (equal (url-type address) "gemini")
1565         (setf (url-filename address)
1566               (elpher-collapse-dot-sequences (url-filename address)))))
1567     (elpher-remove-redundant-ports address)))
1568
1569 (defun elpher-gemini-insert-link (link-line)
1570   "Insert link described by LINK-LINE into a text/gemini document."
1571   (let ((url (elpher-gemini-get-link-url link-line)))
1572     (when url
1573       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1574              (address (elpher-address-from-gemini-url url))
1575              (type (if address (elpher-address-type address) nil))
1576              (type-map-entry (cdr (assoc type elpher-type-map)))
1577              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1578         (when type-map-entry
1579           (insert elpher-gemini-link-string)
1580           (let* ((face (elt type-map-entry 3))
1581                  (display-string (or given-display-string
1582                                      (elpher-address-to-iri address)))
1583                  (page (elpher-make-page display-string
1584                                          address)))
1585             (insert-text-button display-string
1586                                 'face face
1587                                 'elpher-page page
1588                                 'action #'elpher-click-link
1589                                 'follow-link t
1590                                 'help-echo #'elpher--page-button-help))
1591           (newline))))))
1592
1593 (defun elpher-gemini-insert-header (header-line)
1594   "Insert header described by HEADER-LINE into a text/gemini document.
1595 The gemini map file line describing the header is given
1596 by HEADER-LINE."
1597   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1598     (let* ((level (length (match-string 1 header-line)))
1599            (header (substring header-line (match-end 0)))
1600            (face (pcase level
1601                    (1 'elpher-gemini-heading1)
1602                    (2 'elpher-gemini-heading2)
1603                    (3 'elpher-gemini-heading3)
1604                    (_ 'default)))
1605            (fill-column (if (display-graphic-p)
1606                             (/ (* fill-column
1607                                   (font-get (font-spec :name (face-font 'default)) :size))
1608                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1609       (unless (display-graphic-p)
1610         (insert (make-string level ?#) " "))
1611       (insert (propertize header
1612                           'face face
1613                           'gemini-heading t
1614                           'rear-nonsticky t))
1615       (newline))))
1616
1617 (defun elpher-gemini-insert-text (text-line)
1618   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1619 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1620 width defined by `elpher-gemini-max-fill-width'."
1621   (string-match
1622    (rx (: line-start
1623           (optional
1624            (group (or (: "*" (+ (any " \t")))
1625                       (: ">" (* (any " \t"))))))))
1626    text-line)
1627   (let* ((line-prefix (match-string 1 text-line))
1628          (processed-text-line
1629           (if line-prefix
1630               (cond ((string-prefix-p "*" line-prefix)
1631                      (concat
1632                       (replace-regexp-in-string "\\*"
1633                                                 elpher-gemini-bullet-string
1634                                                 (match-string 0 text-line))
1635                       (substring text-line (match-end 0))))
1636                     ((string-prefix-p ">" line-prefix)
1637                      (propertize text-line 'face 'elpher-gemini-quoted))
1638                     (t text-line))
1639             text-line))
1640          (fill-prefix (if line-prefix
1641                           (make-string (length (match-string 0 text-line)) ?\s)
1642                         "")))
1643     (insert (elpher-process-text-for-display processed-text-line))
1644     (newline)))
1645
1646 (defun elpher-gemini-pref-expand-collapse (button)
1647   "Function called when the preformatted text toggle BUTTON is activated."
1648   (let ((id (button-get button 'pref-id)))
1649     (if (invisible-p id)
1650         (remove-from-invisibility-spec id)
1651       (add-to-invisibility-spec id))
1652     (redraw-display)))
1653
1654 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1655   "Insert a button for toggling the visibility of preformatted text.
1656 If non-nil, ALT-TEXT is displayed alongside the button."
1657   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1658          (pref-id (intern (concat "pref-"
1659                                   (number-to-string (point))
1660                                   "-"
1661                                   url-string))))
1662     (insert elpher-gemini-preformatted-toggle-bullet)
1663     (when alt-text
1664       (insert (propertize (concat alt-text " ")
1665                           'face 'elpher-gemin-preformatted)))
1666     (insert-text-button elpher-gemini-preformatted-toggle-label
1667                         'action #'elpher-gemini-pref-expand-collapse
1668                         'pref-id pref-id
1669                         'face 'elpher-gemini-preformatted-toggle)
1670     (add-to-invisibility-spec pref-id)
1671     (newline)
1672     pref-id))
1673
1674 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1675   "Insert a LINE of preformatted text.
1676 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1677 can be used to toggle the display of the preformatted text."
1678   (insert (propertize (concat (elpher-process-text-for-display
1679                                (propertize line 'face 'elpher-gemini-preformatted))
1680                               "\n")
1681                       'invisible pref-id
1682                       'rear-nonsticky t)))
1683
1684 (defun elpher-render-gemini-map (data _parameters)
1685   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1686   (elpher-with-clean-buffer
1687    (auto-fill-mode 1)
1688    (setq-local buffer-invisibility-spec nil)
1689    (let ((preformatted nil)
1690          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1691      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1692      (dolist (line (split-string data "\n"))
1693        (pcase line
1694          ((rx (: string-start "```" (opt (let alt-text (+ any)))))
1695           (setq preformatted
1696                 (if preformatted
1697                     nil
1698                   (if elpher-gemini-hide-preformatted
1699                       (elpher-gemini-insert-preformatted-toggler alt-text)
1700                     t))))
1701          ((guard  preformatted)
1702           (elpher-gemini-insert-preformatted-line line preformatted))
1703          ((pred (string-prefix-p "=>"))
1704           (elpher-gemini-insert-link line))
1705          ((pred (string-prefix-p "#"))
1706           (elpher-gemini-insert-header line))
1707          (_ (elpher-gemini-insert-text line))))
1708    (elpher-cache-content
1709     (elpher-page-address elpher-current-page)
1710     (buffer-string)))))
1711
1712 (defun elpher-render-gemini-plain-text (data _parameters)
1713   "Render DATA as plain text file.  PARAMETERS is currently unused."
1714   (elpher-with-clean-buffer
1715    (insert (elpher-process-text-for-display data))
1716    (elpher-cache-content
1717     (elpher-page-address elpher-current-page)
1718     (buffer-string))))
1719
1720 (defun elpher-build-current-imenu-index ()
1721   "Build imenu index for current elpher buffer."
1722   (save-excursion
1723     (goto-char (point-min))
1724     (let ((match nil)
1725           (headers nil))
1726       (while (setq match (text-property-search-forward 'gemini-heading t t))
1727         (push (cons
1728                (buffer-substring-no-properties (prop-match-beginning match)
1729                                                (prop-match-end match))
1730                (prop-match-beginning match))
1731               headers))
1732       (reverse headers))))
1733
1734
1735 ;;; Finger page connection
1736 ;;
1737
1738 (defun elpher-get-finger-page (renderer)
1739   "Opens a finger connection to the current page address.
1740 The result is rendered using RENDERER."
1741   (let* ((address (elpher-page-address elpher-current-page))
1742          (content (elpher-get-cached-content address)))
1743     (if (and content (funcall renderer nil))
1744         (elpher-with-clean-buffer
1745          (insert content)
1746          (elpher-restore-pos))
1747       (elpher-with-clean-buffer
1748        (insert "LOADING... (use 'u' to cancel)\n"))
1749       (condition-case the-error
1750           (let* ((kill-buffer-query-functions nil)
1751                  (user (let ((filename (elpher-address-filename address)))
1752                          (if (> (length filename) 1)
1753                              (substring filename 1)
1754                            (elpher-address-user address)))))
1755             (elpher-get-host-response address 79
1756                                       (concat user "\r\n")
1757                                       renderer))
1758         (error
1759          (elpher-network-error address the-error))))))
1760
1761
1762 ;;; Telnet page connection
1763 ;;
1764
1765 (defun elpher-get-telnet-page (renderer)
1766   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1767   (when renderer
1768     (elpher-visit-previous-page)
1769     (error "Command not supported for telnet URLs"))
1770   (let* ((address (elpher-page-address elpher-current-page))
1771          (host (elpher-address-host address))
1772          (port (elpher-address-port address)))
1773     (elpher-visit-previous-page)
1774     (if (> port 0)
1775         (telnet host port)
1776       (telnet host))))
1777
1778
1779 ;;; Other URL page opening
1780 ;;
1781
1782 (defun elpher-get-other-url-page (renderer)
1783   "Getter which attempts to open the URL specified by the current page.
1784 The RENDERER argument to this getter must be nil."
1785   (when renderer
1786     (elpher-visit-previous-page)
1787     (error "Command not supported for general URLs"))
1788   (let* ((address (elpher-page-address elpher-current-page))
1789          (url (elpher-address-to-url address)))
1790     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1791     (message "Opening URL...")
1792     (if elpher-open-urls-with-eww
1793         (browse-web url)
1794       (browse-url url))))
1795
1796
1797 ;;; File page
1798 ;;
1799
1800 (defun elpher-get-file-page (renderer)
1801   "Getter which renders a local file using RENDERER.
1802 Assumes UTF-8 encoding for all text files."
1803   (let* ((address (elpher-page-address elpher-current-page))
1804          (filename (elpher-address-filename address)))
1805     (unless (file-exists-p filename)
1806       (elpher-visit-previous-page)
1807         (error "File not found"))
1808     (unless (file-readable-p filename)
1809       (elpher-visit-previous-page)
1810         (error "Could not read from file"))
1811     (let ((body (with-temp-buffer
1812        (let ((coding-system-for-read 'binary)
1813              (coding-system-for-write 'binary))
1814          (insert-file-contents-literally filename)
1815          (encode-coding-string (buffer-string) 'raw-text)))))
1816        (if renderer
1817            (funcall renderer body nil)
1818          (pcase (file-name-extension filename)
1819            ((or  "gmi" "gemini")
1820             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1821            ((or "htm" "html")
1822             (elpher-render-html (decode-coding-string body 'utf-8)))
1823            ((or "txt" "")
1824             (elpher-render-text (decode-coding-string body 'utf-8)))
1825            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1826             (elpher-render-image body))
1827            ((or "gopher" "gophermap")
1828             (elpher-render-index (elpher-decode body)))
1829            (_
1830             (elpher-render-download body))))
1831        (elpher-restore-pos))))
1832
1833
1834 ;;; Welcome page retrieval
1835 ;;
1836
1837 (defun elpher-get-welcome-page (renderer)
1838   "Getter which displays the welcome page (RENDERER must be nil)."
1839   (when renderer
1840     (elpher-visit-previous-page)
1841     (error "Command not supported for welcome page"))
1842   (elpher-with-clean-buffer
1843    (insert "     --------------------------------------------\n"
1844            "           Elpher Gopher and Gemini Client       \n"
1845            "                   version " elpher-version "\n"
1846            "     --------------------------------------------\n"
1847            "\n"
1848            "Default bindings:\n"
1849            "\n"
1850            " - TAB/Shift-TAB: next/prev item on current page\n"
1851            " - RET/mouse-1: open item under cursor\n"
1852            " - m: select an item on current page by name (autocompletes)\n"
1853            " - u/mouse-3/U: return to previous page or to the start page\n"
1854            " - g: go to a particular address (gopher, gemini, finger)\n"
1855            " - o/O: open a different address selector or the root menu of the current server\n"
1856            " - d/D: download item under cursor or current page\n"
1857            " - i/I: info on item under cursor or current page\n"
1858            " - c/C: copy URL representation of item under cursor or current page\n"
1859            " - a/A: bookmark the item under cursor or current page\n"
1860            " - B: list all bookmarks\n"
1861            " - s/S: show current history stack or all previously visted pages\n"
1862            " - r: redraw current page (using cached contents if available)\n"
1863            " - R: reload current page (regenerates cache)\n"
1864            " - !: set character coding system for gopher (default is to autodetect)\n"
1865            " - T: toggle TLS gopher mode\n"
1866            " - F: forget/discard current TLS client certificate\n"
1867            " - .: display the raw server response for the current page\n"
1868            "\n"
1869            "Start your exploration of gopher space and gemini:\n")
1870    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1871                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1872    (elpher-insert-index-record "Project Gemini home page"
1873                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1874    (insert "\n"
1875            "Alternatively, select a search engine and enter some search terms:\n")
1876    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1877                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1878    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1879                                (elpher-address-from-url "gemini://geminispace.info/search"))
1880    (insert "\n"
1881            "Your bookmarks are stored in your ")
1882    (insert-text-button "bookmark list"
1883                        'face 'link
1884                        'action #'elpher-click-link
1885                        'follow-link t
1886                        'help-echo #'elpher--page-button-help
1887                        'elpher-page
1888                        (elpher-make-page "Elpher Bookmarks"
1889                                          (elpher-make-about-address 'bookmarks)))
1890    (insert ".\n")
1891    (insert (propertize
1892             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1893             'face 'shadow))
1894    (insert "\n"
1895            "The gopher home of the Elpher project is here:\n")
1896    (elpher-insert-index-record "The Elpher Project Page"
1897                                (elpher-make-gopher-address ?1
1898                                                            "/projects/elpher/"
1899                                                            "thelambdalab.xyz"
1900                                                            70))
1901    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1902      (insert "\n"
1903              "The following info documentation is available:\n"
1904              "   - ")
1905      (insert-text-button "Elpher Manual"
1906                          'face 'link
1907                          'action (lambda (_)
1908                                    (interactive)
1909                                    (info "(elpher)"))
1910                          'follow-link t
1911                          'help-echo help-string)
1912      (insert "\n   - ")
1913      (insert-text-button "Changes introduced by the latest release"
1914                        'face 'link
1915                        'action (lambda (_)
1916                                  (interactive)
1917                                  (info "(elpher)News"))
1918                        'follow-link t
1919                        'help-echo help-string))
1920    (insert "\n")
1921    (insert (propertize
1922             (concat "(These documents should be available if you have installed Elpher\n"
1923                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1924                     " manual yourself.)\n")
1925             'face 'shadow))
1926    (elpher-restore-pos)))
1927
1928
1929 ;;; History page retrieval
1930 ;;
1931
1932 (defun elpher-show-history ()
1933   "Show the current contents of elpher's history stack.
1934 Use \\[elpher-show-visited-pages] to see the entire history.
1935 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1936   (interactive)
1937   (elpher-visit-page
1938    (elpher-make-page "Current History Stack"
1939                      (elpher-make-about-address 'history))))
1940
1941 (defun elpher-show-visited-pages ()
1942   "Show the all the pages you've visited using Elpher.
1943 Use \\[elpher-show-history] to see just the current history stack.
1944 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1945   (interactive)
1946   (elpher-visit-page
1947    (elpher-make-page "Elpher Visted Pages"
1948                      (elpher-make-about-address 'visited-pages))))
1949
1950 (defun elpher-get-history-page (renderer)
1951   "Getter which displays the history page (RENDERER must be nil)."
1952   (when renderer
1953     (elpher-visit-previous-page)
1954     (error "Command not supported for history page"))
1955   (elpher-display-history-links elpher-history "Current history stack"))
1956
1957 (defun elpher-get-visited-pages-page (renderer)
1958   "Getter which displays the list of visited pages (RENDERER must be nil)."
1959   (when renderer
1960     (elpher-visit-previous-page)
1961     (error "Command not supported for history page"))
1962   (elpher-display-history-links
1963    (seq-filter (lambda (page)
1964                  (not (elpher-address-about-p (elpher-page-address page))))
1965                elpher-visited-pages)
1966    "All visited pages"))
1967
1968 (defun elpher-display-history-links (pages title)
1969   "Show all PAGES in an Elpher buffer with a given TITLE."
1970   (let* ((title-line (concat " ---- " title " ----"))
1971          (footer-line (make-string (length title-line) ?-)))
1972     (elpher-with-clean-buffer
1973      (insert title-line "\n\n")
1974      (if pages
1975          (dolist (page pages)
1976            (when page
1977              (let ((display-string (elpher-page-display-string page))
1978                    (address (elpher-page-address page)))
1979                (elpher-insert-index-record display-string address))))
1980        (insert "No history items found.\n"))
1981      (insert "\n " footer-line "\n"
1982              "Select an entry or press 'u' to return to the previous page.")
1983      (elpher-restore-pos))))
1984
1985
1986 ;;; Bookmarks
1987 ;;
1988
1989 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1990 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1991 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1992 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1993
1994 (defvar elpher-bookmark-link nil
1995   "Prefer bookmarking a link or the current page.
1996 Bind this variable dynamically, or set it to t.
1997 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1998 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1999
2000 (defun elpher-bookmark-make-record ()
2001   "Return a bookmark record.
2002 If `elpher-bookmark-link' is non-nil and point is on a link button,
2003 return a bookmark record for that link.  Otherwise, return a bookmark
2004 record for the current elpher page."
2005   (let* ((button (and elpher-bookmark-link (button-at (point))))
2006          (page (if button
2007                    (button-get button 'elpher-page)
2008                  elpher-current-page)))
2009     (unless page
2010       (error "Cannot bookmark this link"))
2011     (let* ((address (elpher-page-address page))
2012            (url (elpher-address-to-url address))
2013            (display-string (elpher-page-display-string page))
2014            (pos (if button nil (point))))
2015       (if (elpher-address-about-p address)
2016           (error "Cannot bookmark %s" display-string)
2017         `(,display-string
2018           (defaults . (,display-string))
2019           (position . ,pos)
2020           (location . ,url)
2021           (handler . elpher-bookmark-jump))))))
2022
2023 ;;;###autoload
2024 (defun elpher-bookmark-jump (bookmark)
2025   "Handler used to open a bookmark using elpher.
2026 The argument BOOKMARK is a bookmark record passed to the function.
2027 This handler is responsible for loading the bookmark in some buffer,
2028 then making that buffer the current buffer.  It should not switch
2029 to the buffer."
2030   (let* ((url (cdr (assq 'location bookmark)))
2031          (cleaned-url (string-trim url))
2032          (page (elpher-page-from-url cleaned-url))
2033          (buffer (get-buffer-create elpher-buffer-name)))
2034     (elpher-with-clean-buffer
2035      (elpher-visit-page page))
2036     (set-buffer buffer)
2037     nil))
2038
2039 (defun elpher-bookmark-link ()
2040   "Bookmark the link at point.
2041 To bookmark the current page, use \\[elpher-bookmark-current]."
2042   (interactive)
2043   (let ((elpher-bookmark-link t))
2044     (bookmark-set-no-overwrite)))
2045
2046 (defun elpher-bookmark-current ()
2047   "Bookmark the current page.
2048 To bookmark the link at point use \\[elpher-bookmark-link]."
2049   (interactive)
2050   (call-interactively #'bookmark-set-no-overwrite))
2051
2052 (defun elpher-bookmark-import (file)
2053   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2054   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2055                               (file-readable-p elpher-bookmarks-file))
2056                          elpher-bookmarks-file
2057                        (read-file-name "Old Elpher bookmarks: "
2058                                        user-emacs-directory nil t
2059                                        "elpher-bookmarks"))))
2060   (dolist (bookmark (with-temp-buffer
2061                       (insert-file-contents file)
2062                       (read (current-buffer))))
2063     (let* ((display-string (car bookmark))
2064            (url (cadr bookmark))
2065            (record `(,display-string
2066                      (location . ,url)
2067                      (handler . elpher-bookmark-jump))))
2068       (bookmark-store display-string (cdr record) t)))
2069   (bookmark-save))
2070
2071 (defun elpher-get-bookmarks-page (renderer)
2072   "Getter which displays the bookmarks (RENDERER must be nil)."
2073   (when renderer
2074     (elpher-visit-previous-page)
2075     (error "Command not supported for bookmarks page"))
2076
2077   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2078                                      elpher-bookmarks-file)
2079                                 (locate-user-emacs-file "elpher-bookmarks"))))
2080     (when (and (file-readable-p old-bookmarks-file)
2081                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2082                                  old-bookmarks-file
2083                                  "\" found. Import now?")))
2084       (elpher-bookmark-import old-bookmarks-file)
2085       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2086
2087   (if (and elpher-use-emacs-bookmark-menu
2088            elpher-history)
2089       (progn
2090         (elpher-visit-previous-page)
2091         (call-interactively #'bookmark-bmenu-list))
2092     (elpher-with-clean-buffer
2093      (insert " ---- Elpher Bookmarks ---- \n\n")
2094      (bookmark-maybe-load-default-file)
2095      (dolist (bookmark (bookmark-maybe-sort-alist))
2096        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2097          (let* ((name (car bookmark))
2098                 (url (alist-get 'location (cdr bookmark)))
2099                 (address (elpher-address-from-url url)))
2100            (elpher-insert-index-record name address))))
2101      (when (<= (line-number-at-pos) 3)
2102        (insert "No bookmarked pages found.\n"))
2103      (insert "\n --------------------------\n\n"
2104              "Select an entry or press 'u' to return to the previous page.\n\n"
2105              "Bookmarks can be renamed or deleted via the ")
2106      (insert-text-button "Emacs bookmark menu"
2107                          'action (lambda (_)
2108                                    (interactive)
2109                                    (call-interactively #'bookmark-bmenu-list))
2110                          'follow-link t
2111                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2112      (insert (substitute-command-keys
2113               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2114      (elpher-restore-pos))))
2115
2116 (defun elpher-show-bookmarks ()
2117   "Interactive function to display the current list of elpher bookmarks."
2118   (interactive)
2119   (elpher-visit-page
2120    (elpher-make-page "Elpher Bookmarks"
2121                      (elpher-make-about-address 'bookmarks))))
2122
2123
2124 ;;; Integrations
2125 ;;
2126
2127 ;;; Org
2128
2129 (defun elpher-org-export-link (link description format protocol)
2130   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2131
2132 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2133 of gemini, gopher or finger."
2134   (let* ((url (if (equal protocol "elpher")
2135                   (string-remove-prefix "elpher:" link)
2136                 (format "%s:%s" protocol link)))
2137          (desc (or description url)))
2138     (pcase format
2139       (`gemini (format "=> %s %s" url desc))
2140       (`html (format "<a href=\"%s\">%s</a>" url desc))
2141       (`latex (format "\\href{%s}{%s}" url desc))
2142       (_ (if (not description)
2143              url
2144            (format "%s (%s)" desc url))))))
2145
2146 (defun elpher-org-store-link ()
2147   "Store link to an `elpher' page in Org."
2148   (when (eq major-mode 'elpher-mode)
2149     (let* ((url (elpher-info-current))
2150            (desc (car elpher-current-page))
2151            (protocol (cond
2152                       ((string-prefix-p "gemini:" url) "gemini")
2153                       ((string-prefix-p "gopher:" url) "gopher")
2154                       ((string-prefix-p "finger:" url) "finger")
2155                       (t "elpher"))))
2156       (when (equal "elpher" protocol)
2157         ;; Weird link. Or special inner link?
2158         (setq url (concat "elpher:" url)))
2159       (org-link-store-props :type protocol :link url :description desc)
2160       t)))
2161
2162 (defun elpher-org-follow-link (link protocol)
2163   "Visit a LINK for the given PROTOCOL.
2164
2165 PROTOCOL may be one of gemini, gopher or finger.  This method also
2166 supports the old protocol elpher, where the link is self-contained."
2167   (let ((url (if (equal protocol "elpher")
2168                  (string-remove-prefix "elpher:" link)
2169                (format "%s:%s" protocol link))))
2170     (elpher-go url)))
2171
2172 (defun elpher-org-mode-integration ()
2173   "Set up `elpher' integration for `org-mode'."
2174   (org-link-set-parameters
2175    "elpher"
2176    :store #'elpher-org-store-link
2177    :export (lambda (link description format _plist)
2178              (elpher-org-export-link link description format "elpher"))
2179    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2180   (org-link-set-parameters
2181    "gemini"
2182    :export (lambda (link description format _plist)
2183              (elpher-org-export-link link description format "gemini"))
2184    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2185   (org-link-set-parameters
2186    "gopher"
2187    :export (lambda (link description format _plist)
2188              (elpher-org-export-link link description format "gopher"))
2189    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2190   (org-link-set-parameters
2191    "finger"
2192    :export (lambda (link description format _plist)
2193              (elpher-org-export-link link description format "finger"))
2194    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2195
2196 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2197
2198 ;; Browse URL
2199
2200 ;;;###autoload
2201 (defun elpher-browse-url-elpher (url &rest _args)
2202   "Browse URL using Elpher.  This function is used by `browse-url'."
2203   (interactive (browse-url-interactive-arg "Elpher URL: "))
2204   (elpher-go url))
2205
2206 ;; Use elpher to open gopher, finger and gemini links
2207 ;; For recent version of `browse-url' package
2208 (if (boundp 'browse-url-default-handlers)
2209     (add-to-list
2210      'browse-url-default-handlers
2211      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2212   ;; Patch `browse-url-browser-function' for older ones. The value of
2213   ;; that variable is `browse-url-default-browser' by default, so
2214   ;; that's the function that gets advised. If the value is an alist,
2215   ;; however, we don't know what to do. Better not interfere?
2216   (when (and (symbolp browse-url-browser-function)
2217              (fboundp browse-url-browser-function))
2218     (advice-add browse-url-browser-function :before-while
2219                 (lambda (url &rest _args)
2220                   "Handle gemini, gopher, and finger schemes using Elpher."
2221                   (let ((scheme (downcase (car (split-string url ":" t)))))
2222                     (if (member scheme '("gemini" "gopher" "finger"))
2223                         ;; `elpher-go' always returns nil, which will stop the
2224                         ;; advice chain here in a before-while
2225                         (elpher-go url)
2226                       ;; chain must continue, then return t.
2227                       t))))))
2228
2229 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2230 (with-eval-after-load 'thingatpt
2231   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2232
2233 ;; Mu4e:
2234
2235 ;; Make mu4e aware of the gemini world
2236 (setq mu4e~view-beginning-of-url-regexp
2237       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2238
2239 ;; eww:
2240
2241 ;; Let elpher handle gemini, gopher links in eww buffer.
2242 (setq eww-use-browse-url
2243       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2244
2245
2246 ;;; Interactive procedures
2247 ;;
2248
2249 (defun elpher-next-link ()
2250   "Move point to the next link on the current page."
2251   (interactive)
2252   (forward-button 1))
2253
2254 (defun elpher-prev-link ()
2255   "Move point to the previous link on the current page."
2256   (interactive)
2257   (backward-button 1))
2258
2259 (defun elpher-follow-current-link ()
2260   "Open the link or url at point."
2261   (interactive)
2262   (push-button))
2263
2264 ;;;###autoload
2265 (defun elpher-go (host-or-url)
2266   "Go to a particular gopher site HOST-OR-URL.
2267 When run interactively HOST-OR-URL is read from the minibuffer."
2268   (interactive (list
2269                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2270   (let ((trimmed-host-or-url (string-trim host-or-url)))
2271     (unless (string-empty-p trimmed-host-or-url)
2272       (let ((page (elpher-page-from-url trimmed-host-or-url
2273                                         (elpher-get-default-url-scheme))))
2274         (unless (get-buffer-window elpher-buffer-name t)
2275           (switch-to-buffer elpher-buffer-name))
2276         (elpher-with-clean-buffer
2277          (elpher-visit-page page))
2278         nil)))) ; non-nil value is displayed by eshell
2279
2280 (defun elpher-go-current ()
2281   "Go to a particular URL which is read from the minibuffer.
2282 Unlike `elpher-go', the reader is initialized with the URL of the
2283 current page."
2284   (interactive)
2285   (let* ((address (elpher-page-address elpher-current-page))
2286          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2287                            (elpher-address-to-url address))))
2288     (unless (string-empty-p (string-trim url))
2289       (elpher-visit-page (elpher-page-from-url url)))))
2290
2291 (defun elpher-redraw ()
2292   "Redraw current page."
2293   (interactive)
2294   (elpher-visit-page elpher-current-page))
2295
2296 (defun elpher-reload ()
2297   "Reload current page."
2298   (interactive)
2299   (elpher-reload-current-page))
2300
2301 (defun elpher-toggle-tls ()
2302   "Toggle TLS encryption mode for gopher."
2303   (interactive)
2304   (setq elpher-use-tls (not elpher-use-tls))
2305   (if elpher-use-tls
2306       (if (gnutls-available-p)
2307           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2308         (setq elpher-use-tls nil)
2309         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2310     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2311
2312 (defun elpher-view-raw ()
2313   "View raw server response for current page."
2314   (interactive)
2315   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2316       (error "This page was not generated by a server")
2317     (elpher-visit-page elpher-current-page
2318                        #'elpher-render-raw)))
2319
2320 (defun elpher-back ()
2321   "Go to previous site."
2322   (interactive)
2323   (elpher-visit-previous-page))
2324
2325 (defun elpher-back-to-start ()
2326   "Go all the way back to the start page."
2327   (interactive)
2328   (setq-local elpher-current-page nil)
2329   (setq-local elpher-history nil)
2330   (elpher-visit-page (elpher-make-start-page)))
2331
2332 (defun elpher-download ()
2333   "Download the link at point."
2334   (interactive)
2335   (let ((button (button-at (point))))
2336     (if button
2337         (let ((page (button-get button 'elpher-page)))
2338           (unless page
2339             (error "Not an elpher page"))
2340           (when (elpher-address-about-p (elpher-page-address page))
2341             (error "Cannot download %s" (elpher-page-display-string page)))
2342           (elpher-visit-page (button-get button 'elpher-page)
2343                              #'elpher-render-download))
2344       (error "No link selected"))))
2345
2346 (defun elpher-download-current ()
2347   "Download the current page."
2348   (interactive)
2349   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2350       (error "Cannot download %s"
2351              (elpher-page-display-string elpher-current-page))
2352     (elpher-visit-page (elpher-make-page
2353                         (elpher-page-display-string elpher-current-page)
2354                         (elpher-page-address elpher-current-page))
2355                        #'elpher-render-download
2356                        t)))
2357
2358 (defun elpher--build-link-map ()
2359   "Build alist mapping link names to destination pages in current buffer."
2360   (let ((link-map nil)
2361         (b (next-button (point-min) t)))
2362     (while b
2363       (push (cons (button-label b) b) link-map)
2364       (setq b (next-button (button-start b))))
2365     link-map))
2366
2367 (defun elpher-jump ()
2368   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2369   (interactive)
2370   (let* ((link-map (elpher--build-link-map)))
2371     (if link-map
2372         (let ((key (let ((completion-ignore-case t))
2373                      (completing-read "Directory item/link: "
2374                                       link-map nil t))))
2375           (if (and key (> (length key) 0))
2376               (let ((b (cdr (assoc key link-map))))
2377                 (goto-char (button-start b))
2378                 (button-activate b)))))))
2379
2380 (defun elpher-root-dir ()
2381   "Visit root of current server."
2382   (interactive)
2383   (let ((address (elpher-page-address elpher-current-page)))
2384     (if (not (elpher-address-about-p address))
2385         (if (or (member (url-filename address) '("/" ""))
2386                 (and (elpher-address-gopher-p address)
2387                      (= (length (elpher-gopher-address-selector address)) 0)))
2388             (error "Already at root directory of current server")
2389           (let ((address-copy (elpher-address-from-url
2390                                (elpher-address-to-url address))))
2391             (setf (url-filename address-copy) "")
2392             (elpher-go (elpher-address-to-url address-copy))))
2393       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2394
2395 (defun elpher-info-page (page)
2396   "Display URL of PAGE in minibuffer."
2397   (let* ((address (elpher-page-address page))
2398          (url (elpher-address-to-url address))
2399          (iri (elpher-address-to-iri address)))
2400     (if (equal url iri)
2401         (message "%s" url)
2402       (message "%s (Raw: %s)" iri url))))
2403
2404 (defun elpher-info-link ()
2405   "Display information on page corresponding to link at point."
2406   (interactive)
2407   (let ((button (button-at (point))))
2408     (unless button
2409       (error "No item selected"))
2410     (let ((page (button-get button 'elpher-page)))
2411       (unless page
2412         (error "Not an elpher page"))
2413       (elpher-info-page page))))
2414
2415 (defun elpher-info-current ()
2416   "Display information on current page."
2417   (interactive)
2418   (elpher-info-page elpher-current-page))
2419
2420 (defun elpher-copy-page-url (page)
2421   "Copy URL representation of address of PAGE to `kill-ring'."
2422   (let* ((address (elpher-page-address page))
2423          (url (elpher-address-to-url address)))
2424     (message "Copied \"%s\" to kill-ring/clipboard." url)
2425     (kill-new url)))
2426
2427 (defun elpher-copy-link-url ()
2428   "Copy URL of item at point to `kill-ring'."
2429   (interactive)
2430   (let ((button (button-at (point))))
2431     (unless button
2432       (error "No item selected"))
2433     (let ((page (button-get button 'elpher-page)))
2434       (unless page
2435         (error "Not an elpher page"))
2436       (elpher-copy-page-url page))))
2437
2438 (defun elpher-copy-current-url ()
2439   "Copy URL of current page to `kill-ring'."
2440   (interactive)
2441   (elpher-copy-page-url elpher-current-page))
2442
2443 (defun elpher-set-gopher-coding-system ()
2444   "Specify an explicit character coding system for gopher selectors."
2445   (interactive)
2446   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2447     (setq elpher-user-coding-system system)
2448     (if system
2449         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2450       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2451
2452
2453 ;;; Mode and keymap
2454 ;;
2455
2456 (defvar elpher-mode-map
2457   (let ((map (make-sparse-keymap)))
2458     (define-key map (kbd "TAB") 'elpher-next-link)
2459     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2460     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2461     (define-key map (kbd "u") 'elpher-back)
2462     (define-key map (kbd "-") 'elpher-back)
2463     (define-key map (kbd "^") 'elpher-back)
2464     (define-key map [mouse-3] 'elpher-back)
2465     (define-key map (kbd "U") 'elpher-back-to-start)
2466     (define-key map (kbd "g") 'elpher-go)
2467     (define-key map (kbd "o") 'elpher-go-current)
2468     (define-key map (kbd "O") 'elpher-root-dir)
2469     (define-key map (kbd "s") 'elpher-show-history)
2470     (define-key map (kbd "S") 'elpher-show-visited-pages)
2471     (define-key map (kbd "r") 'elpher-redraw)
2472     (define-key map (kbd "R") 'elpher-reload)
2473     (define-key map (kbd "T") 'elpher-toggle-tls)
2474     (define-key map (kbd ".") 'elpher-view-raw)
2475     (define-key map (kbd "d") 'elpher-download)
2476     (define-key map (kbd "D") 'elpher-download-current)
2477     (define-key map (kbd "m") 'elpher-jump)
2478     (define-key map (kbd "i") 'elpher-info-link)
2479     (define-key map (kbd "I") 'elpher-info-current)
2480     (define-key map (kbd "c") 'elpher-copy-link-url)
2481     (define-key map (kbd "C") 'elpher-copy-current-url)
2482     (define-key map (kbd "a") 'elpher-bookmark-link)
2483     (define-key map (kbd "A") 'elpher-bookmark-current)
2484     (define-key map (kbd "B") 'elpher-show-bookmarks)
2485     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2486     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2487     (when (fboundp 'evil-define-key*)
2488       (evil-define-key*
2489        'motion map
2490        (kbd "TAB") 'elpher-next-link
2491        (kbd "C-") 'elpher-follow-current-link
2492        (kbd "C-t") 'elpher-back
2493        (kbd "u") 'elpher-back
2494        (kbd "-") 'elpher-back
2495        (kbd "^") 'elpher-back
2496        [mouse-3] 'elpher-back
2497        (kbd "U") 'elpher-back-to-start
2498        (kbd "g") 'elpher-go
2499        (kbd "o") 'elpher-go-current
2500        (kbd "O") 'elpher-root-dir
2501        (kbd "s") 'elpher-show-history
2502        (kbd "S") 'elpher-show-visited-pages
2503        (kbd "r") 'elpher-redraw
2504        (kbd "R") 'elpher-reload
2505        (kbd "T") 'elpher-toggle-tls
2506        (kbd ".") 'elpher-view-raw
2507        (kbd "d") 'elpher-download
2508        (kbd "D") 'elpher-download-current
2509        (kbd "m") 'elpher-jump
2510        (kbd "i") 'elpher-info-link
2511        (kbd "I") 'elpher-info-current
2512        (kbd "c") 'elpher-copy-link-url
2513        (kbd "C") 'elpher-copy-current-url
2514        (kbd "a") 'elpher-bookmark-link
2515        (kbd "A") 'elpher-bookmark-current
2516        (kbd "B") 'elpher-show-bookmarks
2517        (kbd "!") 'elpher-set-gopher-coding-system
2518        (kbd "F") 'elpher-forget-current-certificate))
2519     map)
2520   "Keymap for gopher client.")
2521
2522 (define-derived-mode elpher-mode special-mode "elpher"
2523   "Major mode for elpher, an elisp gopher client.
2524
2525 This mode is automatically enabled by the interactive
2526 functions which initialize the client, namely
2527 `elpher', and `elpher-go'."
2528   (setq-local elpher-current-page nil)
2529   (setq-local elpher-history nil)
2530   (setq-local elpher-buffer-name (buffer-name))
2531   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2532   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2533
2534 (when (fboundp 'evil-set-initial-state)
2535   (evil-set-initial-state 'elpher-mode 'motion))
2536
2537
2538 ;;; Main start procedure
2539 ;;
2540
2541 ;;;###autoload
2542 (defun elpher (&optional arg)
2543   "Start elpher with default landing page.
2544 The buffer used for Elpher sessions is determined by the value of
2545 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2546 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2547 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2548 \\[execute-extended-command] elpher RET’) switches to the session with
2549 that number, creating it if necessary.  A non numeric prefix ARG means
2550 to create a new session.  Returns the buffer selected (or created)."
2551   (interactive "P")
2552   (let* ((name (default-value 'elpher-buffer-name))
2553          (buf (cond ((numberp arg)
2554                      (get-buffer-create (format "%s<%d>" name arg)))
2555                     (arg
2556                      (generate-new-buffer name))
2557                     (t
2558                      (get-buffer-create name)))))
2559     (pop-to-buffer-same-window buf)
2560     (unless (buffer-modified-p)
2561       (elpher-mode)
2562       (elpher-visit-page (elpher-make-start-page))
2563       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2564
2565 ;;; elpher.el ends here