elpher.el

   1 ;;; elpher.el --- A friendly gopher client.
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 1.4.1
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "25"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical gopher client for GNU Emacs.
  30 ;; It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven interface,
  33 ;; - caching of visited sites (both content and cursor position),
  34 ;; - pleasant and configurable colouring of Gopher directories,
  35 ;; - direct visualisation of image files,
  36 ;; - (m)enu key support, similar to Emacs' info browser,
  37 ;; - clickable web and gopher links in plain text,
  38 ;; - a simple bookmark management system,
  39 ;; - support for TLS gopherholes.
  40
  41 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  42 ;; page containing information on key bindings and suggested starting
  43 ;; points for your gopher exploration.
  44
  45 ;; Faces, caching and other options can be configured via
  46 ;; the Elpher customization group in Applications.
  47
  48 ;;; Code:
  49
  50 (provide 'elpher)
  51 (require 'seq)
  52 (require 'pp)
  53 (require 'shr)
  54
  55 ;;; Global constants
  56 ;;
  57
  58 (defconst elpher-version "1.4.1"
  59   "Current version of elpher.")
  60
  61 (defconst elpher-margin-width 6
  62   "Width of left-hand margin used when rendering indicies.")
  63
  64 (defconst elpher-start-index
  65   (mapconcat
  66    'identity
  67    (list "i\tfake\tfake\t1"
  68          "i     --------------------------------------------\tfake\tfake\t1"
  69          "i                Elpher Gopher Client             \tfake\tfake\t1"
  70          (format "i                   version %s\tfake\tfake\t1" elpher-version)
  71          "i     --------------------------------------------\tfake\tfake\t1"
  72          "i\tfake\tfake\t1"
  73          "iUsage:\tfake\tfake\t1"
  74          "i\tfake\tfake\t1"
  75          "i - tab/shift-tab: next/prev item on current page\tfake\tfake\t1"
  76          "i - RET/mouse-1: open item under cursor\tfake\tfake\t1"
  77          "i - m: select an item on current page by name (autocompletes)\tfake\tfake\t1"
  78          "i - u: return to parent\tfake\tfake\t1"
  79          "i - O: visit the root menu of the current server\tfake\tfake\t1"
  80          "i - g: go to a particular gopher address\tfake\tfake\t1"
  81          "i - i/I: info on item under cursor or current page\tfake\tfake\t1"
  82          "i - c/C: copy URL representation of item under cursor or current page\tfake\tfake\t1"
  83          "i - a/A: bookmark the item under cursor or current page\tfake\tfake\t1"
  84          "i - x/X: remove bookmark for item under cursor or current page\tfake\tfake\t1"
  85          "i - B: visit the bookmarks page\tfake\tfake\t1"
  86          "i - r: redraw current page (using cached contents if available)\tfake\tfake\t1"
  87          "i - R: reload current page (regenerates cache)\tfake\tfake\t1"
  88          "i - T: toggle TLS mode\tfake\tfake\t1"
  89          "i - d: download directory entry under cursor\tfake\tfake\t1"
  90          "i - w: display the raw server response for the current page\tfake\tfake\t1"
  91          "i - S: set an explicit character coding system (default is to autodetect)\tfake\tfake\t1"
  92          "i\tfake\tfake\t1"
  93          "iWhere to start exploring Gopherspace:\tfake\tfake\t1"
  94          "i\tfake\tfake\t1"
  95          "1Floodgap Systems Gopher Server\t/\tgopher.floodgap.com\t70"
  96          "i\tfake\tfake\t1"
  97          "iAlternatively, select the following item and enter some\tfake\tfake\t1"
  98          "isearch terms:\tfake\tfake\t1"
  99          "i\tfake\tfake\t1"
 100          "7Veronica-2 Gopher Search Engine\t/v2/vs\tgopher.floodgap.com\t70"
 101          ".\r\n")
 102    "\r\n")
 103   "Source for elpher start page.")
 104
 105 (defconst elpher-type-map
 106   '((?0 elpher-get-text-node "txt" elpher-text)
 107     (?1 elpher-get-index-node "/" elpher-index)
 108     (?4 elpher-get-node-download "bin" elpher-binary)
 109     (?5 elpher-get-node-download "bin" elpher-binary)
 110     (?7 elpher-get-search-node "?" elpher-search)
 111     (?8 elpher-get-telnet-node "tel" elpher-telnet)
 112     (?9 elpher-get-node-download "bin" elpher-binary)
 113     (?g elpher-get-image-node "img" elpher-image)
 114     (?p elpher-get-image-node "img" elpher-image)
 115     (?I elpher-get-image-node "img" elpher-image)
 116     (?d elpher-get-node-download "doc" elpher-binary)
 117     (?h elpher-get-url-node "web" elpher-url)
 118     (bookmarks elpher-get-bookmarks-node "#" elpher-index)
 119     (start elpher-get-start-node "#" elpher-index))
 120   "Association list from types to getters, margin codes and index faces.")
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher client."
 128   :group 'applications)
 129
 130 ;; Face customizations
 131
 132 (defface elpher-index
 133   '((t :inherit font-lock-keyword-face))
 134   "Face used for directory type directory records.")
 135
 136 (defface elpher-text
 137   '((t :inherit bold))
 138   "Face used for text type directory records.")
 139
 140 (defface elpher-info
 141   '((t :inherit default))
 142   "Face used for info type directory records.")
 143
 144 (defface elpher-image
 145   '((t :inherit font-lock-string-face))
 146   "Face used for image type directory records.")
 147
 148 (defface elpher-search
 149   '((t :inherit warning))
 150   "Face used for search type directory records.")
 151
 152 (defface elpher-url
 153   '((t :inherit font-lock-comment-face))
 154   "Face used for url type directory records.")
 155
 156 (defface elpher-telnet
 157   '((t :inherit font-lock-function-name-face))
 158   "Face used for telnet type directory records.")
 159
 160 (defface elpher-binary
 161   '((t :inherit font-lock-doc-face))
 162   "Face used for binary type directory records.")
 163
 164 (defface elpher-unknown
 165   '((t :inherit error))
 166   "Face used for directory records with unknown/unsupported types.")
 167
 168 (defface elpher-margin-key
 169   '((t :inherit bold))
 170   "Face used for directory margin key.")
 171
 172 (defface elpher-margin-brackets
 173   '((t :inherit shadow))
 174   "Face used for brackets around directory margin key.")
 175
 176 ;; Other customizations
 177
 178 (defcustom elpher-open-urls-with-eww nil
 179   "If non-nil, open URL selectors using eww.
 180 Otherwise, use the system browser via the BROWSE-URL function."
 181   :type '(boolean))
 182
 183 (defcustom elpher-buttonify-urls-in-directories nil
 184   "If non-nil, turns URLs matched in directories into clickable buttons."
 185   :type '(boolean))
 186
 187 (defcustom elpher-cache-images nil
 188   "If non-nil, cache images in memory in the same way as other content."
 189   :type '(boolean))
 190
 191 (defcustom elpher-use-header t
 192   "If non-nil, display current node information in buffer header."
 193   :type '(boolean))
 194
 195 ;;; Model
 196 ;;
 197
 198 ;; Address
 199
 200 (defun elpher-make-address (type &optional selector host port use-tls)
 201   "Create an address of a gopher object with TYPE, SELECTOR, HOST and PORT.
 202 Although selector host and port are optional, they are only omitted for
 203 special address types, such as 'start for the start page.
 204
 205 Setting the USE-TLS parameter to non-nil causes Elpher to engage TLS mode
 206 before attempting to connect to the server."
 207   (if use-tls
 208       (list type selector host port 'tls)
 209     (list type selector host port)))
 210
 211 (defun elpher-address-type (address)
 212   "Retrieve type from ADDRESS."
 213   (elt address 0))
 214
 215 (defun elpher-address-selector (address)
 216   "Retrieve selector from ADDRESS."
 217   (elt address 1))
 218
 219 (defun elpher-address-host (address)
 220   "Retrieve host from ADDRESS."
 221   (elt address 2))
 222
 223 (defun elpher-address-port (address)
 224   "Retrieve port from ADDRESS."
 225   (elt address 3))
 226
 227 (defun elpher-address-use-tls-p (address)
 228   "Returns non-nil if ADDRESS is marked as needing TLS."
 229   (elt address 4))
 230
 231 (defun elpher-address-special-p (address)
 232   "Return non-nil if ADDRESS is special (e.g. start page, bookmarks page)."
 233   (not (elpher-address-host address)))
 234
 235 ;; Node
 236
 237 (defun elpher-make-node (display-string address &optional parent)
 238   "Create a node in the gopher page hierarchy.
 239
 240 DISPLAY-STRING records the display string used for the page.
 241
 242 ADDRESS specifies the address of the gopher page.
 243
 244 The optional PARENT specifies the parent node in the hierarchy.
 245 This is set every time the node is visited, so while it forms
 246 an important part of the node data there is no need to set it
 247 initially."
 248   (list display-string address parent))
 249
 250 (defun elpher-node-display-string (node)
 251   "Retrieve the display string of NODE."
 252   (elt node 0))
 253
 254 (defun elpher-node-address (node)
 255   "Retrieve the address of NODE."
 256   (elt node 1))
 257
 258 (defun elpher-node-parent (node)
 259   "Retrieve the parent node of NODE."
 260   (elt node 2))
 261
 262 (defun elpher-set-node-parent (node parent)
 263   "Set the parent node of NODE to be PARENT."
 264   (setcar (cdr (cdr node)) parent))
 265
 266 ;; Cache
 267
 268 (defvar elpher-content-cache (make-hash-table :test 'equal))
 269 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 270
 271 (defun elpher-get-cached-content (address)
 272   "Retrieve the cached content for ADDRESS, or nil if none exists."
 273   (gethash address elpher-content-cache))
 274
 275 (defun elpher-cache-content (address content)
 276   "Set the content cache for ADDRESS to CONTENT."
 277   (puthash address content elpher-content-cache))
 278
 279 (defun elpher-get-cached-pos (address)
 280   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 281   (gethash address elpher-pos-cache))
 282
 283 (defun elpher-cache-pos (address pos)
 284   "Set the cursor position cache for ADDRESS to POS."
 285   (puthash address pos elpher-pos-cache))
 286
 287 ;; Node graph traversal
 288
 289 (defvar elpher-current-node nil)
 290
 291 (defun elpher-visit-node (node &optional getter preserve-parent)
 292   "Visit NODE using its own getter or GETTER, if non-nil.
 293 Additionally, set the parent of NODE to `elpher-current-node',
 294 unless PRESERVE-PARENT is non-nil."
 295   (elpher-save-pos)
 296   (elpher-process-cleanup)
 297   (unless preserve-parent
 298     (if (and (elpher-node-parent elpher-current-node)
 299              (equal (elpher-node-address elpher-current-node)
 300                     (elpher-node-address node)))
 301         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 302       (elpher-set-node-parent node elpher-current-node)))
 303   (setq elpher-current-node node)
 304   (if getter
 305       (funcall getter)
 306     (let* ((address (elpher-node-address node))
 307            (type (elpher-address-type address)))
 308       (funcall (car (alist-get type elpher-type-map))))))
 309
 310 (defun elpher-visit-parent-node ()
 311   "Visit the parent of the current node."
 312   (let ((parent-node (elpher-node-parent elpher-current-node)))
 313     (when parent-node
 314       (elpher-visit-node parent-node nil t))))
 315
 316 (defun elpher-reload-current-node ()
 317   "Reload the current node, discarding any existing cached content."
 318   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 319   (elpher-visit-node elpher-current-node))
 320
 321 (defun elpher-save-pos ()
 322   "Save the current position of point to the current node."
 323   (when elpher-current-node
 324     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 325
 326 (defun elpher-restore-pos ()
 327   "Restore the position of point to that cached in the current node."
 328   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 329     (if pos
 330         (goto-char pos)
 331       (goto-char (point-min)))))
 332
 333
 334 ;;; Buffer preparation
 335 ;;
 336
 337 (defun elpher-update-header ()
 338   "If `elpher-use-header' is true, display current node info in window header."
 339   (if elpher-use-header
 340       (setq header-line-format (elpher-node-display-string elpher-current-node))))
 341
 342 (defmacro elpher-with-clean-buffer (&rest args)
 343   "Evaluate ARGS with a clean *elpher* buffer as current."
 344   (list 'with-current-buffer "*elpher*"
 345         '(elpher-mode)
 346         (append (list 'let '((inhibit-read-only t))
 347                       '(erase-buffer)
 348                       '(elpher-update-header))
 349                 args)))
 350
 351
 352 ;;; Text Processing
 353 ;;
 354
 355 (defvar elpher-user-coding-system nil
 356   "User-specified coding system to use for decoding text responses.")
 357
 358 (defun elpher-decode (string)
 359   "Decode STRING using autodetected or user-specified coding system."
 360   (decode-coding-string string
 361                         (if elpher-user-coding-system
 362                             elpher-user-coding-system
 363                           (detect-coding-string string t))))
 364
 365 (defun elpher-preprocess-text-response (string)
 366   "Preprocess text selector response contained in STRING.
 367 This involes decoding the character representation, and clearing
 368 away CRs and any terminating period."
 369   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 370                                            (replace-regexp-in-string "\r" "" string))))
 371
 372 ;;; Index rendering
 373 ;;
 374
 375 (defun elpher-insert-index (string)
 376   "Insert the index corresponding to STRING into the current buffer."
 377   ;; Should be able to split directly on CRLF, but some non-conformant
 378   ;; LF-only servers sadly exist, hence the following.
 379   (let ((str-processed (elpher-preprocess-text-response string)))
 380     (dolist (line (split-string str-processed "\n"))
 381       (unless (= (length line) 0)
 382         (let* ((type (elt line 0))
 383                (fields (split-string (substring line 1) "\t"))
 384                (display-string (elt fields 0))
 385                (selector (elt fields 1))
 386                (host (elt fields 2))
 387                (port (if (elt fields 3)
 388                          (string-to-number (elt fields 3))
 389                        nil))
 390                (address (elpher-make-address type selector host port)))
 391           (elpher-insert-index-record display-string address))))))
 392
 393 (defun elpher-insert-margin (&optional type-name)
 394   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 395   (if type-name
 396       (progn
 397         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 398                         (concat
 399                          (propertize "[" 'face 'elpher-margin-brackets)
 400                          (propertize type-name 'face 'elpher-margin-key)
 401                          (propertize "]" 'face 'elpher-margin-brackets))))
 402         (insert " "))
 403     (insert (make-string elpher-margin-width ?\s))))
 404
 405 (defun elpher-node-button-help (node)
 406   "Return a string containing the help text for a button corresponding to NODE."
 407   (let ((address (elpher-node-address node)))
 408     (if (eq (elpher-address-type address) ?h)
 409         (let ((url (cadr (split-string (elpher-address-selector address) "URL:"))))
 410           (format "mouse-1, RET: open url '%s'" url))
 411       (format "mouse-1, RET: open '%s' on %s port %s"
 412               (elpher-address-selector address)
 413               (elpher-address-host address)
 414               (elpher-address-port address)))))
 415
 416
 417 (defun elpher-insert-index-record (display-string address)
 418   "Function to insert an index record into the current buffer.
 419 The contents of the record are dictated by DISPLAY-STRING and ADDRESS."
 420   (let ((type-map-entry (alist-get (elpher-address-type address)
 421                                    elpher-type-map)))
 422     (if type-map-entry
 423         (let* ((margin-code (elt type-map-entry 1))
 424                (face (elt type-map-entry 2))
 425                (node (elpher-make-node display-string address)))
 426           (elpher-insert-margin margin-code)
 427           (insert-text-button display-string
 428                               'face face
 429                               'elpher-node node
 430                               'action #'elpher-click-link
 431                               'follow-link t
 432                               'help-echo (elpher-node-button-help node)))
 433       (pcase type
 434         (?i ;; Information
 435          (elpher-insert-margin)
 436          (insert (propertize
 437                   (if elpher-buttonify-urls-in-directories
 438                       (elpher-buttonify-urls display-string)
 439                     display-string)
 440                   'face 'elpher-info)))
 441         (other ;; Unknown
 442          (elpher-insert-margin (concat (char-to-string type) "?"))
 443          (insert (propertize display-string
 444                              'face 'elpher-unknown)))))
 445     (insert "\n")))
 446
 447 (defun elpher-click-link (button)
 448   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 449   (let ((node (button-get button 'elpher-node)))
 450     (elpher-visit-node node)))
 451
 452
 453 ;;; Selector retrieval (all kinds)
 454 ;;
 455
 456 (defun elpher-process-cleanup ()
 457   "Immediately shut down any extant elpher process."
 458   (let ((p (get-process "elpher-process")))
 459     (if p (delete-process p))))
 460
 461 (defvar elpher-use-tls nil
 462   "If non-nil, use TLS to communicate with gopher servers.")
 463
 464 (defvar elpher-selector-string)
 465
 466 (defun elpher-get-selector (address after)
 467   "Retrieve selector specified by ADDRESS, then execute AFTER.
 468 The result is stored as a string in the variable ‘elpher-selector-string’."
 469   (setq elpher-selector-string "")
 470   (when (elpher-address-use-tls-p address)
 471       (if (gnutls-available-p)
 472           (when (not elpher-use-tls)
 473             (setq elpher-use-tls t)
 474             (message "Engaging TLS mode."))
 475         (error "Cannot retrieve TLS selector: GnuTLS not available.")))
 476   (condition-case the-error
 477       (let* ((kill-buffer-query-functions nil)
 478              (proc (open-network-stream "elpher-process"
 479                                        nil
 480                                        (elpher-address-host address)
 481                                        (elpher-address-port address)
 482                                        :type (if elpher-use-tls 'tls 'plain))))
 483         (set-process-filter proc
 484                             (lambda (proc string)
 485                               (setq elpher-selector-string
 486                                     (concat elpher-selector-string string))))
 487         (set-process-sentinel proc after)
 488         (process-send-string proc
 489                              (concat (elpher-address-selector address) "\n")))
 490     (error
 491      (if (and (consp the-error)
 492               (eq (car the-error) 'gnutls-error)
 493               (not (elpher-address-use-tls-p address)))
 494          (progn
 495            (message "Could not establish TLS connection.  Disengaging TLS mode.")
 496            (setq elpher-use-tls nil)
 497            (elpher-get-selector address after))
 498        (elpher-process-cleanup)
 499        (elpher-with-clean-buffer
 500         (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 501                 "Failed to connect to " (elpher-get-address-url address) ".\n"
 502                 (propertize "\n----------------\n\n" 'face 'error)
 503                 "Press 'u' to return to the previous page."))))))
 504
 505 ;; Index retrieval
 506
 507 (defun elpher-get-index-node ()
 508   "Getter which retrieves the current node contents as an index."
 509   (let* ((address (elpher-node-address elpher-current-node))
 510          (content (elpher-get-cached-content address)))
 511     (if content
 512         (progn
 513           (elpher-with-clean-buffer
 514            (insert content)
 515            (elpher-restore-pos)))
 516       (elpher-with-clean-buffer
 517        (insert "LOADING DIRECTORY... (use 'u' to cancel)"))
 518       (elpher-get-selector address
 519                            (lambda (proc event)
 520                              (unless (string-prefix-p "deleted" event)
 521                                (elpher-with-clean-buffer
 522                                 (elpher-insert-index elpher-selector-string)
 523                                 (elpher-restore-pos)
 524                                 (elpher-cache-content
 525                                  (elpher-node-address elpher-current-node)
 526                                  (buffer-string)))))))))
 527
 528 ;; Text retrieval
 529
 530 (defconst elpher-url-regex
 531   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]+\\)\\(?3::[0-9]+\\)?\\(?4:/[^ \r\n\t(),]*\\)?"
 532   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 533
 534 (defun elpher-make-node-from-matched-url (&optional string)
 535   "Convert most recent `elpher-url-regex' match to a node.
 536
 537 If STRING is non-nil, this is given as an argument to all `match-string'
 538 calls, as is necessary if the match is performed by `string-match'."
 539   (let ((url (match-string 0 string))
 540         (protocol (downcase (match-string 1 string))))
 541     (if (or (string= protocol "gopher")
 542             (string= protocol "gophers"))
 543         (let* ((host (match-string 2 string))
 544                (port (if (> (length (match-string 3 string))  1)
 545                          (string-to-number (substring (match-string 3 string) 1))
 546                        70))
 547                (type-and-selector (match-string 4 string))
 548                (type (if (> (length type-and-selector) 1)
 549                          (elt type-and-selector 1)
 550                        ?1))
 551                (selector (if (> (length type-and-selector) 1)
 552                              (substring type-and-selector 2)
 553                            ""))
 554                (use-tls (string= protocol "gophers"))
 555                (address (elpher-make-address type selector host port use-tls)))
 556           (elpher-make-node url address))
 557       (let* ((host (match-string 2 string))
 558              (port (if (> (length (match-string 3 string)) 1)
 559                        (string-to-number (substring (match-string 3 string) 1))
 560                      70))
 561              (selector (concat "URL:" url))
 562              (address (elpher-make-address ?h selector host port)))
 563         (elpher-make-node url address)))))
 564
 565
 566 (defun elpher-buttonify-urls (string)
 567   "Turn substrings which look like urls in STRING into clickable buttons."
 568   (with-temp-buffer
 569     (insert string)
 570     (goto-char (point-min))
 571     (while (re-search-forward elpher-url-regex nil t)
 572         (let ((node (elpher-make-node-from-matched-url)))
 573           (make-text-button (match-beginning 0)
 574                             (match-end 0)
 575                             'elpher-node  node
 576                             'action #'elpher-click-link
 577                             'follow-link t
 578                             'help-echo (elpher-node-button-help node))))
 579     (buffer-string)))
 580
 581 (defun elpher-get-text-node ()
 582   "Getter which retrieves the current node contents as a text document."
 583   (let* ((address (elpher-node-address elpher-current-node))
 584          (content (elpher-get-cached-content address)))
 585     (if content
 586         (progn
 587           (elpher-with-clean-buffer
 588            (insert content)
 589            (elpher-restore-pos)))
 590       (progn
 591         (elpher-with-clean-buffer
 592          (insert "LOADING TEXT... (use 'u' to cancel)"))
 593         (elpher-get-selector address
 594                               (lambda (proc event)
 595                                 (unless (string-prefix-p "deleted" event)
 596                                   (elpher-with-clean-buffer
 597                                    (insert (elpher-buttonify-urls
 598                                             (elpher-preprocess-text-response
 599                                              elpher-selector-string)))
 600                                    (elpher-restore-pos)
 601                                    (elpher-cache-content
 602                                     (elpher-node-address elpher-current-node)
 603                                     (buffer-string))))))))))
 604
 605 ;; Image retrieval
 606
 607 (defun elpher-get-image-node ()
 608   "Getter which retrieves the current node contents as an image to view."
 609   (let* ((address (elpher-node-address elpher-current-node))
 610          (content (elpher-get-cached-content address)))
 611     (if content
 612         (progn
 613           (elpher-with-clean-buffer
 614            (insert-image content)
 615            (elpher-restore-pos)))
 616       (if (display-images-p)
 617           (progn
 618             (elpher-with-clean-buffer
 619              (insert "LOADING IMAGE... (use 'u' to cancel)"))
 620             (elpher-get-selector address
 621                                  (lambda (proc event)
 622                                    (unless (string-prefix-p "deleted" event)
 623                                      (let ((image (create-image
 624                                                    elpher-selector-string
 625                                                    nil t)))
 626                                        (elpher-with-clean-buffer
 627                                         (insert-image image)
 628                                         (elpher-restore-pos))
 629                                        (if elpher-cache-images
 630                                            (elpher-cache-content
 631                                             (elpher-node-address elpher-current-node)
 632                                             image)))))))
 633         (elpher-get-node-download)))))
 634
 635 ;; Search retrieval
 636
 637 (defun elpher-get-search-node ()
 638   "Getter which submits a search query to the address of the current node."
 639   (let* ((address (elpher-node-address elpher-current-node))
 640          (content (elpher-get-cached-content address))
 641          (aborted t))
 642     (if content
 643         (progn
 644           (elpher-with-clean-buffer
 645            (insert content)
 646            (elpher-restore-pos))
 647           (message "Displaying cached search results.  Reload to perform a new search."))
 648       (unwind-protect
 649           (let* ((query-string (read-string "Query: "))
 650                  (query-selector (concat (elpher-address-selector address) "\t" query-string))
 651                  (search-address (elpher-make-address ?1
 652                                                       query-selector
 653                                                       (elpher-address-host address)
 654                                                       (elpher-address-port address))))
 655             (setq aborted nil)
 656             (elpher-with-clean-buffer
 657              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 658             (elpher-get-selector search-address
 659                                   (lambda (proc event)
 660                                     (unless (string-prefix-p "deleted" event)
 661                                       (elpher-with-clean-buffer
 662                                        (elpher-insert-index elpher-selector-string))
 663                                       (goto-char (point-min))
 664                                       (elpher-cache-content
 665                                        (elpher-node-address elpher-current-node)
 666                                        (buffer-string))))))
 667         (if aborted
 668             (elpher-visit-parent-node))))))
 669
 670 ;; Raw server response retrieval
 671
 672 (defun elpher-get-node-raw ()
 673   "Getter which retrieves the raw server response for the current node."
 674   (let ((address (elpher-node-address elpher-current-node)))
 675     (elpher-with-clean-buffer
 676      (insert "LOADING RAW SERVER RESPONSE... (use 'u' to cancel)"))
 677     (if address
 678         (elpher-get-selector address
 679                               (lambda (proc event)
 680                                 (unless (string-prefix-p "deleted" event)
 681                                   (elpher-with-clean-buffer
 682                                    (insert elpher-selector-string)
 683                                    (goto-char (point-min))))))
 684       (progn
 685         (elpher-with-clean-buffer
 686          (insert elpher-start-index))
 687         (goto-char (point-min)))))
 688   (message "Displaying raw server response.  Reload or redraw to return to standard view."))
 689
 690 ;; File export retrieval
 691
 692 (defvar elpher-download-filename)
 693
 694 (defun elpher-get-node-download ()
 695   "Getter which retrieves the current node and writes the result to a file."
 696   (let* ((address (elpher-node-address elpher-current-node))
 697          (selector (elpher-address-selector address)))
 698     (elpher-visit-parent-node) ; Do first in case of non-local exits.
 699     (let* ((filename-proposal (file-name-nondirectory selector))
 700            (filename (read-file-name "Save file as: "
 701                                      nil nil nil
 702                                      (if (> (length filename-proposal) 0)
 703                                          filename-proposal
 704                                        "gopher.file"))))
 705       (message "Downloading...")
 706       (setq elpher-download-filename filename)
 707       (elpher-get-selector address
 708                             (lambda (proc event)
 709                               (let ((coding-system-for-write 'binary))
 710                                 (with-temp-file elpher-download-filename
 711                                   (insert elpher-selector-string)
 712                                   (message (format "Download complate, saved to file %s."
 713                                                    elpher-download-filename)))))))))
 714
 715 ;; URL retrieval
 716
 717 (defun elpher-insert-rendered-html (string)
 718   "Use shr to insert rendered view of html STRING into current buffer."
 719   (let ((dom (with-temp-buffer
 720                (insert string)
 721                (libxml-parse-html-region (point-min) (point-max)))))
 722     (shr-insert-document dom)))
 723
 724 (defun elpher-get-url-node ()
 725   "Getter which attempts to open the URL specified by the current node."
 726   (let* ((address (elpher-node-address elpher-current-node))
 727          (selector (elpher-address-selector address)))
 728     (let ((url (elt (split-string selector "URL:") 1)))
 729       (if url
 730           (progn
 731             (elpher-visit-parent-node) ; Do first in case of non-local exits.
 732             (message "Opening URL...")
 733             (if elpher-open-urls-with-eww
 734                 (browse-web url)
 735               (browse-url url)))
 736         (let ((content (elpher-get-cached-content address)))
 737           (if content
 738               (progn
 739                 (elpher-with-clean-buffer
 740                  (insert content)
 741                  (elpher-restore-pos)))
 742             (elpher-with-clean-buffer
 743              (insert "LOADING HTML... (use 'u' to cancel)"))
 744             (elpher-get-selector address
 745                                  (lambda (proc event)
 746                                    (unless (string-prefix-p "deleted" event)
 747                                      (elpher-with-clean-buffer
 748                                       (elpher-insert-rendered-html elpher-selector-string)
 749                                       (goto-char (point-min))
 750                                       (elpher-cache-content
 751                                        (elpher-node-address elpher-current-node)
 752                                        (buffer-string))))))))))))
 753
 754 ;; Telnet node connection
 755
 756 (defun elpher-get-telnet-node ()
 757   "Getter which opens a telnet connection to the server specified by the current node."
 758   (let* ((address (elpher-node-address elpher-current-node))
 759          (host (elpher-address-host address))
 760          (port (elpher-address-port address)))
 761     (elpher-visit-parent-node)
 762     (telnet host port)))
 763
 764 ;; Start page node retrieval
 765
 766 (defun elpher-get-start-node ()
 767   "Getter which displays the start page."
 768   (elpher-with-clean-buffer
 769    (elpher-insert-index elpher-start-index)
 770    (elpher-restore-pos)))
 771
 772 ;; Bookmarks page node retrieval
 773
 774 (defun elpher-get-bookmarks-node ()
 775   "Getter to load and display the current bookmark list."
 776   (elpher-with-clean-buffer
 777    (insert "---- Bookmark list ----\n\n")
 778    (let ((bookmarks (elpher-load-bookmarks)))
 779      (if bookmarks
 780          (dolist (bookmark bookmarks)
 781            (let ((display-string (elpher-bookmark-display-string bookmark))
 782                  (address (elpher-bookmark-address bookmark)))
 783              (elpher-insert-index-record display-string address)))
 784        (insert "No bookmarks found.\n")))
 785    (insert "\n-----------------------\n\n"
 786            "- u: return to previous page\n"
 787            "- x: delete selected bookmark\n"
 788            "- a: rename selected bookmark\n\n"
 789            "Bookmarks are stored in the file "
 790            (locate-user-emacs-file "elpher-bookmarks"))
 791    (elpher-restore-pos)))
 792
 793
 794 ;;; Bookmarks
 795 ;;
 796
 797 (defun elpher-make-bookmark (display-string address)
 798   "Make an elpher bookmark.
 799 DISPLAY-STRING determines how the bookmark will appear in the
 800 bookmark list, while ADDRESS is the address of the entry."
 801   (list display-string address))
 802
 803 (defun elpher-bookmark-display-string (bookmark)
 804   "Get the display string of BOOKMARK."
 805   (elt bookmark 0))
 806
 807 (defun elpher-set-bookmark-display-string (bookmark display-string)
 808   "Set the display string of BOOKMARK to DISPLAY-STRING."
 809   (setcar bookmark display-string))
 810
 811 (defun elpher-bookmark-address (bookmark)
 812   "Get the address for BOOKMARK."
 813   (elt bookmark 1))
 814
 815 (defun elpher-save-bookmarks (bookmarks)
 816   "Record the bookmark list BOOKMARKS to the user's bookmark file.
 817 Beware that this completely replaces the existing contents of the file."
 818   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
 819     (erase-buffer)
 820     (insert "; Elpher gopher bookmarks file\n\n"
 821             "; Bookmarks are stored as a list of (label (type selector host port))\n"
 822             "; s-expressions, where type is stored as a character (i.e. 49 = ?1).\n"
 823             "; Feel free to edit by hand, but ensure this structure remains intact.\n\n")
 824     (pp bookmarks (current-buffer))))
 825
 826 (defun elpher-load-bookmarks ()
 827   "Get the list of bookmarks from the users's bookmark file."
 828   (with-temp-buffer
 829     (ignore-errors
 830       (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
 831       (goto-char (point-min))
 832       (read (current-buffer)))))
 833
 834 (defun elpher-add-address-bookmark (address display-string)
 835   "Save a bookmark for ADDRESS with label DISPLAY-STRING.
 836 If ADDRESS is already bookmarked, update the label only."
 837   (let ((bookmarks (elpher-load-bookmarks)))
 838     (let ((existing-bookmark (rassoc (list address) bookmarks)))
 839       (if existing-bookmark
 840           (elpher-set-bookmark-display-string existing-bookmark display-string)
 841         (add-to-list 'bookmarks (elpher-make-bookmark display-string address))))
 842     (elpher-save-bookmarks bookmarks)))
 843
 844 (defun elpher-remove-address-bookmark (address)
 845   "Remove any bookmark to ADDRESS."
 846     (elpher-save-bookmarks
 847      (seq-filter (lambda (bookmark)
 848                    (not (equal (elpher-bookmark-address bookmark) address)))
 849                  (elpher-load-bookmarks))))
 850
 851 ;;; Interactive procedures
 852 ;;
 853
 854 (defun elpher-next-link ()
 855   "Move point to the next link on the current page."
 856   (interactive)
 857   (forward-button 1))
 858
 859 (defun elpher-prev-link ()
 860   "Move point to the previous link on the current page."
 861   (interactive)
 862   (backward-button 1))
 863
 864 (defun elpher-follow-current-link ()
 865   "Open the link or url at point."
 866   (interactive)
 867   (push-button))
 868
 869 (defun elpher-go ()
 870   "Go to a particular gopher site read from the minibuffer.
 871 The site may be specified via a URL or explicitly in terms of
 872 host, selector and port."
 873   (interactive)
 874   (let ((node
 875          (let ((host-or-url (read-string "Gopher host or URL: ")))
 876            (if (string-match elpher-url-regex host-or-url)
 877                (elpher-make-node-from-matched-url host-or-url)
 878              (let ((selector (read-string "Selector (default none): " nil nil ""))
 879                    (port-string (read-string "Port (default 70): " nil nil "70")))
 880                (elpher-make-node (concat "gopher://" host-or-url
 881                                          ":" port-string
 882                                          "/1" selector)
 883                                  (elpher-make-address ?1 selector host-or-url
 884                                                       (string-to-number port-string))))))))
 885     (switch-to-buffer "*elpher*")
 886     (elpher-visit-node node)))
 887
 888 (defun elpher-redraw ()
 889   "Redraw current page."
 890   (interactive)
 891   (if elpher-current-node
 892       (elpher-visit-node elpher-current-node)
 893     (message "No current site.")))
 894
 895 (defun elpher-reload ()
 896   "Reload current page."
 897   (interactive)
 898   (if elpher-current-node
 899       (elpher-reload-current-node)
 900     (message "No current site.")))
 901
 902 (defun elpher-toggle-tls ()
 903   "Toggle TLS encryption mode."
 904   (interactive)
 905   (setq elpher-use-tls (not elpher-use-tls))
 906   (if elpher-use-tls
 907       (if (gnutls-available-p)
 908           (message "TLS mode enabled.  (Will not affect current page until reload.)")
 909         (setq elpher-use-tls nil)
 910         (error "Cannot enable TLS mode: GnuTLS not available"))
 911     (message "TLS mode disabled.  (Will not affect current page until reload.)")))
 912
 913 (defun elpher-view-raw ()
 914   "View raw server response for current page."
 915   (interactive)
 916   (if elpher-current-node
 917       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
 918           (error "This page was not generated by a server")
 919         (elpher-visit-node elpher-current-node
 920                            #'elpher-get-node-raw))
 921     (message "No current site.")))
 922
 923 (defun elpher-back ()
 924   "Go to previous site."
 925   (interactive)
 926   (if (elpher-node-parent elpher-current-node)
 927       (elpher-visit-parent-node)
 928     (error "No previous site")))
 929
 930 (defun elpher-download ()
 931   "Download the link at point."
 932   (interactive)
 933   (let ((button (button-at (point))))
 934     (if button
 935         (let ((node (button-get button 'elpher-node)))
 936           (if (elpher-address-special-p (elpher-node-address node))
 937               (error "Cannot download this link")
 938             (elpher-visit-node (button-get button 'elpher-node)
 939                                #'elpher-get-node-download)))
 940       (error "No link selected"))))
 941
 942 (defun elpher-build-link-map ()
 943   "Build alist mapping link names to destination nodes in current buffer."
 944   (let ((link-map nil)
 945         (b (next-button (point-min) t)))
 946     (while b
 947       (add-to-list 'link-map (cons (button-label b) b))
 948       (setq b (next-button (button-start b))))
 949     link-map))
 950
 951 (defun elpher-jump ()
 952   "Select a directory entry by name.  Similar to the info browser (m)enu command."
 953   (interactive)
 954   (let* ((link-map (elpher-build-link-map)))
 955     (if link-map
 956         (let ((key (let ((completion-ignore-case t))
 957                      (completing-read "Directory item/link: "
 958                                       link-map nil t))))
 959           (if (and key (> (length key) 0))
 960               (let ((b (cdr (assoc key link-map))))
 961                 (goto-char (button-start b))
 962                 (button-activate b)))))))
 963
 964 (defun elpher-root-dir ()
 965   "Visit root of current server."
 966   (interactive)
 967   (let* ((address (elpher-node-address elpher-current-node))
 968          (host (elpher-address-host address)))
 969     (if host
 970         (let ((host (elpher-address-host address))
 971               (selector (elpher-address-selector address))
 972               (port (elpher-address-port address)))
 973           (if (> (length selector) 0)
 974               (let ((root-address (elpher-make-address ?1 "" host port)))
 975                 (elpher-visit-node
 976                  (elpher-make-node (concat "gopher://" host
 977                                            ":" (number-to-string port)
 978                                            "/1/")
 979                                    root-address)))
 980             (error "Already at root directory of current server")))
 981       (error "Command invalid for this page"))))
 982
 983 (defun elpher-bookmarks-current-p ()
 984   "Return non-nil if current node is a bookmarks page."
 985   (eq (elpher-address-type (elpher-node-address elpher-current-node)) 'bookmarks))
 986
 987 (defun elpher-reload-bookmarks ()
 988   "Reload bookmarks if current node is a bookmarks page."
 989   (if (elpher-bookmarks-current-p)
 990       (elpher-reload-current-node)))
 991
 992 (defun elpher-bookmark-current ()
 993   "Bookmark the current node."
 994   (interactive)
 995   (let ((address (elpher-node-address elpher-current-node))
 996         (display-string (elpher-node-display-string elpher-current-node)))
 997     (if (not (elpher-address-special-p address))
 998         (let ((bookmark-display-string (read-string "Bookmark display string: "
 999                                                     display-string)))
1000           (elpher-add-address-bookmark address bookmark-display-string)
1001           (message "Bookmark added."))
1002       (error "Cannot bookmark %s" display-string))))
1003
1004 (defun elpher-bookmark-link ()
1005   "Bookmark the link at point."
1006   (interactive)
1007   (let ((button (button-at (point))))
1008     (if button
1009         (let* ((node (button-get button 'elpher-node))
1010                (address (elpher-node-address node))
1011                (display-string (elpher-node-display-string node)))
1012           (if (not (elpher-address-special-p address))
1013               (let ((bookmark-display-string (read-string "Bookmark display string: "
1014                                                           display-string)))
1015                 (elpher-add-address-bookmark address bookmark-display-string)
1016                 (elpher-reload-bookmarks)
1017                 (message "Bookmark added."))
1018             (error "Cannot bookmark %s" display-string)))
1019       (error "No link selected"))))
1020
1021 (defun elpher-unbookmark-current ()
1022   "Remove bookmark for the current node."
1023   (interactive)
1024   (let ((address (elpher-node-address elpher-current-node)))
1025     (unless (elpher-address-special-p address)
1026       (elpher-remove-address-bookmark address)
1027       (message "Bookmark removed."))))
1028
1029 (defun elpher-unbookmark-link ()
1030   "Remove bookmark for the link at point."
1031   (interactive)
1032   (let ((button (button-at (point))))
1033     (if button
1034         (let ((node (button-get button 'elpher-node)))
1035           (elpher-remove-address-bookmark (elpher-node-address node))
1036           (elpher-reload-bookmarks)
1037           (message "Bookmark removed."))
1038       (error "No link selected"))))
1039
1040 (defun elpher-bookmarks ()
1041   "Visit bookmarks."
1042   (interactive)
1043   (switch-to-buffer "*elpher*")
1044   (elpher-visit-node
1045    (elpher-make-node "Bookmarks Page" (elpher-make-address 'bookmarks))))
1046
1047 (defun elpher-info-node (node)
1048   "Display information on NODE."
1049   (let ((display-string (elpher-node-display-string node))
1050         (address (elpher-node-address node)))
1051     (if (not (elpher-address-special-p address))
1052         (message "`%s' on %s port %s"
1053                 (elpher-address-selector address)
1054                 (elpher-address-host address)
1055                 (elpher-address-port address))
1056       (message "%s" display-string))))
1057
1058 (defun elpher-info-link ()
1059   "Display information on node corresponding to link at point."
1060   (interactive)
1061   (let ((button (button-at (point))))
1062     (if button
1063         (elpher-info-node (button-get button 'elpher-node))
1064       (error "No item selected"))))
1065
1066 (defun elpher-info-current ()
1067   "Display information on current node."
1068   (interactive)
1069   (elpher-info-node elpher-current-node))
1070
1071 (defun elpher-get-address-url (address)
1072   "Get URL representation of ADDRESS."
1073   (let ((type (elpher-address-type address))
1074         (selector (elpher-address-selector address))
1075         (host (elpher-address-host address))
1076         (port (elpher-address-port address)))
1077     (if (and (equal type ?h)
1078              (string-prefix-p "URL:" selector))
1079         (elt (split-string selector "URL:") 1)
1080       (concat "gopher"
1081               (if (elpher-address-use-tls-p address) "s" "")
1082               "://"
1083               host
1084               (if (equal port 70)
1085                   ""
1086                 (format ":%d" port))
1087               "/" (string type)
1088               selector))))
1089
1090 (defun elpher-copy-node-url (node)
1091   "Copy URL representation of address of NODE to `kill-ring'."
1092   (let ((address (elpher-node-address node)))
1093     (if (elpher-address-special-p address)
1094         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1095       (let ((url (elpher-get-address-url address)))
1096         (message "Copied \"%s\" to kill-ring/clipboard." url)
1097         (kill-new url)))))
1098
1099 (defun elpher-copy-link-url ()
1100   "Copy URL of item at point to `kill-ring'."
1101   (interactive)
1102   (let ((button (button-at (point))))
1103     (if button
1104         (elpher-copy-node-url (button-get button 'elpher-node))
1105       (error "No item selected"))))
1106
1107 (defun elpher-copy-current-url ()
1108   "Copy URL of current node to `kill-ring'."
1109   (interactive)
1110   (elpher-copy-node-url elpher-current-node))
1111
1112 (defun elpher-set-coding-system ()
1113   "Specify an explicit character coding system."
1114   (interactive)
1115   (let ((system (read-coding-system "Set coding system to use (default is to autodetect): " nil)))
1116     (setq elpher-user-coding-system system)
1117     (if system
1118         (message "Coding system fixed to %s. (Reload to see effect)." system)
1119       (message "Coding system set to autodetect. (Reload to see effect)."))))
1120
1121 ;;; Mode and keymap
1122 ;;
1123
1124 (defvar elpher-mode-map
1125   (let ((map (make-sparse-keymap)))
1126     (define-key map (kbd "TAB") 'elpher-next-link)
1127     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1128     (define-key map (kbd "u") 'elpher-back)
1129     (define-key map (kbd "O") 'elpher-root-dir)
1130     (define-key map (kbd "g") 'elpher-go)
1131     (define-key map (kbd "r") 'elpher-redraw)
1132     (define-key map (kbd "R") 'elpher-reload)
1133     (define-key map (kbd "T") 'elpher-toggle-tls)
1134     (define-key map (kbd "w") 'elpher-view-raw)
1135     (define-key map (kbd "d") 'elpher-download)
1136     (define-key map (kbd "m") 'elpher-jump)
1137     (define-key map (kbd "i") 'elpher-info-link)
1138     (define-key map (kbd "I") 'elpher-info-current)
1139     (define-key map (kbd "c") 'elpher-copy-link-url)
1140     (define-key map (kbd "C") 'elpher-copy-current-url)
1141     (define-key map (kbd "a") 'elpher-bookmark-link)
1142     (define-key map (kbd "A") 'elpher-bookmark-current)
1143     (define-key map (kbd "x") 'elpher-unbookmark-link)
1144     (define-key map (kbd "X") 'elpher-unbookmark-current)
1145     (define-key map (kbd "B") 'elpher-bookmarks)
1146     (define-key map (kbd "S") 'elpher-set-coding-system)
1147     (when (fboundp 'evil-define-key)
1148       (evil-define-key 'motion map
1149         (kbd "TAB") 'elpher-next-link
1150         (kbd "C-]") 'elpher-follow-current-link
1151         (kbd "C-t") 'elpher-back
1152         (kbd "u") 'elpher-back
1153         (kbd "O") 'elpher-root-dir
1154         (kbd "g") 'elpher-go
1155         (kbd "r") 'elpher-redraw
1156         (kbd "R") 'elpher-reload
1157         (kbd "T") 'elpher-toggle-tls
1158         (kbd "w") 'elpher-view-raw
1159         (kbd "d") 'elpher-download
1160         (kbd "m") 'elpher-jump
1161         (kbd "i") 'elpher-info-link
1162         (kbd "I") 'elpher-info-current
1163         (kbd "c") 'elpher-copy-link-url
1164         (kbd "C") 'elpher-copy-current-url
1165         (kbd "a") 'elpher-bookmark-link
1166         (kbd "A") 'elpher-bookmark-current
1167         (kbd "x") 'elpher-unbookmark-link
1168         (kbd "X") 'elpher-unbookmark-current
1169         (kbd "B") 'elpher-bookmarks
1170         (kbd "S") 'elpher-set-coding-system))
1171     map)
1172   "Keymap for gopher client.")
1173
1174 (define-derived-mode elpher-mode special-mode "elpher"
1175   "Major mode for elpher, an elisp gopher client.")
1176
1177 (when (fboundp 'evil-set-initial-state)
1178   (evil-set-initial-state 'elpher-mode 'motion))
1179
1180 ;;; Main start procedure
1181 ;;
1182
1183 ;;;###autoload
1184 (defun elpher ()
1185   "Start elpher with default landing page."
1186   (interactive)
1187   (if (get-buffer "*elpher*")
1188       (switch-to-buffer "*elpher*")
1189     (switch-to-buffer "*elpher*")
1190     (setq elpher-current-node nil)
1191     (let ((start-node (elpher-make-node "Elpher Start Page"
1192                                         (elpher-make-address 'start))))
1193       (elpher-visit-node start-node)))
1194   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1195
1196 ;;; elpher.el ends here