elpher.el

   1 ;;; elpher.el --- Full-featured gopher client.
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 1.0.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "25"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a full-featured gopher client for GNU Emacs.
  30 ;; It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - caching of visited sites (both content and cursor position),
  34 ;; - pleasant and configurable colouring of Gopher directories,
  35 ;; - direct visualisation of image files,
  36 ;; - (m)enu key support, similar to Emacs' info browser,
  37 ;; - clickable web and gopher links in plain text.
  38
  39 ;; The caching mechanism works by maintaining a hierarchy of visited
  40 ;; pages rather than a linear history, meaning that it is quick and
  41 ;; easy to navigate this history.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Faces, caching options and start page can be configured via
  48 ;; the Elpher customization group in Applications.
  49
  50 ;;; Code:
  51
  52 (provide 'elpher)
  53
  54 ;;; Global constants
  55 ;;
  56
  57 (defconst elpher-version "1.0.0"
  58   "Current version of elpher.")
  59
  60 (defconst elpher-margin-width 6
  61   "Width of left-hand margin used when rendering indicies.")
  62
  63 (defconst elpher-start-index
  64   (mapconcat
  65    'identity
  66    (list "i\tfake\tfake\t1"
  67          "i--------------------------------------------\tfake\tfake\t1"
  68          "i           Elpher Gopher Client             \tfake\tfake\t1"
  69          (format "i              version %s\tfake\tfake\t1" elpher-version)
  70          "i--------------------------------------------\tfake\tfake\t1"
  71          "i\tfake\tfake\t1"
  72          "iUsage:\tfake\tfake\t1"
  73          "i\tfake\tfake\t1"
  74          "i - tab/shift-tab: next/prev directory entry on current page\tfake\tfake\t1"
  75          "i - RET/mouse-1: open directory entry under cursor\tfake\tfake\t1"
  76          "i - m: select a directory entry by name (autocompletes)\tfake\tfake\t1"
  77          "i - u: return to parent directory entry\tfake\tfake\t1"
  78          "i - O: visit the root directory of the current server\tfake\tfake\t1"
  79          "i - g: go to a particular page\tfake\tfake\t1"
  80          "i - r: redraw current page (using cached contents if available)\tfake\tfake\t1"
  81          "i - R: reload current page (regenerates cache)\tfake\tfake\t1"
  82          "i - d: download directory entry under cursor\tfake\tfake\t1"
  83          "i - w: display the raw server response for the current page\tfake\tfake\t1"
  84          "i\tfake\tfake\t1"
  85          "iPlaces to start exploring Gopherspace:\tfake\tfake\t1"
  86          "i\tfake\tfake\t1"
  87          "1Floodgap Systems Gopher Server\t\tgopher.floodgap.com\t70"
  88          "i\tfake\tfake\t1"
  89          "iAlternatively, select the following item and enter some\tfake\tfake\t1"
  90          "isearch terms:\tfake\tfake\t1"
  91          "i\tfake\tfake\t1"
  92          "7Veronica-2 Gopher Search Engine\t/v2/vs\tgopher.floodgap.com\t70"
  93          ".")
  94    "\r\n")
  95   "Source for elpher start page.")
  96
  97 (defconst elpher-type-map
  98   '((?0 elpher-get-text-node "T" elpher-text)
  99     (?1 elpher-get-index-node "/" elpher-index)
 100     (?g elpher-get-image-node "im" elpher-image)
 101     (?p elpher-get-image-node "im" elpher-image)
 102     (?I elpher-get-image-node "im" elpher-image)
 103     (?4 elpher-get-node-download "B" elpher-binary)
 104     (?5 elpher-get-node-download "B" elpher-binary)
 105     (?9 elpher-get-node-download "B" elpher-binary)
 106     (?7 elpher-get-search-node "?" elpher-search))
 107   "Association list from types to getters, margin codes and index faces.")
 108
 109
 110 ;;; Customization group
 111 ;;
 112
 113 (defgroup elpher nil
 114   "A gopher client."
 115   :group 'applications)
 116
 117 ;; Face customizations
 118
 119 (defface elpher-index
 120   '((t :inherit org-drawer))
 121   "Face used for directory type directory records.")
 122
 123 (defface elpher-text
 124   '((t :inherit org-tag))
 125   "Face used for text type directory records.")
 126
 127 (defface elpher-info
 128   '((t :inherit org-default))
 129   "Face used for info type directory records.")
 130
 131 (defface elpher-image
 132   '((t :inherit org-level-4))
 133   "Face used for image type directory records.")
 134
 135 (defface elpher-search
 136   '((t :inherit org-level-5))
 137   "Face used for search type directory records.")
 138
 139 (defface elpher-url
 140   '((t :inherit org-level-6))
 141   "Face used for url type directory records.")
 142
 143 (defface elpher-binary
 144   '((t :inherit org-level-7))
 145   "Face used for binary type directory records.")
 146
 147 (defface elpher-unknown
 148   '((t :inherit org-warning))
 149   "Face used for directory records with unknown/unsupported types.")
 150
 151 (defface elpher-margin-key
 152   '((t :inherit org-tag))
 153   "Face used for directory margin key.")
 154
 155 (defface elpher-margin-brackets
 156   '((t :inherit org-special-keyword))
 157   "Face used for brackets around directory margin key.")
 158
 159 ;; Other customizations
 160
 161 (defcustom elpher-open-urls-with-eww nil
 162   "If non-nil, open URL selectors using eww.
 163 Otherwise, use the system browser via the BROWSE-URL function."
 164   :type '(boolean))
 165
 166 (defcustom elpher-cache-images nil
 167   "If non-nil, cache images in memory in the same way as other content."
 168   :type '(boolean))
 169
 170 (defcustom elpher-start-address nil
 171   "If nil, the default start directory is shown when Elpher is started.
 172 Otherwise, a list containing the selector, host and port of a directory to
 173 use as the start page."
 174   :type '(list string string integer))
 175
 176
 177 ;;; Model
 178 ;;
 179
 180 ;; Address
 181
 182 (defun elpher-make-address (selector host port)
 183   "Create an address of a gopher object with SELECTOR, HOST and PORT."
 184   (list selector host port))
 185
 186 (defun elpher-address-selector (address)
 187   "Retrieve selector from ADDRESS."
 188   (car address))
 189
 190 (defun elpher-address-host (address)
 191   "Retrieve host from ADDRESS."
 192   (cadr address))
 193
 194 (defun elpher-address-port (address)
 195   "Retrieve port from ADDRESS."
 196   (caddr address))
 197
 198 ;; Node
 199
 200 (defun elpher-make-node (parent address getter &optional content pos)
 201   "Create a node in the gopher page hierarchy.
 202
 203 PARENT specifies the parent of the node, ADDRESS specifies the address of
 204 the gopher page, GETTER provides the getter function used to obtain this
 205 page.
 206
 207 The optional arguments CONTENT and POS can be used to fill the cached
 208 content and cursor position fields of the node."
 209   (list parent address getter content pos))
 210
 211 (defun elpher-node-parent (node)
 212   "Retrieve the parent node of NODE."
 213   (elt node 0))
 214
 215 (defun elpher-node-address (node)
 216   "Retrieve the address of NODE."
 217   (elt node 1))
 218
 219 (defun elpher-node-getter (node)
 220   "Retrieve the preferred getter function of NODE."
 221   (elt node 2))
 222
 223 (defun elpher-node-content (node)
 224   "Retrieve the cached content of NODE, or nil if none exists."
 225   (elt node 3))
 226
 227 (defun elpher-node-pos (node)
 228   "Retrieve the cached cursor position for NODE, or nil if none exists."
 229   (elt node 4))
 230
 231 (defun elpher-set-node-content (node content)
 232   "Set the content cache of NODE to CONTENT."
 233   (setcar (nthcdr 3 node) content))
 234
 235 (defun elpher-set-node-pos (node pos)
 236   "Set the cursor position cache of NODE to POS."
 237   (setcar (nthcdr 4 node) pos))
 238
 239 ;; Node graph traversal
 240
 241 (defvar elpher-current-node)
 242
 243 (defun elpher-visit-node (node &optional getter)
 244   "Visit NODE using its own getter or GETTER, if non-nil."
 245   (elpher-save-pos)
 246   (elpher-process-cleanup)
 247   (setq elpher-current-node node)
 248   (if getter
 249       (funcall getter)
 250     (funcall (elpher-node-getter node))))
 251
 252 (defun elpher-visit-parent-node ()
 253   "Visit the parent of the current node."
 254   (let ((parent-node (elpher-node-parent elpher-current-node)))
 255     (when parent-node
 256       (elpher-visit-node parent-node))))
 257
 258 (defun elpher-reload-current-node ()
 259   "Reload the current node, discarding any existing cached content."
 260   (elpher-set-node-content elpher-current-node nil)
 261   (elpher-visit-node elpher-current-node))
 262
 263 (defun elpher-save-pos ()
 264   "Save the current position of point to the current node."
 265   (when elpher-current-node
 266     (elpher-set-node-pos elpher-current-node (point))))
 267
 268 (defun elpher-restore-pos ()
 269   "Restore the position of point to that cached in the current node."
 270   (let ((pos (elpher-node-pos elpher-current-node)))
 271     (if pos
 272         (goto-char pos)
 273       (goto-char (point-min)))))
 274
 275 ;;; Buffer preparation
 276 ;;
 277
 278 (defmacro elpher-with-clean-buffer (&rest args)
 279   "Evaluate ARGS with a clean *elpher* buffer as current."
 280   (list 'with-current-buffer "*elpher*"
 281         '(elpher-mode)
 282         (append (list 'let '((inhibit-read-only t))
 283                       '(erase-buffer))
 284                 args)))
 285
 286 ;;; Index rendering
 287 ;;
 288
 289 (defun elpher-insert-index (string)
 290   "Insert the index corresponding to STRING into the current buffer."
 291   ;; Should be able to split directly on CRLF, but some non-conformant
 292   ;; LF-only servers sadly exist, hence the following.
 293   (dolist (line (split-string (replace-regexp-in-string "\r" "" string) "\n"))
 294     (unless (= (length line) 0)
 295       (elpher-insert-index-record line))))
 296
 297 (defun elpher-insert-margin (&optional type-name)
 298   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 299   (if type-name
 300       (progn
 301         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 302                         (concat
 303                          (propertize "[" 'face 'elpher-margin-brackets)
 304                          (propertize type-name 'face 'elpher-margin-key)
 305                          (propertize "]" 'face 'elpher-margin-brackets))))
 306         (insert " "))
 307     (insert (make-string elpher-margin-width ?\s))))
 308
 309 (defun elpher-insert-index-record (line)
 310   "Insert the index record corresponding to LINE into the current buffer."
 311   (let* ((type (elt line 0))
 312          (fields (split-string (substring line 1) "\t"))
 313          (display-string (elt fields 0))
 314          (selector (elt fields 1))
 315          (host (elt fields 2))
 316          (port (elt fields 3))
 317          (address (elpher-make-address selector host port))
 318          (type-map-entry (alist-get type elpher-type-map)))
 319     (if type-map-entry
 320         (let ((getter (car type-map-entry))
 321               (margin-code (cadr type-map-entry))
 322               (face (caddr type-map-entry)))
 323           (elpher-insert-margin margin-code)
 324           (insert-text-button display-string
 325                               'face face
 326                               'elpher-node (elpher-make-node elpher-current-node
 327                                                                address
 328                                                                getter)
 329                               'action #'elpher-click-link
 330                               'follow-link t
 331                               'help-echo (format "mouse-1, RET: open '%s' on %s port %s"
 332                                                  selector host port)))
 333       (pcase type
 334         (?i (elpher-insert-margin) ;; Information
 335             (insert (propertize display-string
 336                                 'face 'elpher-info)))
 337         (?h (elpher-insert-margin "W") ;; Web link
 338             (let ((url (elt (split-string selector "URL:") 1)))
 339               (insert-text-button display-string
 340                                   'face 'elpher-url
 341                                   'elpher-url url
 342                                   'action #'elpher-click-url
 343                                   'follow-link t
 344                                   'help-echo (format "mouse-1, RET: open url %s" url))))
 345         (?.) ;; Occurs at end of index, can safely ignore.
 346         (tp (elpher-insert-margin (concat (char-to-string tp) "?"))
 347             (insert (propertize display-string
 348                                 'face 'elpher-unknown-face)))))
 349     (insert "\n")))
 350
 351
 352 ;;; Selector retrieval (all kinds)
 353 ;;
 354
 355 (defun elpher-process-cleanup ()
 356   "Immediately shut down any extant elpher process."
 357   (let ((p (get-process "elpher-process")))
 358     (if p (delete-process p))))
 359
 360 (defvar elpher-selector-string)
 361
 362 (defun elpher-get-selector (address after)
 363   "Retrieve selector specified by ADDRESS, then execute AFTER.
 364 The result is stored as a string in the variable ‘elpher-selector-string’."
 365   (setq elpher-selector-string "")
 366   (make-network-process
 367    :name "elpher-process"
 368    :host (elpher-address-host address)
 369    :service (elpher-address-port address)
 370    :filter (lambda (proc string)
 371              (setq elpher-selector-string (concat elpher-selector-string string)))
 372    :sentinel after)
 373   (process-send-string "elpher-process"
 374                        (concat (elpher-address-selector address) "\n")))
 375
 376 ;; Index retrieval
 377
 378 (defun elpher-get-index-node ()
 379   "Getter which retrieves the current node contents as an index."
 380   (let ((content (elpher-node-content elpher-current-node))
 381         (address (elpher-node-address elpher-current-node)))
 382     (if content
 383         (progn
 384           (elpher-with-clean-buffer
 385            (insert content)
 386            (elpher-restore-pos)))
 387       (if address
 388           (progn
 389             (elpher-with-clean-buffer
 390              (insert "LOADING DIRECTORY..."))
 391             (elpher-get-selector address
 392                                   (lambda (proc event)
 393                                     (unless (string-prefix-p "deleted" event)
 394                                       (elpher-with-clean-buffer
 395                                        (elpher-insert-index elpher-selector-string)
 396                                        (elpher-restore-pos)
 397                                        (elpher-set-node-content elpher-current-node
 398                                                                 (buffer-string)))))))
 399         (progn
 400           (elpher-with-clean-buffer
 401            (elpher-insert-index elpher-start-index)
 402            (elpher-restore-pos)
 403            (elpher-set-node-content elpher-current-node
 404                                     (buffer-string))))))))
 405
 406 ;; Text retrieval
 407
 408 (defconst elpher-url-regex
 409   "\\(https?\\|gopher\\)://\\([a-zA-Z0-9.\-]+\\)\\(?3::[0-9]+\\)?\\(?4:/[^ \r\n\t(),]*\\)?"
 410   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 411
 412 (defun elpher-buttonify-urls (string)
 413   "Turn substrings which look like urls in STRING into clickable buttons."
 414   (with-temp-buffer
 415     (insert string)
 416     (goto-char (point-min))
 417     (while (re-search-forward elpher-url-regex nil t)
 418       (let ((url (match-string 0))
 419             (protocol (downcase (match-string 1))))
 420         (if (string= protocol "gopher")
 421             (let* ((host (match-string 2))
 422                    (port 70)
 423                    (type-and-selector (match-string 4))
 424                    (type (if (> (length type-and-selector) 1)
 425                              (elt type-and-selector 1)
 426                            ?1))
 427                    (selector (if (> (length type-and-selector) 1)
 428                                  (substring type-and-selector 2)
 429                                ""))
 430                    (address (elpher-make-address selector host port))
 431                    (getter (car (alist-get type elpher-type-map))))
 432               (make-text-button (match-beginning 0)
 433                                 (match-end 0)
 434                                 'elpher-node (elpher-make-node elpher-current-node
 435                                                                  address
 436                                                                  getter)
 437                                 'action #'elpher-click-link
 438                                 'follow-link t
 439                                 'help-echo (format "mouse-1, RET: open '%s' on %s port %s"
 440                                                    selector host port)))
 441           (make-text-button (match-beginning 0)
 442                             (match-end 0)
 443                             'elpher-url url
 444                             'action #'elpher-click-url
 445                             'follow-link t
 446                             'help-echo (format "mouse-1, RET: open url %s" url)))))
 447     (buffer-string)))
 448
 449 (defun elpher-process-text (string)
 450   "Remove CRs and trailing period from the gopher text document STRING."
 451   (let* ((chopped-str (replace-regexp-in-string "\r\n\.\r\n$" "\r\n" string))
 452          (cleaned-str (replace-regexp-in-string "\r" "" chopped-str)))
 453     (elpher-buttonify-urls cleaned-str)))
 454
 455 (defun elpher-get-text-node ()
 456   "Getter which retrieves the current node contents as a text document."
 457   (let ((content (elpher-node-content elpher-current-node))
 458         (address (elpher-node-address elpher-current-node)))
 459     (if content
 460         (progn
 461           (elpher-with-clean-buffer
 462            (insert content)
 463            (elpher-restore-pos)))
 464       (progn
 465         (elpher-with-clean-buffer
 466          (insert "LOADING TEXT..."))
 467         (elpher-get-selector address
 468                               (lambda (proc event)
 469                                 (unless (string-prefix-p "deleted" event)
 470                                   (elpher-with-clean-buffer
 471                                    (insert (elpher-process-text elpher-selector-string))
 472                                    (elpher-restore-pos)
 473                                    (elpher-set-node-content elpher-current-node
 474                                                             (buffer-string))))))))))
 475
 476 ;; Image retrieval
 477
 478 (defun elpher-get-image-node ()
 479   "Getter which retrieves the current node contents as an image to view."
 480   (let ((content (elpher-node-content elpher-current-node))
 481         (address (elpher-node-address elpher-current-node)))
 482     (if content
 483         (progn
 484           (elpher-with-clean-buffer
 485            (insert-image content)
 486            (elpher-restore-pos)))
 487       (if (display-images-p)
 488           (progn
 489             (elpher-with-clean-buffer
 490              (insert "LOADING IMAGE..."))
 491             (elpher-get-selector address
 492                                  (lambda (proc event)
 493                                    (unless (string-prefix-p "deleted" event)
 494                                      (let ((image (create-image
 495                                                    (encode-coding-string elpher-selector-string
 496                                                                          'no-conversion)
 497                                                    nil t)))
 498                                        (elpher-with-clean-buffer
 499                                         (insert-image image)
 500                                         (elpher-restore-pos))
 501                                        (if elpher-cache-images
 502                                            (elpher-set-node-content elpher-current-node
 503                                                                     image)))))))
 504         (elpher-get-node-download)))))
 505
 506 ;; Search retrieval
 507
 508 (defun elpher-get-search-node ()
 509   "Getter which submits a search query to the address of the current node."
 510   (let ((content (elpher-node-content elpher-current-node))
 511         (address (elpher-node-address elpher-current-node))
 512         (aborted t))
 513     (if content
 514         (progn
 515           (elpher-with-clean-buffer
 516            (insert content)
 517            (elpher-restore-pos))
 518           (message "Displaying cached search results.  Reload to perform a new search."))
 519       (unwind-protect
 520           (let* ((query-string (read-string "Query: "))
 521                  (query-selector (concat (elpher-address-selector address) "\t" query-string))
 522                  (search-address (elpher-make-address query-selector
 523                                                        (elpher-address-host address)
 524                                                        (elpher-address-port address))))
 525             (setq aborted nil)
 526             (elpher-with-clean-buffer
 527              (insert "LOADING RESULTS..."))
 528             (elpher-get-selector search-address
 529                                   (lambda (proc event)
 530                                     (unless (string-prefix-p "deleted" event)
 531                                       (elpher-with-clean-buffer
 532                                        (elpher-insert-index elpher-selector-string))
 533                                       (goto-char (point-min))
 534                                       (elpher-set-node-content elpher-current-node
 535                                                                 (buffer-string))))))
 536         (if aborted
 537             (elpher-visit-parent-node))))))
 538
 539 ;; Raw server response retrieval
 540
 541 (defun elpher-get-node-raw ()
 542   "Getter which retrieves the raw server response for the current node."
 543   (let* ((content (elpher-node-content elpher-current-node))
 544          (address (elpher-node-address elpher-current-node)))
 545     (elpher-with-clean-buffer
 546      (insert "LOADING RAW SERVER RESPONSE..."))
 547     (if address
 548         (elpher-get-selector address
 549                               (lambda (proc event)
 550                                 (unless (string-prefix-p "deleted" event)
 551                                   (elpher-with-clean-buffer
 552                                    (insert elpher-selector-string)
 553                                    (goto-char (point-min))))))
 554       (progn
 555         (elpher-with-clean-buffer
 556          (insert elpher-start-index))
 557         (goto-char (point-min)))))
 558   (message "Displaying raw server response.  Reload or redraw to return to standard view."))
 559
 560 ;; File export retrieval
 561
 562 (defvar elpher-download-filename)
 563
 564 (defun elpher-get-node-download ()
 565   "Getter which retrieves the current node and writes the result to a file."
 566   (let* ((address (elpher-node-address elpher-current-node))
 567          (selector (elpher-address-selector address)))
 568     (elpher-visit-parent-node) ; Do first in case of non-local exits.
 569     (let* ((filename-proposal (file-name-nondirectory selector))
 570            (filename (read-file-name "Save file as: "
 571                                      nil nil nil
 572                                      (if (> (length filename-proposal) 0)
 573                                          filename-proposal
 574                                        "gopher.file"))))
 575       (message "Downloading...")
 576       (setq elpher-download-filename filename)
 577       (elpher-get-selector address
 578                             (lambda (proc event)
 579                               (let ((coding-system-for-write 'binary))
 580                                 (with-temp-file elpher-download-filename
 581                                   (insert elpher-selector-string)
 582                                   (message (format "Download complate, saved to file %s."
 583                                                    elpher-download-filename)))))))))
 584
 585
 586 ;;; Navigation procedures
 587 ;;
 588
 589 (defun elpher-next-link ()
 590   "Move point to the next link on the current page."
 591   (interactive)
 592   (forward-button 1))
 593
 594 (defun elpher-prev-link ()
 595   "Move point to the previous link on the current page."
 596   (interactive)
 597   (backward-button 1))
 598
 599 (defun elpher-click-link (button)
 600   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 601   (let ((node (button-get button 'elpher-node)))
 602     (elpher-visit-node node)))
 603
 604 (defun elpher-click-url (button)
 605   "Function called when the url link BUTTON is activated (via mouse or keypress)."
 606   (let ((url (button-get button 'elpher-url)))
 607     (if elpher-open-urls-with-eww
 608         (browse-web url)
 609       (browse-url url))))
 610
 611 (defun elpher-follow-current-link ()
 612   "Open the link or url at point."
 613   (interactive)
 614   (push-button))
 615
 616 (defun elpher-go ()
 617   "Go to a particular gopher site."
 618   (interactive)
 619   (switch-to-buffer "*elpher*")
 620   (let* (
 621          (hostname (read-string "Gopher host: "))
 622          (selector (read-string "Selector (default none): " nil nil ""))
 623          (port (read-string "Port (default 70): " nil nil 70))
 624          (address (list selector hostname port)))
 625     (elpher-visit-node
 626      (elpher-make-node elpher-current-node
 627                         address
 628                         #'elpher-get-index-node))))
 629
 630 (defun  elpher-redraw ()
 631   "Redraw current page."
 632   (interactive)
 633   (elpher-visit-node elpher-current-node))
 634
 635 (defun  elpher-reload ()
 636   "Reload current page."
 637   (interactive)
 638   (elpher-reload-current-node))
 639
 640 (defun elpher-view-raw ()
 641   "View current page as plain text."
 642   (interactive)
 643   (elpher-visit-node elpher-current-node
 644                       #'elpher-get-node-raw))
 645
 646 (defun elpher-back ()
 647   "Go to previous site."
 648   (interactive)
 649   (if (elpher-node-parent elpher-current-node)
 650       (elpher-visit-parent-node)
 651     (message "No previous site.")))
 652
 653 (defun elpher-download ()
 654   "Download the link at point."
 655   (interactive)
 656   (let ((button (button-at (point))))
 657     (if button
 658         (let ((node (button-get button 'elpher-node)))
 659           (if node
 660               (elpher-visit-node (button-get button 'elpher-node)
 661                                  #'elpher-get-node-download)
 662             (message "Can only download gopher links, not general URLs.")))
 663       (message "No link selected."))))
 664
 665 (defun elpher-build-link-map ()
 666   "Build alist mapping link names to destination nodes in current buffer."
 667   (let ((link-map nil)
 668         (b (next-button (point-min) t)))
 669     (while b
 670       (add-to-list 'link-map (cons (button-label b) b))
 671       (setq b (next-button (button-start b))))
 672     link-map))
 673
 674 (defun elpher-menu ()
 675   "Select a directory entry by name.  Similar to the info browser (m)enu command."
 676   (interactive)
 677   (let* ((link-map (elpher-build-link-map)))
 678     (if link-map
 679         (let ((key (let ((completion-ignore-case t))
 680                      (completing-read "Directory entry/link (tab to autocomplete): "
 681                                       link-map nil t))))
 682           (if (and key (> (length key) 0))
 683               (let ((b (cdr (assoc key link-map))))
 684                 (goto-char (button-start b))
 685                 (button-activate b)))))))
 686
 687 (defun elpher-root-dir ()
 688   "Visit root of current server."
 689   (interactive)
 690   (let ((address (elpher-node-address elpher-current-node)))
 691     (if address
 692         (let ((host (elpher-address-host address))
 693               (selector (elpher-address-selector address))
 694               (port (elpher-address-port address)))
 695           (if (> (length selector) 0)
 696               (let ((root-address (elpher-make-address "" host port)))
 697                 (elpher-visit-node (elpher-make-node elpher-current-node
 698                                                      root-address
 699                                                      #'elpher-get-index-node)))
 700             (message "Already at root directory of current server.")))
 701       (message "Command invalid for Elpher start page."))))
 702
 703 ;;; Mode and keymap
 704 ;;
 705
 706 (defvar elpher-mode-map
 707   (let ((map (make-sparse-keymap)))
 708     (define-key map (kbd "TAB") 'elpher-next-link)
 709     (define-key map (kbd "<backtab>") 'elpher-prev-link)
 710     (define-key map (kbd "u") 'elpher-back)
 711     (define-key map (kbd "O") 'elpher-root-dir)
 712     (define-key map (kbd "g") 'elpher-go)
 713     (define-key map (kbd "r") 'elpher-redraw)
 714     (define-key map (kbd "R") 'elpher-reload)
 715     (define-key map (kbd "w") 'elpher-view-raw)
 716     (define-key map (kbd "d") 'elpher-download)
 717     (define-key map (kbd "m") 'elpher-menu)
 718     (when (fboundp 'evil-define-key)
 719       (evil-define-key 'normal map
 720         (kbd "TAB") 'elpher-next-link
 721         (kbd "C-]") 'elpher-follow-current-link
 722         (kbd "C-t") 'elpher-back
 723         (kbd "u") 'elpher-back
 724         (kbd "O") 'elpher-root-dir
 725         (kbd "g") 'elpher-go
 726         (kbd "r") 'elpher-redraw
 727         (kbd "R") 'elpher-reload
 728         (kbd "w") 'elpher-view-raw
 729         (kbd "d") 'elpher-download
 730         (kbd "m") 'elpher-menu))
 731     map)
 732   "Keymap for gopher client.")
 733
 734 (define-derived-mode elpher-mode special-mode "elpher"
 735   "Major mode for elpher, an elisp gopher client.")
 736
 737
 738 ;;; Main start procedure
 739 ;;
 740
 741 ;;;###autoload
 742 (defun elpher ()
 743   "Start elpher with default landing page."
 744   (interactive)
 745   (if (get-buffer "*elpher*")
 746       (switch-to-buffer "*elpher*")
 747     (switch-to-buffer "*elpher*")
 748     (setq elpher-current-node nil)
 749     (let ((start-node (elpher-make-node nil
 750                                         elpher-start-address
 751                                         #'elpher-get-index-node)))
 752       (elpher-visit-node start-node)))
 753   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
 754
 755 ;;; elpher.el ends here