elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2023 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.5.0
   9 ;; Keywords: comm gopher gemini
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69 (require 'rx)
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "3.5.0"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 (defcustom elpher-certificate-map nil
 245   "Register client certificates to be used for gemini URLs.
 246 This variable contains an alist representing a mapping between gemini
 247 URLs and the names of client certificates which will be automatically
 248 activated for those URLs.  Beware that the certificates will also be
 249 active for all subdirectories of the given URLs."
 250   :type '(alist :key-type string :value-type string))
 251
 252 ;; Face customizations
 253
 254 (defgroup elpher-faces nil
 255   "Elpher face customizations."
 256   :group 'elpher)
 257
 258 (defface elpher-index
 259   '((t :inherit font-lock-keyword-face))
 260   "Face used for directory type directory records.")
 261
 262 (defface elpher-text
 263   '((t :inherit bold))
 264   "Face used for text type directory records.")
 265
 266 (defface elpher-info
 267   '((t :inherit default))
 268   "Face used for info type directory records.")
 269
 270 (defface elpher-image
 271   '((t :inherit font-lock-string-face))
 272   "Face used for image type directory records.")
 273
 274 (defface elpher-search
 275   '((t :inherit warning))
 276   "Face used for search type directory records.")
 277
 278 (defface elpher-html
 279   '((t :inherit font-lock-comment-face))
 280   "Face used for html type directory records.")
 281
 282 (defface elpher-gemini
 283   '((t :inherit font-lock-constant-face))
 284   "Face used for Gemini type directory records.")
 285
 286 (defface elpher-other-url
 287   '((t :inherit font-lock-comment-face))
 288   "Face used for other URL type links records.")
 289
 290 (defface elpher-telnet
 291   '((t :inherit font-lock-function-name-face))
 292   "Face used for telnet type directory records.")
 293
 294 (defface elpher-binary
 295   '((t :inherit font-lock-doc-face))
 296   "Face used for binary type directory records.")
 297
 298 (defface elpher-unknown
 299   '((t :inherit error))
 300   "Face used for directory records with unknown/unsupported types.")
 301
 302 (defface elpher-margin-key
 303   '((t :inherit bold))
 304   "Face used for directory margin key.")
 305
 306 (defface elpher-margin-brackets
 307   '((t :inherit shadow))
 308   "Face used for brackets around directory margin key.")
 309
 310 (defface elpher-gemini-heading1
 311   '((t :inherit bold :height 1.8))
 312   "Face used for gemini heading level 1.")
 313
 314 (defface elpher-gemini-heading2
 315   '((t :inherit bold :height 1.5))
 316   "Face used for gemini heading level 2.")
 317
 318 (defface elpher-gemini-heading3
 319   '((t :inherit bold :height 1.2))
 320   "Face used for gemini heading level 3.")
 321
 322 (defface elpher-gemini-quoted
 323   '((t :inherit font-lock-doc-face))
 324   "Face used for gemini quoted texts.")
 325
 326 (defface elpher-gemini-preformatted
 327   '((t :inherit default))
 328   "Face used for gemini preformatted text.")
 329
 330 (defface elpher-gemini-preformatted-toggle
 331   '((t :inherit button))
 332   "Face used for buttons used to toggle display of preformatted text.")
 333
 334 ;;; Model
 335 ;;
 336
 337 ;; Address
 338
 339 ;; An elpher "address" object is either a url object or a symbol.
 340 ;; Addresses with the "about" type, corresponding to pages generated
 341 ;; dynamically for and by elpher.  All others represent pages which
 342 ;; rely on content retrieved over the network.
 343
 344 (defun elpher-address-from-url (url-string &optional default-scheme)
 345   "Create a ADDRESS object corresponding to the given URL-STRING.
 346 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 347 is not explicitly given."
 348   (let ((data (match-data))) ; Prevent parsing clobbering match data
 349     (unwind-protect
 350         (let ((url (url-generic-parse-url url-string)))
 351           (unless (and (not (url-fullness url)) (url-type url))
 352             (unless (url-type url)
 353               (setf (url-type url) default-scheme))
 354             (unless (url-host url)
 355               (let ((p (split-string (url-filename url) "/" nil nil)))
 356                 (setf (url-host url) (car p))
 357                 (setf (url-filename url)
 358                       (if (cdr p)
 359                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 360                         ""))))
 361             (when (not (string-empty-p (url-host url)))
 362               (setf (url-fullness url) t)
 363               (setf (url-host url) (puny-encode-domain (url-host url))))
 364             (when (or (equal "gopher" (url-type url))
 365                       (equal "gophers" (url-type url)))
 366               ;; Gopher defaults
 367               (when (or (equal (url-filename url) "")
 368                         (equal (url-filename url) "/"))
 369                 (setf (url-filename url) "/1")))
 370             (when (equal "gemini" (url-type url))
 371               ;; Gemini defaults
 372               (if (equal (url-filename url) "")
 373                   (setf (url-filename url) "/"))))
 374           (elpher-remove-redundant-ports url))
 375       (set-match-data data))))
 376
 377 (defun elpher-remove-redundant-ports (address)
 378   "Remove redundant port specifiers from ADDRESS.
 379 Here 'redundant' means that the specified port matches the default
 380 for that protocol, eg 70 for gopher."
 381   (if (and (not (elpher-address-about-p address))
 382            (eq (url-portspec address) ; (url-port) is too slow!
 383                (pcase (url-type address)
 384                  ("gemini" 1965)
 385                  ((or "gopher" "gophers") 70)
 386                  ("finger" 79)
 387                  (_ -1))))
 388       (setf (url-portspec address) nil))
 389   address)
 390
 391 (defun elpher-make-gopher-address (type selector host port &optional tls)
 392   "Create an ADDRESS object using gopher directory record attributes.
 393 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 394 If the optional attribute TLS is non-nil, the address will be marked as
 395 requiring gopher-over-TLS."
 396   (cond
 397    ((equal type ?i) nil)
 398    ((and (equal type ?h)
 399          (string-prefix-p "URL:" selector))
 400     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 401    ((equal type ?8)
 402     (elpher-address-from-url
 403      (concat "telnet"
 404              "://" host
 405              ":" (number-to-string port))))
 406    (t
 407     (elpher-address-from-url
 408      (concat "gopher" (if tls "s" "")
 409              "://" host
 410              ":" (number-to-string port)
 411              "/" (string type)
 412              selector)))))
 413
 414 (defun elpher-make-about-address (type)
 415   "Create an ADDRESS object corresponding to the given about address TYPE."
 416   (elpher-address-from-url (concat "about:" (symbol-name type))))
 417
 418 (defun elpher-address-to-url (address)
 419   "Get string representation of ADDRESS."
 420   (url-encode-url (url-recreate-url address)))
 421
 422 (defun elpher-address-type (address)
 423   "Retrieve type of ADDRESS object.
 424 This is used to determine how to retrieve and render the document the
 425 address refers to, via the table `elpher-type-map'."
 426   (pcase (url-type address)
 427     ("about"
 428      (list 'about (intern (url-filename address))))
 429     ((or "gopher" "gophers")
 430      (list 'gopher
 431            (if (member (url-filename address) '("" "/"))
 432                ?1
 433              (string-to-char (substring (url-filename address) 1)))))
 434     ("gemini" 'gemini)
 435     ("telnet" 'telnet)
 436     ("finger" 'finger)
 437     ("file" 'file)
 438     (_ 'other-url)))
 439
 440 (defun elpher-address-about-p (address)
 441   "Return non-nil if ADDRESS is an about address."
 442   (pcase (elpher-address-type address) (`(about ,_) t)))
 443
 444 (defun elpher-address-gopher-p (address)
 445   "Return non-nil if ADDRESS object is a gopher address."
 446   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 447
 448 (defun elpher-address-protocol (address)
 449   "Retrieve the transport protocol for ADDRESS."
 450   (url-type address))
 451
 452 (defun elpher-address-filename (address)
 453   "Retrieve the filename component of ADDRESS.
 454 For gopher addresses this is a combination of the selector type and selector."
 455   (url-unhex-string (url-filename address)))
 456
 457 (defun elpher-address-host (address)
 458   "Retrieve host from ADDRESS object."
 459   (pcase (url-host address)
 460     ;; The following strips out square brackets which sometimes enclose IPv6
 461     ;; addresses.  Doing this here rather than at the parsing stage may seem
 462     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 463     ;; and reconstruction.  It's also more efficient, as this method is not
 464     ;; called during page rendering.
 465     ((rx (: "[" (let ipv6 (* (not "]"))) "]"))
 466      ipv6)
 467     ;; The following is a work-around for a parsing bug that causes
 468     ;; URLs with empty (but not absent, see RFC 1738) usernames to have
 469     ;; @ prepended to the hostname.
 470     ((rx (: "@" (let rest (+ anything))))
 471      rest)
 472     (addr
 473      addr)))
 474
 475 (defun elpher-address-user (address)
 476   "Retrieve user from ADDRESS object."
 477   (url-user address))
 478
 479 (defun elpher-address-port (address)
 480   "Retrieve port from ADDRESS object.
 481 If no address is defined, returns 0.  (This is for compatibility with
 482 the URL library.)"
 483   (let ((port (url-portspec address))) ; (url-port) is too slow!
 484     (if port port 0)))
 485
 486 (defun elpher-gopher-address-selector (address)
 487   "Retrieve gopher selector from ADDRESS object."
 488   (if (member (url-filename address) '("" "/"))
 489       ""
 490     (url-unhex-string (substring (url-filename address) 2))))
 491
 492
 493 ;; Cache
 494
 495 (defvar elpher-content-cache (make-hash-table :test 'equal))
 496 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 497
 498 (defun elpher-get-cached-content (address)
 499   "Retrieve the cached content for ADDRESS, or nil if none exists."
 500   (gethash address elpher-content-cache))
 501
 502 (defun elpher-cache-content (address content)
 503   "Set the content cache for ADDRESS to CONTENT."
 504   (puthash address content elpher-content-cache))
 505
 506 (defun elpher-get-cached-pos (address)
 507   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 508   (gethash address elpher-pos-cache))
 509
 510 (defun elpher-cache-pos (address pos)
 511   "Set the cursor position cache for ADDRESS to POS."
 512   (puthash address pos elpher-pos-cache))
 513
 514
 515 ;; Page
 516
 517 (defun elpher-make-page (display-string address)
 518   "Create a page with DISPLAY-STRING and ADDRESS."
 519   (list display-string address))
 520
 521 (defun elpher-make-start-page ()
 522   "Create the start page."
 523   (elpher-make-page "Start Page"
 524                     (elpher-address-from-url elpher-start-page-url)))
 525
 526 (defun elpher-page-display-string (page)
 527   "Retrieve the display string corresponding to PAGE."
 528   (elt page 0))
 529
 530 (defun elpher-page-address (page)
 531   "Retrieve the address corresponding to PAGE."
 532   (elt page 1))
 533
 534 (defun elpher-page-set-address (page new-address)
 535   "Set the address corresponding to PAGE to NEW-ADDRESS."
 536   (setcar (cdr page) new-address))
 537
 538 (defun elpher-page-from-url (url &optional default-scheme)
 539   "Create a page with address and display string defined by URL.
 540 The URL is unhexed prior to its use as a display string to improve
 541 readability.
 542
 543 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 544 in the instance that URL itself doesn't specify one."
 545   (let ((address (elpher-address-from-url url default-scheme)))
 546     (elpher-make-page (elpher-address-to-iri address) address)))
 547
 548 (defun elpher-address-to-iri (address)
 549   "Return an IRI for ADDRESS.
 550 Decode percent-escapes and handle punycode in the domain name.
 551 Drop the password, if any."
 552   (let ((data (match-data)) ; Prevent parsing clobbering match data
 553         (host (url-host address))
 554         (pass (url-password address)))
 555     (unwind-protect
 556         (let* ((host (url-host address))
 557                (pass (url-password address)))
 558           (when host
 559             (setf (url-host address) (puny-decode-domain host)))
 560           (when pass                             ; RFC 3986 says we should not render
 561             (setf (url-password address) nil)) ; the password as clear text
 562           (elpher-decode (url-unhex-string (url-recreate-url address))))
 563       (setf (url-host address) host)
 564       (setf (url-password address) pass)
 565       (set-match-data data))))
 566
 567 (defvar elpher-current-page nil
 568   "The current page for this Elpher buffer.")
 569
 570 (defvar elpher-history nil
 571   "The local history stack for this Elpher buffer.
 572 This variable is used by `elpher-back' and
 573 `elpher-show-history'.")
 574
 575 (defvar elpher-visited-pages nil
 576   "The global history for all Elpher buffers.
 577 This variable is used by `elpher-show-visited-pages'.")
 578
 579 (defun elpher-visit-page (page &optional renderer no-history)
 580   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 581 Additionally, push PAGE onto the history stack and the list of
 582 previously-visited pages, unless NO-HISTORY is non-nil."
 583   (elpher-save-pos)
 584   (elpher-process-cleanup)
 585   (unless no-history
 586     (unless (or (not elpher-current-page)
 587                  (equal (elpher-page-address elpher-current-page)
 588                         (elpher-page-address page)))
 589       (push elpher-current-page elpher-history)
 590       (unless (or (elpher-address-about-p (elpher-page-address page))
 591                   (and elpher-visited-pages
 592                        (equal page (car elpher-visited-pages))))
 593         (push page elpher-visited-pages))))
 594   (setq-local elpher-current-page page)
 595   (let* ((address (elpher-page-address page))
 596          (type (elpher-address-type address))
 597          (type-record (cdr (assoc type elpher-type-map))))
 598     (if type-record
 599         (funcall (car type-record)
 600                  (if renderer
 601                      renderer
 602                    (cadr type-record)))
 603       (elpher-visit-previous-page)
 604       (pcase type
 605         (`(gopher ,type-char)
 606          (error "Unsupported gopher selector type '%c' for '%s'"
 607                 type-char (elpher-address-to-url address)))
 608         (other
 609          (error "Unsupported address type '%S' for '%s'"
 610                 other (elpher-address-to-url address)))))))
 611
 612 (defun elpher-visit-previous-page ()
 613   "Visit the previous page in the history."
 614   (if elpher-history
 615       (elpher-visit-page (pop elpher-history) nil t)
 616     (error "No previous page")))
 617
 618 (defun elpher-reload-current-page ()
 619   "Reload the current page, discarding any existing cached content."
 620   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 621   (elpher-visit-page elpher-current-page))
 622
 623 (defun elpher-save-pos ()
 624   "Save the current position of point to the current page."
 625   (when elpher-current-page
 626     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 627
 628 (defun elpher-restore-pos ()
 629   "Restore the position of point to that cached in the current page."
 630   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 631     (if pos
 632         (goto-char pos)
 633       (goto-char (point-min)))))
 634
 635 (defun elpher-get-default-url-scheme ()
 636   "Suggest default URL scheme for visiting addresses based on the current page."
 637   (if elpher-current-page
 638       (let* ((address (elpher-page-address elpher-current-page))
 639              (current-type (elpher-address-type address)))
 640         (pcase current-type
 641           ((or (and 'file (guard (not elpher-history)))
 642                `(about ,_))
 643            elpher-default-url-type)
 644           (_
 645            (url-type address))))
 646       elpher-default-url-type))
 647
 648
 649 ;;; Buffer preparation
 650 ;;
 651
 652 (defvar elpher-buffer-name "*elpher*"
 653   "The default name of the Elpher buffer.")
 654
 655 (defun elpher-update-header ()
 656   "If `elpher-use-header' is true, display current page info in window header."
 657   (if (and elpher-use-header elpher-current-page)
 658       (let* ((display-string (elpher-page-display-string elpher-current-page))
 659              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 660              (address (elpher-page-address elpher-current-page))
 661              (tls-string (if (and (not (elpher-address-about-p address))
 662                                   (member (elpher-address-protocol address)
 663                                           '("gophers" "gemini")))
 664                              " [TLS encryption]"
 665                            ""))
 666              (header (concat sanitized-display-string
 667                              (propertize tls-string 'face 'bold))))
 668         (setq header-line-format header))))
 669
 670 (defmacro elpher-with-clean-buffer (&rest args)
 671   "Evaluate ARGS with a clean *elpher* buffer as current."
 672   (declare (debug (body))) ;; Allow edebug to step through body
 673   `(with-current-buffer elpher-buffer-name
 674      (unless (eq major-mode 'elpher-mode)
 675        ;; avoid resetting buffer-local variables
 676        (elpher-mode))
 677      (let ((inhibit-read-only t)
 678            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 679        (setq-local xterm-color--current-fg nil)
 680        (setq-local xterm-color--current-bg nil)
 681        (setq-local network-security-level
 682                    (default-value 'network-security-level))
 683        (erase-buffer)
 684        (elpher-update-header)
 685        ,@args)))
 686
 687 (defun elpher-buffer-message (string &optional line)
 688   "Replace first line in elpher buffer with STRING.
 689 If LINE is non-nil, replace that line instead."
 690   (with-current-buffer elpher-buffer-name
 691     (let ((inhibit-read-only t))
 692       (goto-char (point-min))
 693       (if line
 694           (forward-line line))
 695       (let ((data (match-data)))
 696         (unwind-protect
 697             (progn
 698               (re-search-forward "^.*$")
 699               (replace-match string))
 700           (set-match-data data))))))
 701
 702
 703 ;;; Text Processing
 704 ;;
 705
 706 (defvar elpher-user-coding-system nil
 707   "User-specified coding system to use for decoding text responses.")
 708
 709 (defun elpher-decode (string)
 710   "Decode STRING using autodetected or user-specified coding system."
 711   (decode-coding-string string
 712                         (if elpher-user-coding-system
 713                             elpher-user-coding-system
 714                           (detect-coding-string string t))))
 715
 716 (defun elpher-preprocess-text-response (string)
 717   "Preprocess text selector response contained in STRING.
 718 This involes decoding the character representation, and clearing
 719 away CRs and any terminating period."
 720   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 721                                            (replace-regexp-in-string "\r" "" string))))
 722
 723 ;;; Buttonify urls
 724
 725 (defconst elpher-url-regex
 726   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 727   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 728
 729 (defun elpher-buttonify-urls (string)
 730   "Turn substrings which look like urls in STRING into clickable buttons."
 731   (with-temp-buffer
 732     (insert string)
 733     (goto-char (point-min))
 734     (while (re-search-forward elpher-url-regex nil t)
 735       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 736         (make-text-button (match-beginning 0)
 737                           (match-end 0)
 738                           'elpher-page  page
 739                           'action #'elpher-click-link
 740                           'follow-link t
 741                           'help-echo #'elpher--page-button-help
 742                           'face 'button)))
 743     (buffer-string)))
 744
 745
 746 ;; ANSI colors or XTerm colors (application and filtering)
 747
 748 (or (require 'xterm-color nil t)
 749     (require 'ansi-color))
 750
 751 (defalias 'elpher-color-filter-apply
 752   (if (fboundp 'xterm-color-filter)
 753       (lambda (s)
 754         (let ((_xterm-color-render nil))
 755           (xterm-color-filter s)))
 756     #'ansi-color-filter-apply)
 757   "A function to filter out ANSI escape sequences.")
 758
 759 (defalias 'elpher-color-apply
 760   (if (fboundp 'xterm-color-filter)
 761       #'xterm-color-filter
 762     #'ansi-color-apply)
 763   "A function to apply ANSI escape sequences.")
 764
 765 (defun elpher-text-has-ansi-escapes-p (string)
 766   "Return non-nil if STRING includes an ANSI escape code."
 767   (save-match-data
 768     (string-match "\x1b\\[" string)))
 769
 770
 771 ;; Processing text for display
 772
 773 (defun elpher-process-text-for-display (string)
 774   "Perform any desired processing of STRING prior to display as text.
 775 Currently includes buttonifying URLs and processing ANSI escape codes."
 776   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 777                              (if elpher-filter-ansi-from-text
 778                                  (elpher-color-filter-apply string)
 779                                (elpher-color-apply string))
 780                            string)))
 781
 782
 783 ;;; General network communication
 784 ;;
 785
 786 (defun elpher-network-error (address error)
 787   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 788 ERROR can be either an error object or a string."
 789   (elpher-with-clean-buffer
 790    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 791            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 792            (if (stringp error) error (error-message-string error)) "\n"
 793            (propertize "\n----------------\n\n" 'face 'error)
 794            "Press 'u' to return to the previous page.")))
 795
 796
 797 (defvar elpher-network-timer nil
 798   "Timer used for network connections.")
 799
 800 (defvar elpher-use-tls nil
 801   "If non-nil, use TLS to communicate with gopher servers.")
 802
 803 (defvar elpher-client-certificate nil
 804   "If non-nil, contains client certificate details to use for TLS connections.")
 805
 806 (defun elpher-process-cleanup ()
 807   "Immediately shut down any extant elpher process and timers."
 808   (let ((p (get-process "elpher-process")))
 809     (if p (delete-process p)))
 810   (if (timerp elpher-network-timer)
 811       (cancel-timer elpher-network-timer)))
 812
 813 (defun elpher-make-network-timer (thunk)
 814   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 815 This is just a wraper around `run-at-time' which additionally sets the
 816 buffer-local variable `elpher-network-timer' to allow
 817 `elpher-process-cleanup' to also clear the timer."
 818   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 819     (setq-local elpher-network-timer timer)
 820     timer))
 821
 822 (defun elpher-get-host-response (address default-port query-string response-processor
 823                                          &optional use-tls force-ipv4)
 824   "Generic function for retrieving data from ADDRESS.
 825
 826 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 827 QUERY-STRING is a string sent to the host specified by ADDRESS to
 828 illicet a response.  This response is passed as an argument to the
 829 function RESPONSE-PROCESSOR.
 830
 831 If non-nil, USE-TLS specifies that the connection is to be made over
 832 TLS.  If set to gemini, the certificate verification will be disabled
 833 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 834
 835 If non-nil, FORCE-IPV4 causes the network connection to be made over
 836 ipv4 only.  (The default behaviour when this is not set depends on
 837 the host operating system and the local network capabilities.)"
 838   (if (and use-tls (not (gnutls-available-p)))
 839       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 840     (unless (< (elpher-address-port address) 65536)
 841       (error "Cannot establish network connection: port number > 65536"))
 842     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 843       (setq-local network-security-level 'low)
 844       (setq-local gnutls-verify-error nil))
 845     (condition-case nil
 846         (let* ((kill-buffer-query-functions nil)
 847                (port (elpher-address-port address))
 848                (host (elpher-address-host address))
 849                (service (if (> port 0) port default-port))
 850                (response-string-parts nil)
 851                (bytes-received 0)
 852                (hkbytes-received 0)
 853                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 854                (gnutls-params (list :type 'gnutls-x509pki
 855                                     :hostname host
 856                                     :keylist
 857                                     (elpher-get-current-keylist address)))
 858                (timer (elpher-make-network-timer
 859                                    (lambda ()
 860                                      (elpher-process-cleanup)
 861                                      (cond
 862                                         ; Try again with IPv4
 863                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 864                                        (message "Connection timed out.  Retrying with IPv4.")
 865                                        (elpher-get-host-response address default-port
 866                                                                  query-string
 867                                                                  response-processor
 868                                                                  use-tls t))
 869                                       ((and use-tls
 870                                             (not (eq use-tls 'gemini))
 871                                             (or elpher-auto-disengage-TLS
 872                                                 (y-or-n-p
 873                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 874                                        (setq elpher-use-tls nil)
 875                                        (elpher-get-host-response address default-port
 876                                                                  query-string
 877                                                                  response-processor
 878                                                                  nil force-ipv4))
 879                                       (t
 880                                        (elpher-network-error address "Connection time-out."))))))
 881                (proc (if socks
 882                          (socks-open-network-stream "elpher-process" nil host service)
 883                        (make-network-process :name "elpher-process"
 884                                              :host host
 885                                              :family (and (or force-ipv4
 886                                                               elpher-ipv4-always)
 887                                                           'ipv4)
 888                                              :service service
 889                                              :buffer nil
 890                                              :nowait t
 891                                              :tls-parameters
 892                                              (and use-tls
 893                                                   (cons 'gnutls-x509pki
 894                                                         (apply #'gnutls-boot-parameters
 895                                                                gnutls-params)))))))
 896           (process-put proc 'elpher-buffer (current-buffer))
 897           (setq elpher-network-timer timer)
 898           (set-process-coding-system proc 'binary 'binary)
 899           (set-process-query-on-exit-flag proc nil)
 900           (elpher-buffer-message (concat "Connecting to " host "..."
 901                                          " (press 'u' to abort)"))
 902           (set-process-filter proc
 903                               (lambda (_proc string)
 904                                 (when timer
 905                                   (cancel-timer timer)
 906                                   (setq timer nil))
 907                                 (setq bytes-received (+ bytes-received (length string)))
 908                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 909                                   (when (> new-hkbytes-received hkbytes-received)
 910                                     (setq hkbytes-received new-hkbytes-received)
 911                                     (elpher-buffer-message
 912                                      (concat "("
 913                                              (number-to-string (/ hkbytes-received 10.0))
 914                                              " MB read)")
 915                                      1)))
 916                                 (setq response-string-parts
 917                                       (cons string response-string-parts))))
 918           (set-process-sentinel proc
 919                                 (lambda (proc event)
 920                                   (when timer
 921                                     (cancel-timer timer))
 922                                   (condition-case the-error
 923                                       (cond
 924                                        ((string-prefix-p "open" event)    ; request URL
 925                                         (elpher-buffer-message
 926                                          (concat "Connected to " host ". Receiving data..."
 927                                                  " (press 'u' to abort)"))
 928                                         (let ((inhibit-eol-conversion t))
 929                                           (process-send-string proc query-string)))
 930                                        ((string-prefix-p "deleted" event)) ; do nothing
 931                                        ((and (not response-string-parts)
 932                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 933                                         ; Try again with IPv4
 934                                         (message "Connection failed. Retrying with IPv4.")
 935                                         (elpher-get-host-response address default-port
 936                                                                   query-string
 937                                                                   response-processor
 938                                                                   use-tls t))
 939                                        (response-string-parts
 940                                         (with-current-buffer (process-get proc 'elpher-buffer)
 941                                           (elpher-with-clean-buffer
 942                                            (insert "Data received.  Rendering..."))
 943                                           (funcall response-processor
 944                                                    (apply #'concat (reverse response-string-parts)))
 945                                           (elpher-restore-pos)))
 946                                        (t
 947                                         (error "No response from server")))
 948                                     (error
 949                                      (elpher-network-error address the-error)))))
 950           (when socks
 951             (if use-tls
 952                 (apply #'gnutls-negotiate :process proc gnutls-params))
 953             (funcall (process-sentinel proc) proc "open\n")))
 954       (error
 955        (elpher-process-cleanup)
 956        (error "Error initiating connection to server")))))
 957
 958
 959 ;;; Client-side TLS Certificate Management
 960 ;;
 961
 962 (defun elpher-generate-certificate (common-name key-file cert-file url-prefix
 963                                                 &optional temporary)
 964   "Generate a key and a self-signed client TLS certificate using openssl.
 965
 966 The Common Name field of the certificate is set to COMMON-NAME.  The
 967 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 968 the key and certificate files to write.
 969
 970 If TEMPORARY is non-nil, the certificate will be given an exporation
 971 period of one day, and the key and certificate files will be deleted
 972 when the certificate is no longer needed for the current session.
 973
 974 Otherwise, the certificate will be given a 100 year expiration period
 975 and the files will not be deleted.
 976
 977 The function returns a list containing the URL-PREFIX of addresses
 978 for which the certificate should be used in this session, the
 979 temporary flag, and the key and cert file names in the form required
 980 by `gnutls-boot-parameters`."
 981   (let ((exp-key-file (expand-file-name key-file))
 982         (exp-cert-file (expand-file-name cert-file)))
 983     (condition-case nil
 984         (progn
 985           (call-process elpher-openssl-command nil nil nil
 986                         "req" "-x509" "-newkey" "rsa:2048"
 987                         "-days" (if temporary "1" "36500")
 988                         "-nodes"
 989                         "-subj" (concat "/CN=" common-name)
 990                         "-keyout" exp-key-file
 991                         "-out" exp-cert-file)
 992           (list url-prefix temporary exp-key-file exp-cert-file))
 993       (error
 994        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 995        (error "Program 'openssl', required for certificate generation, not found")))))
 996
 997 (defun elpher-generate-throwaway-certificate (url-prefix)
 998   "Generate and return details of a throwaway certificate.
 999 The key and certificate files will be deleted when they are no
1000 longer needed for this session.
1001
1002 The certificate will be marked as applying to all addresses with URLs
1003 starting with URL-PREFIX."
1004   (let* ((file-base (make-temp-name "elpher"))
1005          (key-file (concat temporary-file-directory file-base ".key"))
1006          (cert-file (concat temporary-file-directory file-base ".crt")))
1007     (elpher-generate-certificate file-base key-file cert-file url-prefix t)))
1008
1009 (defun elpher-generate-persistent-certificate (file-base common-name url-prefix)
1010   "Generate and return details of a persistent certificate.
1011 The argument FILE-BASE is used as the base for the key and certificate
1012 files, while COMMON-NAME specifies the common name field of the
1013 certificate.
1014
1015 The key and certificate files are written to in `elpher-certificate-directory'.
1016
1017 In this session, the certificate will remain active for all addresses
1018 having URLs starting with URL-PREFIX."
1019   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1020          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1021     (elpher-generate-certificate common-name key-file cert-file url-prefix)))
1022
1023 (defun elpher-get-existing-certificate (file-base url-prefix)
1024   "Return a certificate object corresponding to an existing certificate.
1025 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1026 the directory `elpher-certificate-directory'.
1027
1028 In this session, the certificate will remain active for all addresses
1029 having URLs starting with URL-PREFIX."
1030   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1031          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1032     (list url-prefix
1033           nil
1034           (expand-file-name key-file)
1035           (expand-file-name cert-file))))
1036
1037 (defun elpher-install-certificate (key-file-src cert-file-src file-base url-prefix)
1038   "Install a key+certificate file pair in `elpher-certificate-directory'.
1039 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1040 certificate files to install.  The argument FILE-BASE is used as the
1041 base for the installed key and certificate files.
1042
1043 In this session, the certificate will remain active for all addresses
1044 having URLs starting with URL-PREFIX."
1045   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1046          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1047     (if (or (file-exists-p key-file)
1048             (file-exists-p cert-file))
1049         (error "A certificate with base name %s is already installed" file-base))
1050     (unless (and (file-exists-p key-file-src)
1051                  (file-exists-p cert-file-src))
1052       (error "Either of the key or certificate files do not exist"))
1053     (copy-file key-file-src key-file)
1054     (copy-file cert-file-src cert-file)
1055     (list url-prefix
1056           nil
1057           (expand-file-name key-file)
1058           (expand-file-name cert-file))))
1059
1060 (defun elpher-list-existing-certificates ()
1061   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1062   (unless (file-directory-p elpher-certificate-directory)
1063     (make-directory elpher-certificate-directory))
1064   (mapcar
1065    (lambda (file)
1066      (file-name-sans-extension file))
1067    (directory-files elpher-certificate-directory nil "\\.key$")))
1068
1069 (defun elpher-forget-current-certificate ()
1070   "Causes any current certificate to be forgotten.)
1071 In the case of throwaway certificates, the key and certificate files
1072 are also deleted."
1073   (interactive)
1074   (when elpher-client-certificate
1075     (unless (and (called-interactively-p 'any)
1076                  (not (y-or-n-p (concat "Really forget client certificate? "
1077                                         "(Throwaway certificates will be deleted.)"))))
1078       (when (cadr elpher-client-certificate)
1079         (delete-file (elt elpher-client-certificate 2))
1080         (delete-file (elt elpher-client-certificate 3)))
1081       (setq-local elpher-client-certificate nil)
1082       (if (called-interactively-p 'any)
1083           (message "Client certificate forgotten.")))))
1084
1085 (defun elpher-get-current-keylist (address)
1086   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1087
1088 This is obtained from the client certificate described by
1089 `elpher-current-certificate', if one is available and the
1090 URL prefix for that certificate matches ADDRESS.
1091
1092 If `elpher-current-certificate' is non-nil, and its URL prefix doesn't
1093 match that of ADDRESS, the certificate is forgotten."
1094   (if elpher-client-certificate
1095       (if (string-prefix-p (car elpher-client-certificate)
1096                            (elpher-address-to-url address))
1097           (list (cddr elpher-client-certificate))
1098         (elpher-forget-current-certificate)
1099         (message "Disabling client certificate for new host")
1100         nil)
1101     nil))
1102
1103
1104 ;;; Gopher selector retrieval
1105 ;;
1106
1107 (defun elpher-get-gopher-response (address renderer)
1108   "Get response string from gopher server at ADDRESS and render using RENDERER."
1109   (elpher-get-host-response address 70
1110                             (concat (elpher-gopher-address-selector address) "\r\n")
1111                             renderer
1112                             (or (string= (elpher-address-protocol address) "gophers")
1113                                 elpher-use-tls)))
1114
1115 (defun elpher-get-gopher-page (renderer)
1116   "Getter function for gopher pages.
1117 The RENDERER procedure is used to display the contents of the page
1118 once they are retrieved from the gopher server."
1119   (let* ((address (elpher-page-address elpher-current-page))
1120          (content (elpher-get-cached-content address)))
1121     (if (and content (funcall renderer nil))
1122         (elpher-with-clean-buffer
1123          (insert content)
1124          (elpher-restore-pos))
1125       (elpher-with-clean-buffer
1126        (insert "LOADING... (use 'u' to cancel)\n"))
1127       (condition-case the-error
1128           (elpher-get-gopher-response address renderer)
1129         (error
1130          (elpher-network-error address the-error))))))
1131
1132
1133 ;;; Gopher index rendering
1134 ;;
1135
1136 (defun elpher-insert-margin (&optional type-name)
1137   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1138   (if type-name
1139       (progn
1140         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1141                         (concat
1142                          (propertize "[" 'face 'elpher-margin-brackets)
1143                          (propertize type-name 'face 'elpher-margin-key)
1144                          (propertize "]" 'face 'elpher-margin-brackets))))
1145         (insert " "))
1146     (insert (make-string elpher-margin-width ?\s))))
1147
1148 (defun elpher--page-button-help (_window buffer pos)
1149   "Function called by Emacs to generate mouse-over text.
1150 The arguments specify the BUFFER and the POS within the buffer of the item
1151 for which help is required.  The function returns the help to be
1152 displayed.  The _WINDOW argument is currently unused."
1153   (with-current-buffer buffer
1154     (let ((button (button-at pos)))
1155       (when button
1156         (let* ((page (button-get button 'elpher-page))
1157                (address (elpher-page-address page)))
1158           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1159
1160 (defun elpher-insert-index-record (display-string &optional address)
1161   "Function to insert an index record into the current buffer.
1162 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1163 If ADDRESS is not supplied or nil the record is rendered as an
1164 'information' line."
1165   (let* ((type (if address (elpher-address-type address) nil))
1166          (type-map-entry (cdr (assoc type elpher-type-map))))
1167     (if type-map-entry
1168         (let* ((margin-code (elt type-map-entry 2))
1169                (face (elt type-map-entry 3))
1170                (filtered-display-string (elpher-color-filter-apply display-string))
1171                (page (elpher-make-page filtered-display-string address)))
1172           (elpher-insert-margin margin-code)
1173           (insert-text-button filtered-display-string
1174                               'face face
1175                               'elpher-page page
1176                               'action #'elpher-click-link
1177                               'follow-link t
1178                               'help-echo #'elpher--page-button-help))
1179       (pcase type
1180         ('nil ;; Information
1181          (elpher-insert-margin)
1182          (let ((propertized-display-string
1183                 (propertize display-string 'face 'elpher-info)))
1184            (insert (elpher-process-text-for-display propertized-display-string))))
1185         (`(gopher ,selector-type) ;; Unknown
1186          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1187          (insert (propertize display-string
1188                              'face 'elpher-unknown)))))
1189     (insert "\n")))
1190
1191 (defun elpher-click-link (button)
1192   "Function called when the gopher link BUTTON is activated."
1193   (let ((page (button-get button 'elpher-page)))
1194     (elpher-visit-page page)))
1195
1196 (defun elpher-render-index (data &optional _mime-type-string)
1197   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1198   (elpher-with-clean-buffer
1199    (if (not data)
1200        t
1201      (let ((data-processed (elpher-preprocess-text-response data)))
1202        (dolist (line (split-string data-processed "\n"))
1203          (ignore-errors
1204            (unless (= (length line) 0)
1205              (let* ((type (elt line 0))
1206                     (fields (split-string (substring line 1) "\t"))
1207                     (display-string (elt fields 0))
1208                     (selector (elt fields 1))
1209                     (host (elt fields 2))
1210                     (port (if (elt fields 3)
1211                               (string-to-number (elt fields 3))
1212                             nil))
1213                     (address (elpher-make-gopher-address type selector host port)))
1214                (elpher-insert-index-record display-string address))))))
1215      (elpher-cache-content (elpher-page-address elpher-current-page)
1216                            (buffer-string)))))
1217
1218
1219 ;;; Gopher text rendering
1220 ;;
1221
1222 (defun elpher-render-text (data &optional _mime-type-string)
1223   "Render DATA as text.  MIME-TYPE-STRING is unused."
1224   (elpher-with-clean-buffer
1225    (if (not data)
1226        t
1227      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1228      (elpher-cache-content
1229       (elpher-page-address elpher-current-page)
1230       (buffer-string)))))
1231
1232
1233 ;;; Image retrieval
1234 ;;
1235
1236 (defun elpher-render-image (data &optional _mime-type-string)
1237   "Display DATA as image.  MIME-TYPE-STRING is unused."
1238   (if (not data)
1239       nil
1240     (if (display-images-p)
1241         (let* ((image (create-image
1242                        data
1243                        nil t)))
1244           (if (not image)
1245               (error "Unsupported image format")
1246             (let ((window (get-buffer-window elpher-buffer-name)))
1247               (when window
1248                 (setf (image-property image :max-width) (window-body-width window t))
1249                 (setf (image-property image :max-height) (window-body-height window t))))
1250             (elpher-with-clean-buffer
1251              (insert-image image)
1252              (elpher-restore-pos))))
1253       (elpher-render-download data))))
1254
1255
1256 ;;; Gopher search retrieval and rendering
1257 ;;
1258
1259 (defun elpher-get-gopher-query-page (renderer)
1260   "Getter for gopher addresses requiring input.
1261 The response is rendered using the rendering function RENDERER."
1262   (let* ((address (elpher-page-address elpher-current-page))
1263          (content (elpher-get-cached-content address))
1264          (aborted t))
1265     (if (and content (funcall renderer nil))
1266         (elpher-with-clean-buffer
1267          (insert content)
1268          (elpher-restore-pos)
1269          (message "Displaying cached search results.  Reload to perform a new search."))
1270       (unwind-protect
1271           (let* ((query-string (read-string "Query: "))
1272                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1273                  (search-address (elpher-make-gopher-address ?1
1274                                                              query-selector
1275                                                              (elpher-address-host address)
1276                                                              (elpher-address-port address)
1277                                                              (equal (elpher-address-type address) "gophers"))))
1278             (setq aborted nil)
1279
1280             (elpher-with-clean-buffer
1281              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1282             (elpher-get-gopher-response search-address renderer))
1283         (if aborted
1284             (elpher-visit-previous-page))))))
1285
1286
1287 ;;; Raw server response rendering
1288 ;;
1289
1290 (defun elpher-render-raw (data &optional mime-type-string)
1291   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1292   (if (not data)
1293       nil
1294     (elpher-with-clean-buffer
1295      (when mime-type-string
1296        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1297      (insert data)
1298      (goto-char (point-min)))
1299     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1300
1301
1302 ;;; File save "rendering"
1303 ;;
1304
1305 (defun elpher-render-download (data &optional _mime-type-string)
1306   "Save DATA to file.  MIME-TYPE-STRING is unused."
1307   (if (not data)
1308       nil
1309     (let* ((address (elpher-page-address elpher-current-page))
1310            (selector (if (elpher-address-gopher-p address)
1311                          (elpher-gopher-address-selector address)
1312                        (elpher-address-filename address))))
1313       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1314       (let* ((filename-proposal (file-name-nondirectory selector))
1315              (filename (read-file-name "Download complete. Save file as: "
1316                                        nil nil nil
1317                                        (if (> (length filename-proposal) 0)
1318                                            filename-proposal
1319                                          "download.file"))))
1320         (let ((coding-system-for-write 'binary))
1321           (with-temp-file filename
1322             (insert data)))
1323         (message (format "Saved to file %s." filename))))))
1324
1325
1326 ;;; HTML rendering
1327 ;;
1328
1329 (defun elpher-render-html (data &optional _mime-type-string)
1330   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1331   (elpher-with-clean-buffer
1332    (if (not data)
1333        t
1334      (let ((dom (with-temp-buffer
1335                   (insert data)
1336                   (libxml-parse-html-region (point-min) (point-max)))))
1337        (shr-insert-document dom)))))
1338
1339
1340 ;;; Gemini page retrieval
1341 ;;
1342
1343 (defvar elpher-gemini-redirect-chain)
1344
1345 (defun elpher-get-gemini-response (address renderer)
1346   "Get response string from gemini server at ADDRESS and render using RENDERER."
1347   (elpher-get-host-response address 1965
1348                             (concat (elpher-address-to-url address) "\r\n")
1349                             (lambda (response-string)
1350                               (elpher-process-gemini-response response-string renderer))
1351                             'gemini))
1352
1353 (defun elpher-parse-gemini-response (response)
1354   "Parse the RESPONSE string and return a list of components.
1355 The list is of the form (code meta body).  A response of nil implies
1356 that the response was malformed."
1357   (let ((header-end-idx (string-match "\r\n" response)))
1358     (if header-end-idx
1359         (let ((header (string-trim (substring response 0 header-end-idx)))
1360               (body (substring response (+ header-end-idx 2))))
1361           (if (>= (length header) 2)
1362               (let ((code (substring header 0 2))
1363                     (meta (string-trim (substring header 2))))
1364                 (list code meta body))
1365             (error "Malformed response: No response status found in header %s" header)))
1366       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1367
1368 (defun elpher-process-gemini-response (response-string renderer)
1369   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1370   (let ((response-components (elpher-parse-gemini-response response-string)))
1371     (let ((response-code (elt response-components 0))
1372           (response-meta (elt response-components 1))
1373           (response-body (elt response-components 2)))
1374       (pcase (elt response-code 0)
1375         (?1 ; Input required
1376          (elpher-with-clean-buffer
1377           (insert "Gemini server is requesting input."))
1378          (let* ((query-string
1379                  (with-local-quit
1380                    (if (eq (elt response-code 1) ?1)
1381                        (read-passwd (concat response-meta ": "))
1382                      (read-string (concat response-meta ": ")))))
1383                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1384                 (old-fname (url-filename query-address)))
1385            (if (not query-string)
1386                (elpher-visit-previous-page)
1387              (setf (url-filename query-address)
1388                    (concat old-fname "?" (url-build-query-string `((,query-string)))))
1389              (elpher-get-gemini-response query-address renderer))))
1390         (?2 ; Normal response
1391          (funcall renderer response-body response-meta))
1392         (?3 ; Redirect
1393          (message "Following redirect to %s" response-meta)
1394          (if (>= (length elpher-gemini-redirect-chain) 5)
1395              (error "More than 5 consecutive redirects followed"))
1396          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1397            (if (member redirect-address elpher-gemini-redirect-chain)
1398                (error "Redirect loop detected"))
1399            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1400                (error "Server tried to automatically redirect to non-gemini URL: %s"
1401                       response-meta))
1402            (elpher-page-set-address elpher-current-page redirect-address)
1403            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1404            (elpher-get-gemini-response redirect-address renderer)))
1405         (?4 ; Temporary failure
1406          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1407                 response-code response-meta))
1408         (?5 ; Permanent failure
1409          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1410                 response-code response-meta))
1411         (?6 ; Client certificate required
1412          (elpher-with-clean-buffer
1413           (if elpher-client-certificate
1414               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1415             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1416           (auto-fill-mode 1)
1417           (elpher-gemini-insert-text response-meta))
1418          (let ((chosen-certificate
1419                 (with-local-quit
1420                   (elpher-acquire-client-certificate
1421                    (elpher-address-to-url (elpher-page-address elpher-current-page))))))
1422            (unless chosen-certificate
1423              (error "Gemini server requires a client certificate and none was provided"))
1424            (setq-local elpher-client-certificate chosen-certificate))
1425          (elpher-with-clean-buffer)
1426          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1427         (_other
1428          (error "Gemini server response unknown: %s %s"
1429                 response-code response-meta))))))
1430
1431 (defun elpher-acquire-client-certificate (url-prefix)
1432   "Select a pre-defined client certificate or prompt for one.
1433 In this case, \"pre-defined\" means a certificate provided by
1434 the `elpher-certificate-map' variable.
1435
1436 For this session, the certificate will remain active for all addresses
1437 having URLs begining with URL-PREFIX."
1438   (let ((entry (assoc url-prefix
1439                       elpher-certificate-map
1440                       #'string-prefix-p)))
1441     (if entry
1442         (let ((cert-url-prefix (car entry))
1443               (cert-name (cadr entry)))
1444           (message "Using certificate \"%s\" specified in elpher-certificate-map with prefix \"%s\""
1445                    cert-name cert-url-prefix)
1446           (elpher-get-existing-certificate cert-name cert-url-prefix))
1447       (elpher-prompt-for-client-certificate url-prefix))))
1448
1449 (defun elpher--read-answer-polyfill (question answers)
1450   "Polyfill for `read-answer' in Emacs 26.1.
1451 QUESTION is a string containing a question, and ANSWERS
1452 is a list of possible answers, or an alist whose keys
1453 are the possible answers."
1454     (completing-read question answers))
1455
1456 (if (fboundp 'read-answer)
1457     (defalias 'elpher-read-answer 'read-answer)
1458   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1459
1460
1461
1462 (defun elpher-prompt-for-client-certificate (url-prefix)
1463   "Prompt for a client certificate to use to establish a TLS connection.
1464
1465 In this session, the chosen certificate will remain active for all
1466 addresses with URLs matching URL-PREFIX."
1467   (let* ((read-answer-short t))
1468     (pcase (read-answer "What do you want to do? "
1469                         '(("throwaway" ?t
1470                            "generate and use throw-away certificate")
1471                           ("persistent" ?p
1472                            "generate new or use existing persistent certificate")
1473                           ("abort" ?a
1474                            "stop immediately")))
1475       ("throwaway"
1476        (setq-local elpher-client-certificate (elpher-generate-throwaway-certificate url-prefix)))
1477       ("persistent"
1478        (let* ((existing-certificates (elpher-list-existing-certificates))
1479               (file-base (completing-read
1480                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1481                           existing-certificates)))
1482          (if (string-empty-p (string-trim file-base))
1483              nil
1484            (if (member file-base existing-certificates)
1485                (setq-local elpher-client-certificate
1486                      (elpher-get-existing-certificate file-base url-prefix))
1487              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1488                                  '(("new" ?n
1489                                     "generate new certificate")
1490                                    ("install" ?i
1491                                     "install existing certificate")
1492                                    ("abort" ?a
1493                                     "stop immediately")))
1494                ("new"
1495                 (let ((common-name (read-string "Common Name field for new certificate: "
1496                                                 file-base)))
1497                   (message "New key and self-signed certificate written to %s"
1498                            elpher-certificate-directory)
1499                   (elpher-generate-persistent-certificate file-base
1500                                                           common-name
1501                                                           url-prefix)))
1502                ("install"
1503                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1504                        (key-file (read-file-name "Key file: " nil nil t)))
1505                   (message "Key and certificate installed in %s for future use"
1506                            elpher-certificate-directory)
1507                   (elpher-install-certificate key-file cert-file file-base
1508                                               url-prefix)))
1509                ("abort" nil))))))
1510       ("abort" nil))))
1511
1512 (defun elpher-get-gemini-page (renderer)
1513   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1514   (let* ((address (elpher-page-address elpher-current-page))
1515          (content (elpher-get-cached-content address)))
1516     (condition-case the-error
1517         (if (and content (funcall renderer nil))
1518             (elpher-with-clean-buffer
1519              (insert content)
1520              (elpher-restore-pos))
1521           (elpher-with-clean-buffer
1522            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1523           (setq elpher-gemini-redirect-chain nil)
1524           (elpher-get-gemini-response address renderer))
1525       (error
1526        (elpher-network-error address the-error)))))
1527
1528 ;;; Gemini page rendering
1529 ;;
1530
1531 (defun elpher-render-gemini (body &optional mime-type-string)
1532   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1533   (if (not body)
1534       t
1535     (let* ((mime-type-string* (if (or (not mime-type-string)
1536                                       (string-empty-p mime-type-string))
1537                                   "text/gemini; charset=utf-8"
1538                                 mime-type-string))
1539            (mime-type-split (split-string mime-type-string* ";" t))
1540            (mime-type (string-trim (car mime-type-split)))
1541            (parameters (mapcar (lambda (s)
1542                                  (let ((key-val (split-string s "=")))
1543                                    (list (downcase (string-trim (car key-val)))
1544                                          (downcase (string-trim (cadr key-val))))))
1545                                (cdr mime-type-split))))
1546       (when (string-prefix-p "text/" mime-type)
1547         (setq body (decode-coding-string
1548                     body
1549                     (if (assoc "charset" parameters)
1550                         (intern (cadr (assoc "charset" parameters)))
1551                       'utf-8)))
1552         (setq body (replace-regexp-in-string "\r" "" body)))
1553       (pcase mime-type
1554         ((or "text/gemini" "")
1555          (elpher-render-gemini-map body parameters))
1556         ("text/html"
1557          (elpher-render-html body))
1558         ((pred (string-prefix-p "text/"))
1559          (elpher-render-gemini-plain-text body parameters))
1560         ((pred (string-prefix-p "image/"))
1561          (elpher-render-image body))
1562         (_other
1563          (elpher-render-download body))))))
1564
1565 (defun elpher-gemini-get-link-url (link-line)
1566   "Extract the url portion of LINK-LINE, a gemini map file link line.
1567 Returns nil in the event that the contents of the line following the
1568 => prefix are empty."
1569   (let ((l (split-string (substring link-line 2))))
1570     (if l
1571         (string-trim (elt l 0))
1572       nil)))
1573
1574 (defun elpher-gemini-get-link-display-string (link-line)
1575   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1576 Return nil if this portion is not provided."
1577   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1578          (idx (string-match "[ \t]" rest)))
1579     (and idx
1580          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1581
1582 (defun elpher-collapse-dot-sequences (filename)
1583   "Collapse dot sequences in the (absolute) FILENAME.
1584 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1585   (let* ((path (split-string filename "/" t))
1586          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1587          (path-reversed-normalized
1588           (seq-reduce (lambda (a b)
1589                         (cond ((equal b "..") (cdr a))
1590                               ((equal b ".") a)
1591                               (t (cons b a))))
1592                       path nil))
1593          (path-normalized (reverse path-reversed-normalized)))
1594     (if path-normalized
1595         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1596       "/")))
1597
1598 (defun elpher-address-from-gemini-url (url)
1599   "Extract address from URL with defaults as per gemini map files.
1600 While there's obviously some redundancy here between this function and
1601 `elpher-address-from-url', gemini map file URLs require enough special
1602 treatment that a separate function is warranted."
1603   (let ((address (url-generic-parse-url url))
1604         (current-address (elpher-page-address elpher-current-page)))
1605     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1606       (if (url-host address) ;if there is an explicit host, filenames are absolute
1607           (if (string-empty-p (url-filename address))
1608               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1609         (setf (url-host address) (url-host current-address))
1610         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1611         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1612         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1613           (setf (url-filename address)
1614                 (concat (file-name-directory (url-filename current-address))
1615                         (url-filename address)))))
1616       (when (url-host address)
1617         (setf (url-host address) (puny-encode-domain (url-host address))))
1618       (unless (url-type address)
1619         (setf (url-type address) (url-type current-address)))
1620       (when (equal (url-type address) "gemini")
1621         (setf (url-filename address)
1622               (elpher-collapse-dot-sequences (url-filename address)))))
1623     (elpher-remove-redundant-ports address)))
1624
1625 (defun elpher-gemini-insert-link (link-line)
1626   "Insert link described by LINK-LINE into a text/gemini document."
1627   (let ((url (elpher-gemini-get-link-url link-line)))
1628     (when url
1629       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1630              (address (elpher-address-from-gemini-url url))
1631              (type (if address (elpher-address-type address) nil))
1632              (type-map-entry (cdr (assoc type elpher-type-map)))
1633              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1634         (when type-map-entry
1635           (insert elpher-gemini-link-string)
1636           (let* ((face (elt type-map-entry 3))
1637                  (display-string (or given-display-string
1638                                      (elpher-address-to-iri address)))
1639                  (page (elpher-make-page display-string
1640                                          address)))
1641             (insert-text-button display-string
1642                                 'face face
1643                                 'elpher-page page
1644                                 'action #'elpher-click-link
1645                                 'follow-link t
1646                                 'help-echo #'elpher--page-button-help))
1647           (newline))))))
1648
1649 (defun elpher-gemini-insert-header (header-line)
1650   "Insert header described by HEADER-LINE into a text/gemini document.
1651 The gemini map file line describing the header is given
1652 by HEADER-LINE."
1653   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1654     (let* ((level (length (match-string 1 header-line)))
1655            (header (substring header-line (match-end 0)))
1656            (face (pcase level
1657                    (1 'elpher-gemini-heading1)
1658                    (2 'elpher-gemini-heading2)
1659                    (3 'elpher-gemini-heading3)
1660                    (_ 'default)))
1661            (fill-column (if (display-graphic-p)
1662                             (/ (* fill-column
1663                                   (font-get (font-spec :name (face-font 'default)) :size))
1664                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1665       (unless (display-graphic-p)
1666         (insert (make-string level ?#) " "))
1667       (insert (propertize header
1668                           'face face
1669                           'gemini-heading t
1670                           'rear-nonsticky t))
1671       (newline))))
1672
1673 (defun elpher-gemini-insert-text (text-line)
1674   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1675 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1676 width defined by `elpher-gemini-max-fill-width'."
1677   (string-match
1678    (rx (: line-start
1679           (optional
1680            (group (or (: "*" (+ (any " \t")))
1681                       (: ">" (* (any " \t"))))))))
1682    text-line)
1683   (let* ((line-prefix (match-string 1 text-line))
1684          (processed-text-line
1685           (if line-prefix
1686               (cond ((string-prefix-p "*" line-prefix)
1687                      (concat
1688                       (replace-regexp-in-string "\\*"
1689                                                 elpher-gemini-bullet-string
1690                                                 (match-string 0 text-line))
1691                       (substring text-line (match-end 0))))
1692                     ((string-prefix-p ">" line-prefix)
1693                      (propertize text-line 'face 'elpher-gemini-quoted))
1694                     (t text-line))
1695             text-line))
1696          (fill-prefix (if line-prefix
1697                           (make-string (length (match-string 0 text-line)) ?\s)
1698                         "")))
1699     (insert (elpher-process-text-for-display processed-text-line))
1700     (newline)))
1701
1702 (defun elpher-gemini-pref-expand-collapse (button)
1703   "Function called when the preformatted text toggle BUTTON is activated."
1704   (let ((id (button-get button 'pref-id)))
1705     (if (invisible-p id)
1706         (remove-from-invisibility-spec id)
1707       (add-to-invisibility-spec id))
1708     (redraw-display)))
1709
1710 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1711   "Insert a button for toggling the visibility of preformatted text.
1712 If non-nil, ALT-TEXT is displayed alongside the button."
1713   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1714          (pref-id (intern (concat "pref-"
1715                                   (number-to-string (point))
1716                                   "-"
1717                                   url-string))))
1718     (insert elpher-gemini-preformatted-toggle-bullet)
1719     (when alt-text
1720       (insert (propertize (concat alt-text " ")
1721                           'face 'elpher-gemin-preformatted)))
1722     (insert-text-button elpher-gemini-preformatted-toggle-label
1723                         'action #'elpher-gemini-pref-expand-collapse
1724                         'pref-id pref-id
1725                         'face 'elpher-gemini-preformatted-toggle)
1726     (add-to-invisibility-spec pref-id)
1727     (newline)
1728     pref-id))
1729
1730 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1731   "Insert a LINE of preformatted text.
1732 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1733 can be used to toggle the display of the preformatted text."
1734   (insert (propertize (concat (elpher-process-text-for-display
1735                                (propertize line 'face 'elpher-gemini-preformatted))
1736                               "\n")
1737                       'invisible pref-id
1738                       'rear-nonsticky t)))
1739
1740 (defun elpher-render-gemini-map (data _parameters)
1741   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1742   (elpher-with-clean-buffer
1743    (auto-fill-mode 1)
1744    (setq-local buffer-invisibility-spec nil)
1745    (let ((preformatted nil)
1746          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1747      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1748      (dolist (line (split-string data "\n"))
1749        (pcase line
1750          ((rx (: string-start "```" (opt (let alt-text (+ any)))))
1751           (setq preformatted
1752                 (if preformatted
1753                     nil
1754                   (if elpher-gemini-hide-preformatted
1755                       (elpher-gemini-insert-preformatted-toggler alt-text)
1756                     t))))
1757          ((guard  preformatted)
1758           (elpher-gemini-insert-preformatted-line line preformatted))
1759          ((pred (string-prefix-p "=>"))
1760           (elpher-gemini-insert-link line))
1761          ((pred (string-prefix-p "#"))
1762           (elpher-gemini-insert-header line))
1763          (_ (elpher-gemini-insert-text line))))
1764    (elpher-cache-content
1765     (elpher-page-address elpher-current-page)
1766     (buffer-string)))))
1767
1768 (defun elpher-render-gemini-plain-text (data _parameters)
1769   "Render DATA as plain text file.  PARAMETERS is currently unused."
1770   (elpher-with-clean-buffer
1771    (insert (elpher-process-text-for-display data))
1772    (elpher-cache-content
1773     (elpher-page-address elpher-current-page)
1774     (buffer-string))))
1775
1776 (defun elpher-build-current-imenu-index ()
1777   "Build imenu index for current elpher buffer."
1778   (save-excursion
1779     (goto-char (point-min))
1780     (let ((match nil)
1781           (headers nil))
1782       (while (setq match (text-property-search-forward 'gemini-heading t t))
1783         (push (cons
1784                (buffer-substring-no-properties (prop-match-beginning match)
1785                                                (prop-match-end match))
1786                (prop-match-beginning match))
1787               headers))
1788       (reverse headers))))
1789
1790
1791 ;;; Finger page connection
1792 ;;
1793
1794 (defun elpher-get-finger-page (renderer)
1795   "Opens a finger connection to the current page address.
1796 The result is rendered using RENDERER."
1797   (let* ((address (elpher-page-address elpher-current-page))
1798          (content (elpher-get-cached-content address)))
1799     (if (and content (funcall renderer nil))
1800         (elpher-with-clean-buffer
1801          (insert content)
1802          (elpher-restore-pos))
1803       (elpher-with-clean-buffer
1804        (insert "LOADING... (use 'u' to cancel)\n"))
1805       (condition-case the-error
1806           (let* ((kill-buffer-query-functions nil)
1807                  (user (let ((filename (elpher-address-filename address)))
1808                          (if (> (length filename) 1)
1809                              (substring filename 1)
1810                            (elpher-address-user address)))))
1811             (elpher-get-host-response address 79
1812                                       (concat user "\r\n")
1813                                       renderer))
1814         (error
1815          (elpher-network-error address the-error))))))
1816
1817
1818 ;;; Telnet page connection
1819 ;;
1820
1821 (defun elpher-get-telnet-page (renderer)
1822   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1823   (when renderer
1824     (elpher-visit-previous-page)
1825     (error "Command not supported for telnet URLs"))
1826   (let* ((address (elpher-page-address elpher-current-page))
1827          (host (elpher-address-host address))
1828          (port (elpher-address-port address)))
1829     (elpher-visit-previous-page)
1830     (if (> port 0)
1831         (telnet host port)
1832       (telnet host))))
1833
1834
1835 ;;; Other URL page opening
1836 ;;
1837
1838 (defun elpher-get-other-url-page (renderer)
1839   "Getter which attempts to open the URL specified by the current page.
1840 The RENDERER argument to this getter must be nil."
1841   (when renderer
1842     (elpher-visit-previous-page)
1843     (error "Command not supported for general URLs"))
1844   (let* ((address (elpher-page-address elpher-current-page))
1845          (url (elpher-address-to-url address)))
1846     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1847     (message "Opening URL...")
1848     (if elpher-open-urls-with-eww
1849         (browse-web url)
1850       (browse-url url))))
1851
1852
1853 ;;; File page
1854 ;;
1855
1856 (defun elpher-get-file-page (renderer)
1857   "Getter which renders a local file using RENDERER.
1858 Assumes UTF-8 encoding for all text files."
1859   (let* ((address (elpher-page-address elpher-current-page))
1860          (filename (elpher-address-filename address)))
1861     (unless (file-exists-p filename)
1862       (elpher-visit-previous-page)
1863       (error "File not found"))
1864     (unless (file-readable-p filename)
1865       (elpher-visit-previous-page)
1866       (error "Could not read from file"))
1867     (let ((body (with-temp-buffer
1868        (let ((coding-system-for-read 'binary)
1869              (coding-system-for-write 'binary))
1870          (insert-file-contents-literally filename)
1871          (encode-coding-string (buffer-string) 'raw-text)))))
1872        (if renderer
1873            (funcall renderer body nil)
1874          (pcase (file-name-extension filename)
1875            ((or  "gmi" "gemini")
1876             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1877            ((or "htm" "html")
1878             (elpher-render-html (decode-coding-string body 'utf-8)))
1879            ((or "txt" "")
1880             (elpher-render-text (decode-coding-string body 'utf-8)))
1881            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1882             (elpher-render-image body))
1883            ((or "gopher" "gophermap")
1884             (elpher-render-index (elpher-decode body)))
1885            (_
1886             (elpher-render-download body))))
1887        (elpher-restore-pos))))
1888
1889
1890 ;;; Welcome page retrieval
1891 ;;
1892
1893 (defun elpher-get-welcome-page (renderer)
1894   "Getter which displays the welcome page (RENDERER must be nil)."
1895   (when renderer
1896     (elpher-visit-previous-page)
1897     (error "Command not supported for welcome page"))
1898   (elpher-with-clean-buffer
1899    (insert "     --------------------------------------------\n"
1900            "           Elpher Gopher and Gemini Client       \n"
1901            "                   version " elpher-version "\n"
1902            "     --------------------------------------------\n"
1903            "\n"
1904            "Default bindings:\n"
1905            "\n"
1906            " - TAB/Shift-TAB: next/prev item on current page\n"
1907            " - RET/mouse-1: open item under cursor\n"
1908            " - m: select an item on current page by name (autocompletes)\n"
1909            " - u/mouse-3/U: return to previous page or to the start page\n"
1910            " - g: go to a particular address (gopher, gemini, finger)\n"
1911            " - o/O: open a different address selector or the root menu of the current server\n"
1912            " - d/D: download item under cursor or current page\n"
1913            " - i/I: info on item under cursor or current page\n"
1914            " - c/C: copy URL representation of item under cursor or current page\n"
1915            " - a/A: bookmark the item under cursor or current page\n"
1916            " - B: list all bookmarks\n"
1917            " - s/S: show current history stack or all previously visted pages\n"
1918            " - r: redraw current page (using cached contents if available)\n"
1919            " - R: reload current page (regenerates cache)\n"
1920            " - !: set character coding system for gopher (default is to autodetect)\n"
1921            " - T: toggle TLS gopher mode\n"
1922            " - F: forget/discard current TLS client certificate\n"
1923            " - .: display the raw server response for the current page\n"
1924            "\n"
1925            "Start your exploration of gopher space and gemini:\n")
1926    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1927                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1928    (elpher-insert-index-record "Project Gemini home page"
1929                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1930    (insert "\n"
1931            "Alternatively, select a search engine and enter some search terms:\n")
1932    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1933                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1934    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1935                                (elpher-address-from-url "gemini://geminispace.info/search"))
1936    (insert "\n"
1937            "Your bookmarks are stored in your ")
1938    (insert-text-button "bookmark list"
1939                        'face 'link
1940                        'action #'elpher-click-link
1941                        'follow-link t
1942                        'help-echo #'elpher--page-button-help
1943                        'elpher-page
1944                        (elpher-make-page "Elpher Bookmarks"
1945                                          (elpher-make-about-address 'bookmarks)))
1946    (insert ".\n")
1947    (insert (propertize
1948             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1949             'face 'shadow))
1950    (insert "\n"
1951            "The gopher home of the Elpher project is here:\n")
1952    (elpher-insert-index-record "The Elpher Project Page"
1953                                (elpher-make-gopher-address ?1
1954                                                            "/projects/elpher/"
1955                                                            "thelambdalab.xyz"
1956                                                            70))
1957    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1958      (insert "\n"
1959              "The following info documentation is available:\n"
1960              "   - ")
1961      (insert-text-button "Elpher Manual"
1962                          'face 'link
1963                          'action (lambda (_)
1964                                    (interactive)
1965                                    (info "(elpher)"))
1966                          'follow-link t
1967                          'help-echo help-string)
1968      (insert "\n   - ")
1969      (insert-text-button "Changes introduced by the latest release"
1970                        'face 'link
1971                        'action (lambda (_)
1972                                  (interactive)
1973                                  (info "(elpher)News"))
1974                        'follow-link t
1975                        'help-echo help-string))
1976    (insert "\n")
1977    (insert (propertize
1978             (concat "(These documents should be available if you have installed Elpher\n"
1979                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1980                     " manual yourself.)\n")
1981             'face 'shadow))
1982    (elpher-restore-pos)))
1983
1984
1985 ;;; History page retrieval
1986 ;;
1987
1988 (defun elpher-show-history ()
1989   "Show the current contents of elpher's history stack.
1990 Use \\[elpher-show-visited-pages] to see the entire history.
1991 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1992   (interactive)
1993   (elpher-visit-page
1994    (elpher-make-page "Current History Stack"
1995                      (elpher-make-about-address 'history))))
1996
1997 (defun elpher-show-visited-pages ()
1998   "Show the all the pages you've visited using Elpher.
1999 Use \\[elpher-show-history] to see just the current history stack.
2000 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
2001   (interactive)
2002   (elpher-visit-page
2003    (elpher-make-page "Elpher Visted Pages"
2004                      (elpher-make-about-address 'visited-pages))))
2005
2006 (defun elpher-get-history-page (renderer)
2007   "Getter which displays the history page (RENDERER must be nil)."
2008   (when renderer
2009     (elpher-visit-previous-page)
2010     (error "Command not supported for history page"))
2011   (elpher-display-history-links elpher-history "Current history stack"))
2012
2013 (defun elpher-get-visited-pages-page (renderer)
2014   "Getter which displays the list of visited pages (RENDERER must be nil)."
2015   (when renderer
2016     (elpher-visit-previous-page)
2017     (error "Command not supported for history page"))
2018   (elpher-display-history-links
2019    (seq-filter (lambda (page)
2020                  (not (elpher-address-about-p (elpher-page-address page))))
2021                elpher-visited-pages)
2022    "All visited pages"))
2023
2024 (defun elpher-display-history-links (pages title)
2025   "Show all PAGES in an Elpher buffer with a given TITLE."
2026   (let* ((title-line (concat " ---- " title " ----"))
2027          (footer-line (make-string (length title-line) ?-)))
2028     (elpher-with-clean-buffer
2029      (insert title-line "\n\n")
2030      (if pages
2031          (dolist (page pages)
2032            (when page
2033              (let ((display-string (elpher-page-display-string page))
2034                    (address (elpher-page-address page)))
2035                (elpher-insert-index-record display-string address))))
2036        (insert "No history items found.\n"))
2037      (insert "\n " footer-line "\n"
2038              "Select an entry or press 'u' to return to the previous page.")
2039      (elpher-restore-pos))))
2040
2041
2042 ;;; Bookmarks
2043 ;;
2044
2045 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2046 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2047 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2048 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2049
2050 (defvar elpher-bookmark-link nil
2051   "Prefer bookmarking a link or the current page.
2052 Bind this variable dynamically, or set it to t.
2053 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2054 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2055
2056 (defun elpher-bookmark-make-record ()
2057   "Return a bookmark record.
2058 If `elpher-bookmark-link' is non-nil and point is on a link button,
2059 return a bookmark record for that link.  Otherwise, return a bookmark
2060 record for the current elpher page."
2061   (let* ((button (and elpher-bookmark-link (button-at (point))))
2062          (page (if button
2063                    (button-get button 'elpher-page)
2064                  elpher-current-page)))
2065     (unless page
2066       (error "Cannot bookmark this link"))
2067     (let* ((address (elpher-page-address page))
2068            (url (elpher-address-to-url address))
2069            (display-string (elpher-page-display-string page))
2070            (pos (if button nil (point))))
2071       (if (elpher-address-about-p address)
2072           (error "Cannot bookmark %s" display-string)
2073         `(,display-string
2074           (defaults . (,display-string))
2075           (position . ,pos)
2076           (location . ,url)
2077           (handler . elpher-bookmark-jump))))))
2078
2079 ;;;###autoload
2080 (defun elpher-bookmark-jump (bookmark)
2081   "Handler used to open a bookmark using elpher.
2082 The argument BOOKMARK is a bookmark record passed to the function.
2083 This handler is responsible for loading the bookmark in some buffer,
2084 then making that buffer the current buffer.  It should not switch
2085 to the buffer."
2086   (let* ((url (cdr (assq 'location bookmark)))
2087          (cleaned-url (string-trim url))
2088          (page (elpher-page-from-url cleaned-url))
2089          (buffer (get-buffer-create elpher-buffer-name)))
2090     (elpher-with-clean-buffer
2091      (elpher-visit-page page))
2092     (set-buffer buffer)
2093     nil))
2094
2095 (defun elpher-bookmark-link ()
2096   "Bookmark the link at point.
2097 To bookmark the current page, use \\[elpher-bookmark-current]."
2098   (interactive)
2099   (let ((elpher-bookmark-link t))
2100     (bookmark-set-no-overwrite)))
2101
2102 (defun elpher-bookmark-current ()
2103   "Bookmark the current page.
2104 To bookmark the link at point use \\[elpher-bookmark-link]."
2105   (interactive)
2106   (call-interactively #'bookmark-set-no-overwrite))
2107
2108 (defun elpher-bookmark-import (file)
2109   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2110   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2111                               (file-readable-p elpher-bookmarks-file))
2112                          elpher-bookmarks-file
2113                        (read-file-name "Old Elpher bookmarks: "
2114                                        user-emacs-directory nil t
2115                                        "elpher-bookmarks"))))
2116   (dolist (bookmark (with-temp-buffer
2117                       (insert-file-contents file)
2118                       (read (current-buffer))))
2119     (let* ((display-string (car bookmark))
2120            (url (cadr bookmark))
2121            (record `(,display-string
2122                      (location . ,url)
2123                      (handler . elpher-bookmark-jump))))
2124       (bookmark-store display-string (cdr record) t)))
2125   (bookmark-save))
2126
2127 (defun elpher-get-bookmarks-page (renderer)
2128   "Getter which displays the bookmarks (RENDERER must be nil)."
2129   (when renderer
2130     (elpher-visit-previous-page)
2131     (error "Command not supported for bookmarks page"))
2132
2133   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2134                                      elpher-bookmarks-file)
2135                                 (locate-user-emacs-file "elpher-bookmarks"))))
2136     (when (and (file-readable-p old-bookmarks-file)
2137                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2138                                  old-bookmarks-file
2139                                  "\" found. Import now?")))
2140       (elpher-bookmark-import old-bookmarks-file)
2141       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2142
2143   (if (and elpher-use-emacs-bookmark-menu
2144            elpher-history)
2145       (progn
2146         (elpher-visit-previous-page)
2147         (call-interactively #'bookmark-bmenu-list))
2148     (elpher-with-clean-buffer
2149      (insert " ---- Elpher Bookmarks ---- \n\n")
2150      (bookmark-maybe-load-default-file)
2151      (dolist (bookmark (bookmark-maybe-sort-alist))
2152        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2153          (let* ((name (car bookmark))
2154                 (url (alist-get 'location (cdr bookmark)))
2155                 (address (elpher-address-from-url url)))
2156            (elpher-insert-index-record name address))))
2157      (when (<= (line-number-at-pos) 3)
2158        (insert "No bookmarked pages found.\n"))
2159      (insert "\n --------------------------\n\n"
2160              "Select an entry or press 'u' to return to the previous page.\n\n"
2161              "Bookmarks can be renamed or deleted via the ")
2162      (insert-text-button "Emacs bookmark menu"
2163                          'action (lambda (_)
2164                                    (interactive)
2165                                    (call-interactively #'bookmark-bmenu-list))
2166                          'follow-link t
2167                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2168      (insert (substitute-command-keys
2169               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2170      (elpher-restore-pos))))
2171
2172 (defun elpher-show-bookmarks ()
2173   "Interactive function to display the current list of elpher bookmarks."
2174   (interactive)
2175   (elpher-visit-page
2176    (elpher-make-page "Elpher Bookmarks"
2177                      (elpher-make-about-address 'bookmarks))))
2178
2179
2180 ;;; Integrations
2181 ;;
2182
2183 ;;; Org
2184
2185 (defun elpher-org-export-link (link description format protocol)
2186   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2187
2188 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2189 of gemini, gopher or finger."
2190   (let* ((url (if (equal protocol "elpher")
2191                   (string-remove-prefix "elpher:" link)
2192                 (format "%s:%s" protocol link)))
2193          (desc (or description url)))
2194     (pcase format
2195       (`gemini (format "=> %s %s" url desc))
2196       (`html (format "<a href=\"%s\">%s</a>" url desc))
2197       (`latex (format "\\href{%s}{%s}" url desc))
2198       (_ (if (not description)
2199              url
2200            (format "%s (%s)" desc url))))))
2201
2202 (defun elpher-org-store-link ()
2203   "Store link to an `elpher' page in Org."
2204   (when (eq major-mode 'elpher-mode)
2205     (let* ((url (elpher-info-current))
2206            (desc (car elpher-current-page))
2207            (protocol (cond
2208                       ((string-prefix-p "gemini:" url) "gemini")
2209                       ((string-prefix-p "gopher:" url) "gopher")
2210                       ((string-prefix-p "finger:" url) "finger")
2211                       (t "elpher"))))
2212       (when (equal "elpher" protocol)
2213         ;; Weird link. Or special inner link?
2214         (setq url (concat "elpher:" url)))
2215       (org-link-store-props :type protocol :link url :description desc)
2216       t)))
2217
2218 (defun elpher-org-follow-link (link protocol)
2219   "Visit a LINK for the given PROTOCOL.
2220
2221 PROTOCOL may be one of gemini, gopher or finger.  This method also
2222 supports the old protocol elpher, where the link is self-contained."
2223   (let ((url (if (equal protocol "elpher")
2224                  (string-remove-prefix "elpher:" link)
2225                (format "%s:%s" protocol link))))
2226     (elpher-go url)))
2227
2228 (defun elpher-org-mode-integration ()
2229   "Set up `elpher' integration for `org-mode'."
2230   (org-link-set-parameters
2231    "elpher"
2232    :store #'elpher-org-store-link
2233    :export (lambda (link description format _plist)
2234              (elpher-org-export-link link description format "elpher"))
2235    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2236   (org-link-set-parameters
2237    "gemini"
2238    :export (lambda (link description format _plist)
2239              (elpher-org-export-link link description format "gemini"))
2240    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2241   (org-link-set-parameters
2242    "gopher"
2243    :export (lambda (link description format _plist)
2244              (elpher-org-export-link link description format "gopher"))
2245    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2246   (org-link-set-parameters
2247    "gophers"
2248    :export (lambda (link description format _plist)
2249              (elpher-org-export-link link description format "gophers"))
2250    :follow (lambda (link _arg) (elpher-org-follow-link link "gophers")))
2251   (org-link-set-parameters
2252    "finger"
2253    :export (lambda (link description format _plist)
2254              (elpher-org-export-link link description format "finger"))
2255    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2256
2257 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2258
2259 ;; Browse URL
2260
2261 ;;;###autoload
2262 (defun elpher-browse-url-elpher (url &rest _args)
2263   "Browse URL using Elpher.  This function is used by `browse-url'."
2264   (interactive (browse-url-interactive-arg "Elpher URL: "))
2265   (elpher-go url))
2266
2267 ;; Use elpher to open gopher, finger and gemini links
2268 ;; For recent version of `browse-url' package
2269 (if (boundp 'browse-url-default-handlers)
2270     (add-to-list
2271      'browse-url-default-handlers
2272      '("^\\(gopher\\|gophers\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2273   ;; Patch `browse-url-browser-function' for older ones. The value of
2274   ;; that variable is `browse-url-default-browser' by default, so
2275   ;; that's the function that gets advised. If the value is an alist,
2276   ;; however, we don't know what to do. Better not interfere?
2277   (when (and (symbolp browse-url-browser-function)
2278              (fboundp browse-url-browser-function))
2279     (advice-add browse-url-browser-function :before-while
2280                 (lambda (url &rest _args)
2281                   "Handle gemini, gopher, and finger schemes using Elpher."
2282                   (let ((scheme (downcase (car (split-string url ":" t)))))
2283                     (if (member scheme '("gemini" "gopher" "gophers" "finger"))
2284                         ;; `elpher-go' always returns nil, which will stop the
2285                         ;; advice chain here in a before-while
2286                         (elpher-go url)
2287                       ;; chain must continue, then return t.
2288                       t))))))
2289
2290 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2291 (with-eval-after-load 'thingatpt
2292   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2293
2294 ;; Mu4e:
2295
2296 ;; Make mu4e aware of the gemini world
2297 (setq mu4e~view-beginning-of-url-regexp
2298       "\\(?:https?\\|gopher\\|gophers\\|finger\\|gemini\\)://\\|mailto:")
2299
2300 ;; eww:
2301
2302 ;; Let elpher handle gemini, gopher links in eww buffer.
2303 (setq eww-use-browse-url
2304       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`gophers\\|\\`finger\\)://")
2305
2306
2307 ;;; Interactive procedures
2308 ;;
2309
2310 (defun elpher-next-link ()
2311   "Move point to the next link on the current page."
2312   (interactive)
2313   (forward-button 1))
2314
2315 (defun elpher-prev-link ()
2316   "Move point to the previous link on the current page."
2317   (interactive)
2318   (backward-button 1))
2319
2320 (defun elpher-follow-current-link ()
2321   "Open the link or url at point."
2322   (interactive)
2323   (push-button))
2324
2325 ;;;###autoload
2326 (defun elpher-go (host-or-url)
2327   "Go to a particular gopher site HOST-OR-URL.
2328 When run interactively HOST-OR-URL is read from the minibuffer."
2329   (interactive (list
2330                 (read-string (format "Visit URL (default scheme %s): "
2331                                      (elpher-get-default-url-scheme)))))
2332   (let ((trimmed-host-or-url (string-trim host-or-url)))
2333     (unless (string-empty-p trimmed-host-or-url)
2334       (let ((page (elpher-page-from-url trimmed-host-or-url
2335                                         (elpher-get-default-url-scheme))))
2336         (unless (get-buffer-window elpher-buffer-name t)
2337           (switch-to-buffer elpher-buffer-name))
2338         (elpher-with-clean-buffer
2339          (elpher-visit-page page))
2340         nil)))) ; non-nil value is displayed by eshell
2341
2342 (defun elpher-go-current ()
2343   "Go to a particular URL which is read from the minibuffer.
2344 Unlike `elpher-go', the reader is initialized with the URL of the
2345 current page."
2346   (interactive)
2347   (let* ((address (elpher-page-address elpher-current-page))
2348          (url (read-string (format "Visit URL (default scheme %s): "
2349                                    (elpher-get-default-url-scheme))
2350                            (elpher-address-to-url address))))
2351     (let ((trimmed-url (string-trim url)))
2352       (unless (string-empty-p trimmed-url)
2353         (elpher-with-clean-buffer
2354          (elpher-visit-page
2355           (elpher-page-from-url trimmed-url (elpher-get-default-url-scheme))))))))
2356
2357 (defun elpher-redraw ()
2358   "Redraw current page."
2359   (interactive)
2360   (elpher-visit-page elpher-current-page))
2361
2362 (defun elpher-reload ()
2363   "Reload current page."
2364   (interactive)
2365   (elpher-reload-current-page))
2366
2367 (defun elpher-toggle-tls ()
2368   "Toggle TLS encryption mode for gopher."
2369   (interactive)
2370   (setq elpher-use-tls (not elpher-use-tls))
2371   (if elpher-use-tls
2372       (if (gnutls-available-p)
2373           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2374         (setq elpher-use-tls nil)
2375         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2376     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2377
2378 (defun elpher-view-raw ()
2379   "View raw server response for current page."
2380   (interactive)
2381   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2382       (error "This page was not generated by a server")
2383     (elpher-visit-page elpher-current-page
2384                        #'elpher-render-raw)))
2385
2386 (defun elpher-back ()
2387   "Go to previous site."
2388   (interactive)
2389   (elpher-visit-previous-page))
2390
2391 (defun elpher-back-to-start ()
2392   "Go all the way back to the start page."
2393   (interactive)
2394   (setq-local elpher-current-page nil)
2395   (setq-local elpher-history nil)
2396   (elpher-visit-page (elpher-make-start-page)))
2397
2398 (defun elpher-download ()
2399   "Download the link at point."
2400   (interactive)
2401   (let ((button (button-at (point))))
2402     (if button
2403         (let ((page (button-get button 'elpher-page)))
2404           (unless page
2405             (error "Not an elpher page"))
2406           (when (elpher-address-about-p (elpher-page-address page))
2407             (error "Cannot download %s" (elpher-page-display-string page)))
2408           (elpher-visit-page (button-get button 'elpher-page)
2409                              #'elpher-render-download))
2410       (error "No link selected"))))
2411
2412 (defun elpher-download-current ()
2413   "Download the current page."
2414   (interactive)
2415   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2416       (error "Cannot download %s"
2417              (elpher-page-display-string elpher-current-page))
2418     (elpher-visit-page elpher-current-page
2419                        #'elpher-render-download
2420                        t)))
2421
2422 (defun elpher--build-link-map ()
2423   "Build alist mapping link names to destination pages in current buffer."
2424   (let ((link-map nil)
2425         (b (next-button (point-min) t)))
2426     (while b
2427       (push (cons (button-label b) b) link-map)
2428       (setq b (next-button (button-start b))))
2429     link-map))
2430
2431 (defun elpher-jump ()
2432   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2433   (interactive)
2434   (let* ((link-map (elpher--build-link-map)))
2435     (if link-map
2436         (let ((key (let ((completion-ignore-case t))
2437                      (completing-read "Directory item/link: "
2438                                       link-map nil t))))
2439           (if (and key (> (length key) 0))
2440               (let ((b (cdr (assoc key link-map))))
2441                 (goto-char (button-start b))
2442                 (button-activate b)))))))
2443
2444 (defun elpher-root-dir ()
2445   "Visit root of current server."
2446   (interactive)
2447   (let ((address (elpher-page-address elpher-current-page)))
2448     (if (not (elpher-address-about-p address))
2449         (if (or (member (url-filename address) '("/" ""))
2450                 (and (elpher-address-gopher-p address)
2451                      (= (length (elpher-gopher-address-selector address)) 0)))
2452             (error "Already at root directory of current server")
2453           (let ((address-copy (elpher-address-from-url
2454                                (elpher-address-to-url address))))
2455             (setf (url-filename address-copy) "")
2456             (elpher-go (elpher-address-to-url address-copy))))
2457       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2458
2459 (defun elpher-info-page (page)
2460   "Display URL of PAGE in minibuffer."
2461   (let* ((address (elpher-page-address page))
2462          (url (elpher-address-to-url address))
2463          (iri (elpher-address-to-iri address)))
2464     (if (equal url iri)
2465         (message "%s" url)
2466       (message "%s (Raw: %s)" iri url))))
2467
2468 (defun elpher-info-link ()
2469   "Display information on page corresponding to link at point."
2470   (interactive)
2471   (let ((button (button-at (point))))
2472     (unless button
2473       (error "No item selected"))
2474     (let ((page (button-get button 'elpher-page)))
2475       (unless page
2476         (error "Not an elpher page"))
2477       (elpher-info-page page))))
2478
2479 (defun elpher-info-current ()
2480   "Display information on current page."
2481   (interactive)
2482   (elpher-info-page elpher-current-page))
2483
2484 (defun elpher-copy-page-url (page)
2485   "Copy URL representation of address of PAGE to `kill-ring'."
2486   (let* ((address (elpher-page-address page))
2487          (url (elpher-address-to-url address)))
2488     (message "Copied \"%s\" to kill-ring/clipboard." url)
2489     (kill-new url)))
2490
2491 (defun elpher-copy-link-url ()
2492   "Copy URL of item at point to `kill-ring'."
2493   (interactive)
2494   (let ((button (button-at (point))))
2495     (unless button
2496       (error "No item selected"))
2497     (let ((page (button-get button 'elpher-page)))
2498       (unless page
2499         (error "Not an elpher page"))
2500       (elpher-copy-page-url page))))
2501
2502 (defun elpher-copy-current-url ()
2503   "Copy URL of current page to `kill-ring'."
2504   (interactive)
2505   (elpher-copy-page-url elpher-current-page))
2506
2507 (defun elpher-set-gopher-coding-system ()
2508   "Specify an explicit character coding system for gopher selectors."
2509   (interactive)
2510   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2511     (setq elpher-user-coding-system system)
2512     (if system
2513         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2514       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2515
2516
2517 ;;; Mode and keymap
2518 ;;
2519
2520 (defvar elpher-mode-map
2521   (let ((map (make-sparse-keymap)))
2522     (define-key map (kbd "TAB") 'elpher-next-link)
2523     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2524     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2525     (define-key map (kbd "u") 'elpher-back)
2526     (define-key map (kbd "-") 'elpher-back)
2527     (define-key map (kbd "^") 'elpher-back)
2528     (define-key map [mouse-3] 'elpher-back)
2529     (define-key map (kbd "U") 'elpher-back-to-start)
2530     (define-key map (kbd "g") 'elpher-go)
2531     (define-key map (kbd "o") 'elpher-go-current)
2532     (define-key map (kbd "O") 'elpher-root-dir)
2533     (define-key map (kbd "s") 'elpher-show-history)
2534     (define-key map (kbd "S") 'elpher-show-visited-pages)
2535     (define-key map (kbd "r") 'elpher-redraw)
2536     (define-key map (kbd "R") 'elpher-reload)
2537     (define-key map (kbd "T") 'elpher-toggle-tls)
2538     (define-key map (kbd ".") 'elpher-view-raw)
2539     (define-key map (kbd "d") 'elpher-download)
2540     (define-key map (kbd "D") 'elpher-download-current)
2541     (define-key map (kbd "m") 'elpher-jump)
2542     (define-key map (kbd "i") 'elpher-info-link)
2543     (define-key map (kbd "I") 'elpher-info-current)
2544     (define-key map (kbd "c") 'elpher-copy-link-url)
2545     (define-key map (kbd "C") 'elpher-copy-current-url)
2546     (define-key map (kbd "a") 'elpher-bookmark-link)
2547     (define-key map (kbd "A") 'elpher-bookmark-current)
2548     (define-key map (kbd "B") 'elpher-show-bookmarks)
2549     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2550     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2551     (when (fboundp 'evil-define-key*)
2552       (evil-define-key*
2553        'motion map
2554        (kbd "TAB") 'elpher-next-link
2555        (kbd "C-") 'elpher-follow-current-link
2556        (kbd "C-t") 'elpher-back
2557        (kbd "u") 'elpher-back
2558        (kbd "-") 'elpher-back
2559        (kbd "^") 'elpher-back
2560        [mouse-3] 'elpher-back
2561        (kbd "U") 'elpher-back-to-start
2562        (kbd "g") 'elpher-go
2563        (kbd "o") 'elpher-go-current
2564        (kbd "O") 'elpher-root-dir
2565        (kbd "s") 'elpher-show-history
2566        (kbd "S") 'elpher-show-visited-pages
2567        (kbd "r") 'elpher-redraw
2568        (kbd "R") 'elpher-reload
2569        (kbd "T") 'elpher-toggle-tls
2570        (kbd ".") 'elpher-view-raw
2571        (kbd "d") 'elpher-download
2572        (kbd "D") 'elpher-download-current
2573        (kbd "m") 'elpher-jump
2574        (kbd "i") 'elpher-info-link
2575        (kbd "I") 'elpher-info-current
2576        (kbd "c") 'elpher-copy-link-url
2577        (kbd "C") 'elpher-copy-current-url
2578        (kbd "a") 'elpher-bookmark-link
2579        (kbd "A") 'elpher-bookmark-current
2580        (kbd "B") 'elpher-show-bookmarks
2581        (kbd "!") 'elpher-set-gopher-coding-system
2582        (kbd "F") 'elpher-forget-current-certificate))
2583     map)
2584   "Keymap for gopher client.")
2585
2586 (define-derived-mode elpher-mode special-mode "elpher"
2587   "Major mode for elpher, an elisp gopher client.
2588
2589 This mode is automatically enabled by the interactive
2590 functions which initialize the client, namely
2591 `elpher', and `elpher-go'."
2592   (setq-local elpher-current-page nil)
2593   (setq-local elpher-history nil)
2594   (setq-local elpher-buffer-name (buffer-name))
2595   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2596   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2597
2598 (when (fboundp 'evil-set-initial-state)
2599   (evil-set-initial-state 'elpher-mode 'motion))
2600
2601
2602 ;;; Main start procedure
2603 ;;
2604
2605 ;;;###autoload
2606 (defun elpher (&optional arg)
2607   "Start elpher with default landing page.
2608 The buffer used for Elpher sessions is determined by the value of
2609 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2610 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2611 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2612 \\[execute-extended-command] elpher RET’) switches to the session with
2613 that number, creating it if necessary.  A non numeric prefix ARG means
2614 to create a new session.  Returns the buffer selected (or created)."
2615   (interactive "P")
2616   (let* ((name (default-value 'elpher-buffer-name))
2617          (buf (cond ((numberp arg)
2618                      (get-buffer-create (format "%s<%d>" name arg)))
2619                     (arg
2620                      (generate-new-buffer name))
2621                     (t
2622                      (get-buffer-create name)))))
2623     (pop-to-buffer-same-window buf)
2624     (unless (buffer-modified-p)
2625       (elpher-mode)
2626       (elpher-visit-page (elpher-make-start-page))
2627       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2628
2629 ;;; elpher.el ends here