elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.2
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.2"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     (file elpher-get-file-page nil "~" elpher-gemini)
  98     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
  99     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 100     ((about history) elpher-get-history-page nil "E" elpher-index)
 101     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 102   "Association list from types to getters, renderers, margin codes and index faces.")
 103
 104
 105 ;;; Declarations to avoid compiler warnings.
 106 ;;
 107
 108 (eval-when-compile
 109   (declare-function ansi-color-filter-apply "ansi-color")
 110   (declare-function ansi-color-apply "ansi-color")
 111   (declare-function bookmark-store "bookmark")
 112   (declare-function org-link-store-props "ol")
 113   (declare-function org-link-set-parameters "ol")
 114   (defvar ansi-color-context)
 115   (defvar xterm-color--current-fg)
 116   (defvar xterm-color--current-bg)
 117   (defvar bookmark-make-record-function)
 118   (defvar mu4e~view-beginning-of-url-regexp)
 119   (defvar eww-use-browse-url)
 120   (defvar thing-at-point-uri-schemes))
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher and gemini client."
 128   :group 'applications)
 129
 130 ;; General appearance and customizations
 131
 132 (defcustom elpher-open-urls-with-eww nil
 133   "If non-nil, open URL selectors using eww.
 134 Otherwise, use the system browser via the `browse-url' function."
 135   :type '(boolean))
 136
 137 (defcustom elpher-use-header t
 138   "If non-nil, display current page information in buffer header."
 139   :type '(boolean))
 140
 141 (defcustom elpher-auto-disengage-TLS nil
 142   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 143 While enabling this may seem convenient, it is also potentially
 144 dangerous as it allows switching from an encrypted channel back to
 145 plain text without user input."
 146   :type '(boolean))
 147
 148 (defcustom elpher-connection-timeout 5
 149   "Specifies the number of seconds to wait for a network connection to time out."
 150   :type '(integer))
 151
 152 (defcustom elpher-filter-ansi-from-text nil
 153   "If non-nil, filter ANSI escape sequences from text.
 154 The default behaviour is to use the ansi-color package (or xterm-color if it is
 155 available) to interpret these sequences."
 156   :type '(boolean))
 157
 158 (defcustom elpher-certificate-directory
 159   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 160   "Specify the name of the directory where client certificates will be stored.
 161 These certificates may be used for establishing authenticated TLS connections."
 162   :type '(directory))
 163
 164 (defcustom elpher-openssl-command "openssl"
 165   "The command used to launch openssl when generating TLS client certificates."
 166   :type '(file))
 167
 168 (defcustom elpher-default-url-type "gopher"
 169   "Default URL type (i.e. scheme) to assume if not explicitly given."
 170   :type '(choice (const "gopher")
 171                  (const "gemini")))
 172
 173 (defcustom elpher-gemini-TLS-cert-checks nil
 174   "If non-nil, verify gemini server TLS certs using the default security level.
 175 Otherwise, certificate verification is disabled.
 176
 177 This defaults to off because it is standard practice for Gemini servers
 178 to use self-signed certificates, meaning that most servers provide what
 179 EMACS considers to be an invalid certificate."
 180   :type '(boolean))
 181
 182 (defcustom elpher-gemini-max-fill-width 80
 183   "Specify the maximum default width (in columns) of text/gemini documents.
 184 The actual width used is the minimum of this value and the window width at
 185 the time when the text is rendered."
 186   :type '(integer))
 187
 188 (defcustom elpher-gemini-link-string "→ "
 189   "Specify the string used to indicate links when rendering gemini maps.
 190 May be empty."
 191   :type '(string))
 192
 193 (defcustom elpher-gemini-bullet-string "•"
 194   "Specify the string used for bullets when rendering gemini maps."
 195   :type '(string))
 196
 197 (defcustom elpher-ipv4-always nil
 198   "If non-nil, elpher will always use IPv4 to establish network connections.
 199 This can be useful when browsing from a computer that supports IPv6, because
 200 some servers which do not support IPv6 can take a long time to time-out."
 201   :type '(boolean))
 202
 203 (defcustom elpher-socks-always nil
 204   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 205 Otherwise, the SOCKS proxy is only used for connections to onion services."
 206   :type '(boolean))
 207
 208 (defcustom elpher-use-emacs-bookmark-menu nil
 209   "If non-nil, elpher will only use the native Emacs bookmark menu.
 210 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 211 page within which all of the standard elpher keybindings are active."
 212   :type '(boolean))
 213
 214 (defcustom elpher-start-page-url "about:welcome"
 215   "Specify the page displayed initially by elpher.
 216 The default welcome screen is \"about:welcome\", while the bookmarks list
 217 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 218
 219 Beware that using \"about:bookmarks\" as a start page in combination with
 220 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 221 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 222 the start page."
 223   :type '(string))
 224
 225 (defcustom elpher-gemini-hide-preformatted nil
 226   "Cause elpher to hide preformatted gemini text by default.
 227 When this option is enabled, preformatted text in text/gemini documents
 228 is replaced with a button which can be used to toggle its display.
 229
 230 This is intended to improve accessibility, as preformatted text often
 231 includes art which can be difficult for screen readers to interpret
 232 meaningfully."
 233   :type '(boolean))
 234
 235 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 236   "Margin symbol used to distinguish the preformatted text toggle."
 237   :type '(string))
 238
 239 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 240   "Label of button used to toggle formatted text."
 241   :type '(string))
 242
 243 ;; Face customizations
 244
 245 (defgroup elpher-faces nil
 246   "Elpher face customizations."
 247   :group 'elpher)
 248
 249 (defface elpher-index
 250   '((t :inherit font-lock-keyword-face))
 251   "Face used for directory type directory records.")
 252
 253 (defface elpher-text
 254   '((t :inherit bold))
 255   "Face used for text type directory records.")
 256
 257 (defface elpher-info
 258   '((t :inherit default))
 259   "Face used for info type directory records.")
 260
 261 (defface elpher-image
 262   '((t :inherit font-lock-string-face))
 263   "Face used for image type directory records.")
 264
 265 (defface elpher-search
 266   '((t :inherit warning))
 267   "Face used for search type directory records.")
 268
 269 (defface elpher-html
 270   '((t :inherit font-lock-comment-face))
 271   "Face used for html type directory records.")
 272
 273 (defface elpher-gemini
 274   '((t :inherit font-lock-constant-face))
 275   "Face used for Gemini type directory records.")
 276
 277 (defface elpher-other-url
 278   '((t :inherit font-lock-comment-face))
 279   "Face used for other URL type links records.")
 280
 281 (defface elpher-telnet
 282   '((t :inherit font-lock-function-name-face))
 283   "Face used for telnet type directory records.")
 284
 285 (defface elpher-binary
 286   '((t :inherit font-lock-doc-face))
 287   "Face used for binary type directory records.")
 288
 289 (defface elpher-unknown
 290   '((t :inherit error))
 291   "Face used for directory records with unknown/unsupported types.")
 292
 293 (defface elpher-margin-key
 294   '((t :inherit bold))
 295   "Face used for directory margin key.")
 296
 297 (defface elpher-margin-brackets
 298   '((t :inherit shadow))
 299   "Face used for brackets around directory margin key.")
 300
 301 (defface elpher-gemini-heading1
 302   '((t :inherit bold :height 1.8))
 303   "Face used for gemini heading level 1.")
 304
 305 (defface elpher-gemini-heading2
 306   '((t :inherit bold :height 1.5))
 307   "Face used for gemini heading level 2.")
 308
 309 (defface elpher-gemini-heading3
 310   '((t :inherit bold :height 1.2))
 311   "Face used for gemini heading level 3.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 (defface elpher-gemini-preformatted
 318   '((t :inherit default))
 319   "Face used for gemini preformatted text.")
 320
 321 (defface elpher-gemini-preformatted-toggle
 322   '((t :inherit button))
 323   "Face used for buttons used to toggle display of preformatted text.")
 324
 325 ;;; Model
 326 ;;
 327
 328 ;; Address
 329
 330 ;; An elpher "address" object is either a url object or a symbol.
 331 ;; Addresses with the "about" type, corresponding to pages generated
 332 ;; dynamically for and by elpher.  All others represent pages which
 333 ;; rely on content retrieved over the network.
 334
 335 (defun elpher-address-from-url (url-string &optional default-scheme)
 336   "Create a ADDRESS object corresponding to the given URL-STRING.
 337 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 338 is not explicitly given."
 339   (let ((data (match-data))) ; Prevent parsing clobbering match data
 340     (unwind-protect
 341         (let ((url (url-generic-parse-url url-string)))
 342           (unless (and (not (url-fullness url)) (url-type url))
 343             (unless (url-type url)
 344               (setf (url-type url) default-scheme))
 345             (unless (url-host url)
 346               (let ((p (split-string (url-filename url) "/" nil nil)))
 347                 (setf (url-host url) (car p))
 348                 (setf (url-filename url)
 349                       (if (cdr p)
 350                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 351                         ""))))
 352             (when (not (string-empty-p (url-host url)))
 353               (setf (url-fullness url) t)
 354               (setf (url-host url) (puny-encode-domain (url-host url))))
 355             (when (or (equal "gopher" (url-type url))
 356                       (equal "gophers" (url-type url)))
 357               ;; Gopher defaults
 358               (when (or (equal (url-filename url) "")
 359                         (equal (url-filename url) "/"))
 360                 (setf (url-filename url) "/1")))
 361             (when (equal "gemini" (url-type url))
 362               ;; Gemini defaults
 363               (if (equal (url-filename url) "")
 364                   (setf (url-filename url) "/"))))
 365           (elpher-remove-redundant-ports url))
 366       (set-match-data data))))
 367
 368 (defun elpher-remove-redundant-ports (address)
 369   "Remove redundant port specifiers from ADDRESS.
 370 Here 'redundant' means that the specified port matches the default
 371 for that protocol, eg 70 for gopher."
 372   (if (and (not (elpher-address-about-p address))
 373            (eq (url-portspec address) ; (url-port) is too slow!
 374                (pcase (url-type address)
 375                  ("gemini" 1965)
 376                  ((or "gopher" "gophers") 70)
 377                  ("finger" 79)
 378                  (_ -1))))
 379       (setf (url-portspec address) nil))
 380   address)
 381
 382 (defun elpher-make-gopher-address (type selector host port &optional tls)
 383   "Create an ADDRESS object using gopher directory record attributes.
 384 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 385 If the optional attribute TLS is non-nil, the address will be marked as
 386 requiring gopher-over-TLS."
 387   (cond
 388    ((equal type ?i) nil)
 389    ((and (equal type ?h)
 390          (string-prefix-p "URL:" selector))
 391     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 392    ((equal type ?8)
 393     (elpher-address-from-url
 394      (concat "telnet"
 395              "://" host
 396              ":" (number-to-string port))))
 397    (t
 398     (elpher-address-from-url
 399      (concat "gopher" (if tls "s" "")
 400              "://" host
 401              ":" (number-to-string port)
 402              "/" (string type)
 403              selector)))))
 404
 405 (defun elpher-make-about-address (type)
 406   "Create an ADDRESS object corresponding to the given about address TYPE."
 407   (elpher-address-from-url (concat "about:" (symbol-name type))))
 408
 409 (defun elpher-address-to-url (address)
 410   "Get string representation of ADDRESS."
 411   (url-encode-url (url-recreate-url address)))
 412
 413 (defun elpher-address-type (address)
 414   "Retrieve type of ADDRESS object.
 415 This is used to determine how to retrieve and render the document the
 416 address refers to, via the table `elpher-type-map'."
 417   (pcase (url-type address)
 418     ("about"
 419      (list 'about (intern (url-filename address))))
 420     ((or "gopher" "gophers")
 421      (list 'gopher
 422            (if (member (url-filename address) '("" "/"))
 423                ?1
 424              (string-to-char (substring (url-filename address) 1)))))
 425     ("gemini" 'gemini)
 426     ("telnet" 'telnet)
 427     ("finger" 'finger)
 428     ("file" 'file)
 429     (_ 'other-url)))
 430
 431 (defun elpher-address-about-p (address)
 432   "Return non-nil if ADDRESS is an about address."
 433   (pcase (elpher-address-type address) (`(about ,_) t)))
 434
 435 (defun elpher-address-gopher-p (address)
 436   "Return non-nil if ADDRESS object is a gopher address."
 437   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 438
 439 (defun elpher-address-protocol (address)
 440   "Retrieve the transport protocol for ADDRESS."
 441   (url-type address))
 442
 443 (defun elpher-address-filename (address)
 444   "Retrieve the filename component of ADDRESS.
 445 For gopher addresses this is a combination of the selector type and selector."
 446   (url-unhex-string (url-filename address)))
 447
 448 (defun elpher-address-host (address)
 449   "Retrieve host from ADDRESS object."
 450   (let ((host-pre (url-host address)))
 451     ;; The following strips out square brackets which sometimes enclose IPv6
 452     ;; addresses.  Doing this here rather than at the parsing stage may seem
 453     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 454     ;; and reconstruction.  It's also more efficient, as this method is not
 455     ;; called during page rendering.
 456     (if (and (> (length host-pre) 2)
 457              (eq (elt host-pre 0) ?\[)
 458              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 459         (substring host-pre 1 (- (length host-pre) 1))
 460       host-pre)))
 461
 462 (defun elpher-address-user (address)
 463   "Retrieve user from ADDRESS object."
 464   (url-user address))
 465
 466 (defun elpher-address-port (address)
 467   "Retrieve port from ADDRESS object.
 468 If no address is defined, returns 0.  (This is for compatibility with
 469 the URL library.)"
 470   (let ((port (url-portspec address))) ; (url-port) is too slow!
 471     (if port port 0)))
 472
 473 (defun elpher-gopher-address-selector (address)
 474   "Retrieve gopher selector from ADDRESS object."
 475   (if (member (url-filename address) '("" "/"))
 476       ""
 477     (url-unhex-string (substring (url-filename address) 2))))
 478
 479
 480 ;; Cache
 481
 482 (defvar elpher-content-cache (make-hash-table :test 'equal))
 483 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 484
 485 (defun elpher-get-cached-content (address)
 486   "Retrieve the cached content for ADDRESS, or nil if none exists."
 487   (gethash address elpher-content-cache))
 488
 489 (defun elpher-cache-content (address content)
 490   "Set the content cache for ADDRESS to CONTENT."
 491   (puthash address content elpher-content-cache))
 492
 493 (defun elpher-get-cached-pos (address)
 494   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 495   (gethash address elpher-pos-cache))
 496
 497 (defun elpher-cache-pos (address pos)
 498   "Set the cursor position cache for ADDRESS to POS."
 499   (puthash address pos elpher-pos-cache))
 500
 501
 502 ;; Page
 503
 504 (defun elpher-make-page (display-string address)
 505   "Create a page with DISPLAY-STRING and ADDRESS."
 506   (list display-string address))
 507
 508 (defun elpher-make-start-page ()
 509   "Create the start page."
 510   (elpher-make-page "Start Page"
 511                     (elpher-address-from-url elpher-start-page-url)))
 512
 513 (defun elpher-page-display-string (page)
 514   "Retrieve the display string corresponding to PAGE."
 515   (elt page 0))
 516
 517 (defun elpher-page-address (page)
 518   "Retrieve the address corresponding to PAGE."
 519   (elt page 1))
 520
 521 (defun elpher-page-set-address (page new-address)
 522   "Set the address corresponding to PAGE to NEW-ADDRESS."
 523   (setcar (cdr page) new-address))
 524
 525 (defun elpher-page-from-url (url &optional default-scheme)
 526   "Create a page with address and display string defined by URL.
 527 The URL is unhexed prior to its use as a display string to improve
 528 readability.
 529
 530 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 531 in the instance that URL itself doesn't specify one."
 532   (let ((address (elpher-address-from-url url default-scheme)))
 533     (elpher-make-page (elpher-address-to-iri address) address)))
 534
 535 (defun elpher-address-to-iri (address)
 536   "Return an IRI for ADDRESS.
 537 Decode percent-escapes and handle punycode in the domain name.
 538 Drop the password, if any."
 539   (let ((data (match-data)) ; Prevent parsing clobbering match data
 540         (host (url-host address))
 541         (pass (url-password address)))
 542     (unwind-protect
 543         (let* ((host (url-host address))
 544                (pass (url-password address)))
 545           (when host
 546             (setf (url-host address) (puny-decode-domain host)))
 547           (when pass                             ; RFC 3986 says we should not render
 548             (setf (url-password address) nil)) ; the password as clear text
 549           (elpher-decode (url-unhex-string (url-recreate-url address))))
 550       (setf (url-host address) host)
 551       (setf (url-password address) pass)
 552       (set-match-data data))))
 553
 554 (defvar elpher-current-page nil
 555   "The current page for this Elpher buffer.")
 556
 557 (defvar elpher-history nil
 558   "The local history stack for this Elpher buffer.
 559 This variable is used by `elpher-back' and
 560 `elpher-show-history'.")
 561
 562 (defvar elpher-visited-pages nil
 563   "The global history for all Elpher buffers.
 564 This variable is used by `elpher-show-visited-pages'.")
 565
 566 (defun elpher-visit-page (page &optional renderer no-history)
 567   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 568 Additionally, push PAGE onto the history stack and the list of
 569 previously-visited pages,unless NO-HISTORY is non-nil."
 570   (elpher-save-pos)
 571   (elpher-process-cleanup)
 572   (unless no-history
 573     (unless (or (not elpher-current-page)
 574                  (equal (elpher-page-address elpher-current-page)
 575                         (elpher-page-address page)))
 576       (push elpher-current-page elpher-history)
 577       (unless (or (elpher-address-about-p (elpher-page-address page))
 578                   (and elpher-visited-pages
 579                        (equal page (car elpher-visited-pages))))
 580         (push page elpher-visited-pages))))
 581   (setq-local elpher-current-page page)
 582   (let* ((address (elpher-page-address page))
 583          (type (elpher-address-type address))
 584          (type-record (cdr (assoc type elpher-type-map))))
 585     (if type-record
 586         (funcall (car type-record)
 587                  (if renderer
 588                      renderer
 589                    (cadr type-record)))
 590       (elpher-visit-previous-page)
 591       (pcase type
 592         (`(gopher ,type-char)
 593          (error "Unsupported gopher selector type '%c' for '%s'"
 594                 type-char (elpher-address-to-url address)))
 595         (other
 596          (error "Unsupported address type '%S' for '%s'"
 597                 other (elpher-address-to-url address)))))))
 598
 599 (defun elpher-visit-previous-page ()
 600   "Visit the previous page in the history."
 601   (if elpher-history
 602       (elpher-visit-page (pop elpher-history) nil t)
 603     (error "No previous page")))
 604
 605 (defun elpher-reload-current-page ()
 606   "Reload the current page, discarding any existing cached content."
 607   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 608   (elpher-visit-page elpher-current-page))
 609
 610 (defun elpher-save-pos ()
 611   "Save the current position of point to the current page."
 612   (when elpher-current-page
 613     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 614
 615 (defun elpher-restore-pos ()
 616   "Restore the position of point to that cached in the current page."
 617   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 618     (if pos
 619         (goto-char pos)
 620       (goto-char (point-min)))))
 621
 622 (defun elpher-get-default-url-scheme ()
 623   "Suggest default URL scheme for visiting addresses based on the current page."
 624   (if elpher-current-page
 625       (let* ((address (elpher-page-address elpher-current-page))
 626              (current-type (elpher-address-type address)))
 627         (pcase current-type
 628           ((or (and 'file (guard (not elpher-history)))
 629                `(about ,_))
 630            elpher-default-url-type)
 631           (_
 632            (url-type address))))
 633       elpher-default-url-type))
 634
 635
 636 ;;; Buffer preparation
 637 ;;
 638
 639 (defvar elpher-buffer-name "*elpher*"
 640   "The default name of the Elpher buffer.")
 641
 642 (defun elpher-update-header ()
 643   "If `elpher-use-header' is true, display current page info in window header."
 644   (if (and elpher-use-header elpher-current-page)
 645       (let* ((display-string (elpher-page-display-string elpher-current-page))
 646              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 647              (address (elpher-page-address elpher-current-page))
 648              (tls-string (if (and (not (elpher-address-about-p address))
 649                                   (member (elpher-address-protocol address)
 650                                           '("gophers" "gemini")))
 651                              " [TLS encryption]"
 652                            ""))
 653              (header (concat sanitized-display-string
 654                              (propertize tls-string 'face 'bold))))
 655         (setq header-line-format header))))
 656
 657 (defmacro elpher-with-clean-buffer (&rest args)
 658   "Evaluate ARGS with a clean *elpher* buffer as current."
 659   (declare (debug (body))) ;; Allow edebug to step through body
 660   `(with-current-buffer elpher-buffer-name
 661      (unless (eq major-mode 'elpher-mode)
 662        ;; avoid resetting buffer-local variables
 663        (elpher-mode))
 664      (let ((inhibit-read-only t)
 665            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 666        (setq-local xterm-color--current-fg nil)
 667        (setq-local xterm-color--current-bg nil)
 668        (setq-local network-security-level
 669                    (default-value 'network-security-level))
 670        (erase-buffer)
 671        (elpher-update-header)
 672        ,@args)))
 673
 674 (defun elpher-buffer-message (string &optional line)
 675   "Replace first line in elpher buffer with STRING.
 676 If LINE is non-nil, replace that line instead."
 677   (with-current-buffer elpher-buffer-name
 678     (let ((inhibit-read-only t))
 679       (goto-char (point-min))
 680       (if line
 681           (forward-line line))
 682       (let ((data (match-data)))
 683         (unwind-protect
 684             (progn
 685               (re-search-forward "^.*$")
 686               (replace-match string))
 687           (set-match-data data))))))
 688
 689
 690 ;;; Text Processing
 691 ;;
 692
 693 (defvar elpher-user-coding-system nil
 694   "User-specified coding system to use for decoding text responses.")
 695
 696 (defun elpher-decode (string)
 697   "Decode STRING using autodetected or user-specified coding system."
 698   (decode-coding-string string
 699                         (if elpher-user-coding-system
 700                             elpher-user-coding-system
 701                           (detect-coding-string string t))))
 702
 703 (defun elpher-preprocess-text-response (string)
 704   "Preprocess text selector response contained in STRING.
 705 This involes decoding the character representation, and clearing
 706 away CRs and any terminating period."
 707   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 708                                            (replace-regexp-in-string "\r" "" string))))
 709
 710 ;;; Buttonify urls
 711
 712 (defconst elpher-url-regex
 713   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 714   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 715
 716 (defun elpher-buttonify-urls (string)
 717   "Turn substrings which look like urls in STRING into clickable buttons."
 718   (with-temp-buffer
 719     (insert string)
 720     (goto-char (point-min))
 721     (while (re-search-forward elpher-url-regex nil t)
 722       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 723         (make-text-button (match-beginning 0)
 724                           (match-end 0)
 725                           'elpher-page  page
 726                           'action #'elpher-click-link
 727                           'follow-link t
 728                           'help-echo #'elpher--page-button-help
 729                           'face 'button)))
 730     (buffer-string)))
 731
 732
 733 ;; ANSI colors or XTerm colors (application and filtering)
 734
 735 (or (require 'xterm-color nil t)
 736     (require 'ansi-color))
 737
 738 (defalias 'elpher-color-filter-apply
 739   (if (fboundp 'xterm-color-filter)
 740       (lambda (s)
 741         (let ((_xterm-color-render nil))
 742           (xterm-color-filter s)))
 743     #'ansi-color-filter-apply)
 744   "A function to filter out ANSI escape sequences.")
 745
 746 (defalias 'elpher-color-apply
 747   (if (fboundp 'xterm-color-filter)
 748       #'xterm-color-filter
 749     #'ansi-color-apply)
 750   "A function to apply ANSI escape sequences.")
 751
 752 (defun elpher-text-has-ansi-escapes-p (string)
 753   "Return non-nil if STRING includes an ANSI escape code."
 754   (save-match-data
 755     (string-match "\x1b\\[" string)))
 756
 757
 758 ;; Processing text for display
 759
 760 (defun elpher-process-text-for-display (string)
 761   "Perform any desired processing of STRING prior to display as text.
 762 Currently includes buttonifying URLs and processing ANSI escape codes."
 763   (elpher-buttonify-urls (if (elpher-text-has-ansi-escapes-p string)
 764                              (if elpher-filter-ansi-from-text
 765                                  (elpher-color-filter-apply string)
 766                                (elpher-color-apply string))
 767                            string)))
 768
 769
 770 ;;; General network communication
 771 ;;
 772
 773 (defun elpher-network-error (address error)
 774   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 775 ERROR can be either an error object or a string."
 776   (elpher-with-clean-buffer
 777    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 778            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 779            (if (stringp error) error (error-message-string error)) "\n"
 780            (propertize "\n----------------\n\n" 'face 'error)
 781            "Press 'u' to return to the previous page.")))
 782
 783
 784 (defvar elpher-network-timer nil
 785   "Timer used for network connections.")
 786
 787 (defvar elpher-use-tls nil
 788   "If non-nil, use TLS to communicate with gopher servers.")
 789
 790 (defvar elpher-client-certificate nil
 791   "If non-nil, contains client certificate details to use for TLS connections.")
 792
 793 (defun elpher-process-cleanup ()
 794   "Immediately shut down any extant elpher process and timers."
 795   (let ((p (get-process "elpher-process")))
 796     (if p (delete-process p)))
 797   (if (timerp elpher-network-timer)
 798       (cancel-timer elpher-network-timer)))
 799
 800 (defun elpher-make-network-timer (thunk)
 801   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 802 This is just a wraper around `run-at-time' which additionally sets the
 803 buffer-local variable `elpher-network-timer' to allow
 804 `elpher-process-cleanup' to also clear the timer."
 805   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 806     (setq-local elpher-network-timer timer)
 807     timer))
 808
 809 (defun elpher-get-host-response (address default-port query-string response-processor
 810                                          &optional use-tls force-ipv4)
 811   "Generic function for retrieving data from ADDRESS.
 812
 813 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 814 QUERY-STRING is a string sent to the host specified by ADDRESS to
 815 illicet a response.  This response is passed as an argument to the
 816 function RESPONSE-PROCESSOR.
 817
 818 If non-nil, USE-TLS specifies that the connection is to be made over
 819 TLS.  If set to gemini, the certificate verification will be disabled
 820 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 821
 822 If non-nil, FORCE-IPV4 causes the network connection to be made over
 823 ipv4 only.  (The default behaviour when this is not set depends on
 824 the host operating system and the local network capabilities.)"
 825   (if (and use-tls (not (gnutls-available-p)))
 826       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 827     (unless (< (elpher-address-port address) 65536)
 828       (error "Cannot establish network connection: port number > 65536"))
 829     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 830       (setq-local network-security-level 'low)
 831       (setq-local gnutls-verify-error nil))
 832     (condition-case nil
 833         (let* ((kill-buffer-query-functions nil)
 834                (port (elpher-address-port address))
 835                (host (elpher-address-host address))
 836                (service (if (> port 0) port default-port))
 837                (response-string-parts nil)
 838                (bytes-received 0)
 839                (hkbytes-received 0)
 840                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 841                (gnutls-params (list :type 'gnutls-x509pki
 842                                     :hostname host
 843                                     :keylist
 844                                     (elpher-get-current-keylist address)))
 845                (timer (elpher-make-network-timer
 846                                    (lambda ()
 847                                      (elpher-process-cleanup)
 848                                      (cond
 849                                         ; Try again with IPv4
 850                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 851                                        (message "Connection timed out.  Retrying with IPv4.")
 852                                        (elpher-get-host-response address default-port
 853                                                                  query-string
 854                                                                  response-processor
 855                                                                  use-tls t))
 856                                       ((and use-tls
 857                                             (not (eq use-tls 'gemini))
 858                                             (or elpher-auto-disengage-TLS
 859                                                 (y-or-n-p
 860                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 861                                        (setq elpher-use-tls nil)
 862                                        (elpher-get-host-response address default-port
 863                                                                  query-string
 864                                                                  response-processor
 865                                                                  nil force-ipv4))
 866                                       (t
 867                                        (elpher-network-error address "Connection time-out."))))))
 868                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 869                        (make-network-process :name "elpher-process"
 870                                              :host host
 871                                              :family (and (or force-ipv4
 872                                                               elpher-ipv4-always)
 873                                                           'ipv4)
 874                                              :service service
 875                                              :buffer nil
 876                                              :nowait t
 877                                              :tls-parameters
 878                                              (and use-tls
 879                                                   (cons 'gnutls-x509pki
 880                                                         (apply #'gnutls-boot-parameters
 881                                                                gnutls-params)))))))
 882           (setq elpher-network-timer timer)
 883           (set-process-coding-system proc 'binary 'binary)
 884           (set-process-query-on-exit-flag proc nil)
 885           (elpher-buffer-message (concat "Connecting to " host "..."
 886                                          " (press 'u' to abort)"))
 887           (set-process-filter proc
 888                               (lambda (_proc string)
 889                                 (when timer
 890                                   (cancel-timer timer)
 891                                   (setq timer nil))
 892                                 (setq bytes-received (+ bytes-received (length string)))
 893                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 894                                   (when (> new-hkbytes-received hkbytes-received)
 895                                     (setq hkbytes-received new-hkbytes-received)
 896                                     (elpher-buffer-message
 897                                      (concat "("
 898                                              (number-to-string (/ hkbytes-received 10.0))
 899                                              " MB read)")
 900                                      1)))
 901                                 (setq response-string-parts
 902                                       (cons string response-string-parts))))
 903           (set-process-sentinel proc
 904                                 (lambda (proc event)
 905                                   (when timer
 906                                     (cancel-timer timer))
 907                                   (condition-case the-error
 908                                       (cond
 909                                        ((string-prefix-p "open" event)    ; request URL
 910                                         (elpher-buffer-message
 911                                          (concat "Connected to " host ". Receiving data..."
 912                                                  " (press 'u' to abort)"))
 913                                         (let ((inhibit-eol-conversion t))
 914                                           (process-send-string proc query-string)))
 915                                        ((string-prefix-p "deleted" event)) ; do nothing
 916                                        ((and (not response-string-parts)
 917                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 918                                         ; Try again with IPv4
 919                                         (message "Connection failed. Retrying with IPv4.")
 920                                         (elpher-get-host-response address default-port
 921                                                                   query-string
 922                                                                   response-processor
 923                                                                   use-tls t))
 924                                        (response-string-parts
 925                                         (elpher-with-clean-buffer
 926                                          (insert "Data received.  Rendering..."))
 927                                         (funcall response-processor
 928                                                  (apply #'concat (reverse response-string-parts)))
 929                                         (elpher-restore-pos))
 930                                        (t
 931                                         (error "No response from server")))
 932                                     (error
 933                                      (elpher-network-error address the-error)))))
 934           (when socks
 935             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 936             (funcall (process-sentinel proc) proc "open\n")))
 937       (error
 938        (elpher-process-cleanup)
 939        (error "Error initiating connection to server")))))
 940
 941
 942 ;;; Client-side TLS Certificate Management
 943 ;;
 944
 945 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 946   "Generate a key and a self-signed client TLS certificate using openssl.
 947
 948 The Common Name field of the certificate is set to COMMON-NAME.  The
 949 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 950 the key and certificate files to write.
 951
 952 If TEMPORARY is non-nil, the certificate will be given an exporation
 953 period of one day, and the key and certificate files will be deleted
 954 when the certificate is no longer needed for the current session.
 955
 956 Otherwise, the certificate will be given a 100 year expiration period
 957 and the files will not be deleted.
 958
 959 The function returns a list containing the current host name, the
 960 temporary flag, and the key and cert file names in the form required
 961 by `gnutls-boot-parameters`."
 962   (let ((exp-key-file (expand-file-name key-file))
 963         (exp-cert-file (expand-file-name cert-file)))
 964     (condition-case nil
 965         (progn
 966           (call-process elpher-openssl-command nil nil nil
 967                         "req" "-x509" "-newkey" "rsa:2048"
 968                         "-days" (if temporary "1" "36500")
 969                         "-nodes"
 970                         "-subj" (concat "/CN=" common-name)
 971                         "-keyout" exp-key-file
 972                         "-out" exp-cert-file)
 973           (list (elpher-address-host (elpher-page-address elpher-current-page))
 974                 temporary exp-key-file exp-cert-file))
 975       (error
 976        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 977        (error "Program 'openssl', required for certificate generation, not found")))))
 978
 979 (defun elpher-generate-throwaway-certificate ()
 980   "Generate and return details of a throwaway certificate.
 981 The key and certificate files will be deleted when they are no
 982 longer needed for this session."
 983   (let* ((file-base (make-temp-name "elpher"))
 984          (key-file (concat temporary-file-directory file-base ".key"))
 985          (cert-file (concat temporary-file-directory file-base ".crt")))
 986     (elpher-generate-certificate file-base key-file cert-file t)))
 987
 988 (defun elpher-generate-persistent-certificate (file-base common-name)
 989   "Generate and return details of a persistent certificate.
 990 The argument FILE-BASE is used as the base for the key and certificate
 991 files, while COMMON-NAME specifies the common name field of the
 992 certificate.
 993
 994 The key and certificate files are written to in `elpher-certificate-directory'."
 995   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 996          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 997     (elpher-generate-certificate common-name key-file cert-file)))
 998
 999 (defun elpher-get-existing-certificate (file-base)
1000   "Return a certificate object corresponding to an existing certificate.
1001 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1002 the directory `elpher-certificate-directory'."
1003   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1004          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1005     (list (elpher-address-host (elpher-page-address elpher-current-page))
1006           nil
1007           (expand-file-name key-file)
1008           (expand-file-name cert-file))))
1009
1010 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1011   "Install a key+certificate file pair in `elpher-certificate-directory'.
1012 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1013 certificate files to install.  The argument FILE-BASE is used as the
1014 base for the installed key and certificate files."
1015   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1016          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1017     (if (or (file-exists-p key-file)
1018             (file-exists-p cert-file))
1019         (error "A certificate with base name %s is already installed" file-base))
1020     (copy-file key-file-src key-file)
1021     (copy-file cert-file-src cert-file)
1022     (list (elpher-address-host (elpher-page-address elpher-current-page))
1023           nil
1024           (expand-file-name key-file)
1025           (expand-file-name cert-file))))
1026
1027 (defun elpher-list-existing-certificates ()
1028   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1029   (unless (file-directory-p elpher-certificate-directory)
1030     (make-directory elpher-certificate-directory))
1031   (mapcar
1032    (lambda (file)
1033      (file-name-sans-extension file))
1034    (directory-files elpher-certificate-directory nil "\\.key$")))
1035
1036 (defun elpher-forget-current-certificate ()
1037   "Causes any current certificate to be forgotten.)
1038 In the case of throwaway certificates, the key and certificate files
1039 are also deleted."
1040   (interactive)
1041   (when elpher-client-certificate
1042     (unless (and (called-interactively-p 'any)
1043                  (not (y-or-n-p (concat "Really forget client certificate? "
1044                                         "(Throwaway certificates will be deleted.)"))))
1045       (when (cadr elpher-client-certificate)
1046         (delete-file (elt elpher-client-certificate 2))
1047         (delete-file (elt elpher-client-certificate 3)))
1048       (setq elpher-client-certificate nil)
1049       (if (called-interactively-p 'any)
1050           (message "Client certificate forgotten.")))))
1051
1052 (defun elpher-get-current-keylist (address)
1053   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1054
1055 This is obtained from the client certificate described by
1056 `elpher-current-certificate', if one is available and the host for
1057 that certificate matches the host in ADDRESS.
1058
1059 If `elpher-current-certificate' is non-nil, and its host name doesn't
1060 match that of ADDRESS, the certificate is forgotten."
1061   (if elpher-client-certificate
1062       (if (string= (car elpher-client-certificate)
1063                    (elpher-address-host address))
1064           (list (cddr elpher-client-certificate))
1065         (elpher-forget-current-certificate)
1066         (message "Disabling client certificate for new host")
1067         nil)
1068     nil))
1069
1070
1071 ;;; Gopher selector retrieval
1072 ;;
1073
1074 (defun elpher-get-gopher-response (address renderer)
1075   "Get response string from gopher server at ADDRESS and render using RENDERER."
1076   (elpher-get-host-response address 70
1077                             (concat (elpher-gopher-address-selector address) "\r\n")
1078                             renderer
1079                             (or (string= (elpher-address-protocol address) "gophers")
1080                                 elpher-use-tls)))
1081
1082 (defun elpher-get-gopher-page (renderer)
1083   "Getter function for gopher pages.
1084 The RENDERER procedure is used to display the contents of the page
1085 once they are retrieved from the gopher server."
1086   (let* ((address (elpher-page-address elpher-current-page))
1087          (content (elpher-get-cached-content address)))
1088     (if (and content (funcall renderer nil))
1089         (elpher-with-clean-buffer
1090          (insert content)
1091          (elpher-restore-pos))
1092       (elpher-with-clean-buffer
1093        (insert "LOADING... (use 'u' to cancel)\n"))
1094       (condition-case the-error
1095           (elpher-get-gopher-response address renderer)
1096         (error
1097          (elpher-network-error address the-error))))))
1098
1099
1100 ;;; Gopher index rendering
1101 ;;
1102
1103 (defun elpher-insert-margin (&optional type-name)
1104   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1105   (if type-name
1106       (progn
1107         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1108                         (concat
1109                          (propertize "[" 'face 'elpher-margin-brackets)
1110                          (propertize type-name 'face 'elpher-margin-key)
1111                          (propertize "]" 'face 'elpher-margin-brackets))))
1112         (insert " "))
1113     (insert (make-string elpher-margin-width ?\s))))
1114
1115 (defun elpher--page-button-help (_window buffer pos)
1116   "Function called by Emacs to generate mouse-over text.
1117 The arguments specify the BUFFER and the POS within the buffer of the item
1118 for which help is required.  The function returns the help to be
1119 displayed.  The _WINDOW argument is currently unused."
1120   (with-current-buffer buffer
1121     (let ((button (button-at pos)))
1122       (when button
1123         (let* ((page (button-get button 'elpher-page))
1124                (address (elpher-page-address page)))
1125           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1126
1127 (defun elpher-insert-index-record (display-string &optional address)
1128   "Function to insert an index record into the current buffer.
1129 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1130 If ADDRESS is not supplied or nil the record is rendered as an
1131 'information' line."
1132   (let* ((type (if address (elpher-address-type address) nil))
1133          (type-map-entry (cdr (assoc type elpher-type-map))))
1134     (if type-map-entry
1135         (let* ((margin-code (elt type-map-entry 2))
1136                (face (elt type-map-entry 3))
1137                (filtered-display-string (elpher-color-filter-apply display-string))
1138                (page (elpher-make-page filtered-display-string address)))
1139           (elpher-insert-margin margin-code)
1140           (insert-text-button filtered-display-string
1141                               'face face
1142                               'elpher-page page
1143                               'action #'elpher-click-link
1144                               'follow-link t
1145                               'help-echo #'elpher--page-button-help))
1146       (pcase type
1147         ('nil ;; Information
1148          (elpher-insert-margin)
1149          (let ((propertized-display-string
1150                 (propertize display-string 'face 'elpher-info)))
1151            (insert (elpher-process-text-for-display propertized-display-string))))
1152         (`(gopher ,selector-type) ;; Unknown
1153          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1154          (insert (propertize display-string
1155                              'face 'elpher-unknown)))))
1156     (insert "\n")))
1157
1158 (defun elpher-click-link (button)
1159   "Function called when the gopher link BUTTON is activated."
1160   (let ((page (button-get button 'elpher-page)))
1161     (elpher-visit-page page)))
1162
1163 (defun elpher-render-index (data &optional _mime-type-string)
1164   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1165   (elpher-with-clean-buffer
1166    (if (not data)
1167        t
1168      (let ((data-processed (elpher-preprocess-text-response data)))
1169        (dolist (line (split-string data-processed "\n"))
1170          (ignore-errors
1171            (unless (= (length line) 0)
1172              (let* ((type (elt line 0))
1173                     (fields (split-string (substring line 1) "\t"))
1174                     (display-string (elt fields 0))
1175                     (selector (elt fields 1))
1176                     (host (elt fields 2))
1177                     (port (if (elt fields 3)
1178                               (string-to-number (elt fields 3))
1179                             nil))
1180                     (address (elpher-make-gopher-address type selector host port)))
1181                (elpher-insert-index-record display-string address))))))
1182      (elpher-cache-content (elpher-page-address elpher-current-page)
1183                            (buffer-string)))))
1184
1185
1186 ;;; Gopher text rendering
1187 ;;
1188
1189 (defun elpher-render-text (data &optional _mime-type-string)
1190   "Render DATA as text.  MIME-TYPE-STRING is unused."
1191   (elpher-with-clean-buffer
1192    (if (not data)
1193        t
1194      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1195      (elpher-cache-content
1196       (elpher-page-address elpher-current-page)
1197       (buffer-string)))))
1198
1199
1200 ;;; Image retrieval
1201 ;;
1202
1203 (defun elpher-render-image (data &optional _mime-type-string)
1204   "Display DATA as image.  MIME-TYPE-STRING is unused."
1205   (if (not data)
1206       nil
1207     (if (display-images-p)
1208         (let* ((image (create-image
1209                        data
1210                        nil t)))
1211           (if (not image)
1212               (error "Unsupported image format")
1213             (let ((window (get-buffer-window elpher-buffer-name)))
1214               (when window
1215                 (setf (image-property image :max-width) (window-body-width window t))
1216                 (setf (image-property image :max-height) (window-body-height window t))))
1217             (elpher-with-clean-buffer
1218              (insert-image image)
1219              (elpher-restore-pos))))
1220       (elpher-render-download data))))
1221
1222
1223 ;;; Gopher search retrieval and rendering
1224 ;;
1225
1226 (defun elpher-get-gopher-query-page (renderer)
1227   "Getter for gopher addresses requiring input.
1228 The response is rendered using the rendering function RENDERER."
1229   (let* ((address (elpher-page-address elpher-current-page))
1230          (content (elpher-get-cached-content address))
1231          (aborted t))
1232     (if (and content (funcall renderer nil))
1233         (elpher-with-clean-buffer
1234          (insert content)
1235          (elpher-restore-pos)
1236          (message "Displaying cached search results.  Reload to perform a new search."))
1237       (unwind-protect
1238           (let* ((query-string (read-string "Query: "))
1239                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1240                  (search-address (elpher-make-gopher-address ?1
1241                                                              query-selector
1242                                                              (elpher-address-host address)
1243                                                              (elpher-address-port address)
1244                                                              (equal (elpher-address-type address) "gophers"))))
1245             (setq aborted nil)
1246
1247             (elpher-with-clean-buffer
1248              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1249             (elpher-get-gopher-response search-address renderer))
1250         (if aborted
1251             (elpher-visit-previous-page))))))
1252
1253
1254 ;;; Raw server response rendering
1255 ;;
1256
1257 (defun elpher-render-raw (data &optional mime-type-string)
1258   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1259   (if (not data)
1260       nil
1261     (elpher-with-clean-buffer
1262      (when mime-type-string
1263        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1264      (insert data)
1265      (goto-char (point-min)))
1266     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1267
1268
1269 ;;; File save "rendering"
1270 ;;
1271
1272 (defun elpher-render-download (data &optional _mime-type-string)
1273   "Save DATA to file.  MIME-TYPE-STRING is unused."
1274   (if (not data)
1275       nil
1276     (let* ((address (elpher-page-address elpher-current-page))
1277            (selector (if (elpher-address-gopher-p address)
1278                          (elpher-gopher-address-selector address)
1279                        (elpher-address-filename address))))
1280       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1281       (let* ((filename-proposal (file-name-nondirectory selector))
1282              (filename (read-file-name "Download complete. Save file as: "
1283                                        nil nil nil
1284                                        (if (> (length filename-proposal) 0)
1285                                            filename-proposal
1286                                          "download.file"))))
1287         (let ((coding-system-for-write 'binary))
1288           (with-temp-file filename
1289             (insert data)))
1290         (message (format "Saved to file %s." filename))))))
1291
1292
1293 ;;; HTML rendering
1294 ;;
1295
1296 (defun elpher-render-html (data &optional _mime-type-string)
1297   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1298   (elpher-with-clean-buffer
1299    (if (not data)
1300        t
1301      (let ((dom (with-temp-buffer
1302                   (insert data)
1303                   (libxml-parse-html-region (point-min) (point-max)))))
1304        (shr-insert-document dom)))))
1305
1306
1307 ;;; Gemini page retrieval
1308 ;;
1309
1310 (defvar elpher-gemini-redirect-chain)
1311
1312 (defun elpher-get-gemini-response (address renderer)
1313   "Get response string from gemini server at ADDRESS and render using RENDERER."
1314   (elpher-get-host-response address 1965
1315                             (concat (elpher-address-to-url address) "\r\n")
1316                             (lambda (response-string)
1317                               (elpher-process-gemini-response response-string renderer))
1318                             'gemini))
1319
1320 (defun elpher-parse-gemini-response (response)
1321   "Parse the RESPONSE string and return a list of components.
1322 The list is of the form (code meta body).  A response of nil implies
1323 that the response was malformed."
1324   (let ((header-end-idx (string-match "\r\n" response)))
1325     (if header-end-idx
1326         (let ((header (string-trim (substring response 0 header-end-idx)))
1327               (body (substring response (+ header-end-idx 2))))
1328           (if (>= (length header) 2)
1329               (let ((code (substring header 0 2))
1330                     (meta (string-trim (substring header 2))))
1331                 (list code meta body))
1332             (error "Malformed response: No response status found in header %s" header)))
1333       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1334
1335 (defun elpher-process-gemini-response (response-string renderer)
1336   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1337   (let ((response-components (elpher-parse-gemini-response response-string)))
1338     (let ((response-code (elt response-components 0))
1339           (response-meta (elt response-components 1))
1340           (response-body (elt response-components 2)))
1341       (pcase (elt response-code 0)
1342         (?1 ; Input required
1343          (elpher-with-clean-buffer
1344           (insert "Gemini server is requesting input."))
1345          (let* ((query-string
1346                  (if (eq (elt response-code 1) ?1)
1347                      (read-passwd (concat response-meta ": "))
1348                    (read-string (concat response-meta ": "))))
1349                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1350                 (old-fname (url-filename query-address)))
1351            (setf (url-filename query-address)
1352                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1353            (elpher-get-gemini-response query-address renderer)))
1354         (?2 ; Normal response
1355          (funcall renderer response-body response-meta))
1356         (?3 ; Redirect
1357          (message "Following redirect to %s" response-meta)
1358          (if (>= (length elpher-gemini-redirect-chain) 5)
1359              (error "More than 5 consecutive redirects followed"))
1360          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1361            (if (member redirect-address elpher-gemini-redirect-chain)
1362                (error "Redirect loop detected"))
1363            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1364                (error "Server tried to automatically redirect to non-gemini URL: %s"
1365                       response-meta))
1366            (elpher-page-set-address elpher-current-page redirect-address)
1367            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1368            (elpher-get-gemini-response redirect-address renderer)))
1369         (?4 ; Temporary failure
1370          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1371                 response-code response-meta))
1372         (?5 ; Permanent failure
1373          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1374                 response-code response-meta))
1375         (?6 ; Client certificate required
1376          (elpher-with-clean-buffer
1377           (if elpher-client-certificate
1378               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1379             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1380           (auto-fill-mode 1)
1381           (elpher-gemini-insert-text response-meta))
1382          (let ((chosen-certificate (elpher-choose-client-certificate)))
1383            (unless chosen-certificate
1384              (error "Gemini server requires a client certificate and none was provided"))
1385            (setq elpher-client-certificate chosen-certificate))
1386          (elpher-with-clean-buffer)
1387          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1388         (_other
1389          (error "Gemini server response unknown: %s %s"
1390                 response-code response-meta))))))
1391
1392 (defun elpher--read-answer-polyfill (question answers)
1393   "Polyfill for `read-answer' in Emacs 26.1.
1394 QUESTION is a string containing a question, and ANSWERS
1395 is a list of possible answers."
1396     (completing-read question (mapcar 'identity answers)))
1397
1398 (if (fboundp 'read-answer)
1399     (defalias 'elpher-read-answer 'read-answer)
1400   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1401
1402 (defun elpher-choose-client-certificate ()
1403   "Prompt for a client certificate to use to establish a TLS connection."
1404   (let* ((read-answer-short t))
1405     (pcase (read-answer "What do you want to do? "
1406                         '(("throwaway" ?t
1407                            "generate and use throw-away certificate")
1408                           ("persistent" ?p
1409                            "generate new or use existing persistent certificate")
1410                           ("abort" ?a
1411                            "stop immediately")))
1412       ("throwaway"
1413        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1414       ("persistent"
1415        (let* ((existing-certificates (elpher-list-existing-certificates))
1416               (file-base (completing-read
1417                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1418                           existing-certificates)))
1419          (if (string-empty-p (string-trim file-base))
1420              nil
1421            (if (member file-base existing-certificates)
1422                (setq elpher-client-certificate
1423                      (elpher-get-existing-certificate file-base))
1424              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1425                                  '(("new" ?n
1426                                     "generate new certificate")
1427                                    ("install" ?i
1428                                     "install existing certificate")
1429                                    ("abort" ?a
1430                                     "stop immediately")))
1431                ("new"
1432                 (let ((common-name (read-string "Common Name field for new certificate: "
1433                                                 file-base)))
1434                   (message "New key and self-signed certificate written to %s"
1435                            elpher-certificate-directory)
1436                   (elpher-generate-persistent-certificate file-base common-name)))
1437                ("install"
1438                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1439                        (key-file (read-file-name "Key file: " nil nil t)))
1440                   (message "Key and certificate installed in %s for future use"
1441                            elpher-certificate-directory)
1442                   (elpher-install-and-use-existing-certificate key-file
1443                                                                cert-file
1444                                                                file-base)))
1445                ("abort" nil))))))
1446       ("abort" nil))))
1447
1448 (defun elpher-get-gemini-page (renderer)
1449   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1450   (let* ((address (elpher-page-address elpher-current-page))
1451          (content (elpher-get-cached-content address)))
1452     (condition-case the-error
1453         (if (and content (funcall renderer nil))
1454             (elpher-with-clean-buffer
1455              (insert content)
1456              (elpher-restore-pos))
1457           (elpher-with-clean-buffer
1458            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1459           (setq elpher-gemini-redirect-chain nil)
1460           (elpher-get-gemini-response address renderer))
1461       (error
1462        (elpher-network-error address the-error)))))
1463
1464 ;;; Gemini page rendering
1465 ;;
1466
1467 (defun elpher-render-gemini (body &optional mime-type-string)
1468   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1469   (if (not body)
1470       t
1471     (let* ((mime-type-string* (if (or (not mime-type-string)
1472                                       (string-empty-p mime-type-string))
1473                                   "text/gemini; charset=utf-8"
1474                                 mime-type-string))
1475            (mime-type-split (split-string mime-type-string* ";" t))
1476            (mime-type (string-trim (car mime-type-split)))
1477            (parameters (mapcar (lambda (s)
1478                                  (let ((key-val (split-string s "=")))
1479                                    (list (downcase (string-trim (car key-val)))
1480                                          (downcase (string-trim (cadr key-val))))))
1481                                (cdr mime-type-split))))
1482       (when (string-prefix-p "text/" mime-type)
1483         (setq body (decode-coding-string
1484                     body
1485                     (if (assoc "charset" parameters)
1486                         (intern (cadr (assoc "charset" parameters)))
1487                       'utf-8)))
1488         (setq body (replace-regexp-in-string "\r" "" body)))
1489       (pcase mime-type
1490         ((or "text/gemini" "")
1491          (elpher-render-gemini-map body parameters))
1492         ("text/html"
1493          (elpher-render-html body))
1494         ((pred (string-prefix-p "text/"))
1495          (elpher-render-gemini-plain-text body parameters))
1496         ((pred (string-prefix-p "image/"))
1497          (elpher-render-image body))
1498         (_other
1499          (elpher-render-download body))))))
1500
1501 (defun elpher-gemini-get-link-url (link-line)
1502   "Extract the url portion of LINK-LINE, a gemini map file link line.
1503 Returns nil in the event that the contents of the line following the
1504 => prefix are empty."
1505   (let ((l (split-string (substring link-line 2))))
1506     (if l
1507         (string-trim (elt l 0))
1508       nil)))
1509
1510 (defun elpher-gemini-get-link-display-string (link-line)
1511   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1512 Return nil if this portion is not provided."
1513   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1514          (idx (string-match "[ \t]" rest)))
1515     (and idx
1516          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1517
1518 (defun elpher-collapse-dot-sequences (filename)
1519   "Collapse dot sequences in the (absolute) FILENAME.
1520 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1521   (let* ((path (split-string filename "/" t))
1522          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1523          (path-reversed-normalized
1524           (seq-reduce (lambda (a b)
1525                         (cond ((equal b "..") (cdr a))
1526                               ((equal b ".") a)
1527                               (t (cons b a))))
1528                       path nil))
1529          (path-normalized (reverse path-reversed-normalized)))
1530     (if path-normalized
1531         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1532       "/")))
1533
1534 (defun elpher-address-from-gemini-url (url)
1535   "Extract address from URL with defaults as per gemini map files.
1536 While there's obviously some redundancy here between this function and
1537 `elpher-address-from-url', gemini map file URLs require enough special
1538 treatment that a separate function is warranted."
1539   (let ((address (url-generic-parse-url url))
1540         (current-address (elpher-page-address elpher-current-page)))
1541     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1542       (if (url-host address) ;if there is an explicit host, filenames are absolute
1543           (if (string-empty-p (url-filename address))
1544               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1545         (setf (url-host address) (url-host current-address))
1546         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1547         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1548         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1549           (setf (url-filename address)
1550                 (concat (file-name-directory (url-filename current-address))
1551                         (url-filename address)))))
1552       (when (url-host address)
1553         (setf (url-host address) (puny-encode-domain (url-host address))))
1554       (unless (url-type address)
1555         (setf (url-type address) (url-type current-address)))
1556       (when (equal (url-type address) "gemini")
1557         (setf (url-filename address)
1558               (elpher-collapse-dot-sequences (url-filename address)))))
1559     (elpher-remove-redundant-ports address)))
1560
1561 (defun elpher-gemini-insert-link (link-line)
1562   "Insert link described by LINK-LINE into a text/gemini document."
1563   (let ((url (elpher-gemini-get-link-url link-line)))
1564     (when url
1565       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1566              (address (elpher-address-from-gemini-url url))
1567              (type (if address (elpher-address-type address) nil))
1568              (type-map-entry (cdr (assoc type elpher-type-map)))
1569              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1570         (when type-map-entry
1571           (insert elpher-gemini-link-string)
1572           (let* ((face (elt type-map-entry 3))
1573                  (display-string (or given-display-string
1574                                      (elpher-address-to-iri address)))
1575                  (page (elpher-make-page display-string
1576                                          address)))
1577             (insert-text-button display-string
1578                                 'face face
1579                                 'elpher-page page
1580                                 'action #'elpher-click-link
1581                                 'follow-link t
1582                                 'help-echo #'elpher--page-button-help))
1583           (newline))))))
1584
1585 (defun elpher-gemini-insert-header (header-line)
1586   "Insert header described by HEADER-LINE into a text/gemini document.
1587 The gemini map file line describing the header is given
1588 by HEADER-LINE."
1589   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1590     (let* ((level (length (match-string 1 header-line)))
1591            (header (substring header-line (match-end 0)))
1592            (face (pcase level
1593                    (1 'elpher-gemini-heading1)
1594                    (2 'elpher-gemini-heading2)
1595                    (3 'elpher-gemini-heading3)
1596                    (_ 'default)))
1597            (fill-column (if (display-graphic-p)
1598                             (/ (* fill-column
1599                                   (font-get (font-spec :name (face-font 'default)) :size))
1600                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1601       (unless (display-graphic-p)
1602         (insert (make-string level ?#) " "))
1603       (insert (propertize header
1604                           'face face
1605                           'gemini-heading t
1606                           'rear-nonsticky t))
1607       (newline))))
1608
1609 (defun elpher-gemini-insert-text (text-line)
1610   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1611 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1612 width defined by `elpher-gemini-max-fill-width'."
1613   (string-match
1614    (rx (: line-start
1615           (optional
1616            (group (or (: "*" (+ (any " \t")))
1617                       (: ">" (* (any " \t"))))))))
1618    text-line)
1619   (let* ((line-prefix (match-string 1 text-line))
1620          (processed-text-line
1621           (if line-prefix
1622               (cond ((string-prefix-p "*" line-prefix)
1623                      (concat
1624                       (replace-regexp-in-string "\\*"
1625                                                 elpher-gemini-bullet-string
1626                                                 (match-string 0 text-line))
1627                       (substring text-line (match-end 0))))
1628                     ((string-prefix-p ">" line-prefix)
1629                      (propertize text-line 'face 'elpher-gemini-quoted))
1630                     (t text-line))
1631             text-line))
1632          (fill-prefix (if line-prefix
1633                           (make-string (length (match-string 0 text-line)) ?\s)
1634                         "")))
1635     (insert (elpher-process-text-for-display processed-text-line))
1636     (newline)))
1637
1638 (defun elpher-gemini-pref-expand-collapse (button)
1639   "Function called when the preformatted text toggle BUTTON is activated."
1640   (let ((id (button-get button 'pref-id)))
1641     (if (invisible-p id)
1642         (remove-from-invisibility-spec id)
1643       (add-to-invisibility-spec id))
1644     (redraw-display)))
1645
1646 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1647   "Insert a button for toggling the visibility of preformatted text.
1648 If non-nil, ALT-TEXT is displayed alongside the button."
1649   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1650          (pref-id (intern (concat "pref-"
1651                                   (number-to-string (point))
1652                                   "-"
1653                                   url-string))))
1654     (insert elpher-gemini-preformatted-toggle-bullet)
1655     (when alt-text
1656       (insert (propertize (concat alt-text " ")
1657                           'face 'elpher-gemin-preformatted)))
1658     (insert-text-button elpher-gemini-preformatted-toggle-label
1659                         'action #'elpher-gemini-pref-expand-collapse
1660                         'pref-id pref-id
1661                         'face 'elpher-gemini-preformatted-toggle)
1662     (add-to-invisibility-spec pref-id)
1663     (newline)
1664     pref-id))
1665
1666 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1667   "Insert a LINE of preformatted text.
1668 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1669 can be used to toggle the display of the preformatted text."
1670   (insert (propertize (concat (elpher-process-text-for-display
1671                                (propertize line 'face 'elpher-gemini-preformatted))
1672                               "\n")
1673                       'invisible pref-id
1674                       'rear-nonsticky t)))
1675
1676 (defun elpher-render-gemini-map (data _parameters)
1677   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1678   (elpher-with-clean-buffer
1679    (auto-fill-mode 1)
1680    (setq-local buffer-invisibility-spec nil)
1681    (let ((preformatted nil)
1682          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1683      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1684      (dolist (line (split-string data "\n"))
1685        (pcase line
1686          ((rx (: "```" (opt (let alt-text (+ any)))))
1687           (setq preformatted
1688                 (if preformatted
1689                     nil
1690                   (if elpher-gemini-hide-preformatted
1691                       (elpher-gemini-insert-preformatted-toggler alt-text)
1692                     t))))
1693          ((guard  preformatted)
1694           (elpher-gemini-insert-preformatted-line line preformatted))
1695          ((pred (string-prefix-p "=>"))
1696           (elpher-gemini-insert-link line))
1697          ((pred (string-prefix-p "#"))
1698           (elpher-gemini-insert-header line))
1699          (_ (elpher-gemini-insert-text line))))
1700    (elpher-cache-content
1701     (elpher-page-address elpher-current-page)
1702     (buffer-string)))))
1703
1704 (defun elpher-render-gemini-plain-text (data _parameters)
1705   "Render DATA as plain text file.  PARAMETERS is currently unused."
1706   (elpher-with-clean-buffer
1707    (insert (elpher-process-text-for-display data))
1708    (elpher-cache-content
1709     (elpher-page-address elpher-current-page)
1710     (buffer-string))))
1711
1712 (defun elpher-build-current-imenu-index ()
1713   "Build imenu index for current elpher buffer."
1714   (save-excursion
1715     (goto-char (point-min))
1716     (let ((match nil)
1717           (headers nil))
1718       (while (setq match (text-property-search-forward 'gemini-heading t t))
1719         (push (cons
1720                (buffer-substring-no-properties (prop-match-beginning match)
1721                                                (prop-match-end match))
1722                (prop-match-beginning match))
1723               headers))
1724       (reverse headers))))
1725
1726
1727 ;;; Finger page connection
1728 ;;
1729
1730 (defun elpher-get-finger-page (renderer)
1731   "Opens a finger connection to the current page address.
1732 The result is rendered using RENDERER."
1733   (let* ((address (elpher-page-address elpher-current-page))
1734          (content (elpher-get-cached-content address)))
1735     (if (and content (funcall renderer nil))
1736         (elpher-with-clean-buffer
1737          (insert content)
1738          (elpher-restore-pos))
1739       (elpher-with-clean-buffer
1740        (insert "LOADING... (use 'u' to cancel)\n"))
1741       (condition-case the-error
1742           (let* ((kill-buffer-query-functions nil)
1743                  (user (let ((filename (elpher-address-filename address)))
1744                          (if (> (length filename) 1)
1745                              (substring filename 1)
1746                            (elpher-address-user address)))))
1747             (elpher-get-host-response address 79
1748                                       (concat user "\r\n")
1749                                       renderer))
1750         (error
1751          (elpher-network-error address the-error))))))
1752
1753
1754 ;;; Telnet page connection
1755 ;;
1756
1757 (defun elpher-get-telnet-page (renderer)
1758   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1759   (when renderer
1760     (elpher-visit-previous-page)
1761     (error "Command not supported for telnet URLs"))
1762   (let* ((address (elpher-page-address elpher-current-page))
1763          (host (elpher-address-host address))
1764          (port (elpher-address-port address)))
1765     (elpher-visit-previous-page)
1766     (if (> port 0)
1767         (telnet host port)
1768       (telnet host))))
1769
1770
1771 ;;; Other URL page opening
1772 ;;
1773
1774 (defun elpher-get-other-url-page (renderer)
1775   "Getter which attempts to open the URL specified by the current page.
1776 The RENDERER argument to this getter must be nil."
1777   (when renderer
1778     (elpher-visit-previous-page)
1779     (error "Command not supported for general URLs"))
1780   (let* ((address (elpher-page-address elpher-current-page))
1781          (url (elpher-address-to-url address)))
1782     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1783     (message "Opening URL...")
1784     (if elpher-open-urls-with-eww
1785         (browse-web url)
1786       (browse-url url))))
1787
1788
1789 ;;; File page
1790 ;;
1791
1792 (defun elpher-get-file-page (renderer)
1793   "Getter which renders a local file using RENDERER.
1794 Assumes UTF-8 encoding for all text files."
1795   (let* ((address (elpher-page-address elpher-current-page))
1796          (filename (elpher-address-filename address)))
1797     (unless (file-exists-p filename)
1798       (elpher-visit-previous-page)
1799         (error "File not found"))
1800     (unless (file-readable-p filename)
1801       (elpher-visit-previous-page)
1802         (error "Could not read from file"))
1803     (let ((body (with-temp-buffer
1804        (let ((coding-system-for-read 'binary)
1805              (coding-system-for-write 'binary))
1806          (insert-file-contents-literally filename)
1807          (encode-coding-string (buffer-string) 'raw-text)))))
1808        (if renderer
1809            (funcall renderer body nil)
1810          (pcase (file-name-extension filename)
1811            ((or  "gmi" "gemini")
1812             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1813            ((or "htm" "html")
1814             (elpher-render-html (decode-coding-string body 'utf-8)))
1815            ((or "txt" "")
1816             (elpher-render-text (decode-coding-string body 'utf-8)))
1817            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1818             (elpher-render-image body))
1819            ((or "gopher" "gophermap")
1820             (elpher-render-index (elpher-decode body)))
1821            (_
1822             (elpher-render-download body))))
1823        (elpher-restore-pos))))
1824
1825
1826 ;;; Welcome page retrieval
1827 ;;
1828
1829 (defun elpher-get-welcome-page (renderer)
1830   "Getter which displays the welcome page (RENDERER must be nil)."
1831   (when renderer
1832     (elpher-visit-previous-page)
1833     (error "Command not supported for welcome page"))
1834   (elpher-with-clean-buffer
1835    (insert "     --------------------------------------------\n"
1836            "           Elpher Gopher and Gemini Client       \n"
1837            "                   version " elpher-version "\n"
1838            "     --------------------------------------------\n"
1839            "\n"
1840            "Default bindings:\n"
1841            "\n"
1842            " - TAB/Shift-TAB: next/prev item on current page\n"
1843            " - RET/mouse-1: open item under cursor\n"
1844            " - m: select an item on current page by name (autocompletes)\n"
1845            " - u/mouse-3/U: return to previous page or to the start page\n"
1846            " - g: go to a particular address (gopher, gemini, finger)\n"
1847            " - o/O: open a different address selector or the root menu of the current server\n"
1848            " - d/D: download item under cursor or current page\n"
1849            " - i/I: info on item under cursor or current page\n"
1850            " - c/C: copy URL representation of item under cursor or current page\n"
1851            " - a/A: bookmark the item under cursor or current page\n"
1852            " - B: list all bookmarks\n"
1853            " - s/S: show current history stack or all previously visted pages\n"
1854            " - r: redraw current page (using cached contents if available)\n"
1855            " - R: reload current page (regenerates cache)\n"
1856            " - !: set character coding system for gopher (default is to autodetect)\n"
1857            " - T: toggle TLS gopher mode\n"
1858            " - F: forget/discard current TLS client certificate\n"
1859            " - .: display the raw server response for the current page\n"
1860            "\n"
1861            "Start your exploration of gopher space and gemini:\n")
1862    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1863                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1864    (elpher-insert-index-record "Project Gemini home page"
1865                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1866    (insert "\n"
1867            "Alternatively, select a search engine and enter some search terms:\n")
1868    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1869                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1870    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1871                                (elpher-address-from-url "gemini://geminispace.info/search"))
1872    (insert "\n"
1873            "Your bookmarks are stored in your ")
1874    (insert-text-button "bookmark list"
1875                        'face 'link
1876                        'action #'elpher-click-link
1877                        'follow-link t
1878                        'help-echo #'elpher--page-button-help
1879                        'elpher-page
1880                        (elpher-make-page "Elpher Bookmarks"
1881                                          (elpher-make-about-address 'bookmarks)))
1882    (insert ".\n")
1883    (insert (propertize
1884             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1885             'face 'shadow))
1886    (insert "\n"
1887            "The gopher home of the Elpher project is here:\n")
1888    (elpher-insert-index-record "The Elpher Project Page"
1889                                (elpher-make-gopher-address ?1
1890                                                            "/projects/elpher/"
1891                                                            "thelambdalab.xyz"
1892                                                            70))
1893    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1894      (insert "\n"
1895              "The following info documentation is available:\n"
1896              "   - ")
1897      (insert-text-button "Elpher Manual"
1898                          'face 'link
1899                          'action (lambda (_)
1900                                    (interactive)
1901                                    (info "(elpher)"))
1902                          'follow-link t
1903                          'help-echo help-string)
1904      (insert "\n   - ")
1905      (insert-text-button "Changes introduced by the latest release"
1906                        'face 'link
1907                        'action (lambda (_)
1908                                  (interactive)
1909                                  (info "(elpher)News"))
1910                        'follow-link t
1911                        'help-echo help-string))
1912    (insert "\n")
1913    (insert (propertize
1914             (concat "(These documents should be available if you have installed Elpher\n"
1915                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1916                     " manual yourself.)\n")
1917             'face 'shadow))
1918    (elpher-restore-pos)))
1919
1920
1921 ;;; History page retrieval
1922 ;;
1923
1924 (defun elpher-show-history ()
1925   "Show the current contents of elpher's history stack.
1926 Use \\[elpher-show-visited-pages] to see the entire history.
1927 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1928   (interactive)
1929   (elpher-visit-page
1930    (elpher-make-page "Current History Stack"
1931                      (elpher-make-about-address 'history))))
1932
1933 (defun elpher-show-visited-pages ()
1934   "Show the all the pages you've visited using Elpher.
1935 Use \\[elpher-show-history] to see just the current history stack.
1936 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1937   (interactive)
1938   (elpher-visit-page
1939    (elpher-make-page "Elpher Visted Pages"
1940                      (elpher-make-about-address 'visited-pages))))
1941
1942 (defun elpher-get-history-page (renderer)
1943   "Getter which displays the history page (RENDERER must be nil)."
1944   (when renderer
1945     (elpher-visit-previous-page)
1946     (error "Command not supported for history page"))
1947   (elpher-display-history-links elpher-history "Current history stack"))
1948
1949 (defun elpher-get-visited-pages-page (renderer)
1950   "Getter which displays the list of visited pages (RENDERER must be nil)."
1951   (when renderer
1952     (elpher-visit-previous-page)
1953     (error "Command not supported for history page"))
1954   (elpher-display-history-links
1955    (seq-filter (lambda (page)
1956                  (not (elpher-address-about-p (elpher-page-address page))))
1957                elpher-visited-pages)
1958    "All visited pages"))
1959
1960 (defun elpher-display-history-links (pages title)
1961   "Show all PAGES in an Elpher buffer with a given TITLE."
1962   (let* ((title-line (concat " ---- " title " ----"))
1963          (footer-line (make-string (length title-line) ?-)))
1964     (elpher-with-clean-buffer
1965      (insert title-line "\n\n")
1966      (if pages
1967          (dolist (page pages)
1968            (when page
1969              (let ((display-string (elpher-page-display-string page))
1970                    (address (elpher-page-address page)))
1971                (elpher-insert-index-record display-string address))))
1972        (insert "No history items found.\n"))
1973      (insert "\n " footer-line "\n"
1974              "Select an entry or press 'u' to return to the previous page.")
1975      (elpher-restore-pos))))
1976
1977
1978 ;;; Bookmarks
1979 ;;
1980
1981 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1982 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1983 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1984 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1985
1986 (defvar elpher-bookmark-link nil
1987   "Prefer bookmarking a link or the current page.
1988 Bind this variable dynamically, or set it to t.
1989 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1990 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1991
1992 (defun elpher-bookmark-make-record ()
1993   "Return a bookmark record.
1994 If `elpher-bookmark-link' is non-nil and point is on a link button,
1995 return a bookmark record for that link.  Otherwise, return a bookmark
1996 record for the current elpher page."
1997   (let* ((button (and elpher-bookmark-link (button-at (point))))
1998          (page (if button
1999                    (button-get button 'elpher-page)
2000                  elpher-current-page)))
2001     (unless page
2002       (error "Cannot bookmark this link"))
2003     (let* ((address (elpher-page-address page))
2004            (url (elpher-address-to-url address))
2005            (display-string (elpher-page-display-string page))
2006            (pos (if button nil (point))))
2007       (if (elpher-address-about-p address)
2008           (error "Cannot bookmark %s" display-string)
2009         `(,display-string
2010           (defaults . (,display-string))
2011           (position . ,pos)
2012           (location . ,url)
2013           (handler . elpher-bookmark-jump))))))
2014
2015 ;;;###autoload
2016 (defun elpher-bookmark-jump (bookmark)
2017   "Handler used to open a bookmark using elpher.
2018 The argument BOOKMARK is a bookmark record passed to the function.
2019 This handler is responsible for loading the bookmark in some buffer,
2020 then making that buffer the current buffer.  It should not switch
2021 to the buffer."
2022   (let* ((url (cdr (assq 'location bookmark)))
2023          (cleaned-url (string-trim url))
2024          (page (elpher-page-from-url cleaned-url))
2025          (buffer (get-buffer-create elpher-buffer-name)))
2026     (elpher-with-clean-buffer
2027      (elpher-visit-page page))
2028     (set-buffer buffer)
2029     nil))
2030
2031 (defun elpher-bookmark-link ()
2032   "Bookmark the link at point.
2033 To bookmark the current page, use \\[elpher-bookmark-current]."
2034   (interactive)
2035   (let ((elpher-bookmark-link t))
2036     (bookmark-set-no-overwrite)))
2037
2038 (defun elpher-bookmark-current ()
2039   "Bookmark the current page.
2040 To bookmark the link at point use \\[elpher-bookmark-link]."
2041   (interactive)
2042   (call-interactively #'bookmark-set-no-overwrite))
2043
2044 (defun elpher-bookmark-import (file)
2045   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2046   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2047                               (file-readable-p elpher-bookmarks-file))
2048                          elpher-bookmarks-file
2049                        (read-file-name "Old Elpher bookmarks: "
2050                                        user-emacs-directory nil t
2051                                        "elpher-bookmarks"))))
2052   (dolist (bookmark (with-temp-buffer
2053                       (insert-file-contents file)
2054                       (read (current-buffer))))
2055     (let* ((display-string (car bookmark))
2056            (url (cadr bookmark))
2057            (record `(,display-string
2058                      (location . ,url)
2059                      (handler . elpher-bookmark-jump))))
2060       (bookmark-store display-string (cdr record) t)))
2061   (bookmark-save))
2062
2063 (defun elpher-get-bookmarks-page (renderer)
2064   "Getter which displays the bookmarks (RENDERER must be nil)."
2065   (when renderer
2066     (elpher-visit-previous-page)
2067     (error "Command not supported for bookmarks page"))
2068
2069   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2070                                      elpher-bookmarks-file)
2071                                 (locate-user-emacs-file "elpher-bookmarks"))))
2072     (when (and (file-readable-p old-bookmarks-file)
2073                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2074                                  old-bookmarks-file
2075                                  "\" found. Import now?")))
2076       (elpher-bookmark-import old-bookmarks-file)
2077       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2078
2079   (if (and elpher-use-emacs-bookmark-menu
2080            elpher-history)
2081       (progn
2082         (elpher-visit-previous-page)
2083         (call-interactively #'bookmark-bmenu-list))
2084     (elpher-with-clean-buffer
2085      (insert " ---- Elpher Bookmarks ---- \n\n")
2086      (bookmark-maybe-load-default-file)
2087      (dolist (bookmark (bookmark-maybe-sort-alist))
2088        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2089          (let* ((name (car bookmark))
2090                 (url (alist-get 'location (cdr bookmark)))
2091                 (address (elpher-address-from-url url)))
2092            (elpher-insert-index-record name address))))
2093      (when (<= (line-number-at-pos) 3)
2094        (insert "No bookmarked pages found.\n"))
2095      (insert "\n --------------------------\n\n"
2096              "Select an entry or press 'u' to return to the previous page.\n\n"
2097              "Bookmarks can be renamed or deleted via the ")
2098      (insert-text-button "Emacs bookmark menu"
2099                          'action (lambda (_)
2100                                    (interactive)
2101                                    (call-interactively #'bookmark-bmenu-list))
2102                          'follow-link t
2103                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2104      (insert (substitute-command-keys
2105               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2106      (elpher-restore-pos))))
2107
2108 (defun elpher-show-bookmarks ()
2109   "Interactive function to display the current list of elpher bookmarks."
2110   (interactive)
2111   (elpher-visit-page
2112    (elpher-make-page "Elpher Bookmarks"
2113                      (elpher-make-about-address 'bookmarks))))
2114
2115
2116 ;;; Integrations
2117 ;;
2118
2119 ;;; Org
2120
2121 (defun elpher-org-export-link (link description format protocol)
2122   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2123
2124 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2125 of gemini, gopher or finger."
2126   (let* ((url (if (equal protocol "elpher")
2127                   (string-remove-prefix "elpher:" link)
2128                 (format "%s:%s" protocol link)))
2129          (desc (or description url)))
2130     (pcase format
2131       (`gemini (format "=> %s %s" url desc))
2132       (`html (format "<a href=\"%s\">%s</a>" url desc))
2133       (`latex (format "\\href{%s}{%s}" url desc))
2134       (_ (if (not description)
2135              url
2136            (format "%s (%s)" desc url))))))
2137
2138 (defun elpher-org-store-link ()
2139   "Store link to an `elpher' page in Org."
2140   (when (eq major-mode 'elpher-mode)
2141     (let* ((url (elpher-info-current))
2142            (desc (car elpher-current-page))
2143            (protocol (cond
2144                       ((string-prefix-p "gemini:" url) "gemini")
2145                       ((string-prefix-p "gopher:" url) "gopher")
2146                       ((string-prefix-p "finger:" url) "finger")
2147                       (t "elpher"))))
2148       (when (equal "elpher" protocol)
2149         ;; Weird link. Or special inner link?
2150         (setq url (concat "elpher:" url)))
2151       (org-link-store-props :type protocol :link url :description desc)
2152       t)))
2153
2154 (defun elpher-org-follow-link (link protocol)
2155   "Visit a LINK for the given PROTOCOL.
2156
2157 PROTOCOL may be one of gemini, gopher or finger.  This method also
2158 supports the old protocol elpher, where the link is self-contained."
2159   (let ((url (if (equal protocol "elpher")
2160                  (string-remove-prefix "elpher:" link)
2161                (format "%s:%s" protocol link))))
2162     (elpher-go url)))
2163
2164 (defun elpher-org-mode-integration ()
2165   "Set up `elpher' integration for `org-mode'."
2166   (org-link-set-parameters
2167    "elpher"
2168    :store #'elpher-org-store-link
2169    :export (lambda (link description format _plist)
2170              (elpher-org-export-link link description format "elpher"))
2171    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2172   (org-link-set-parameters
2173    "gemini"
2174    :export (lambda (link description format _plist)
2175              (elpher-org-export-link link description format "gemini"))
2176    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2177   (org-link-set-parameters
2178    "gopher"
2179    :export (lambda (link description format _plist)
2180              (elpher-org-export-link link description format "gopher"))
2181    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2182   (org-link-set-parameters
2183    "finger"
2184    :export (lambda (link description format _plist)
2185              (elpher-org-export-link link description format "finger"))
2186    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2187
2188 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2189
2190 ;; Browse URL
2191
2192 ;;;###autoload
2193 (defun elpher-browse-url-elpher (url &rest _args)
2194   "Browse URL using Elpher.  This function is used by `browse-url'."
2195   (interactive (browse-url-interactive-arg "Elpher URL: "))
2196   (elpher-go url))
2197
2198 ;; Use elpher to open gopher, finger and gemini links
2199 ;; For recent version of `browse-url' package
2200 (if (boundp 'browse-url-default-handlers)
2201     (add-to-list
2202      'browse-url-default-handlers
2203      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2204   ;; Patch `browse-url-browser-function' for older ones. The value of
2205   ;; that variable is `browse-url-default-browser' by default, so
2206   ;; that's the function that gets advised. If the value is an alist,
2207   ;; however, we don't know what to do. Better not interfere?
2208   (when (and (symbolp browse-url-browser-function)
2209              (fboundp browse-url-browser-function))
2210     (advice-add browse-url-browser-function :before-while
2211                 (lambda (url &rest _args)
2212                   "Handle gemini, gopher, and finger schemes using Elpher."
2213                   (let ((scheme (downcase (car (split-string url ":" t)))))
2214                     (if (member scheme '("gemini" "gopher" "finger"))
2215                         ;; `elpher-go' always returns nil, which will stop the
2216                         ;; advice chain here in a before-while
2217                         (elpher-go url)
2218                       ;; chain must continue, then return t.
2219                       t))))))
2220
2221 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2222 (with-eval-after-load 'thingatpt
2223   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2224
2225 ;; Mu4e:
2226
2227 ;; Make mu4e aware of the gemini world
2228 (setq mu4e~view-beginning-of-url-regexp
2229       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2230
2231 ;; eww:
2232
2233 ;; Let elpher handle gemini, gopher links in eww buffer.
2234 (setq eww-use-browse-url
2235       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2236
2237
2238 ;;; Interactive procedures
2239 ;;
2240
2241 (defun elpher-next-link ()
2242   "Move point to the next link on the current page."
2243   (interactive)
2244   (forward-button 1))
2245
2246 (defun elpher-prev-link ()
2247   "Move point to the previous link on the current page."
2248   (interactive)
2249   (backward-button 1))
2250
2251 (defun elpher-follow-current-link ()
2252   "Open the link or url at point."
2253   (interactive)
2254   (push-button))
2255
2256 ;;;###autoload
2257 (defun elpher-go (host-or-url)
2258   "Go to a particular gopher site HOST-OR-URL.
2259 When run interactively HOST-OR-URL is read from the minibuffer."
2260   (interactive (list
2261                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2262   (let ((trimmed-host-or-url (string-trim host-or-url)))
2263     (unless (string-empty-p trimmed-host-or-url)
2264       (let ((page (elpher-page-from-url trimmed-host-or-url
2265                                         (elpher-get-default-url-scheme))))
2266         (unless (get-buffer-window elpher-buffer-name t)
2267           (switch-to-buffer elpher-buffer-name))
2268         (elpher-with-clean-buffer
2269          (elpher-visit-page page))
2270         nil)))) ; non-nil value is displayed by eshell
2271
2272 (defun elpher-go-current ()
2273   "Go to a particular URL which is read from the minibuffer.
2274 Unlike `elpher-go', the reader is initialized with the URL of the
2275 current page."
2276   (interactive)
2277   (let* ((address (elpher-page-address elpher-current-page))
2278          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2279                            (elpher-address-to-url address))))
2280     (unless (string-empty-p (string-trim url))
2281       (elpher-visit-page (elpher-page-from-url url)))))
2282
2283 (defun elpher-redraw ()
2284   "Redraw current page."
2285   (interactive)
2286   (elpher-visit-page elpher-current-page))
2287
2288 (defun elpher-reload ()
2289   "Reload current page."
2290   (interactive)
2291   (elpher-reload-current-page))
2292
2293 (defun elpher-toggle-tls ()
2294   "Toggle TLS encryption mode for gopher."
2295   (interactive)
2296   (setq elpher-use-tls (not elpher-use-tls))
2297   (if elpher-use-tls
2298       (if (gnutls-available-p)
2299           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2300         (setq elpher-use-tls nil)
2301         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2302     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2303
2304 (defun elpher-view-raw ()
2305   "View raw server response for current page."
2306   (interactive)
2307   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2308       (error "This page was not generated by a server")
2309     (elpher-visit-page elpher-current-page
2310                        #'elpher-render-raw)))
2311
2312 (defun elpher-back ()
2313   "Go to previous site."
2314   (interactive)
2315   (elpher-visit-previous-page))
2316
2317 (defun elpher-back-to-start ()
2318   "Go all the way back to the start page."
2319   (interactive)
2320   (setq-local elpher-current-page nil)
2321   (setq-local elpher-history nil)
2322   (elpher-visit-page (elpher-make-start-page)))
2323
2324 (defun elpher-download ()
2325   "Download the link at point."
2326   (interactive)
2327   (let ((button (button-at (point))))
2328     (if button
2329         (let ((page (button-get button 'elpher-page)))
2330           (unless page
2331             (error "Not an elpher page"))
2332           (when (elpher-address-about-p (elpher-page-address page))
2333             (error "Cannot download %s" (elpher-page-display-string page)))
2334           (elpher-visit-page (button-get button 'elpher-page)
2335                              #'elpher-render-download))
2336       (error "No link selected"))))
2337
2338 (defun elpher-download-current ()
2339   "Download the current page."
2340   (interactive)
2341   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2342       (error "Cannot download %s"
2343              (elpher-page-display-string elpher-current-page))
2344     (elpher-visit-page (elpher-make-page
2345                         (elpher-page-display-string elpher-current-page)
2346                         (elpher-page-address elpher-current-page))
2347                        #'elpher-render-download
2348                        t)))
2349
2350 (defun elpher--build-link-map ()
2351   "Build alist mapping link names to destination pages in current buffer."
2352   (let ((link-map nil)
2353         (b (next-button (point-min) t)))
2354     (while b
2355       (push (cons (button-label b) b) link-map)
2356       (setq b (next-button (button-start b))))
2357     link-map))
2358
2359 (defun elpher-jump ()
2360   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2361   (interactive)
2362   (let* ((link-map (elpher--build-link-map)))
2363     (if link-map
2364         (let ((key (let ((completion-ignore-case t))
2365                      (completing-read "Directory item/link: "
2366                                       link-map nil t))))
2367           (if (and key (> (length key) 0))
2368               (let ((b (cdr (assoc key link-map))))
2369                 (goto-char (button-start b))
2370                 (button-activate b)))))))
2371
2372 (defun elpher-root-dir ()
2373   "Visit root of current server."
2374   (interactive)
2375   (let ((address (elpher-page-address elpher-current-page)))
2376     (if (not (elpher-address-about-p address))
2377         (if (or (member (url-filename address) '("/" ""))
2378                 (and (elpher-address-gopher-p address)
2379                      (= (length (elpher-gopher-address-selector address)) 0)))
2380             (error "Already at root directory of current server")
2381           (let ((address-copy (elpher-address-from-url
2382                                (elpher-address-to-url address))))
2383             (setf (url-filename address-copy) "")
2384             (elpher-go (elpher-address-to-url address-copy))))
2385       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2386
2387 (defun elpher-info-page (page)
2388   "Display URL of PAGE in minibuffer."
2389   (let* ((address (elpher-page-address page))
2390          (url (elpher-address-to-url address))
2391          (iri (elpher-address-to-iri address)))
2392     (if (equal url iri)
2393         (message "%s" url)
2394       (message "%s (Raw: %s)" iri url))))
2395
2396 (defun elpher-info-link ()
2397   "Display information on page corresponding to link at point."
2398   (interactive)
2399   (let ((button (button-at (point))))
2400     (unless button
2401       (error "No item selected"))
2402     (let ((page (button-get button 'elpher-page)))
2403       (unless page
2404         (error "Not an elpher page"))
2405       (elpher-info-page page))))
2406
2407 (defun elpher-info-current ()
2408   "Display information on current page."
2409   (interactive)
2410   (elpher-info-page elpher-current-page))
2411
2412 (defun elpher-copy-page-url (page)
2413   "Copy URL representation of address of PAGE to `kill-ring'."
2414   (let* ((address (elpher-page-address page))
2415          (url (elpher-address-to-url address)))
2416     (message "Copied \"%s\" to kill-ring/clipboard." url)
2417     (kill-new url)))
2418
2419 (defun elpher-copy-link-url ()
2420   "Copy URL of item at point to `kill-ring'."
2421   (interactive)
2422   (let ((button (button-at (point))))
2423     (unless button
2424       (error "No item selected"))
2425     (let ((page (button-get button 'elpher-page)))
2426       (unless page
2427         (error "Not an elpher page"))
2428       (elpher-copy-page-url page))))
2429
2430 (defun elpher-copy-current-url ()
2431   "Copy URL of current page to `kill-ring'."
2432   (interactive)
2433   (elpher-copy-page-url elpher-current-page))
2434
2435 (defun elpher-set-gopher-coding-system ()
2436   "Specify an explicit character coding system for gopher selectors."
2437   (interactive)
2438   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2439     (setq elpher-user-coding-system system)
2440     (if system
2441         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2442       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2443
2444
2445 ;;; Mode and keymap
2446 ;;
2447
2448 (defvar elpher-mode-map
2449   (let ((map (make-sparse-keymap)))
2450     (define-key map (kbd "TAB") 'elpher-next-link)
2451     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2452     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2453     (define-key map (kbd "u") 'elpher-back)
2454     (define-key map (kbd "-") 'elpher-back)
2455     (define-key map (kbd "^") 'elpher-back)
2456     (define-key map [mouse-3] 'elpher-back)
2457     (define-key map (kbd "U") 'elpher-back-to-start)
2458     (define-key map (kbd "g") 'elpher-go)
2459     (define-key map (kbd "o") 'elpher-go-current)
2460     (define-key map (kbd "O") 'elpher-root-dir)
2461     (define-key map (kbd "s") 'elpher-show-history)
2462     (define-key map (kbd "S") 'elpher-show-visited-pages)
2463     (define-key map (kbd "r") 'elpher-redraw)
2464     (define-key map (kbd "R") 'elpher-reload)
2465     (define-key map (kbd "T") 'elpher-toggle-tls)
2466     (define-key map (kbd ".") 'elpher-view-raw)
2467     (define-key map (kbd "d") 'elpher-download)
2468     (define-key map (kbd "D") 'elpher-download-current)
2469     (define-key map (kbd "m") 'elpher-jump)
2470     (define-key map (kbd "i") 'elpher-info-link)
2471     (define-key map (kbd "I") 'elpher-info-current)
2472     (define-key map (kbd "c") 'elpher-copy-link-url)
2473     (define-key map (kbd "C") 'elpher-copy-current-url)
2474     (define-key map (kbd "a") 'elpher-bookmark-link)
2475     (define-key map (kbd "A") 'elpher-bookmark-current)
2476     (define-key map (kbd "B") 'elpher-show-bookmarks)
2477     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2478     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2479     (when (fboundp 'evil-define-key*)
2480       (evil-define-key*
2481        'motion map
2482        (kbd "TAB") 'elpher-next-link
2483        (kbd "C-") 'elpher-follow-current-link
2484        (kbd "C-t") 'elpher-back
2485        (kbd "u") 'elpher-back
2486        (kbd "-") 'elpher-back
2487        (kbd "^") 'elpher-back
2488        [mouse-3] 'elpher-back
2489        (kbd "U") 'elpher-back-to-start
2490        (kbd "g") 'elpher-go
2491        (kbd "o") 'elpher-go-current
2492        (kbd "O") 'elpher-root-dir
2493        (kbd "s") 'elpher-show-history
2494        (kbd "S") 'elpher-show-visited-pages
2495        (kbd "r") 'elpher-redraw
2496        (kbd "R") 'elpher-reload
2497        (kbd "T") 'elpher-toggle-tls
2498        (kbd ".") 'elpher-view-raw
2499        (kbd "d") 'elpher-download
2500        (kbd "D") 'elpher-download-current
2501        (kbd "m") 'elpher-jump
2502        (kbd "i") 'elpher-info-link
2503        (kbd "I") 'elpher-info-current
2504        (kbd "c") 'elpher-copy-link-url
2505        (kbd "C") 'elpher-copy-current-url
2506        (kbd "a") 'elpher-bookmark-link
2507        (kbd "A") 'elpher-bookmark-current
2508        (kbd "B") 'elpher-show-bookmarks
2509        (kbd "!") 'elpher-set-gopher-coding-system
2510        (kbd "F") 'elpher-forget-current-certificate))
2511     map)
2512   "Keymap for gopher client.")
2513
2514 (define-derived-mode elpher-mode special-mode "elpher"
2515   "Major mode for elpher, an elisp gopher client.
2516
2517 This mode is automatically enabled by the interactive
2518 functions which initialize the client, namely
2519 `elpher', and `elpher-go'."
2520   (setq-local elpher-current-page nil)
2521   (setq-local elpher-history nil)
2522   (setq-local elpher-buffer-name (buffer-name))
2523   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2524   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2525
2526 (when (fboundp 'evil-set-initial-state)
2527   (evil-set-initial-state 'elpher-mode 'motion))
2528
2529
2530 ;;; Main start procedure
2531 ;;
2532
2533 ;;;###autoload
2534 (defun elpher (&optional arg)
2535   "Start elpher with default landing page.
2536 The buffer used for Elpher sessions is determined by the value of
2537 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2538 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2539 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2540 \\[execute-extended-command] elpher RET’) switches to the session with
2541 that number, creating it if necessary.  A non numeric prefix ARG means
2542 to create a new session.  Returns the buffer selected (or created)."
2543   (interactive "P")
2544   (let* ((name (default-value 'elpher-buffer-name))
2545          (buf (cond ((numberp arg)
2546                      (get-buffer-create (format "%s<%d>" name arg)))
2547                     (arg
2548                      (generate-new-buffer name))
2549                     (t
2550                      (get-buffer-create name)))))
2551     (pop-to-buffer-same-window buf)
2552     (unless (buffer-modified-p)
2553       (elpher-mode)
2554       (elpher-visit-page (elpher-make-start-page))
2555       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2556
2557 ;;; elpher.el ends here