elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.2
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.2"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     (file elpher-get-file-page nil "~" elpher-gemini)
  98     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
  99     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 100     ((about history) elpher-get-history-page nil "E" elpher-index)
 101     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 102   "Association list from types to getters, renderers, margin codes and index faces.")
 103
 104
 105 ;;; Declarations to avoid compiler warnings.
 106 ;;
 107
 108 (eval-when-compile
 109   (declare-function ansi-color-filter-apply "ansi-color")
 110   (declare-function ansi-color-apply "ansi-color")
 111   (declare-function bookmark-store "bookmark")
 112   (declare-function org-link-store-props "ol")
 113   (declare-function org-link-set-parameters "ol")
 114   (defvar ansi-color-context)
 115   (defvar xterm-color--current-fg)
 116   (defvar xterm-color--current-bg)
 117   (defvar bookmark-make-record-function)
 118   (defvar mu4e~view-beginning-of-url-regexp)
 119   (defvar eww-use-browse-url)
 120   (defvar thing-at-point-uri-schemes))
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher and gemini client."
 128   :group 'applications)
 129
 130 ;; General appearance and customizations
 131
 132 (defcustom elpher-open-urls-with-eww nil
 133   "If non-nil, open URL selectors using eww.
 134 Otherwise, use the system browser via the `browse-url' function."
 135   :type '(boolean))
 136
 137 (defcustom elpher-use-header t
 138   "If non-nil, display current page information in buffer header."
 139   :type '(boolean))
 140
 141 (defcustom elpher-auto-disengage-TLS nil
 142   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 143 While enabling this may seem convenient, it is also potentially
 144 dangerous as it allows switching from an encrypted channel back to
 145 plain text without user input."
 146   :type '(boolean))
 147
 148 (defcustom elpher-connection-timeout 5
 149   "Specifies the number of seconds to wait for a network connection to time out."
 150   :type '(integer))
 151
 152 (defcustom elpher-filter-ansi-from-text nil
 153   "If non-nil, filter ANSI escape sequences from text.
 154 The default behaviour is to use the ansi-color package (or xterm-color if it is
 155 available) to interpret these sequences."
 156   :type '(boolean))
 157
 158 (defcustom elpher-certificate-directory
 159   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 160   "Specify the name of the directory where client certificates will be stored.
 161 These certificates may be used for establishing authenticated TLS connections."
 162   :type '(directory))
 163
 164 (defcustom elpher-openssl-command "openssl"
 165   "The command used to launch openssl when generating TLS client certificates."
 166   :type '(file))
 167
 168 (defcustom elpher-default-url-type "gopher"
 169   "Default URL type (i.e. scheme) to assume if not explicitly given."
 170   :type '(choice (const "gopher")
 171                  (const "gemini")))
 172
 173 (defcustom elpher-gemini-TLS-cert-checks nil
 174   "If non-nil, verify gemini server TLS certs using the default security level.
 175 Otherwise, certificate verification is disabled.
 176
 177 This defaults to off because it is standard practice for Gemini servers
 178 to use self-signed certificates, meaning that most servers provide what
 179 EMACS considers to be an invalid certificate."
 180   :type '(boolean))
 181
 182 (defcustom elpher-gemini-max-fill-width 80
 183   "Specify the maximum default width (in columns) of text/gemini documents.
 184 The actual width used is the minimum of this value and the window width at
 185 the time when the text is rendered."
 186   :type '(integer))
 187
 188 (defcustom elpher-gemini-link-string "→ "
 189   "Specify the string used to indicate links when rendering gemini maps.
 190 May be empty."
 191   :type '(string))
 192
 193 (defcustom elpher-gemini-bullet-string "•"
 194   "Specify the string used for bullets when rendering gemini maps."
 195   :type '(string))
 196
 197 (defcustom elpher-ipv4-always nil
 198   "If non-nil, elpher will always use IPv4 to establish network connections.
 199 This can be useful when browsing from a computer that supports IPv6, because
 200 some servers which do not support IPv6 can take a long time to time-out."
 201   :type '(boolean))
 202
 203 (defcustom elpher-socks-always nil
 204   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 205 Otherwise, the SOCKS proxy is only used for connections to onion services."
 206   :type '(boolean))
 207
 208 (defcustom elpher-use-emacs-bookmark-menu nil
 209   "If non-nil, elpher will only use the native Emacs bookmark menu.
 210 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 211 page within which all of the standard elpher keybindings are active."
 212   :type '(boolean))
 213
 214 (defcustom elpher-start-page-url "about:welcome"
 215   "Specify the page displayed initially by elpher.
 216 The default welcome screen is \"about:welcome\", while the bookmarks list
 217 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 218
 219 Beware that using \"about:bookmarks\" as a start page in combination with
 220 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 221 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 222 the start page."
 223   :type '(string))
 224
 225 (defcustom elpher-gemini-hide-preformatted nil
 226   "Cause elpher to hide preformatted gemini text by default.
 227 When this option is enabled, preformatted text in text/gemini documents
 228 is replaced with a button which can be used to toggle its display.
 229
 230 This is intended to improve accessibility, as preformatted text often
 231 includes art which can be difficult for screen readers to interpret
 232 meaningfully."
 233   :type '(boolean))
 234
 235 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 236   "Margin symbol used to distinguish the preformatted text toggle."
 237   :type '(string))
 238
 239 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 240   "Label of button used to toggle formatted text."
 241   :type '(string))
 242
 243 ;; Face customizations
 244
 245 (defgroup elpher-faces nil
 246   "Elpher face customizations."
 247   :group 'elpher)
 248
 249 (defface elpher-index
 250   '((t :inherit font-lock-keyword-face))
 251   "Face used for directory type directory records.")
 252
 253 (defface elpher-text
 254   '((t :inherit bold))
 255   "Face used for text type directory records.")
 256
 257 (defface elpher-info
 258   '((t :inherit default))
 259   "Face used for info type directory records.")
 260
 261 (defface elpher-image
 262   '((t :inherit font-lock-string-face))
 263   "Face used for image type directory records.")
 264
 265 (defface elpher-search
 266   '((t :inherit warning))
 267   "Face used for search type directory records.")
 268
 269 (defface elpher-html
 270   '((t :inherit font-lock-comment-face))
 271   "Face used for html type directory records.")
 272
 273 (defface elpher-gemini
 274   '((t :inherit font-lock-constant-face))
 275   "Face used for Gemini type directory records.")
 276
 277 (defface elpher-other-url
 278   '((t :inherit font-lock-comment-face))
 279   "Face used for other URL type links records.")
 280
 281 (defface elpher-telnet
 282   '((t :inherit font-lock-function-name-face))
 283   "Face used for telnet type directory records.")
 284
 285 (defface elpher-binary
 286   '((t :inherit font-lock-doc-face))
 287   "Face used for binary type directory records.")
 288
 289 (defface elpher-unknown
 290   '((t :inherit error))
 291   "Face used for directory records with unknown/unsupported types.")
 292
 293 (defface elpher-margin-key
 294   '((t :inherit bold))
 295   "Face used for directory margin key.")
 296
 297 (defface elpher-margin-brackets
 298   '((t :inherit shadow))
 299   "Face used for brackets around directory margin key.")
 300
 301 (defface elpher-gemini-heading1
 302   '((t :inherit bold :height 1.8))
 303   "Face used for gemini heading level 1.")
 304
 305 (defface elpher-gemini-heading2
 306   '((t :inherit bold :height 1.5))
 307   "Face used for gemini heading level 2.")
 308
 309 (defface elpher-gemini-heading3
 310   '((t :inherit bold :height 1.2))
 311   "Face used for gemini heading level 3.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 (defface elpher-gemini-preformatted
 318   '((t :inherit default))
 319   "Face used for gemini preformatted text.")
 320
 321 (defface elpher-gemini-preformatted-toggle
 322   '((t :inherit button))
 323   "Face used for buttons used to toggle display of preformatted text.")
 324
 325 ;;; Model
 326 ;;
 327
 328 ;; Address
 329
 330 ;; An elpher "address" object is either a url object or a symbol.
 331 ;; Addresses with the "about" type, corresponding to pages generated
 332 ;; dynamically for and by elpher.  All others represent pages which
 333 ;; rely on content retrieved over the network.
 334
 335 (defun elpher-address-from-url (url-string &optional default-scheme)
 336   "Create a ADDRESS object corresponding to the given URL-STRING.
 337 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 338 is not explicitly given."
 339   (let ((data (match-data))) ; Prevent parsing clobbering match data
 340     (unwind-protect
 341         (let ((url (url-generic-parse-url url-string)))
 342           (unless (and (not (url-fullness url)) (url-type url))
 343             (unless (url-type url)
 344               (setf (url-type url) default-scheme))
 345             (unless (url-host url)
 346               (let ((p (split-string (url-filename url) "/" nil nil)))
 347                 (setf (url-host url) (car p))
 348                 (setf (url-filename url)
 349                       (if (cdr p)
 350                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 351                         ""))))
 352             (when (not (string-empty-p (url-host url)))
 353               (setf (url-fullness url) t)
 354               (setf (url-host url) (puny-encode-domain (url-host url))))
 355             (when (or (equal "gopher" (url-type url))
 356                       (equal "gophers" (url-type url)))
 357               ;; Gopher defaults
 358               (when (or (equal (url-filename url) "")
 359                         (equal (url-filename url) "/"))
 360                 (setf (url-filename url) "/1")))
 361             (when (equal "gemini" (url-type url))
 362               ;; Gemini defaults
 363               (if (equal (url-filename url) "")
 364                   (setf (url-filename url) "/"))))
 365           (elpher-remove-redundant-ports url))
 366       (set-match-data data))))
 367
 368 (defun elpher-remove-redundant-ports (address)
 369   "Remove redundant port specifiers from ADDRESS.
 370 Here 'redundant' means that the specified port matches the default
 371 for that protocol, eg 70 for gopher."
 372   (if (and (not (elpher-address-about-p address))
 373            (eq (url-portspec address) ; (url-port) is too slow!
 374                (pcase (url-type address)
 375                  ("gemini" 1965)
 376                  ((or "gopher" "gophers") 70)
 377                  ("finger" 79)
 378                  (_ -1))))
 379       (setf (url-portspec address) nil))
 380   address)
 381
 382 (defun elpher-make-gopher-address (type selector host port &optional tls)
 383   "Create an ADDRESS object using gopher directory record attributes.
 384 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 385 If the optional attribute TLS is non-nil, the address will be marked as
 386 requiring gopher-over-TLS."
 387   (cond
 388    ((equal type ?i) nil)
 389    ((and (equal type ?h)
 390          (string-prefix-p "URL:" selector))
 391     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 392    ((equal type ?8)
 393     (elpher-address-from-url
 394      (concat "telnet"
 395              "://" host
 396              ":" (number-to-string port))))
 397    (t
 398     (elpher-address-from-url
 399      (concat "gopher" (if tls "s" "")
 400              "://" host
 401              ":" (number-to-string port)
 402              "/" (string type)
 403              selector)))))
 404
 405 (defun elpher-make-about-address (type)
 406   "Create an ADDRESS object corresponding to the given about address TYPE."
 407   (elpher-address-from-url (concat "about:" (symbol-name type))))
 408
 409 (defun elpher-address-to-url (address)
 410   "Get string representation of ADDRESS."
 411   (url-encode-url (url-recreate-url address)))
 412
 413 (defun elpher-address-type (address)
 414   "Retrieve type of ADDRESS object.
 415 This is used to determine how to retrieve and render the document the
 416 address refers to, via the table `elpher-type-map'."
 417   (pcase (url-type address)
 418     ("about"
 419      (list 'about (intern (url-filename address))))
 420     ((or "gopher" "gophers")
 421      (list 'gopher
 422            (if (member (url-filename address) '("" "/"))
 423                ?1
 424              (string-to-char (substring (url-filename address) 1)))))
 425     ("gemini" 'gemini)
 426     ("telnet" 'telnet)
 427     ("finger" 'finger)
 428     ("file" 'file)
 429     (_ 'other-url)))
 430
 431 (defun elpher-address-about-p (address)
 432   "Return non-nil if ADDRESS is an about address."
 433   (pcase (elpher-address-type address) (`(about ,_) t)))
 434
 435 (defun elpher-address-gopher-p (address)
 436   "Return non-nil if ADDRESS object is a gopher address."
 437   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 438
 439 (defun elpher-address-protocol (address)
 440   "Retrieve the transport protocol for ADDRESS."
 441   (url-type address))
 442
 443 (defun elpher-address-filename (address)
 444   "Retrieve the filename component of ADDRESS.
 445 For gopher addresses this is a combination of the selector type and selector."
 446   (url-unhex-string (url-filename address)))
 447
 448 (defun elpher-address-host (address)
 449   "Retrieve host from ADDRESS object."
 450   (pcase (url-host address)
 451     ;; The following strips out square brackets which sometimes enclose IPv6
 452     ;; addresses.  Doing this here rather than at the parsing stage may seem
 453     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 454     ;; and reconstruction.  It's also more efficient, as this method is not
 455     ;; called during page rendering.
 456     ((rx (: "[" (let ipv6 (* (not "]"))) "]"))
 457      ipv6)
 458     ;; The following is a work-around for a parsing bug that causes
 459     ;; URLs with empty (but not absent, see RFC 1738) usernames to have
 460     ;; @ prepended to the hostname.
 461     ((rx (: "@" (let rest (+ anything))))
 462      rest)
 463     (addr
 464      addr)))
 465
 466 (defun elpher-address-user (address)
 467   "Retrieve user from ADDRESS object."
 468   (url-user address))
 469
 470 (defun elpher-address-port (address)
 471   "Retrieve port from ADDRESS object.
 472 If no address is defined, returns 0.  (This is for compatibility with
 473 the URL library.)"
 474   (let ((port (url-portspec address))) ; (url-port) is too slow!
 475     (if port port 0)))
 476
 477 (defun elpher-gopher-address-selector (address)
 478   "Retrieve gopher selector from ADDRESS object."
 479   (if (member (url-filename address) '("" "/"))
 480       ""
 481     (url-unhex-string (substring (url-filename address) 2))))
 482
 483
 484 ;; Cache
 485
 486 (defvar elpher-content-cache (make-hash-table :test 'equal))
 487 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 488
 489 (defun elpher-get-cached-content (address)
 490   "Retrieve the cached content for ADDRESS, or nil if none exists."
 491   (gethash address elpher-content-cache))
 492
 493 (defun elpher-cache-content (address content)
 494   "Set the content cache for ADDRESS to CONTENT."
 495   (puthash address content elpher-content-cache))
 496
 497 (defun elpher-get-cached-pos (address)
 498   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 499   (gethash address elpher-pos-cache))
 500
 501 (defun elpher-cache-pos (address pos)
 502   "Set the cursor position cache for ADDRESS to POS."
 503   (puthash address pos elpher-pos-cache))
 504
 505
 506 ;; Page
 507
 508 (defun elpher-make-page (display-string address)
 509   "Create a page with DISPLAY-STRING and ADDRESS."
 510   (list display-string address))
 511
 512 (defun elpher-make-start-page ()
 513   "Create the start page."
 514   (elpher-make-page "Start Page"
 515                     (elpher-address-from-url elpher-start-page-url)))
 516
 517 (defun elpher-page-display-string (page)
 518   "Retrieve the display string corresponding to PAGE."
 519   (elt page 0))
 520
 521 (defun elpher-page-address (page)
 522   "Retrieve the address corresponding to PAGE."
 523   (elt page 1))
 524
 525 (defun elpher-page-set-address (page new-address)
 526   "Set the address corresponding to PAGE to NEW-ADDRESS."
 527   (setcar (cdr page) new-address))
 528
 529 (defun elpher-page-from-url (url &optional default-scheme)
 530   "Create a page with address and display string defined by URL.
 531 The URL is unhexed prior to its use as a display string to improve
 532 readability.
 533
 534 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 535 in the instance that URL itself doesn't specify one."
 536   (let ((address (elpher-address-from-url url default-scheme)))
 537     (elpher-make-page (elpher-address-to-iri address) address)))
 538
 539 (defun elpher-address-to-iri (address)
 540   "Return an IRI for ADDRESS.
 541 Decode percent-escapes and handle punycode in the domain name.
 542 Drop the password, if any."
 543   (let ((data (match-data)) ; Prevent parsing clobbering match data
 544         (host (url-host address))
 545         (pass (url-password address)))
 546     (unwind-protect
 547         (let* ((host (url-host address))
 548                (pass (url-password address)))
 549           (when host
 550             (setf (url-host address) (puny-decode-domain host)))
 551           (when pass                             ; RFC 3986 says we should not render
 552             (setf (url-password address) nil)) ; the password as clear text
 553           (elpher-decode (url-unhex-string (url-recreate-url address))))
 554       (setf (url-host address) host)
 555       (setf (url-password address) pass)
 556       (set-match-data data))))
 557
 558 (defvar elpher-current-page nil
 559   "The current page for this Elpher buffer.")
 560
 561 (defvar elpher-history nil
 562   "The local history stack for this Elpher buffer.
 563 This variable is used by `elpher-back' and
 564 `elpher-show-history'.")
 565
 566 (defvar elpher-visited-pages nil
 567   "The global history for all Elpher buffers.
 568 This variable is used by `elpher-show-visited-pages'.")
 569
 570 (defun elpher-visit-page (page &optional renderer no-history)
 571   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 572 Additionally, push PAGE onto the history stack and the list of
 573 previously-visited pages,unless NO-HISTORY is non-nil."
 574   (elpher-save-pos)
 575   (elpher-process-cleanup)
 576   (unless no-history
 577     (unless (or (not elpher-current-page)
 578                  (equal (elpher-page-address elpher-current-page)
 579                         (elpher-page-address page)))
 580       (push elpher-current-page elpher-history)
 581       (unless (or (elpher-address-about-p (elpher-page-address page))
 582                   (and elpher-visited-pages
 583                        (equal page (car elpher-visited-pages))))
 584         (push page elpher-visited-pages))))
 585   (setq-local elpher-current-page page)
 586   (let* ((address (elpher-page-address page))
 587          (type (elpher-address-type address))
 588          (type-record (cdr (assoc type elpher-type-map))))
 589     (if type-record
 590         (funcall (car type-record)
 591                  (if renderer
 592                      renderer
 593                    (cadr type-record)))
 594       (elpher-visit-previous-page)
 595       (pcase type
 596         (`(gopher ,type-char)
 597          (error "Unsupported gopher selector type '%c' for '%s'"
 598                 type-char (elpher-address-to-url address)))
 599         (other
 600          (error "Unsupported address type '%S' for '%s'"
 601                 other (elpher-address-to-url address)))))))
 602
 603 (defun elpher-visit-previous-page ()
 604   "Visit the previous page in the history."
 605   (if elpher-history
 606       (elpher-visit-page (pop elpher-history) nil t)
 607     (error "No previous page")))
 608
 609 (defun elpher-reload-current-page ()
 610   "Reload the current page, discarding any existing cached content."
 611   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 612   (elpher-visit-page elpher-current-page))
 613
 614 (defun elpher-save-pos ()
 615   "Save the current position of point to the current page."
 616   (when elpher-current-page
 617     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 618
 619 (defun elpher-restore-pos ()
 620   "Restore the position of point to that cached in the current page."
 621   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 622     (if pos
 623         (goto-char pos)
 624       (goto-char (point-min)))))
 625
 626 (defun elpher-get-default-url-scheme ()
 627   "Suggest default URL scheme for visiting addresses based on the current page."
 628   (if elpher-current-page
 629       (let* ((address (elpher-page-address elpher-current-page))
 630              (current-type (elpher-address-type address)))
 631         (pcase current-type
 632           ((or (and 'file (guard (not elpher-history)))
 633                `(about ,_))
 634            elpher-default-url-type)
 635           (_
 636            (url-type address))))
 637       elpher-default-url-type))
 638
 639
 640 ;;; Buffer preparation
 641 ;;
 642
 643 (defvar elpher-buffer-name "*elpher*"
 644   "The default name of the Elpher buffer.")
 645
 646 (defun elpher-update-header ()
 647   "If `elpher-use-header' is true, display current page info in window header."
 648   (if (and elpher-use-header elpher-current-page)
 649       (let* ((display-string (elpher-page-display-string elpher-current-page))
 650              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 651              (address (elpher-page-address elpher-current-page))
 652              (tls-string (if (and (not (elpher-address-about-p address))
 653                                   (member (elpher-address-protocol address)
 654                                           '("gophers" "gemini")))
 655                              " [TLS encryption]"
 656                            ""))
 657              (header (concat sanitized-display-string
 658                              (propertize tls-string 'face 'bold))))
 659         (setq header-line-format header))))
 660
 661 (defmacro elpher-with-clean-buffer (&rest args)
 662   "Evaluate ARGS with a clean *elpher* buffer as current."
 663   (declare (debug (body))) ;; Allow edebug to step through body
 664   `(with-current-buffer elpher-buffer-name
 665      (unless (eq major-mode 'elpher-mode)
 666        ;; avoid resetting buffer-local variables
 667        (elpher-mode))
 668      (let ((inhibit-read-only t)
 669            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 670        (setq-local xterm-color--current-fg nil)
 671        (setq-local xterm-color--current-bg nil)
 672        (setq-local network-security-level
 673                    (default-value 'network-security-level))
 674        (erase-buffer)
 675        (elpher-update-header)
 676        ,@args)))
 677
 678 (defun elpher-buffer-message (string &optional line)
 679   "Replace first line in elpher buffer with STRING.
 680 If LINE is non-nil, replace that line instead."
 681   (with-current-buffer elpher-buffer-name
 682     (let ((inhibit-read-only t))
 683       (goto-char (point-min))
 684       (if line
 685           (forward-line line))
 686       (let ((data (match-data)))
 687         (unwind-protect
 688             (progn
 689               (re-search-forward "^.*$")
 690               (replace-match string))
 691           (set-match-data data))))))
 692
 693
 694 ;;; Text Processing
 695 ;;
 696
 697 (defvar elpher-user-coding-system nil
 698   "User-specified coding system to use for decoding text responses.")
 699
 700 (defun elpher-decode (string)
 701   "Decode STRING using autodetected or user-specified coding system."
 702   (decode-coding-string string
 703                         (if elpher-user-coding-system
 704                             elpher-user-coding-system
 705                           (detect-coding-string string t))))
 706
 707 (defun elpher-preprocess-text-response (string)
 708   "Preprocess text selector response contained in STRING.
 709 This involes decoding the character representation, and clearing
 710 away CRs and any terminating period."
 711   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 712                                            (replace-regexp-in-string "\r" "" string))))
 713
 714 ;;; Buttonify urls
 715
 716 (defconst elpher-url-regex
 717   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 718   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 719
 720 (defun elpher-buttonify-urls (string)
 721   "Turn substrings which look like urls in STRING into clickable buttons."
 722   (with-temp-buffer
 723     (insert string)
 724     (goto-char (point-min))
 725     (while (re-search-forward elpher-url-regex nil t)
 726       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 727         (make-text-button (match-beginning 0)
 728                           (match-end 0)
 729                           'elpher-page  page
 730                           'action #'elpher-click-link
 731                           'follow-link t
 732                           'help-echo #'elpher--page-button-help
 733                           'face 'button)))
 734     (buffer-string)))
 735
 736
 737 ;; ANSI colors or XTerm colors (application and filtering)
 738
 739 (or (require 'xterm-color nil t)
 740     (require 'ansi-color))
 741
 742 (defalias 'elpher-color-filter-apply
 743   (if (fboundp 'xterm-color-filter)
 744       (lambda (s)
 745         (let ((_xterm-color-render nil))
 746           (xterm-color-filter s)))
 747     #'ansi-color-filter-apply)
 748   "A function to filter out ANSI escape sequences.")
 749
 750 (defalias 'elpher-color-apply
 751   (if (fboundp 'xterm-color-filter)
 752       #'xterm-color-filter
 753     #'ansi-color-apply)
 754   "A function to apply ANSI escape sequences.")
 755
 756 (defun elpher-text-has-ansi-escapes-p (string)
 757   "Return non-nil if STRING includes an ANSI escape code."
 758   (save-match-data
 759     (string-match "\x1b\\[" string)))
 760
 761
 762 ;; Processing text for display
 763
 764 (defun elpher-process-text-for-display (string)
 765   "Perform any desired processing of STRING prior to display as text.
 766 Currently includes buttonifying URLs and processing ANSI escape codes."
 767   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 768                              (if elpher-filter-ansi-from-text
 769                                  (elpher-color-filter-apply string)
 770                                (elpher-color-apply string))
 771                            string)))
 772
 773
 774 ;;; General network communication
 775 ;;
 776
 777 (defun elpher-network-error (address error)
 778   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 779 ERROR can be either an error object or a string."
 780   (elpher-with-clean-buffer
 781    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 782            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 783            (if (stringp error) error (error-message-string error)) "\n"
 784            (propertize "\n----------------\n\n" 'face 'error)
 785            "Press 'u' to return to the previous page.")))
 786
 787
 788 (defvar elpher-network-timer nil
 789   "Timer used for network connections.")
 790
 791 (defvar elpher-use-tls nil
 792   "If non-nil, use TLS to communicate with gopher servers.")
 793
 794 (defvar elpher-client-certificate nil
 795   "If non-nil, contains client certificate details to use for TLS connections.")
 796
 797 (defun elpher-process-cleanup ()
 798   "Immediately shut down any extant elpher process and timers."
 799   (let ((p (get-process "elpher-process")))
 800     (if p (delete-process p)))
 801   (if (timerp elpher-network-timer)
 802       (cancel-timer elpher-network-timer)))
 803
 804 (defun elpher-make-network-timer (thunk)
 805   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 806 This is just a wraper around `run-at-time' which additionally sets the
 807 buffer-local variable `elpher-network-timer' to allow
 808 `elpher-process-cleanup' to also clear the timer."
 809   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 810     (setq-local elpher-network-timer timer)
 811     timer))
 812
 813 (defun elpher-get-host-response (address default-port query-string response-processor
 814                                          &optional use-tls force-ipv4)
 815   "Generic function for retrieving data from ADDRESS.
 816
 817 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 818 QUERY-STRING is a string sent to the host specified by ADDRESS to
 819 illicet a response.  This response is passed as an argument to the
 820 function RESPONSE-PROCESSOR.
 821
 822 If non-nil, USE-TLS specifies that the connection is to be made over
 823 TLS.  If set to gemini, the certificate verification will be disabled
 824 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 825
 826 If non-nil, FORCE-IPV4 causes the network connection to be made over
 827 ipv4 only.  (The default behaviour when this is not set depends on
 828 the host operating system and the local network capabilities.)"
 829   (if (and use-tls (not (gnutls-available-p)))
 830       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 831     (unless (< (elpher-address-port address) 65536)
 832       (error "Cannot establish network connection: port number > 65536"))
 833     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 834       (setq-local network-security-level 'low)
 835       (setq-local gnutls-verify-error nil))
 836     (condition-case nil
 837         (let* ((kill-buffer-query-functions nil)
 838                (port (elpher-address-port address))
 839                (host (elpher-address-host address))
 840                (service (if (> port 0) port default-port))
 841                (response-string-parts nil)
 842                (bytes-received 0)
 843                (hkbytes-received 0)
 844                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 845                (gnutls-params (list :type 'gnutls-x509pki
 846                                     :hostname host
 847                                     :keylist
 848                                     (elpher-get-current-keylist address)))
 849                (timer (elpher-make-network-timer
 850                                    (lambda ()
 851                                      (elpher-process-cleanup)
 852                                      (cond
 853                                         ; Try again with IPv4
 854                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 855                                        (message "Connection timed out.  Retrying with IPv4.")
 856                                        (elpher-get-host-response address default-port
 857                                                                  query-string
 858                                                                  response-processor
 859                                                                  use-tls t))
 860                                       ((and use-tls
 861                                             (not (eq use-tls 'gemini))
 862                                             (or elpher-auto-disengage-TLS
 863                                                 (y-or-n-p
 864                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 865                                        (setq elpher-use-tls nil)
 866                                        (elpher-get-host-response address default-port
 867                                                                  query-string
 868                                                                  response-processor
 869                                                                  nil force-ipv4))
 870                                       (t
 871                                        (elpher-network-error address "Connection time-out."))))))
 872                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 873                        (make-network-process :name "elpher-process"
 874                                              :host host
 875                                              :family (and (or force-ipv4
 876                                                               elpher-ipv4-always)
 877                                                           'ipv4)
 878                                              :service service
 879                                              :buffer nil
 880                                              :nowait t
 881                                              :tls-parameters
 882                                              (and use-tls
 883                                                   (cons 'gnutls-x509pki
 884                                                         (apply #'gnutls-boot-parameters
 885                                                                gnutls-params)))))))
 886           (setq elpher-network-timer timer)
 887           (set-process-coding-system proc 'binary 'binary)
 888           (set-process-query-on-exit-flag proc nil)
 889           (elpher-buffer-message (concat "Connecting to " host "..."
 890                                          " (press 'u' to abort)"))
 891           (set-process-filter proc
 892                               (lambda (_proc string)
 893                                 (when timer
 894                                   (cancel-timer timer)
 895                                   (setq timer nil))
 896                                 (setq bytes-received (+ bytes-received (length string)))
 897                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 898                                   (when (> new-hkbytes-received hkbytes-received)
 899                                     (setq hkbytes-received new-hkbytes-received)
 900                                     (elpher-buffer-message
 901                                      (concat "("
 902                                              (number-to-string (/ hkbytes-received 10.0))
 903                                              " MB read)")
 904                                      1)))
 905                                 (setq response-string-parts
 906                                       (cons string response-string-parts))))
 907           (set-process-sentinel proc
 908                                 (lambda (proc event)
 909                                   (when timer
 910                                     (cancel-timer timer))
 911                                   (condition-case the-error
 912                                       (cond
 913                                        ((string-prefix-p "open" event)    ; request URL
 914                                         (elpher-buffer-message
 915                                          (concat "Connected to " host ". Receiving data..."
 916                                                  " (press 'u' to abort)"))
 917                                         (let ((inhibit-eol-conversion t))
 918                                           (process-send-string proc query-string)))
 919                                        ((string-prefix-p "deleted" event)) ; do nothing
 920                                        ((and (not response-string-parts)
 921                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 922                                         ; Try again with IPv4
 923                                         (message "Connection failed. Retrying with IPv4.")
 924                                         (elpher-get-host-response address default-port
 925                                                                   query-string
 926                                                                   response-processor
 927                                                                   use-tls t))
 928                                        (response-string-parts
 929                                         (elpher-with-clean-buffer
 930                                          (insert "Data received.  Rendering..."))
 931                                         (funcall response-processor
 932                                                  (apply #'concat (reverse response-string-parts)))
 933                                         (elpher-restore-pos))
 934                                        (t
 935                                         (error "No response from server")))
 936                                     (error
 937                                      (elpher-network-error address the-error)))))
 938           (when socks
 939             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 940             (funcall (process-sentinel proc) proc "open\n")))
 941       (error
 942        (elpher-process-cleanup)
 943        (error "Error initiating connection to server")))))
 944
 945
 946 ;;; Client-side TLS Certificate Management
 947 ;;
 948
 949 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 950   "Generate a key and a self-signed client TLS certificate using openssl.
 951
 952 The Common Name field of the certificate is set to COMMON-NAME.  The
 953 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 954 the key and certificate files to write.
 955
 956 If TEMPORARY is non-nil, the certificate will be given an exporation
 957 period of one day, and the key and certificate files will be deleted
 958 when the certificate is no longer needed for the current session.
 959
 960 Otherwise, the certificate will be given a 100 year expiration period
 961 and the files will not be deleted.
 962
 963 The function returns a list containing the current host name, the
 964 temporary flag, and the key and cert file names in the form required
 965 by `gnutls-boot-parameters`."
 966   (let ((exp-key-file (expand-file-name key-file))
 967         (exp-cert-file (expand-file-name cert-file)))
 968     (condition-case nil
 969         (progn
 970           (call-process elpher-openssl-command nil nil nil
 971                         "req" "-x509" "-newkey" "rsa:2048"
 972                         "-days" (if temporary "1" "36500")
 973                         "-nodes"
 974                         "-subj" (concat "/CN=" common-name)
 975                         "-keyout" exp-key-file
 976                         "-out" exp-cert-file)
 977           (list (elpher-address-host (elpher-page-address elpher-current-page))
 978                 temporary exp-key-file exp-cert-file))
 979       (error
 980        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 981        (error "Program 'openssl', required for certificate generation, not found")))))
 982
 983 (defun elpher-generate-throwaway-certificate ()
 984   "Generate and return details of a throwaway certificate.
 985 The key and certificate files will be deleted when they are no
 986 longer needed for this session."
 987   (let* ((file-base (make-temp-name "elpher"))
 988          (key-file (concat temporary-file-directory file-base ".key"))
 989          (cert-file (concat temporary-file-directory file-base ".crt")))
 990     (elpher-generate-certificate file-base key-file cert-file t)))
 991
 992 (defun elpher-generate-persistent-certificate (file-base common-name)
 993   "Generate and return details of a persistent certificate.
 994 The argument FILE-BASE is used as the base for the key and certificate
 995 files, while COMMON-NAME specifies the common name field of the
 996 certificate.
 997
 998 The key and certificate files are written to in `elpher-certificate-directory'."
 999   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1000          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1001     (elpher-generate-certificate common-name key-file cert-file)))
1002
1003 (defun elpher-get-existing-certificate (file-base)
1004   "Return a certificate object corresponding to an existing certificate.
1005 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1006 the directory `elpher-certificate-directory'."
1007   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1008          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1009     (list (elpher-address-host (elpher-page-address elpher-current-page))
1010           nil
1011           (expand-file-name key-file)
1012           (expand-file-name cert-file))))
1013
1014 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1015   "Install a key+certificate file pair in `elpher-certificate-directory'.
1016 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1017 certificate files to install.  The argument FILE-BASE is used as the
1018 base for the installed key and certificate files."
1019   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1020          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1021     (if (or (file-exists-p key-file)
1022             (file-exists-p cert-file))
1023         (error "A certificate with base name %s is already installed" file-base))
1024     (copy-file key-file-src key-file)
1025     (copy-file cert-file-src cert-file)
1026     (list (elpher-address-host (elpher-page-address elpher-current-page))
1027           nil
1028           (expand-file-name key-file)
1029           (expand-file-name cert-file))))
1030
1031 (defun elpher-list-existing-certificates ()
1032   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1033   (unless (file-directory-p elpher-certificate-directory)
1034     (make-directory elpher-certificate-directory))
1035   (mapcar
1036    (lambda (file)
1037      (file-name-sans-extension file))
1038    (directory-files elpher-certificate-directory nil "\\.key$")))
1039
1040 (defun elpher-forget-current-certificate ()
1041   "Causes any current certificate to be forgotten.)
1042 In the case of throwaway certificates, the key and certificate files
1043 are also deleted."
1044   (interactive)
1045   (when elpher-client-certificate
1046     (unless (and (called-interactively-p 'any)
1047                  (not (y-or-n-p (concat "Really forget client certificate? "
1048                                         "(Throwaway certificates will be deleted.)"))))
1049       (when (cadr elpher-client-certificate)
1050         (delete-file (elt elpher-client-certificate 2))
1051         (delete-file (elt elpher-client-certificate 3)))
1052       (setq elpher-client-certificate nil)
1053       (if (called-interactively-p 'any)
1054           (message "Client certificate forgotten.")))))
1055
1056 (defun elpher-get-current-keylist (address)
1057   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1058
1059 This is obtained from the client certificate described by
1060 `elpher-current-certificate', if one is available and the host for
1061 that certificate matches the host in ADDRESS.
1062
1063 If `elpher-current-certificate' is non-nil, and its host name doesn't
1064 match that of ADDRESS, the certificate is forgotten."
1065   (if elpher-client-certificate
1066       (if (string= (car elpher-client-certificate)
1067                    (elpher-address-host address))
1068           (list (cddr elpher-client-certificate))
1069         (elpher-forget-current-certificate)
1070         (message "Disabling client certificate for new host")
1071         nil)
1072     nil))
1073
1074
1075 ;;; Gopher selector retrieval
1076 ;;
1077
1078 (defun elpher-get-gopher-response (address renderer)
1079   "Get response string from gopher server at ADDRESS and render using RENDERER."
1080   (elpher-get-host-response address 70
1081                             (concat (elpher-gopher-address-selector address) "\r\n")
1082                             renderer
1083                             (or (string= (elpher-address-protocol address) "gophers")
1084                                 elpher-use-tls)))
1085
1086 (defun elpher-get-gopher-page (renderer)
1087   "Getter function for gopher pages.
1088 The RENDERER procedure is used to display the contents of the page
1089 once they are retrieved from the gopher server."
1090   (let* ((address (elpher-page-address elpher-current-page))
1091          (content (elpher-get-cached-content address)))
1092     (if (and content (funcall renderer nil))
1093         (elpher-with-clean-buffer
1094          (insert content)
1095          (elpher-restore-pos))
1096       (elpher-with-clean-buffer
1097        (insert "LOADING... (use 'u' to cancel)\n"))
1098       (condition-case the-error
1099           (elpher-get-gopher-response address renderer)
1100         (error
1101          (elpher-network-error address the-error))))))
1102
1103
1104 ;;; Gopher index rendering
1105 ;;
1106
1107 (defun elpher-insert-margin (&optional type-name)
1108   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1109   (if type-name
1110       (progn
1111         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1112                         (concat
1113                          (propertize "[" 'face 'elpher-margin-brackets)
1114                          (propertize type-name 'face 'elpher-margin-key)
1115                          (propertize "]" 'face 'elpher-margin-brackets))))
1116         (insert " "))
1117     (insert (make-string elpher-margin-width ?\s))))
1118
1119 (defun elpher--page-button-help (_window buffer pos)
1120   "Function called by Emacs to generate mouse-over text.
1121 The arguments specify the BUFFER and the POS within the buffer of the item
1122 for which help is required.  The function returns the help to be
1123 displayed.  The _WINDOW argument is currently unused."
1124   (with-current-buffer buffer
1125     (let ((button (button-at pos)))
1126       (when button
1127         (let* ((page (button-get button 'elpher-page))
1128                (address (elpher-page-address page)))
1129           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1130
1131 (defun elpher-insert-index-record (display-string &optional address)
1132   "Function to insert an index record into the current buffer.
1133 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1134 If ADDRESS is not supplied or nil the record is rendered as an
1135 'information' line."
1136   (let* ((type (if address (elpher-address-type address) nil))
1137          (type-map-entry (cdr (assoc type elpher-type-map))))
1138     (if type-map-entry
1139         (let* ((margin-code (elt type-map-entry 2))
1140                (face (elt type-map-entry 3))
1141                (filtered-display-string (elpher-color-filter-apply display-string))
1142                (page (elpher-make-page filtered-display-string address)))
1143           (elpher-insert-margin margin-code)
1144           (insert-text-button filtered-display-string
1145                               'face face
1146                               'elpher-page page
1147                               'action #'elpher-click-link
1148                               'follow-link t
1149                               'help-echo #'elpher--page-button-help))
1150       (pcase type
1151         ('nil ;; Information
1152          (elpher-insert-margin)
1153          (let ((propertized-display-string
1154                 (propertize display-string 'face 'elpher-info)))
1155            (insert (elpher-process-text-for-display propertized-display-string))))
1156         (`(gopher ,selector-type) ;; Unknown
1157          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1158          (insert (propertize display-string
1159                              'face 'elpher-unknown)))))
1160     (insert "\n")))
1161
1162 (defun elpher-click-link (button)
1163   "Function called when the gopher link BUTTON is activated."
1164   (let ((page (button-get button 'elpher-page)))
1165     (elpher-visit-page page)))
1166
1167 (defun elpher-render-index (data &optional _mime-type-string)
1168   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1169   (elpher-with-clean-buffer
1170    (if (not data)
1171        t
1172      (let ((data-processed (elpher-preprocess-text-response data)))
1173        (dolist (line (split-string data-processed "\n"))
1174          (ignore-errors
1175            (unless (= (length line) 0)
1176              (let* ((type (elt line 0))
1177                     (fields (split-string (substring line 1) "\t"))
1178                     (display-string (elt fields 0))
1179                     (selector (elt fields 1))
1180                     (host (elt fields 2))
1181                     (port (if (elt fields 3)
1182                               (string-to-number (elt fields 3))
1183                             nil))
1184                     (address (elpher-make-gopher-address type selector host port)))
1185                (elpher-insert-index-record display-string address))))))
1186      (elpher-cache-content (elpher-page-address elpher-current-page)
1187                            (buffer-string)))))
1188
1189
1190 ;;; Gopher text rendering
1191 ;;
1192
1193 (defun elpher-render-text (data &optional _mime-type-string)
1194   "Render DATA as text.  MIME-TYPE-STRING is unused."
1195   (elpher-with-clean-buffer
1196    (if (not data)
1197        t
1198      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1199      (elpher-cache-content
1200       (elpher-page-address elpher-current-page)
1201       (buffer-string)))))
1202
1203
1204 ;;; Image retrieval
1205 ;;
1206
1207 (defun elpher-render-image (data &optional _mime-type-string)
1208   "Display DATA as image.  MIME-TYPE-STRING is unused."
1209   (if (not data)
1210       nil
1211     (if (display-images-p)
1212         (let* ((image (create-image
1213                        data
1214                        nil t)))
1215           (if (not image)
1216               (error "Unsupported image format")
1217             (let ((window (get-buffer-window elpher-buffer-name)))
1218               (when window
1219                 (setf (image-property image :max-width) (window-body-width window t))
1220                 (setf (image-property image :max-height) (window-body-height window t))))
1221             (elpher-with-clean-buffer
1222              (insert-image image)
1223              (elpher-restore-pos))))
1224       (elpher-render-download data))))
1225
1226
1227 ;;; Gopher search retrieval and rendering
1228 ;;
1229
1230 (defun elpher-get-gopher-query-page (renderer)
1231   "Getter for gopher addresses requiring input.
1232 The response is rendered using the rendering function RENDERER."
1233   (let* ((address (elpher-page-address elpher-current-page))
1234          (content (elpher-get-cached-content address))
1235          (aborted t))
1236     (if (and content (funcall renderer nil))
1237         (elpher-with-clean-buffer
1238          (insert content)
1239          (elpher-restore-pos)
1240          (message "Displaying cached search results.  Reload to perform a new search."))
1241       (unwind-protect
1242           (let* ((query-string (read-string "Query: "))
1243                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1244                  (search-address (elpher-make-gopher-address ?1
1245                                                              query-selector
1246                                                              (elpher-address-host address)
1247                                                              (elpher-address-port address)
1248                                                              (equal (elpher-address-type address) "gophers"))))
1249             (setq aborted nil)
1250
1251             (elpher-with-clean-buffer
1252              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1253             (elpher-get-gopher-response search-address renderer))
1254         (if aborted
1255             (elpher-visit-previous-page))))))
1256
1257
1258 ;;; Raw server response rendering
1259 ;;
1260
1261 (defun elpher-render-raw (data &optional mime-type-string)
1262   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1263   (if (not data)
1264       nil
1265     (elpher-with-clean-buffer
1266      (when mime-type-string
1267        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1268      (insert data)
1269      (goto-char (point-min)))
1270     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1271
1272
1273 ;;; File save "rendering"
1274 ;;
1275
1276 (defun elpher-render-download (data &optional _mime-type-string)
1277   "Save DATA to file.  MIME-TYPE-STRING is unused."
1278   (if (not data)
1279       nil
1280     (let* ((address (elpher-page-address elpher-current-page))
1281            (selector (if (elpher-address-gopher-p address)
1282                          (elpher-gopher-address-selector address)
1283                        (elpher-address-filename address))))
1284       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1285       (let* ((filename-proposal (file-name-nondirectory selector))
1286              (filename (read-file-name "Download complete. Save file as: "
1287                                        nil nil nil
1288                                        (if (> (length filename-proposal) 0)
1289                                            filename-proposal
1290                                          "download.file"))))
1291         (let ((coding-system-for-write 'binary))
1292           (with-temp-file filename
1293             (insert data)))
1294         (message (format "Saved to file %s." filename))))))
1295
1296
1297 ;;; HTML rendering
1298 ;;
1299
1300 (defun elpher-render-html (data &optional _mime-type-string)
1301   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1302   (elpher-with-clean-buffer
1303    (if (not data)
1304        t
1305      (let ((dom (with-temp-buffer
1306                   (insert data)
1307                   (libxml-parse-html-region (point-min) (point-max)))))
1308        (shr-insert-document dom)))))
1309
1310
1311 ;;; Gemini page retrieval
1312 ;;
1313
1314 (defvar elpher-gemini-redirect-chain)
1315
1316 (defun elpher-get-gemini-response (address renderer)
1317   "Get response string from gemini server at ADDRESS and render using RENDERER."
1318   (elpher-get-host-response address 1965
1319                             (concat (elpher-address-to-url address) "\r\n")
1320                             (lambda (response-string)
1321                               (elpher-process-gemini-response response-string renderer))
1322                             'gemini))
1323
1324 (defun elpher-parse-gemini-response (response)
1325   "Parse the RESPONSE string and return a list of components.
1326 The list is of the form (code meta body).  A response of nil implies
1327 that the response was malformed."
1328   (let ((header-end-idx (string-match "\r\n" response)))
1329     (if header-end-idx
1330         (let ((header (string-trim (substring response 0 header-end-idx)))
1331               (body (substring response (+ header-end-idx 2))))
1332           (if (>= (length header) 2)
1333               (let ((code (substring header 0 2))
1334                     (meta (string-trim (substring header 2))))
1335                 (list code meta body))
1336             (error "Malformed response: No response status found in header %s" header)))
1337       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1338
1339 (defun elpher-process-gemini-response (response-string renderer)
1340   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1341   (let ((response-components (elpher-parse-gemini-response response-string)))
1342     (let ((response-code (elt response-components 0))
1343           (response-meta (elt response-components 1))
1344           (response-body (elt response-components 2)))
1345       (pcase (elt response-code 0)
1346         (?1 ; Input required
1347          (elpher-with-clean-buffer
1348           (insert "Gemini server is requesting input."))
1349          (let* ((query-string
1350                  (if (eq (elt response-code 1) ?1)
1351                      (read-passwd (concat response-meta ": "))
1352                    (read-string (concat response-meta ": "))))
1353                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1354                 (old-fname (url-filename query-address)))
1355            (setf (url-filename query-address)
1356                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1357            (elpher-get-gemini-response query-address renderer)))
1358         (?2 ; Normal response
1359          (funcall renderer response-body response-meta))
1360         (?3 ; Redirect
1361          (message "Following redirect to %s" response-meta)
1362          (if (>= (length elpher-gemini-redirect-chain) 5)
1363              (error "More than 5 consecutive redirects followed"))
1364          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1365            (if (member redirect-address elpher-gemini-redirect-chain)
1366                (error "Redirect loop detected"))
1367            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1368                (error "Server tried to automatically redirect to non-gemini URL: %s"
1369                       response-meta))
1370            (elpher-page-set-address elpher-current-page redirect-address)
1371            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1372            (elpher-get-gemini-response redirect-address renderer)))
1373         (?4 ; Temporary failure
1374          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1375                 response-code response-meta))
1376         (?5 ; Permanent failure
1377          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1378                 response-code response-meta))
1379         (?6 ; Client certificate required
1380          (elpher-with-clean-buffer
1381           (if elpher-client-certificate
1382               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1383             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1384           (auto-fill-mode 1)
1385           (elpher-gemini-insert-text response-meta))
1386          (let ((chosen-certificate (elpher-choose-client-certificate)))
1387            (unless chosen-certificate
1388              (error "Gemini server requires a client certificate and none was provided"))
1389            (setq elpher-client-certificate chosen-certificate))
1390          (elpher-with-clean-buffer)
1391          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1392         (_other
1393          (error "Gemini server response unknown: %s %s"
1394                 response-code response-meta))))))
1395
1396 (defun elpher--read-answer-polyfill (question answers)
1397   "Polyfill for `read-answer' in Emacs 26.1.
1398 QUESTION is a string containing a question, and ANSWERS
1399 is a list of possible answers."
1400     (completing-read question (mapcar 'identity answers)))
1401
1402 (if (fboundp 'read-answer)
1403     (defalias 'elpher-read-answer 'read-answer)
1404   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1405
1406 (defun elpher-choose-client-certificate ()
1407   "Prompt for a client certificate to use to establish a TLS connection."
1408   (let* ((read-answer-short t))
1409     (pcase (read-answer "What do you want to do? "
1410                         '(("throwaway" ?t
1411                            "generate and use throw-away certificate")
1412                           ("persistent" ?p
1413                            "generate new or use existing persistent certificate")
1414                           ("abort" ?a
1415                            "stop immediately")))
1416       ("throwaway"
1417        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1418       ("persistent"
1419        (let* ((existing-certificates (elpher-list-existing-certificates))
1420               (file-base (completing-read
1421                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1422                           existing-certificates)))
1423          (if (string-empty-p (string-trim file-base))
1424              nil
1425            (if (member file-base existing-certificates)
1426                (setq elpher-client-certificate
1427                      (elpher-get-existing-certificate file-base))
1428              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1429                                  '(("new" ?n
1430                                     "generate new certificate")
1431                                    ("install" ?i
1432                                     "install existing certificate")
1433                                    ("abort" ?a
1434                                     "stop immediately")))
1435                ("new"
1436                 (let ((common-name (read-string "Common Name field for new certificate: "
1437                                                 file-base)))
1438                   (message "New key and self-signed certificate written to %s"
1439                            elpher-certificate-directory)
1440                   (elpher-generate-persistent-certificate file-base common-name)))
1441                ("install"
1442                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1443                        (key-file (read-file-name "Key file: " nil nil t)))
1444                   (message "Key and certificate installed in %s for future use"
1445                            elpher-certificate-directory)
1446                   (elpher-install-and-use-existing-certificate key-file
1447                                                                cert-file
1448                                                                file-base)))
1449                ("abort" nil))))))
1450       ("abort" nil))))
1451
1452 (defun elpher-get-gemini-page (renderer)
1453   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1454   (let* ((address (elpher-page-address elpher-current-page))
1455          (content (elpher-get-cached-content address)))
1456     (condition-case the-error
1457         (if (and content (funcall renderer nil))
1458             (elpher-with-clean-buffer
1459              (insert content)
1460              (elpher-restore-pos))
1461           (elpher-with-clean-buffer
1462            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1463           (setq elpher-gemini-redirect-chain nil)
1464           (elpher-get-gemini-response address renderer))
1465       (error
1466        (elpher-network-error address the-error)))))
1467
1468 ;;; Gemini page rendering
1469 ;;
1470
1471 (defun elpher-render-gemini (body &optional mime-type-string)
1472   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1473   (if (not body)
1474       t
1475     (let* ((mime-type-string* (if (or (not mime-type-string)
1476                                       (string-empty-p mime-type-string))
1477                                   "text/gemini; charset=utf-8"
1478                                 mime-type-string))
1479            (mime-type-split (split-string mime-type-string* ";" t))
1480            (mime-type (string-trim (car mime-type-split)))
1481            (parameters (mapcar (lambda (s)
1482                                  (let ((key-val (split-string s "=")))
1483                                    (list (downcase (string-trim (car key-val)))
1484                                          (downcase (string-trim (cadr key-val))))))
1485                                (cdr mime-type-split))))
1486       (when (string-prefix-p "text/" mime-type)
1487         (setq body (decode-coding-string
1488                     body
1489                     (if (assoc "charset" parameters)
1490                         (intern (cadr (assoc "charset" parameters)))
1491                       'utf-8)))
1492         (setq body (replace-regexp-in-string "\r" "" body)))
1493       (pcase mime-type
1494         ((or "text/gemini" "")
1495          (elpher-render-gemini-map body parameters))
1496         ("text/html"
1497          (elpher-render-html body))
1498         ((pred (string-prefix-p "text/"))
1499          (elpher-render-gemini-plain-text body parameters))
1500         ((pred (string-prefix-p "image/"))
1501          (elpher-render-image body))
1502         (_other
1503          (elpher-render-download body))))))
1504
1505 (defun elpher-gemini-get-link-url (link-line)
1506   "Extract the url portion of LINK-LINE, a gemini map file link line.
1507 Returns nil in the event that the contents of the line following the
1508 => prefix are empty."
1509   (let ((l (split-string (substring link-line 2))))
1510     (if l
1511         (string-trim (elt l 0))
1512       nil)))
1513
1514 (defun elpher-gemini-get-link-display-string (link-line)
1515   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1516 Return nil if this portion is not provided."
1517   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1518          (idx (string-match "[ \t]" rest)))
1519     (and idx
1520          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1521
1522 (defun elpher-collapse-dot-sequences (filename)
1523   "Collapse dot sequences in the (absolute) FILENAME.
1524 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1525   (let* ((path (split-string filename "/" t))
1526          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1527          (path-reversed-normalized
1528           (seq-reduce (lambda (a b)
1529                         (cond ((equal b "..") (cdr a))
1530                               ((equal b ".") a)
1531                               (t (cons b a))))
1532                       path nil))
1533          (path-normalized (reverse path-reversed-normalized)))
1534     (if path-normalized
1535         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1536       "/")))
1537
1538 (defun elpher-address-from-gemini-url (url)
1539   "Extract address from URL with defaults as per gemini map files.
1540 While there's obviously some redundancy here between this function and
1541 `elpher-address-from-url', gemini map file URLs require enough special
1542 treatment that a separate function is warranted."
1543   (let ((address (url-generic-parse-url url))
1544         (current-address (elpher-page-address elpher-current-page)))
1545     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1546       (if (url-host address) ;if there is an explicit host, filenames are absolute
1547           (if (string-empty-p (url-filename address))
1548               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1549         (setf (url-host address) (url-host current-address))
1550         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1551         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1552         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1553           (setf (url-filename address)
1554                 (concat (file-name-directory (url-filename current-address))
1555                         (url-filename address)))))
1556       (when (url-host address)
1557         (setf (url-host address) (puny-encode-domain (url-host address))))
1558       (unless (url-type address)
1559         (setf (url-type address) (url-type current-address)))
1560       (when (equal (url-type address) "gemini")
1561         (setf (url-filename address)
1562               (elpher-collapse-dot-sequences (url-filename address)))))
1563     (elpher-remove-redundant-ports address)))
1564
1565 (defun elpher-gemini-insert-link (link-line)
1566   "Insert link described by LINK-LINE into a text/gemini document."
1567   (let ((url (elpher-gemini-get-link-url link-line)))
1568     (when url
1569       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1570              (address (elpher-address-from-gemini-url url))
1571              (type (if address (elpher-address-type address) nil))
1572              (type-map-entry (cdr (assoc type elpher-type-map)))
1573              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1574         (when type-map-entry
1575           (insert elpher-gemini-link-string)
1576           (let* ((face (elt type-map-entry 3))
1577                  (display-string (or given-display-string
1578                                      (elpher-address-to-iri address)))
1579                  (page (elpher-make-page display-string
1580                                          address)))
1581             (insert-text-button display-string
1582                                 'face face
1583                                 'elpher-page page
1584                                 'action #'elpher-click-link
1585                                 'follow-link t
1586                                 'help-echo #'elpher--page-button-help))
1587           (newline))))))
1588
1589 (defun elpher-gemini-insert-header (header-line)
1590   "Insert header described by HEADER-LINE into a text/gemini document.
1591 The gemini map file line describing the header is given
1592 by HEADER-LINE."
1593   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1594     (let* ((level (length (match-string 1 header-line)))
1595            (header (substring header-line (match-end 0)))
1596            (face (pcase level
1597                    (1 'elpher-gemini-heading1)
1598                    (2 'elpher-gemini-heading2)
1599                    (3 'elpher-gemini-heading3)
1600                    (_ 'default)))
1601            (fill-column (if (display-graphic-p)
1602                             (/ (* fill-column
1603                                   (font-get (font-spec :name (face-font 'default)) :size))
1604                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1605       (unless (display-graphic-p)
1606         (insert (make-string level ?#) " "))
1607       (insert (propertize header
1608                           'face face
1609                           'gemini-heading t
1610                           'rear-nonsticky t))
1611       (newline))))
1612
1613 (defun elpher-gemini-insert-text (text-line)
1614   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1615 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1616 width defined by `elpher-gemini-max-fill-width'."
1617   (string-match
1618    (rx (: line-start
1619           (optional
1620            (group (or (: "*" (+ (any " \t")))
1621                       (: ">" (* (any " \t"))))))))
1622    text-line)
1623   (let* ((line-prefix (match-string 1 text-line))
1624          (processed-text-line
1625           (if line-prefix
1626               (cond ((string-prefix-p "*" line-prefix)
1627                      (concat
1628                       (replace-regexp-in-string "\\*"
1629                                                 elpher-gemini-bullet-string
1630                                                 (match-string 0 text-line))
1631                       (substring text-line (match-end 0))))
1632                     ((string-prefix-p ">" line-prefix)
1633                      (propertize text-line 'face 'elpher-gemini-quoted))
1634                     (t text-line))
1635             text-line))
1636          (fill-prefix (if line-prefix
1637                           (make-string (length (match-string 0 text-line)) ?\s)
1638                         "")))
1639     (insert (elpher-process-text-for-display processed-text-line))
1640     (newline)))
1641
1642 (defun elpher-gemini-pref-expand-collapse (button)
1643   "Function called when the preformatted text toggle BUTTON is activated."
1644   (let ((id (button-get button 'pref-id)))
1645     (if (invisible-p id)
1646         (remove-from-invisibility-spec id)
1647       (add-to-invisibility-spec id))
1648     (redraw-display)))
1649
1650 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1651   "Insert a button for toggling the visibility of preformatted text.
1652 If non-nil, ALT-TEXT is displayed alongside the button."
1653   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1654          (pref-id (intern (concat "pref-"
1655                                   (number-to-string (point))
1656                                   "-"
1657                                   url-string))))
1658     (insert elpher-gemini-preformatted-toggle-bullet)
1659     (when alt-text
1660       (insert (propertize (concat alt-text " ")
1661                           'face 'elpher-gemin-preformatted)))
1662     (insert-text-button elpher-gemini-preformatted-toggle-label
1663                         'action #'elpher-gemini-pref-expand-collapse
1664                         'pref-id pref-id
1665                         'face 'elpher-gemini-preformatted-toggle)
1666     (add-to-invisibility-spec pref-id)
1667     (newline)
1668     pref-id))
1669
1670 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1671   "Insert a LINE of preformatted text.
1672 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1673 can be used to toggle the display of the preformatted text."
1674   (insert (propertize (concat (elpher-process-text-for-display
1675                                (propertize line 'face 'elpher-gemini-preformatted))
1676                               "\n")
1677                       'invisible pref-id
1678                       'rear-nonsticky t)))
1679
1680 (defun elpher-render-gemini-map (data _parameters)
1681   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1682   (elpher-with-clean-buffer
1683    (auto-fill-mode 1)
1684    (setq-local buffer-invisibility-spec nil)
1685    (let ((preformatted nil)
1686          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1687      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1688      (dolist (line (split-string data "\n"))
1689        (pcase line
1690          ((rx (: string-start "```" (opt (let alt-text (+ any)))))
1691           (setq preformatted
1692                 (if preformatted
1693                     nil
1694                   (if elpher-gemini-hide-preformatted
1695                       (elpher-gemini-insert-preformatted-toggler alt-text)
1696                     t))))
1697          ((guard  preformatted)
1698           (elpher-gemini-insert-preformatted-line line preformatted))
1699          ((pred (string-prefix-p "=>"))
1700           (elpher-gemini-insert-link line))
1701          ((pred (string-prefix-p "#"))
1702           (elpher-gemini-insert-header line))
1703          (_ (elpher-gemini-insert-text line))))
1704    (elpher-cache-content
1705     (elpher-page-address elpher-current-page)
1706     (buffer-string)))))
1707
1708 (defun elpher-render-gemini-plain-text (data _parameters)
1709   "Render DATA as plain text file.  PARAMETERS is currently unused."
1710   (elpher-with-clean-buffer
1711    (insert (elpher-process-text-for-display data))
1712    (elpher-cache-content
1713     (elpher-page-address elpher-current-page)
1714     (buffer-string))))
1715
1716 (defun elpher-build-current-imenu-index ()
1717   "Build imenu index for current elpher buffer."
1718   (save-excursion
1719     (goto-char (point-min))
1720     (let ((match nil)
1721           (headers nil))
1722       (while (setq match (text-property-search-forward 'gemini-heading t t))
1723         (push (cons
1724                (buffer-substring-no-properties (prop-match-beginning match)
1725                                                (prop-match-end match))
1726                (prop-match-beginning match))
1727               headers))
1728       (reverse headers))))
1729
1730
1731 ;;; Finger page connection
1732 ;;
1733
1734 (defun elpher-get-finger-page (renderer)
1735   "Opens a finger connection to the current page address.
1736 The result is rendered using RENDERER."
1737   (let* ((address (elpher-page-address elpher-current-page))
1738          (content (elpher-get-cached-content address)))
1739     (if (and content (funcall renderer nil))
1740         (elpher-with-clean-buffer
1741          (insert content)
1742          (elpher-restore-pos))
1743       (elpher-with-clean-buffer
1744        (insert "LOADING... (use 'u' to cancel)\n"))
1745       (condition-case the-error
1746           (let* ((kill-buffer-query-functions nil)
1747                  (user (let ((filename (elpher-address-filename address)))
1748                          (if (> (length filename) 1)
1749                              (substring filename 1)
1750                            (elpher-address-user address)))))
1751             (elpher-get-host-response address 79
1752                                       (concat user "\r\n")
1753                                       renderer))
1754         (error
1755          (elpher-network-error address the-error))))))
1756
1757
1758 ;;; Telnet page connection
1759 ;;
1760
1761 (defun elpher-get-telnet-page (renderer)
1762   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1763   (when renderer
1764     (elpher-visit-previous-page)
1765     (error "Command not supported for telnet URLs"))
1766   (let* ((address (elpher-page-address elpher-current-page))
1767          (host (elpher-address-host address))
1768          (port (elpher-address-port address)))
1769     (elpher-visit-previous-page)
1770     (if (> port 0)
1771         (telnet host port)
1772       (telnet host))))
1773
1774
1775 ;;; Other URL page opening
1776 ;;
1777
1778 (defun elpher-get-other-url-page (renderer)
1779   "Getter which attempts to open the URL specified by the current page.
1780 The RENDERER argument to this getter must be nil."
1781   (when renderer
1782     (elpher-visit-previous-page)
1783     (error "Command not supported for general URLs"))
1784   (let* ((address (elpher-page-address elpher-current-page))
1785          (url (elpher-address-to-url address)))
1786     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1787     (message "Opening URL...")
1788     (if elpher-open-urls-with-eww
1789         (browse-web url)
1790       (browse-url url))))
1791
1792
1793 ;;; File page
1794 ;;
1795
1796 (defun elpher-get-file-page (renderer)
1797   "Getter which renders a local file using RENDERER.
1798 Assumes UTF-8 encoding for all text files."
1799   (let* ((address (elpher-page-address elpher-current-page))
1800          (filename (elpher-address-filename address)))
1801     (unless (file-exists-p filename)
1802       (elpher-visit-previous-page)
1803         (error "File not found"))
1804     (unless (file-readable-p filename)
1805       (elpher-visit-previous-page)
1806         (error "Could not read from file"))
1807     (let ((body (with-temp-buffer
1808        (let ((coding-system-for-read 'binary)
1809              (coding-system-for-write 'binary))
1810          (insert-file-contents-literally filename)
1811          (encode-coding-string (buffer-string) 'raw-text)))))
1812        (if renderer
1813            (funcall renderer body nil)
1814          (pcase (file-name-extension filename)
1815            ((or  "gmi" "gemini")
1816             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1817            ((or "htm" "html")
1818             (elpher-render-html (decode-coding-string body 'utf-8)))
1819            ((or "txt" "")
1820             (elpher-render-text (decode-coding-string body 'utf-8)))
1821            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1822             (elpher-render-image body))
1823            ((or "gopher" "gophermap")
1824             (elpher-render-index (elpher-decode body)))
1825            (_
1826             (elpher-render-download body))))
1827        (elpher-restore-pos))))
1828
1829
1830 ;;; Welcome page retrieval
1831 ;;
1832
1833 (defun elpher-get-welcome-page (renderer)
1834   "Getter which displays the welcome page (RENDERER must be nil)."
1835   (when renderer
1836     (elpher-visit-previous-page)
1837     (error "Command not supported for welcome page"))
1838   (elpher-with-clean-buffer
1839    (insert "     --------------------------------------------\n"
1840            "           Elpher Gopher and Gemini Client       \n"
1841            "                   version " elpher-version "\n"
1842            "     --------------------------------------------\n"
1843            "\n"
1844            "Default bindings:\n"
1845            "\n"
1846            " - TAB/Shift-TAB: next/prev item on current page\n"
1847            " - RET/mouse-1: open item under cursor\n"
1848            " - m: select an item on current page by name (autocompletes)\n"
1849            " - u/mouse-3/U: return to previous page or to the start page\n"
1850            " - g: go to a particular address (gopher, gemini, finger)\n"
1851            " - o/O: open a different address selector or the root menu of the current server\n"
1852            " - d/D: download item under cursor or current page\n"
1853            " - i/I: info on item under cursor or current page\n"
1854            " - c/C: copy URL representation of item under cursor or current page\n"
1855            " - a/A: bookmark the item under cursor or current page\n"
1856            " - B: list all bookmarks\n"
1857            " - s/S: show current history stack or all previously visted pages\n"
1858            " - r: redraw current page (using cached contents if available)\n"
1859            " - R: reload current page (regenerates cache)\n"
1860            " - !: set character coding system for gopher (default is to autodetect)\n"
1861            " - T: toggle TLS gopher mode\n"
1862            " - F: forget/discard current TLS client certificate\n"
1863            " - .: display the raw server response for the current page\n"
1864            "\n"
1865            "Start your exploration of gopher space and gemini:\n")
1866    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1867                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1868    (elpher-insert-index-record "Project Gemini home page"
1869                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1870    (insert "\n"
1871            "Alternatively, select a search engine and enter some search terms:\n")
1872    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1873                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1874    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1875                                (elpher-address-from-url "gemini://geminispace.info/search"))
1876    (insert "\n"
1877            "Your bookmarks are stored in your ")
1878    (insert-text-button "bookmark list"
1879                        'face 'link
1880                        'action #'elpher-click-link
1881                        'follow-link t
1882                        'help-echo #'elpher--page-button-help
1883                        'elpher-page
1884                        (elpher-make-page "Elpher Bookmarks"
1885                                          (elpher-make-about-address 'bookmarks)))
1886    (insert ".\n")
1887    (insert (propertize
1888             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1889             'face 'shadow))
1890    (insert "\n"
1891            "The gopher home of the Elpher project is here:\n")
1892    (elpher-insert-index-record "The Elpher Project Page"
1893                                (elpher-make-gopher-address ?1
1894                                                            "/projects/elpher/"
1895                                                            "thelambdalab.xyz"
1896                                                            70))
1897    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1898      (insert "\n"
1899              "The following info documentation is available:\n"
1900              "   - ")
1901      (insert-text-button "Elpher Manual"
1902                          'face 'link
1903                          'action (lambda (_)
1904                                    (interactive)
1905                                    (info "(elpher)"))
1906                          'follow-link t
1907                          'help-echo help-string)
1908      (insert "\n   - ")
1909      (insert-text-button "Changes introduced by the latest release"
1910                        'face 'link
1911                        'action (lambda (_)
1912                                  (interactive)
1913                                  (info "(elpher)News"))
1914                        'follow-link t
1915                        'help-echo help-string))
1916    (insert "\n")
1917    (insert (propertize
1918             (concat "(These documents should be available if you have installed Elpher\n"
1919                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1920                     " manual yourself.)\n")
1921             'face 'shadow))
1922    (elpher-restore-pos)))
1923
1924
1925 ;;; History page retrieval
1926 ;;
1927
1928 (defun elpher-show-history ()
1929   "Show the current contents of elpher's history stack.
1930 Use \\[elpher-show-visited-pages] to see the entire history.
1931 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1932   (interactive)
1933   (elpher-visit-page
1934    (elpher-make-page "Current History Stack"
1935                      (elpher-make-about-address 'history))))
1936
1937 (defun elpher-show-visited-pages ()
1938   "Show the all the pages you've visited using Elpher.
1939 Use \\[elpher-show-history] to see just the current history stack.
1940 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1941   (interactive)
1942   (elpher-visit-page
1943    (elpher-make-page "Elpher Visted Pages"
1944                      (elpher-make-about-address 'visited-pages))))
1945
1946 (defun elpher-get-history-page (renderer)
1947   "Getter which displays the history page (RENDERER must be nil)."
1948   (when renderer
1949     (elpher-visit-previous-page)
1950     (error "Command not supported for history page"))
1951   (elpher-display-history-links elpher-history "Current history stack"))
1952
1953 (defun elpher-get-visited-pages-page (renderer)
1954   "Getter which displays the list of visited pages (RENDERER must be nil)."
1955   (when renderer
1956     (elpher-visit-previous-page)
1957     (error "Command not supported for history page"))
1958   (elpher-display-history-links
1959    (seq-filter (lambda (page)
1960                  (not (elpher-address-about-p (elpher-page-address page))))
1961                elpher-visited-pages)
1962    "All visited pages"))
1963
1964 (defun elpher-display-history-links (pages title)
1965   "Show all PAGES in an Elpher buffer with a given TITLE."
1966   (let* ((title-line (concat " ---- " title " ----"))
1967          (footer-line (make-string (length title-line) ?-)))
1968     (elpher-with-clean-buffer
1969      (insert title-line "\n\n")
1970      (if pages
1971          (dolist (page pages)
1972            (when page
1973              (let ((display-string (elpher-page-display-string page))
1974                    (address (elpher-page-address page)))
1975                (elpher-insert-index-record display-string address))))
1976        (insert "No history items found.\n"))
1977      (insert "\n " footer-line "\n"
1978              "Select an entry or press 'u' to return to the previous page.")
1979      (elpher-restore-pos))))
1980
1981
1982 ;;; Bookmarks
1983 ;;
1984
1985 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1986 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1987 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1988 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1989
1990 (defvar elpher-bookmark-link nil
1991   "Prefer bookmarking a link or the current page.
1992 Bind this variable dynamically, or set it to t.
1993 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1994 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1995
1996 (defun elpher-bookmark-make-record ()
1997   "Return a bookmark record.
1998 If `elpher-bookmark-link' is non-nil and point is on a link button,
1999 return a bookmark record for that link.  Otherwise, return a bookmark
2000 record for the current elpher page."
2001   (let* ((button (and elpher-bookmark-link (button-at (point))))
2002          (page (if button
2003                    (button-get button 'elpher-page)
2004                  elpher-current-page)))
2005     (unless page
2006       (error "Cannot bookmark this link"))
2007     (let* ((address (elpher-page-address page))
2008            (url (elpher-address-to-url address))
2009            (display-string (elpher-page-display-string page))
2010            (pos (if button nil (point))))
2011       (if (elpher-address-about-p address)
2012           (error "Cannot bookmark %s" display-string)
2013         `(,display-string
2014           (defaults . (,display-string))
2015           (position . ,pos)
2016           (location . ,url)
2017           (handler . elpher-bookmark-jump))))))
2018
2019 ;;;###autoload
2020 (defun elpher-bookmark-jump (bookmark)
2021   "Handler used to open a bookmark using elpher.
2022 The argument BOOKMARK is a bookmark record passed to the function.
2023 This handler is responsible for loading the bookmark in some buffer,
2024 then making that buffer the current buffer.  It should not switch
2025 to the buffer."
2026   (let* ((url (cdr (assq 'location bookmark)))
2027          (cleaned-url (string-trim url))
2028          (page (elpher-page-from-url cleaned-url))
2029          (buffer (get-buffer-create elpher-buffer-name)))
2030     (elpher-with-clean-buffer
2031      (elpher-visit-page page))
2032     (set-buffer buffer)
2033     nil))
2034
2035 (defun elpher-bookmark-link ()
2036   "Bookmark the link at point.
2037 To bookmark the current page, use \\[elpher-bookmark-current]."
2038   (interactive)
2039   (let ((elpher-bookmark-link t))
2040     (bookmark-set-no-overwrite)))
2041
2042 (defun elpher-bookmark-current ()
2043   "Bookmark the current page.
2044 To bookmark the link at point use \\[elpher-bookmark-link]."
2045   (interactive)
2046   (call-interactively #'bookmark-set-no-overwrite))
2047
2048 (defun elpher-bookmark-import (file)
2049   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2050   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2051                               (file-readable-p elpher-bookmarks-file))
2052                          elpher-bookmarks-file
2053                        (read-file-name "Old Elpher bookmarks: "
2054                                        user-emacs-directory nil t
2055                                        "elpher-bookmarks"))))
2056   (dolist (bookmark (with-temp-buffer
2057                       (insert-file-contents file)
2058                       (read (current-buffer))))
2059     (let* ((display-string (car bookmark))
2060            (url (cadr bookmark))
2061            (record `(,display-string
2062                      (location . ,url)
2063                      (handler . elpher-bookmark-jump))))
2064       (bookmark-store display-string (cdr record) t)))
2065   (bookmark-save))
2066
2067 (defun elpher-get-bookmarks-page (renderer)
2068   "Getter which displays the bookmarks (RENDERER must be nil)."
2069   (when renderer
2070     (elpher-visit-previous-page)
2071     (error "Command not supported for bookmarks page"))
2072
2073   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2074                                      elpher-bookmarks-file)
2075                                 (locate-user-emacs-file "elpher-bookmarks"))))
2076     (when (and (file-readable-p old-bookmarks-file)
2077                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2078                                  old-bookmarks-file
2079                                  "\" found. Import now?")))
2080       (elpher-bookmark-import old-bookmarks-file)
2081       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2082
2083   (if (and elpher-use-emacs-bookmark-menu
2084            elpher-history)
2085       (progn
2086         (elpher-visit-previous-page)
2087         (call-interactively #'bookmark-bmenu-list))
2088     (elpher-with-clean-buffer
2089      (insert " ---- Elpher Bookmarks ---- \n\n")
2090      (bookmark-maybe-load-default-file)
2091      (dolist (bookmark (bookmark-maybe-sort-alist))
2092        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2093          (let* ((name (car bookmark))
2094                 (url (alist-get 'location (cdr bookmark)))
2095                 (address (elpher-address-from-url url)))
2096            (elpher-insert-index-record name address))))
2097      (when (<= (line-number-at-pos) 3)
2098        (insert "No bookmarked pages found.\n"))
2099      (insert "\n --------------------------\n\n"
2100              "Select an entry or press 'u' to return to the previous page.\n\n"
2101              "Bookmarks can be renamed or deleted via the ")
2102      (insert-text-button "Emacs bookmark menu"
2103                          'action (lambda (_)
2104                                    (interactive)
2105                                    (call-interactively #'bookmark-bmenu-list))
2106                          'follow-link t
2107                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2108      (insert (substitute-command-keys
2109               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2110      (elpher-restore-pos))))
2111
2112 (defun elpher-show-bookmarks ()
2113   "Interactive function to display the current list of elpher bookmarks."
2114   (interactive)
2115   (elpher-visit-page
2116    (elpher-make-page "Elpher Bookmarks"
2117                      (elpher-make-about-address 'bookmarks))))
2118
2119
2120 ;;; Integrations
2121 ;;
2122
2123 ;;; Org
2124
2125 (defun elpher-org-export-link (link description format protocol)
2126   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2127
2128 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2129 of gemini, gopher or finger."
2130   (let* ((url (if (equal protocol "elpher")
2131                   (string-remove-prefix "elpher:" link)
2132                 (format "%s:%s" protocol link)))
2133          (desc (or description url)))
2134     (pcase format
2135       (`gemini (format "=> %s %s" url desc))
2136       (`html (format "<a href=\"%s\">%s</a>" url desc))
2137       (`latex (format "\\href{%s}{%s}" url desc))
2138       (_ (if (not description)
2139              url
2140            (format "%s (%s)" desc url))))))
2141
2142 (defun elpher-org-store-link ()
2143   "Store link to an `elpher' page in Org."
2144   (when (eq major-mode 'elpher-mode)
2145     (let* ((url (elpher-info-current))
2146            (desc (car elpher-current-page))
2147            (protocol (cond
2148                       ((string-prefix-p "gemini:" url) "gemini")
2149                       ((string-prefix-p "gopher:" url) "gopher")
2150                       ((string-prefix-p "finger:" url) "finger")
2151                       (t "elpher"))))
2152       (when (equal "elpher" protocol)
2153         ;; Weird link. Or special inner link?
2154         (setq url (concat "elpher:" url)))
2155       (org-link-store-props :type protocol :link url :description desc)
2156       t)))
2157
2158 (defun elpher-org-follow-link (link protocol)
2159   "Visit a LINK for the given PROTOCOL.
2160
2161 PROTOCOL may be one of gemini, gopher or finger.  This method also
2162 supports the old protocol elpher, where the link is self-contained."
2163   (let ((url (if (equal protocol "elpher")
2164                  (string-remove-prefix "elpher:" link)
2165                (format "%s:%s" protocol link))))
2166     (elpher-go url)))
2167
2168 (defun elpher-org-mode-integration ()
2169   "Set up `elpher' integration for `org-mode'."
2170   (org-link-set-parameters
2171    "elpher"
2172    :store #'elpher-org-store-link
2173    :export (lambda (link description format _plist)
2174              (elpher-org-export-link link description format "elpher"))
2175    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2176   (org-link-set-parameters
2177    "gemini"
2178    :export (lambda (link description format _plist)
2179              (elpher-org-export-link link description format "gemini"))
2180    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2181   (org-link-set-parameters
2182    "gopher"
2183    :export (lambda (link description format _plist)
2184              (elpher-org-export-link link description format "gopher"))
2185    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2186   (org-link-set-parameters
2187    "finger"
2188    :export (lambda (link description format _plist)
2189              (elpher-org-export-link link description format "finger"))
2190    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2191
2192 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2193
2194 ;; Browse URL
2195
2196 ;;;###autoload
2197 (defun elpher-browse-url-elpher (url &rest _args)
2198   "Browse URL using Elpher.  This function is used by `browse-url'."
2199   (interactive (browse-url-interactive-arg "Elpher URL: "))
2200   (elpher-go url))
2201
2202 ;; Use elpher to open gopher, finger and gemini links
2203 ;; For recent version of `browse-url' package
2204 (if (boundp 'browse-url-default-handlers)
2205     (add-to-list
2206      'browse-url-default-handlers
2207      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2208   ;; Patch `browse-url-browser-function' for older ones. The value of
2209   ;; that variable is `browse-url-default-browser' by default, so
2210   ;; that's the function that gets advised. If the value is an alist,
2211   ;; however, we don't know what to do. Better not interfere?
2212   (when (and (symbolp browse-url-browser-function)
2213              (fboundp browse-url-browser-function))
2214     (advice-add browse-url-browser-function :before-while
2215                 (lambda (url &rest _args)
2216                   "Handle gemini, gopher, and finger schemes using Elpher."
2217                   (let ((scheme (downcase (car (split-string url ":" t)))))
2218                     (if (member scheme '("gemini" "gopher" "finger"))
2219                         ;; `elpher-go' always returns nil, which will stop the
2220                         ;; advice chain here in a before-while
2221                         (elpher-go url)
2222                       ;; chain must continue, then return t.
2223                       t))))))
2224
2225 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2226 (with-eval-after-load 'thingatpt
2227   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2228
2229 ;; Mu4e:
2230
2231 ;; Make mu4e aware of the gemini world
2232 (setq mu4e~view-beginning-of-url-regexp
2233       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2234
2235 ;; eww:
2236
2237 ;; Let elpher handle gemini, gopher links in eww buffer.
2238 (setq eww-use-browse-url
2239       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2240
2241
2242 ;;; Interactive procedures
2243 ;;
2244
2245 (defun elpher-next-link ()
2246   "Move point to the next link on the current page."
2247   (interactive)
2248   (forward-button 1))
2249
2250 (defun elpher-prev-link ()
2251   "Move point to the previous link on the current page."
2252   (interactive)
2253   (backward-button 1))
2254
2255 (defun elpher-follow-current-link ()
2256   "Open the link or url at point."
2257   (interactive)
2258   (push-button))
2259
2260 ;;;###autoload
2261 (defun elpher-go (host-or-url)
2262   "Go to a particular gopher site HOST-OR-URL.
2263 When run interactively HOST-OR-URL is read from the minibuffer."
2264   (interactive (list
2265                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2266   (let ((trimmed-host-or-url (string-trim host-or-url)))
2267     (unless (string-empty-p trimmed-host-or-url)
2268       (let ((page (elpher-page-from-url trimmed-host-or-url
2269                                         (elpher-get-default-url-scheme))))
2270         (unless (get-buffer-window elpher-buffer-name t)
2271           (switch-to-buffer elpher-buffer-name))
2272         (elpher-with-clean-buffer
2273          (elpher-visit-page page))
2274         nil)))) ; non-nil value is displayed by eshell
2275
2276 (defun elpher-go-current ()
2277   "Go to a particular URL which is read from the minibuffer.
2278 Unlike `elpher-go', the reader is initialized with the URL of the
2279 current page."
2280   (interactive)
2281   (let* ((address (elpher-page-address elpher-current-page))
2282          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2283                            (elpher-address-to-url address))))
2284     (unless (string-empty-p (string-trim url))
2285       (elpher-visit-page (elpher-page-from-url url)))))
2286
2287 (defun elpher-redraw ()
2288   "Redraw current page."
2289   (interactive)
2290   (elpher-visit-page elpher-current-page))
2291
2292 (defun elpher-reload ()
2293   "Reload current page."
2294   (interactive)
2295   (elpher-reload-current-page))
2296
2297 (defun elpher-toggle-tls ()
2298   "Toggle TLS encryption mode for gopher."
2299   (interactive)
2300   (setq elpher-use-tls (not elpher-use-tls))
2301   (if elpher-use-tls
2302       (if (gnutls-available-p)
2303           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2304         (setq elpher-use-tls nil)
2305         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2306     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2307
2308 (defun elpher-view-raw ()
2309   "View raw server response for current page."
2310   (interactive)
2311   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2312       (error "This page was not generated by a server")
2313     (elpher-visit-page elpher-current-page
2314                        #'elpher-render-raw)))
2315
2316 (defun elpher-back ()
2317   "Go to previous site."
2318   (interactive)
2319   (elpher-visit-previous-page))
2320
2321 (defun elpher-back-to-start ()
2322   "Go all the way back to the start page."
2323   (interactive)
2324   (setq-local elpher-current-page nil)
2325   (setq-local elpher-history nil)
2326   (elpher-visit-page (elpher-make-start-page)))
2327
2328 (defun elpher-download ()
2329   "Download the link at point."
2330   (interactive)
2331   (let ((button (button-at (point))))
2332     (if button
2333         (let ((page (button-get button 'elpher-page)))
2334           (unless page
2335             (error "Not an elpher page"))
2336           (when (elpher-address-about-p (elpher-page-address page))
2337             (error "Cannot download %s" (elpher-page-display-string page)))
2338           (elpher-visit-page (button-get button 'elpher-page)
2339                              #'elpher-render-download))
2340       (error "No link selected"))))
2341
2342 (defun elpher-download-current ()
2343   "Download the current page."
2344   (interactive)
2345   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2346       (error "Cannot download %s"
2347              (elpher-page-display-string elpher-current-page))
2348     (elpher-visit-page (elpher-make-page
2349                         (elpher-page-display-string elpher-current-page)
2350                         (elpher-page-address elpher-current-page))
2351                        #'elpher-render-download
2352                        t)))
2353
2354 (defun elpher--build-link-map ()
2355   "Build alist mapping link names to destination pages in current buffer."
2356   (let ((link-map nil)
2357         (b (next-button (point-min) t)))
2358     (while b
2359       (push (cons (button-label b) b) link-map)
2360       (setq b (next-button (button-start b))))
2361     link-map))
2362
2363 (defun elpher-jump ()
2364   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2365   (interactive)
2366   (let* ((link-map (elpher--build-link-map)))
2367     (if link-map
2368         (let ((key (let ((completion-ignore-case t))
2369                      (completing-read "Directory item/link: "
2370                                       link-map nil t))))
2371           (if (and key (> (length key) 0))
2372               (let ((b (cdr (assoc key link-map))))
2373                 (goto-char (button-start b))
2374                 (button-activate b)))))))
2375
2376 (defun elpher-root-dir ()
2377   "Visit root of current server."
2378   (interactive)
2379   (let ((address (elpher-page-address elpher-current-page)))
2380     (if (not (elpher-address-about-p address))
2381         (if (or (member (url-filename address) '("/" ""))
2382                 (and (elpher-address-gopher-p address)
2383                      (= (length (elpher-gopher-address-selector address)) 0)))
2384             (error "Already at root directory of current server")
2385           (let ((address-copy (elpher-address-from-url
2386                                (elpher-address-to-url address))))
2387             (setf (url-filename address-copy) "")
2388             (elpher-go (elpher-address-to-url address-copy))))
2389       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2390
2391 (defun elpher-info-page (page)
2392   "Display URL of PAGE in minibuffer."
2393   (let* ((address (elpher-page-address page))
2394          (url (elpher-address-to-url address))
2395          (iri (elpher-address-to-iri address)))
2396     (if (equal url iri)
2397         (message "%s" url)
2398       (message "%s (Raw: %s)" iri url))))
2399
2400 (defun elpher-info-link ()
2401   "Display information on page corresponding to link at point."
2402   (interactive)
2403   (let ((button (button-at (point))))
2404     (unless button
2405       (error "No item selected"))
2406     (let ((page (button-get button 'elpher-page)))
2407       (unless page
2408         (error "Not an elpher page"))
2409       (elpher-info-page page))))
2410
2411 (defun elpher-info-current ()
2412   "Display information on current page."
2413   (interactive)
2414   (elpher-info-page elpher-current-page))
2415
2416 (defun elpher-copy-page-url (page)
2417   "Copy URL representation of address of PAGE to `kill-ring'."
2418   (let* ((address (elpher-page-address page))
2419          (url (elpher-address-to-url address)))
2420     (message "Copied \"%s\" to kill-ring/clipboard." url)
2421     (kill-new url)))
2422
2423 (defun elpher-copy-link-url ()
2424   "Copy URL of item at point to `kill-ring'."
2425   (interactive)
2426   (let ((button (button-at (point))))
2427     (unless button
2428       (error "No item selected"))
2429     (let ((page (button-get button 'elpher-page)))
2430       (unless page
2431         (error "Not an elpher page"))
2432       (elpher-copy-page-url page))))
2433
2434 (defun elpher-copy-current-url ()
2435   "Copy URL of current page to `kill-ring'."
2436   (interactive)
2437   (elpher-copy-page-url elpher-current-page))
2438
2439 (defun elpher-set-gopher-coding-system ()
2440   "Specify an explicit character coding system for gopher selectors."
2441   (interactive)
2442   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2443     (setq elpher-user-coding-system system)
2444     (if system
2445         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2446       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2447
2448
2449 ;;; Mode and keymap
2450 ;;
2451
2452 (defvar elpher-mode-map
2453   (let ((map (make-sparse-keymap)))
2454     (define-key map (kbd "TAB") 'elpher-next-link)
2455     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2456     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2457     (define-key map (kbd "u") 'elpher-back)
2458     (define-key map (kbd "-") 'elpher-back)
2459     (define-key map (kbd "^") 'elpher-back)
2460     (define-key map [mouse-3] 'elpher-back)
2461     (define-key map (kbd "U") 'elpher-back-to-start)
2462     (define-key map (kbd "g") 'elpher-go)
2463     (define-key map (kbd "o") 'elpher-go-current)
2464     (define-key map (kbd "O") 'elpher-root-dir)
2465     (define-key map (kbd "s") 'elpher-show-history)
2466     (define-key map (kbd "S") 'elpher-show-visited-pages)
2467     (define-key map (kbd "r") 'elpher-redraw)
2468     (define-key map (kbd "R") 'elpher-reload)
2469     (define-key map (kbd "T") 'elpher-toggle-tls)
2470     (define-key map (kbd ".") 'elpher-view-raw)
2471     (define-key map (kbd "d") 'elpher-download)
2472     (define-key map (kbd "D") 'elpher-download-current)
2473     (define-key map (kbd "m") 'elpher-jump)
2474     (define-key map (kbd "i") 'elpher-info-link)
2475     (define-key map (kbd "I") 'elpher-info-current)
2476     (define-key map (kbd "c") 'elpher-copy-link-url)
2477     (define-key map (kbd "C") 'elpher-copy-current-url)
2478     (define-key map (kbd "a") 'elpher-bookmark-link)
2479     (define-key map (kbd "A") 'elpher-bookmark-current)
2480     (define-key map (kbd "B") 'elpher-show-bookmarks)
2481     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2482     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2483     (when (fboundp 'evil-define-key*)
2484       (evil-define-key*
2485        'motion map
2486        (kbd "TAB") 'elpher-next-link
2487        (kbd "C-") 'elpher-follow-current-link
2488        (kbd "C-t") 'elpher-back
2489        (kbd "u") 'elpher-back
2490        (kbd "-") 'elpher-back
2491        (kbd "^") 'elpher-back
2492        [mouse-3] 'elpher-back
2493        (kbd "U") 'elpher-back-to-start
2494        (kbd "g") 'elpher-go
2495        (kbd "o") 'elpher-go-current
2496        (kbd "O") 'elpher-root-dir
2497        (kbd "s") 'elpher-show-history
2498        (kbd "S") 'elpher-show-visited-pages
2499        (kbd "r") 'elpher-redraw
2500        (kbd "R") 'elpher-reload
2501        (kbd "T") 'elpher-toggle-tls
2502        (kbd ".") 'elpher-view-raw
2503        (kbd "d") 'elpher-download
2504        (kbd "D") 'elpher-download-current
2505        (kbd "m") 'elpher-jump
2506        (kbd "i") 'elpher-info-link
2507        (kbd "I") 'elpher-info-current
2508        (kbd "c") 'elpher-copy-link-url
2509        (kbd "C") 'elpher-copy-current-url
2510        (kbd "a") 'elpher-bookmark-link
2511        (kbd "A") 'elpher-bookmark-current
2512        (kbd "B") 'elpher-show-bookmarks
2513        (kbd "!") 'elpher-set-gopher-coding-system
2514        (kbd "F") 'elpher-forget-current-certificate))
2515     map)
2516   "Keymap for gopher client.")
2517
2518 (define-derived-mode elpher-mode special-mode "elpher"
2519   "Major mode for elpher, an elisp gopher client.
2520
2521 This mode is automatically enabled by the interactive
2522 functions which initialize the client, namely
2523 `elpher', and `elpher-go'."
2524   (setq-local elpher-current-page nil)
2525   (setq-local elpher-history nil)
2526   (setq-local elpher-buffer-name (buffer-name))
2527   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2528   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2529
2530 (when (fboundp 'evil-set-initial-state)
2531   (evil-set-initial-state 'elpher-mode 'motion))
2532
2533
2534 ;;; Main start procedure
2535 ;;
2536
2537 ;;;###autoload
2538 (defun elpher (&optional arg)
2539   "Start elpher with default landing page.
2540 The buffer used for Elpher sessions is determined by the value of
2541 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2542 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2543 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2544 \\[execute-extended-command] elpher RET’) switches to the session with
2545 that number, creating it if necessary.  A non numeric prefix ARG means
2546 to create a new session.  Returns the buffer selected (or created)."
2547   (interactive "P")
2548   (let* ((name (default-value 'elpher-buffer-name))
2549          (buf (cond ((numberp arg)
2550                      (get-buffer-create (format "%s<%d>" name arg)))
2551                     (arg
2552                      (generate-new-buffer name))
2553                     (t
2554                      (get-buffer-create name)))))
2555     (pop-to-buffer-same-window buf)
2556     (unless (buffer-modified-p)
2557       (elpher-mode)
2558       (elpher-visit-page (elpher-make-start-page))
2559       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2560
2561 ;;; elpher.el ends here