src/forth.jl

   1 module forth
   2
   3 import Base.REPLCompletions
   4
   5 # VM mem size
   6 size_mem = 1000000 # 1 mega-int
   7
   8 # Buffer sizes
   9 size_RS = 1000   # Return stack size
  10 size_PS = 1000   # Parameter stack size
  11 size_TIB = 1000  # Terminal input buffer size
  12 size_FIB = 1000  # File input buffer size
  13
  14 # Memory arrays
  15 mem = Array{Int64,1}(size_mem)
  16 primitives = Array{Function,1}()
  17 primNames = Array{AbstractString,1}()
  18
  19 # Memory geography and built-in variables
  20
  21 nextVarAddr = 1
  22 H = nextVarAddr; nextVarAddr += 1              # Next free memory address
  23 FORTH_LATEST = nextVarAddr; nextVarAddr += 1   # FORTH dict latest
  24 CURRENT = nextVarAddr; nextVarAddr += 1        # Current compilation dict
  25
  26 RSP0 = nextVarAddr                  # bottom of RS
  27 PSP0 = RSP0 + size_RS               # bottom of PS
  28 TIB = PSP0 + size_PS                # address of terminal input buffer
  29 FIB = TIB + size_TIB                # address of terminal input buffer
  30 mem[H] = FIB + size_FIB             # location of bottom of dictionary
  31 mem[FORTH_LATEST] = 0               # zero FORTH dict latest (no previous def)
  32 mem[CURRENT] = FORTH_LATEST-1       # Compile words to system dict initially
  33
  34 DICT = mem[H] # Save bottom of dictionary as constant
  35
  36 # VM registers
  37 type Reg
  38     RSP::Int64  # Return stack pointer
  39     PSP::Int64  # Parameter/data stack pointer
  40     IP::Int64   # Instruction pointer
  41     W::Int64    # Working register
  42 end
  43 reg = Reg(RSP0, PSP0, 0, 0)
  44
  45 # Stack manipulation functions
  46
  47 function ensurePSDepth(depth::Int64)
  48     if reg.PSP - PSP0 < depth
  49         error("Parameter stack underflow.")
  50     end
  51 end
  52
  53 function ensurePSCapacity(toAdd::Int64)
  54     if reg.PSP + toAdd >= PSP0 + size_PS
  55         error("Parameter stack overflow.")
  56     end
  57 end
  58
  59 function ensureRSDepth(depth::Int64)
  60     if reg.RSP - RSP0 < depth
  61         error("Return stack underflow.")
  62     end
  63 end
  64
  65 function ensureRSCapacity(toAdd::Int64)
  66     if reg.RSP + toAdd >= RSP0 + size_RS
  67         error("Return stack overflow.")
  68     end
  69 end
  70
  71 function pushRS(val::Int64)
  72     ensureRSCapacity(1)
  73     mem[reg.RSP+=1] = val
  74 end
  75
  76 function popRS()
  77     ensureRSDepth(1)
  78
  79     val = mem[reg.RSP]
  80     reg.RSP -= 1
  81     return val
  82 end
  83
  84 function pushPS(val::Int64)
  85     ensurePSCapacity(1)
  86
  87     mem[reg.PSP += 1] = val
  88 end
  89
  90 function popPS()
  91     ensurePSDepth(1)
  92
  93     val = mem[reg.PSP]
  94     reg.PSP -= 1
  95     return val
  96 end
  97
  98 # Handy functions for adding/retrieving strings to/from memory.
  99
 100 getString(addr::Int64, len::Int64) = AbstractString([Char(c) for c in mem[addr:(addr+len-1)]])
 101
 102 function putString(str::AbstractString, addr::Int64)
 103     mem[addr:(addr+length(str)-1)] = [Int64(c) for c in str]
 104 end
 105
 106 function putString(str::AbstractString, addr::Int64, maxLen::Int64)
 107     len = min(length(str), maxLen)
 108     mem[addr:(addr+len-1)] = [Int64(c) for c in str]
 109 end
 110
 111 stringAsInts(str::AbstractString) = [Int(c) for c in collect(str)]
 112
 113 # Primitive creation and calling functions
 114
 115 function defPrim(f::Function; name="nameless")
 116     push!(primitives, f)
 117     push!(primNames, replace(name, "\004", "EOF"))
 118
 119     return -length(primitives)
 120 end
 121
 122 function callPrim(addr::Int64)
 123     if addr >=0 || -addr>length(primitives)
 124         error("Attempted to execute non-existent primitive at address $addr.")
 125     else
 126         primitives[-addr]()
 127     end
 128 end
 129 getPrimName(addr::Int64) = primNames[-addr]
 130
 131 # Word creation functions
 132
 133 F_LENMASK = 31
 134 F_IMMED = 32
 135 F_HIDDEN = 64
 136 NFA_MARK = 128
 137
 138 function dictWrite(ints::Array{Int64,1})
 139     mem[mem[H]:(mem[H]+length(ints)-1)] = ints
 140     mem[H] += length(ints)
 141 end
 142 dictWrite(int::Int64) = dictWrite([int])
 143 dictWriteString(string::AbstractString) = dictWrite([Int64(c) for c in string])
 144
 145 function createHeader(name::AbstractString, flags::Int64)
 146     mem[mem[H]] = mem[mem[CURRENT]+1]
 147     mem[mem[CURRENT]+1] = mem[H]
 148     mem[H] += 1
 149
 150     dictWrite(length(name) | flags | NFA_MARK)
 151     dictWriteString(name)
 152 end
 153
 154 function defPrimWord(name::AbstractString, f::Function; flags::Int64=0)
 155     createHeader(name, flags)
 156
 157     codeWordAddr = mem[H]
 158     dictWrite(defPrim(f, name=name))
 159
 160     return codeWordAddr
 161 end
 162
 163 function defWord(name::AbstractString, wordAddrs::Array{Int64,1}; flags::Int64=0)
 164     createHeader(name, flags)
 165
 166     addr = mem[H]
 167     dictWrite(DOCOL)
 168
 169     dictWrite(wordAddrs)
 170
 171     return addr
 172 end
 173
 174 # Variable creation functions
 175
 176 function defExistingVar(name::AbstractString, varAddr::Int64; flags::Int64=0)
 177
 178     defPrimWord(name, eval(:(() -> begin
 179         pushPS($(varAddr))
 180         return NEXT
 181     end)))
 182 end
 183
 184 function defNewVar(name::AbstractString, initial::Array{Int64,1}; flags::Int64=0)
 185     createHeader(name, flags)
 186
 187     codeWordAddr = mem[H]
 188     varAddr = mem[H] + 1
 189
 190     dictWrite(DOVAR)
 191     dictWrite(initial)
 192
 193     return varAddr, codeWordAddr
 194 end
 195
 196 defNewVar(name::AbstractString, initial::Int64; flags::Int64=0) =
 197     defNewVar(name, [initial]; flags=flags)
 198
 199 function defConst(name::AbstractString, val::Int64; flags::Int64=0)
 200     createHeader(name, flags)
 201
 202     codeWordAddr = mem[H]
 203
 204     dictWrite(DOCON)
 205     dictWrite(val)
 206
 207     return codeWordAddr
 208 end
 209
 210 # Threading Primitives (inner interpreter)
 211
 212 NEXT = defPrim(() -> begin
 213     reg.W = mem[reg.IP]
 214     reg.IP += 1
 215     return mem[reg.W]
 216 end, name="NEXT")
 217
 218 DOCOL = defPrim(() -> begin
 219     pushRS(reg.IP)
 220     reg.IP = reg.W + 1
 221     return NEXT
 222 end, name="DOCOL")
 223
 224 DOVAR = defPrim(() -> begin
 225     pushPS(reg.W + 1)
 226     return NEXT
 227 end, name="DOVAR")
 228
 229 DOCON = defPrim(() -> begin
 230     pushPS(mem[reg.W + 1])
 231     return NEXT
 232 end, name="DOVAR")
 233
 234 EXIT_CFA = defPrimWord("EXIT", () -> begin
 235     reg.IP = popRS()
 236     return NEXT
 237 end)
 238
 239 # Dictionary entries for core built-in variables, constants
 240
 241 H_CFA = defExistingVar("H", H)
 242
 243 PSP0_CFA = defConst("PSP0", PSP0)
 244 RSP0_CFA = defConst("RSP0", RSP0)
 245
 246 defConst("DOCOL", DOCOL)
 247 defConst("DOCON", DOCON)
 248 defConst("DOVAR", DOVAR)
 249
 250 defConst("DICT", DICT)
 251 defConst("MEMSIZE", size_mem)
 252
 253 F_IMMED_CFA = defConst("F_IMMED", F_IMMED)
 254 F_HIDDEN_CFA = defConst("F_HIDDEN", F_HIDDEN)
 255 F_LENMASK_CFA = defConst("F_LENMASK", F_LENMASK)
 256 NFA_MARK_CFA = defConst("NFA_MARK", NFA_MARK)
 257
 258 # Basic forth primitives
 259
 260 DROP_CFA = defPrimWord("DROP", () -> begin
 261     popPS()
 262     return NEXT
 263 end)
 264
 265 SWAP_CFA = defPrimWord("SWAP", () -> begin
 266     a = popPS()
 267     b = popPS()
 268     pushPS(a)
 269     pushPS(b)
 270     return NEXT
 271 end)
 272
 273 DUP_CFA = defPrimWord("DUP", () -> begin
 274     ensurePSDepth(1)
 275     pushPS(mem[reg.PSP])
 276     return NEXT
 277 end)
 278
 279 OVER_CFA = defPrimWord("OVER", () -> begin
 280     ensurePSDepth(2)
 281     pushPS(mem[reg.PSP-1])
 282     return NEXT
 283 end)
 284
 285 ROT_CFA = defPrimWord("ROT", () -> begin
 286     a = popPS()
 287     b = popPS()
 288     c = popPS()
 289     pushPS(b)
 290     pushPS(a)
 291     pushPS(c)
 292     return NEXT
 293 end)
 294
 295 NROT_CFA = defPrimWord("-ROT", () -> begin
 296     a = popPS()
 297     b = popPS()
 298     c = popPS()
 299     pushPS(a)
 300     pushPS(c)
 301     pushPS(b)
 302     return NEXT
 303 end)
 304
 305
 306 TWODROP_CFA = defPrimWord("2DROP", () -> begin
 307     popPS()
 308     popPS()
 309     return NEXT
 310 end)
 311
 312 TWODUP_CFA = defPrimWord("2DUP", () -> begin
 313     ensurePSDepth(2)
 314     a = mem[reg.PSP-1]
 315     b = mem[reg.PSP]
 316     pushPS(a)
 317     pushPS(b)
 318     return NEXT
 319 end)
 320
 321 TWOSWAP_CFA = defPrimWord("2SWAP", () -> begin
 322     a = popPS()
 323     b = popPS()
 324     c = popPS()
 325     d = popPS()
 326     pushPS(b)
 327     pushPS(a)
 328     pushPS(d)
 329     pushPS(c)
 330     return NEXT
 331 end)
 332
 333 TWOOVER_CFA = defPrimWord("2OVER", () -> begin
 334     ensurePSDepth(4)
 335     a = mem[reg.PSP-3]
 336     b = mem[reg.PSP-2]
 337     pushPS(a)
 338     pushPS(b)
 339     return NEXT
 340 end)
 341
 342 QDUP_CFA = defPrimWord("?DUP", () -> begin
 343     ensurePSDepth(1)
 344     val = mem[reg.PSP]
 345     if val != 0
 346         pushPS(val)
 347     end
 348     return NEXT
 349 end)
 350
 351 INCR_CFA = defPrimWord("1+", () -> begin
 352     ensurePSDepth(1)
 353     mem[reg.PSP] += 1
 354     return NEXT
 355 end)
 356
 357 DECR_CFA = defPrimWord("1-", () -> begin
 358     ensurePSDepth(1)
 359     mem[reg.PSP] -= 1
 360     return NEXT
 361 end)
 362
 363 INCR2_CFA = defPrimWord("2+", () -> begin
 364     ensurePSDepth(1)
 365     mem[reg.PSP] += 2
 366     return NEXT
 367 end)
 368
 369 DECR2_CFA = defPrimWord("2-", () -> begin
 370     ensurePSDepth(1)
 371     mem[reg.PSP] -= 2
 372     return NEXT
 373 end)
 374
 375 ADD_CFA = defPrimWord("+", () -> begin
 376     b = popPS()
 377     a = popPS()
 378     pushPS(a+b)
 379     return NEXT
 380 end)
 381
 382 SUB_CFA = defPrimWord("-", () -> begin
 383     b = popPS()
 384     a = popPS()
 385     pushPS(a-b)
 386     return NEXT
 387 end)
 388
 389 MUL_CFA = defPrimWord("*", () -> begin
 390     b = popPS()
 391     a = popPS()
 392     pushPS(a*b)
 393     return NEXT
 394 end)
 395
 396 DIVMOD_CFA = defPrimWord("/MOD", () -> begin
 397     b = popPS()
 398     a = popPS()
 399     q,r = divrem(a,b)
 400     pushPS(r)
 401     pushPS(q)
 402     return NEXT
 403 end)
 404
 405 TWOMUL_CFA = defPrimWord("2*", () -> begin
 406     pushPS(popPS() << 1)
 407     return NEXT
 408 end)
 409
 410 TWODIV_CFA = defPrimWord("2/", () -> begin
 411     pushPS(popPS() >> 1)
 412     return NEXT
 413 end)
 414
 415 EQ_CFA = defPrimWord("=", () -> begin
 416     b = popPS()
 417     a = popPS()
 418     pushPS(a==b ? -1 : 0)
 419     return NEXT
 420 end)
 421
 422 NE_CFA = defPrimWord("<>", () -> begin
 423     b = popPS()
 424     a = popPS()
 425     pushPS(a!=b ? -1 : 0)
 426     return NEXT
 427 end)
 428
 429 LT_CFA = defPrimWord("<", () -> begin
 430     b = popPS()
 431     a = popPS()
 432     pushPS(a<b ? -1 : 0)
 433     return NEXT
 434 end)
 435
 436 GT_CFA = defPrimWord(">", () -> begin
 437     b = popPS()
 438     a = popPS()
 439     pushPS(a>b ? -1 : 0)
 440     return NEXT
 441 end)
 442
 443 LE_CFA = defPrimWord("<=", () -> begin
 444     b = popPS()
 445     a = popPS()
 446     pushPS(a<=b ? -1 : 0)
 447     return NEXT
 448 end)
 449
 450 GE_CFA = defPrimWord(">=", () -> begin
 451     b = popPS()
 452     a = popPS()
 453     pushPS(a>=b ? -1 : 0)
 454     return NEXT
 455 end)
 456
 457 ZE_CFA = defPrimWord("0=", () -> begin
 458     pushPS(popPS() == 0 ? -1 : 0)
 459     return NEXT
 460 end)
 461
 462 ZNE_CFA = defPrimWord("0<>", () -> begin
 463     pushPS(popPS() != 0 ? -1 : 0)
 464     return NEXT
 465 end)
 466
 467 ZLT_CFA = defPrimWord("0<", () -> begin
 468     pushPS(popPS() < 0 ? -1 : 0)
 469     return NEXT
 470 end)
 471
 472 ZGT_CFA = defPrimWord("0>", () -> begin
 473     pushPS(popPS() > 0 ? -1 : 0)
 474     return NEXT
 475 end)
 476
 477 ZLE_CFA = defPrimWord("0<=", () -> begin
 478     pushPS(popPS() <= 0 ? -1 : 0)
 479     return NEXT
 480 end)
 481
 482 ZGE_CFA = defPrimWord("0>=", () -> begin
 483     pushPS(popPS() >= 0 ? -1 : 0)
 484     return NEXT
 485 end)
 486
 487 AND_CFA = defPrimWord("AND", () -> begin
 488     b = popPS()
 489     a = popPS()
 490     pushPS(a & b)
 491     return NEXT
 492 end)
 493
 494 OR_CFA = defPrimWord("OR", () -> begin
 495     b = popPS()
 496     a = popPS()
 497     pushPS(a | b)
 498     return NEXT
 499 end)
 500
 501 XOR_CFA = defPrimWord("XOR", () -> begin
 502     b = popPS()
 503     a = popPS()
 504     pushPS(a $ b)
 505     return NEXT
 506 end)
 507
 508 INVERT_CFA = defPrimWord("INVERT", () -> begin
 509     pushPS(~popPS())
 510     return NEXT
 511 end)
 512
 513 # Literals
 514
 515 LIT_CFA = defPrimWord("LIT", () -> begin
 516     pushPS(mem[reg.IP])
 517     reg.IP += 1
 518     return NEXT
 519 end)
 520
 521 # Memory primitives
 522
 523 STORE_CFA = defPrimWord("!", () -> begin
 524     addr = popPS()
 525     dat = popPS()
 526     mem[addr] = dat
 527     return NEXT
 528 end)
 529
 530 FETCH_CFA = defPrimWord("@", () -> begin
 531     addr = popPS()
 532     pushPS(mem[addr])
 533     return NEXT
 534 end)
 535
 536 ADDSTORE_CFA = defPrimWord("+!", () -> begin
 537     addr = popPS()
 538     toAdd = popPS()
 539     mem[addr] += toAdd
 540     return NEXT
 541 end)
 542
 543 SUBSTORE_CFA = defPrimWord("-!", () -> begin
 544     addr = popPS()
 545     toSub = popPS()
 546     mem[addr] -= toSub
 547     return NEXT
 548 end)
 549
 550
 551 # Return Stack
 552
 553 TOR_CFA = defPrimWord(">R", () -> begin
 554     pushRS(popPS())
 555     return NEXT
 556 end)
 557
 558 FROMR_CFA = defPrimWord("R>", () -> begin
 559     pushPS(popRS())
 560     return NEXT
 561 end)
 562
 563 RFETCH_CFA = defPrimWord("R@", () -> begin
 564     pushPS(mem[reg.RSP])
 565     return NEXT
 566 end)
 567
 568 RSPFETCH_CFA = defPrimWord("RSP@", () -> begin
 569     pushPS(reg.RSP)
 570     return NEXT
 571 end)
 572
 573 RSPSTORE_CFA = defPrimWord("RSP!", () -> begin
 574     reg.RSP = popPS()
 575     return NEXT
 576 end)
 577
 578 RDROP_CFA = defPrimWord("RDROP", () -> begin
 579     popRS()
 580     return NEXT
 581 end)
 582
 583 # Parameter Stack
 584
 585 PSPFETCH_CFA = defPrimWord("PSP@", () -> begin
 586     pushPS(reg.PSP)
 587     return NEXT
 588 end)
 589
 590 PSPSTORE_CFA = defPrimWord("PSP!", () -> begin
 591     reg.PSP = popPS()
 592     return NEXT
 593 end)
 594
 595 # Working Register
 596
 597 WFETCH_CFA = defPrimWord("W@", () -> begin
 598     pushPS(reg.W)
 599     return NEXT
 600 end)
 601
 602 WSTORE_CFA = defPrimWord("W!", () -> begin
 603     reg.W = popPS()
 604     return NEXT
 605 end)
 606
 607 # I/O
 608
 609 openFiles = Dict{Int64,IOStream}()
 610 nextFileID = 1
 611
 612
 613 ## File access modes
 614 FAM_RO = 0
 615 FAM_WO = 1
 616 FAM_RO_CFA = defConst("R/O", FAM_RO)
 617 FAM_WO_CFA = defConst("W/O", FAM_WO)
 618
 619 function fileOpener(create::Bool)
 620     fam = popPS()
 621     fnameLen = popPS()
 622     fnameAddr = popPS()
 623
 624     fname = getString(fnameAddr, fnameLen)
 625
 626     if create && !isfile(fname)
 627         pushPS(0)
 628         pushPS(-1) # error
 629         return NEXT
 630     end
 631
 632     if (fam == FAM_RO)
 633         mode = "r"
 634     else
 635         mode = "w"
 636     end
 637
 638     global nextFileID
 639     openFiles[nextFileID] = open(fname, mode)
 640     pushPS(nextFileID)
 641     pushPS(0)
 642
 643     nextFileID += 1
 644 end
 645
 646 OPEN_FILE_CFA = defPrimWord("OPEN-FILE", () -> begin
 647     fileOpener(false)
 648     return NEXT
 649 end);
 650
 651 CREATE_FILE_CFA = defPrimWord("CREATE-FILE", () -> begin
 652     fileOpener(true)
 653     return NEXT
 654 end);
 655
 656 CLOSE_FILE_CFA = defPrimWord("CLOSE-FILE", () -> begin
 657     fid = popPS()
 658     close(openFiles[fid])
 659     delete!(openFiles, fid)
 660
 661     pushPS(0) # Result code 0
 662     return NEXT
 663 end)
 664
 665 CLOSE_FILES_CFA = defPrimWord("CLOSE-FILES", () -> begin
 666     for fh in values(openFiles)
 667         close(fh)
 668     end
 669     empty!(openFiles)
 670
 671     pushPS(0) # Result code 0
 672     return NEXT
 673 end)
 674
 675 READ_LINE_CFA = defPrimWord("READ-LINE", () -> begin
 676     fid = popPS()
 677     maxSize = popPS()
 678     addr = popPS()
 679
 680     fh = openFiles[fid]
 681     line = readline(fh)
 682
 683     eofFlag = endswith(line, '\n') ? 0 : -1
 684     line = chomp(line)
 685
 686     println("Reading: $line");
 687
 688     putString(line, addr, maxSize)
 689
 690     pushPS(length(line))
 691     pushPS(eofFlag)
 692     pushPS(0)
 693
 694     return NEXT
 695 end)
 696
 697
 698 EMIT_CFA = defPrimWord("EMIT", () -> begin
 699     print(Char(popPS()))
 700     return NEXT
 701 end)
 702
 703 function raw_mode!(mode::Bool)
 704     if ccall(:jl_tty_set_mode, Int32, (Ptr{Void}, Int32), STDIN.handle, mode) != 0
 705         throw("FATAL: Terminal unable to enter raw mode.")
 706     end
 707 end
 708
 709 function getKey()
 710     raw_mode!(true)
 711     byte = readbytes(STDIN, 1)[1]
 712     raw_mode!(false)
 713
 714     if byte == 0x0d
 715         return 0x0a
 716     elseif byte == 127
 717         return 0x08
 718     else
 719         return byte
 720     end
 721 end
 722
 723 KEY_CFA = defPrimWord("KEY", () -> begin
 724     pushPS(Int(getKey()))
 725     return NEXT
 726 end)
 727
 728 function getLineFromSTDIN()
 729
 730     function getFrag(s)
 731         chars = collect(s)
 732         slashIdx = findlast(chars, '\\')
 733
 734         if slashIdx > 0
 735             return join(chars[slashIdx:length(chars)])
 736         else
 737             return nothing
 738         end
 739     end
 740
 741     function backspaceStr(s, bsCount)
 742         oldLen = length(s)
 743         newLen = max(0, oldLen - bsCount)
 744         return join(collect(s)[1:newLen])
 745     end
 746
 747     line = ""
 748     while true
 749         key = Char(getKey())
 750
 751         if key == '\n'
 752             print(" ")
 753             return AbstractString(line)
 754
 755         elseif key == '\x04'
 756             if isempty(line)
 757                 return string("\x04")
 758             end
 759
 760         elseif key == '\b'
 761             if !isempty(line)
 762                 print("\b\033[K")
 763                 line = backspaceStr(line, 1)
 764             end
 765
 766         elseif key == '\e'
 767             # Strip ANSI escape sequence
 768             nextKey = Char(getKey())
 769             if nextKey == '['
 770                 while true
 771                     nextKey = Char(getKey())
 772                     if nextKey >= '@' || nextKey <= '~'
 773                         break
 774                     end
 775                 end
 776             end
 777
 778         elseif key == '\t'
 779             # Currently do nothing
 780
 781             frag = getFrag(line)
 782             if frag != nothing
 783                 if haskey(REPLCompletions.latex_symbols, frag)
 784                     print(repeat("\b", length(frag)))
 785                     print("\033[K")
 786                     comp = REPLCompletions.latex_symbols[frag]
 787                     line = string(backspaceStr(line, length(frag)), comp)
 788                     print(comp)
 789                 end
 790             end
 791
 792         else
 793             print(key)
 794             line = string(line, key)
 795         end
 796     end
 797 end
 798
 799 SPAN, SPAN_CFA = defNewVar("SPAN", 0)
 800 EXPECT_CFA = defPrimWord("EXPECT", () -> begin
 801     maxLen = popPS()
 802     addr = popPS()
 803
 804     line = getLineFromSTDIN()
 805
 806     mem[SPAN] = min(length(line), maxLen)
 807     putString(line, addr, maxLen)
 808
 809     return NEXT
 810 end)
 811
 812 BASE, BASE_CFA = defNewVar("BASE", 10)
 813 NUMBER_CFA = defPrimWord("NUMBER", () -> begin
 814     wordAddr = popPS()+1
 815     wordLen = mem[wordAddr-1]
 816
 817     s = getString(wordAddr, wordLen)
 818
 819     pushPS(parse(Int64, s, mem[BASE]))
 820
 821     return NEXT
 822 end)
 823
 824 # Dictionary searches
 825
 826 FROMLINK_CFA = defPrimWord("LINK>", () -> begin
 827
 828     addr = popPS()
 829     lenAndFlags = mem[addr+1]
 830     len = lenAndFlags & F_LENMASK
 831
 832     pushPS(addr + 2 + len)
 833
 834     return NEXT
 835 end)
 836
 837 NUMCONTEXT, NUMCONTEXT_CFA = defNewVar("#CONTEXT", 1)
 838
 839 createHeader("FORTH", 0)
 840 FORTH_CFA = mem[H]
 841 dictWrite(defPrim(() -> begin
 842     mem[CONTEXT + mem[NUMCONTEXT] - 1] = reg.W
 843     return NEXT
 844 end, name="FORTH"))
 845 dictWrite(0) # cell for latest
 846
 847 CURRENT_CFA = defExistingVar("CURRENT", CURRENT)
 848
 849 # Switch to new FORTH vocabulary cfa
 850 mem[FORTH_CFA+1] = mem[mem[CURRENT]+1]
 851 mem[CURRENT] = FORTH_CFA
 852
 853 CONTEXT, CONTEXT_CFA = defNewVar("CONTEXT", zeros(Int64, 10))
 854 mem[CONTEXT] = FORTH_CFA
 855
 856 FINDVOCAB_CFA = defPrimWord("FINDVOCAB", () -> begin
 857     vocabCFA = popPS()
 858     countedAddr = popPS()
 859
 860     wordAddr = countedAddr + 1
 861     wordLen = mem[countedAddr]
 862     word = lowercase(getString(wordAddr, wordLen))
 863
 864     lfa = vocabCFA+1
 865     lenAndFlags = 0
 866
 867     while (lfa = mem[lfa]) > 0
 868
 869         lenAndFlags = mem[lfa+1]
 870         len = lenAndFlags & F_LENMASK
 871         hidden = (lenAndFlags & F_HIDDEN) == F_HIDDEN
 872
 873         if hidden || len != wordLen
 874             continue
 875         end
 876
 877         thisWord = lowercase(getString(lfa+2, len))
 878
 879         if thisWord == word
 880             break
 881         end
 882     end
 883
 884     if lfa > 0
 885         pushPS(lfa)
 886         callPrim(mem[FROMLINK_CFA])
 887         if (lenAndFlags & F_IMMED) == F_IMMED
 888             pushPS(1)
 889         else
 890             pushPS(-1)
 891         end
 892     else
 893         pushPS(countedAddr)
 894         pushPS(0)
 895     end
 896
 897     return NEXT
 898 end)
 899
 900 FIND_CFA = defPrimWord("FIND", () -> begin
 901
 902     countedAddr = popPS()
 903     context = mem[CONTEXT:(CONTEXT+mem[NUMCONTEXT]-1)]
 904
 905     for vocabCFA in reverse(context)
 906         pushPS(countedAddr)
 907         pushPS(vocabCFA)
 908         callPrim(mem[FINDVOCAB_CFA])
 909
 910         callPrim(mem[DUP_CFA])
 911         if popPS() != 0
 912             return NEXT
 913         else
 914             popPS()
 915             popPS()
 916         end
 917     end
 918
 919     pushPS(countedAddr)
 920     pushPS(0)
 921
 922     return NEXT
 923 end)
 924
 925
 926 # Branching
 927
 928 BRANCH_CFA = defPrimWord("BRANCH", () -> begin
 929     reg.IP += mem[reg.IP]
 930     return NEXT
 931 end)
 932
 933 ZBRANCH_CFA = defPrimWord("0BRANCH", () -> begin
 934     if (popPS() == 0)
 935         reg.IP += mem[reg.IP]
 936     else
 937         reg.IP += 1
 938     end
 939
 940     return NEXT
 941 end)
 942
 943 # Strings
 944
 945 LITSTRING_CFA = defPrimWord("LITSTRING", () -> begin
 946     len = mem[reg.IP]
 947     reg.IP += 1
 948     pushPS(reg.IP)
 949     pushPS(len)
 950     reg.IP += len
 951
 952     return NEXT
 953 end)
 954
 955 TYPE_CFA = defPrimWord("TYPE", () -> begin
 956     len = popPS()
 957     addr = popPS()
 958     str = getString(addr, len)
 959     print(str)
 960     return NEXT
 961 end)
 962
 963 # Interpreter/Compiler-specific I/O
 964
 965 TIB_CFA = defConst("TIB", TIB)
 966 NUMTIB, NUMTIB_CFA = defNewVar("#TIB", 0)
 967
 968 FIB_CFA = defConst("FIB", FIB)
 969 NUMFIB, NUMFIB_CFA = defNewVar("#FIB", 0)
 970
 971 IB_CFA = defPrimWord("IB", () -> begin
 972     pushPS(mem[SOURCE_ID] == 0 ? TIB : FIB)
 973 end)
 974
 975 NUMIB_CFA = defPrimWord("#IB", () -> begin
 976     pushPS(mem[SOURCE_ID] == 0 ? NUMTIB : NUMFIB)
 977 end)
 978
 979 TOIN, TOIN_CFA = defNewVar(">IN", 0)
 980
 981 SOURCE_ID, SOURCE_ID_CFA = defNewVar("SOURCE-ID", 0)
 982
 983 SOURCE_CFA = defPrimWord("SOURCE", () -> begin
 984     if mem[SOURCE_ID] == 0
 985         pushPS(TIB)
 986         pushPS(NUMTIB)
 987     else
 988         pushPS(FIB)
 989         pushPS(NUMFIB)
 990     end
 991     return NEXT
 992 end)
 993
 994 QUERY_CFA = defWord("QUERY",
 995     [TIB_CFA, LIT_CFA, 160, EXPECT_CFA,
 996     SPAN_CFA, FETCH_CFA, NUMTIB_CFA, STORE_CFA,
 997     LIT_CFA, 0, TOIN_CFA, STORE_CFA,
 998     EXIT_CFA])
 999
1000 # ( fid -- flag )
1001 # Flag is false when EOF is reached.
1002 QUERY_FILE_CFA = defWord("QUERY-FILE",
1003     [FIB_CFA, LIT_CFA, 160, ROT_CFA, READ_LINE_CFA,
1004     DROP_CFA, SWAP_CFA,
1005     NUMFIB_CFA, STORE_CFA,
1006     EXIT_CFA])
1007
1008 WORD_CFA = defPrimWord("WORD", () -> begin
1009     delim = popPS()
1010
1011     callPrim(mem[SOURCE_CFA])
1012     sizeAddr = popPS()
1013     bufferAddr = popPS()
1014
1015     # Chew up initial occurrences of delim
1016     while (mem[TOIN]<mem[sizeAddr] && mem[bufferAddr+mem[TOIN]] == delim)
1017         mem[TOIN] += 1
1018     end
1019
1020     countAddr = mem[H]
1021     addr = mem[H]+1
1022
1023     # Start reading in word
1024     count = 0
1025     while (mem[TOIN]<mem[sizeAddr])
1026         mem[addr] = mem[bufferAddr+mem[TOIN]]
1027         mem[TOIN] += 1
1028
1029         if (mem[addr] == delim)
1030             break
1031         end
1032
1033         count += 1
1034         addr += 1
1035     end
1036
1037     # Record count
1038     mem[countAddr] = count
1039     pushPS(countAddr)
1040
1041     #println("Processing word: '$(getString(countAddr+1,mem[countAddr]))'")
1042
1043     return NEXT
1044 end)
1045
1046 # Compilation
1047
1048 STATE, STATE_CFA = defNewVar("STATE", 0)
1049
1050 COMMA_CFA = defPrimWord(",", () -> begin
1051     mem[mem[H]] = popPS()
1052     mem[H] += 1
1053
1054     return NEXT
1055 end)
1056
1057 HERE_CFA = defWord("HERE",
1058     [H_CFA, FETCH_CFA, EXIT_CFA])
1059
1060 HEADER_CFA = defPrimWord("HEADER", () -> begin
1061     wordAddr = popPS()+1
1062     wordLen = mem[wordAddr-1]
1063     word = getString(wordAddr, wordLen)
1064
1065     createHeader(word, 0)
1066
1067     return NEXT
1068 end)
1069
1070 CREATE_CFA = defWord("CREATE",
1071     [LIT_CFA, 32, WORD_CFA, HEADER_CFA,
1072     LIT_CFA, DOVAR, COMMA_CFA,
1073     EXIT_CFA])
1074
1075 DODOES = defPrim(() -> begin
1076     pushRS(reg.IP)
1077     reg.IP = popPS()
1078     pushPS(reg.W + 1)
1079     return NEXT
1080 end, name="DODOES")
1081
1082 DOES_HELPER_CFA = defPrimWord("(DOES>)", () -> begin
1083
1084     pushPS(mem[mem[CURRENT]+1])
1085     callPrim(mem[FROMLINK_CFA])
1086     cfa = popPS()
1087
1088     runtimeAddr = popPS()
1089
1090     mem[cfa] = defPrim(eval(:(() -> begin
1091         pushPS($(runtimeAddr))
1092         return DODOES
1093     end)), name="doesPrim")
1094
1095     return NEXT
1096 end, flags=F_IMMED | F_HIDDEN)
1097
1098 DOES_CFA = defWord("DOES>",
1099     [LIT_CFA, LIT_CFA, COMMA_CFA, HERE_CFA, LIT_CFA, 3, ADD_CFA, COMMA_CFA,
1100     LIT_CFA, DOES_HELPER_CFA, COMMA_CFA, LIT_CFA, EXIT_CFA, COMMA_CFA, EXIT_CFA],
1101     flags=F_IMMED)
1102
1103 LBRAC_CFA = defPrimWord("[", () -> begin
1104     mem[STATE] = 0
1105     return NEXT
1106 end, flags=F_IMMED)
1107
1108 RBRAC_CFA = defPrimWord("]", () -> begin
1109     mem[STATE] = 1
1110     return NEXT
1111 end, flags=F_IMMED)
1112
1113 HIDDEN_CFA = defPrimWord("HIDDEN", () -> begin
1114     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
1115     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_HIDDEN
1116     return NEXT
1117 end)
1118
1119 COLON_CFA = defWord(":",
1120     [LIT_CFA, 32, WORD_CFA,
1121     HEADER_CFA,
1122     LIT_CFA, DOCOL, COMMA_CFA,
1123     HIDDEN_CFA,
1124     RBRAC_CFA,
1125     EXIT_CFA])
1126
1127 SEMICOLON_CFA = defWord(";",
1128     [LIT_CFA, EXIT_CFA, COMMA_CFA,
1129     HIDDEN_CFA,
1130     LBRAC_CFA,
1131     EXIT_CFA], flags=F_IMMED)
1132
1133 IMMEDIATE_CFA = defPrimWord("IMMEDIATE", () -> begin
1134     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
1135     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_IMMED
1136     return NEXT
1137 end, flags=F_IMMED)
1138
1139 CODE_CFA = defPrimWord("CODE", () -> begin
1140     pushPS(32)
1141     callPrim(mem[WORD_CFA])
1142     callPrim(mem[HEADER_CFA])
1143
1144     exprString = "() -> begin\n"
1145     while true
1146         if mem[TOIN] >= mem[NUMTIB]
1147             exprString = string(exprString, "\n")
1148             if currentSource() == STDIN
1149                 println()
1150             end
1151
1152             pushPS(TIB)
1153             pushPS(160)
1154             callPrim(mem[EXPECT_CFA])
1155             mem[NUMTIB] = mem[SPAN]
1156             mem[TOIN] = 0
1157         end
1158
1159         pushPS(32)
1160         callPrim(mem[WORD_CFA])
1161         cAddr = popPS()
1162         thisWord = getString(cAddr+1, mem[cAddr])
1163
1164         if uppercase(thisWord) == "END-CODE"
1165             break
1166         end
1167
1168         exprString = string(exprString, " ", thisWord)
1169     end
1170     exprString = string(exprString, "\nreturn NEXT\nend")
1171
1172     func = eval(parse(exprString))
1173     dictWrite(defPrim(func))
1174
1175     return NEXT
1176 end)
1177
1178 # Outer Interpreter
1179
1180 EXECUTE_CFA = defPrimWord("EXECUTE", () -> begin
1181     reg.W = popPS()
1182     return mem[reg.W]
1183 end)
1184
1185 INTERPRET_CFA = defWord("INTERPRET",
1186     [LIT_CFA, 32, WORD_CFA, # Read next space-delimited word
1187
1188     DUP_CFA, FETCH_CFA, ZE_CFA, ZBRANCH_CFA, 3,
1189         DROP_CFA, EXIT_CFA, # Exit if input buffer is exhausted
1190
1191     STATE_CFA, FETCH_CFA, ZBRANCH_CFA, 24,
1192         # Compiling
1193         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 13,
1194
1195             # Found word.
1196             LIT_CFA, -1, EQ_CFA, INVERT_CFA, ZBRANCH_CFA, 4,
1197
1198                 # Immediate: Execute!
1199                 EXECUTE_CFA, BRANCH_CFA, -26,
1200
1201                 # Not immediate: Compile!
1202                 COMMA_CFA, BRANCH_CFA, -29,
1203
1204             # No word found, parse number
1205             NUMBER_CFA, LIT_CFA, LIT_CFA, COMMA_CFA, COMMA_CFA, BRANCH_CFA, -36,
1206
1207        # Interpreting
1208         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 5,
1209
1210             # Found word. Execute!
1211             DROP_CFA, EXECUTE_CFA, BRANCH_CFA, -44,
1212
1213             # No word found, parse number and leave on stack
1214             NUMBER_CFA, BRANCH_CFA, -47,
1215     EXIT_CFA])
1216
1217 PROMPT_CFA = defPrimWord("PROMPT", () -> begin
1218     if mem[STATE] == 0
1219         print(" ok")
1220     end
1221     println()
1222
1223     return NEXT
1224 end)
1225
1226 QUIT_CFA = defWord("QUIT",
1227     [LIT_CFA, 0, STATE_CFA, STORE_CFA,      # Set mode to interpret
1228     LIT_CFA, 0, SOURCE_ID_CFA, STORE_CFA,   # Set terminal as input stream
1229     LIT_CFA, 0, NUMTIB_CFA, STORE_CFA,      # Clear the input buffer
1230     RSP0_CFA, RSPSTORE_CFA,                 # Clear the return stack
1231     QUERY_CFA,                              # Read line of input
1232     INTERPRET_CFA, PROMPT_CFA,              # Interpret line
1233     BRANCH_CFA,-4])                         # Loop
1234
1235 INCLUDED_CFA = defWord("INCLUDED",
1236     [LIT_CFA, 0, STATE_CFA, STORE_CFA,      # Set mode to interpret
1237     SOURCE_ID_CFA, FETCH_CFA, TOR_CFA,      # Store current source on return stack
1238     FAM_RO_CFA, OPEN_FILE_CFA, DROP_CFA,    # Open the file
1239     DUP_CFA, SOURCE_ID_CFA, STORE_CFA,      # Mark this as the current source
1240     DUP_CFA, QUERY_FILE_CFA,                # Read line from file
1241     INTERPRET_CFA,                          # Interpret line
1242     ZBRANCH_CFA, -4,                        # Loop if not EOF
1243     CLOSE_FILE_CFA, DROP_CFA,               # Close file
1244     FROMR_CFA, SOURCE_ID_CFA, STORE_CFA,    # Restore input source
1245     EXIT_CFA])
1246
1247 INCLUDE_CFA = defWord("INCLUDE", [LIT_CFA, 32, WORD_CFA, INCLUDED_CFA, EXIT_CFA]);
1248
1249
1250 ABORT_CFA = defWord("ABORT",
1251     [CLOSE_FILES_CFA, DROP_CFA, PSP0_CFA, PSPSTORE_CFA, QUIT_CFA])
1252
1253 BYE_CFA = defPrimWord("BYE", () -> begin
1254     println("\nBye!")
1255     return 0
1256 end)
1257
1258 EOF_CFA = defPrimWord("\x04", () -> begin
1259     return 0
1260 end)
1261
1262 #### VM loop ####
1263
1264 initialized = false
1265 initFileName = nothing
1266 if isfile("lib.4th")
1267     initFileName = "lib.4th"
1268 elseif isfile(Pkg.dir("forth","src", "lib.4th"))
1269     initFileName = Pkg.dir("forth","src","lib.4th")
1270 end
1271
1272 function run(;initialize=true)
1273
1274     # Start with IP pointing to first instruction of outer interpreter
1275     pushRS(QUIT_CFA+1)
1276
1277     # Load library files
1278     global initialized, initFileName
1279     if !initialized && initialize
1280         if initFileName != nothing
1281             print("Including definitions from $initFileName...")
1282
1283             putString(initFileName, mem[H])
1284             pushPS(mem[H])
1285             pushPS(length(initFileName))
1286             pushRS(INCLUDED_CFA+1)
1287
1288             initialized = true
1289         else
1290             println("No library file found. Only primitive words available.")
1291         end
1292     end
1293
1294
1295     # Primitive processing loop.
1296     # Everyting else is simply a consequence of this loop!
1297     jmp = mem[EXIT_CFA]
1298     while jmp != 0
1299         try
1300             #print("Entering prim $(getPrimName(jmp)), PS: ")
1301             #printPS()
1302
1303             jmp = callPrim(jmp)
1304
1305         catch ex
1306             showerror(STDOUT, ex)
1307             println()
1308
1309             # QUIT
1310             reg.IP = ABORT_CFA + 1
1311             jmp = NEXT
1312         end
1313     end
1314 end
1315
1316 # Debugging tools
1317
1318 TRACE_CFA = defPrimWord("TRACE", () -> begin
1319     println("reg.W: $(reg.W) reg.IP: $(reg.IP)")
1320     print("PS: "); printPS()
1321     print("RS: "); printRS()
1322     print("[paused]")
1323     readline()
1324
1325     return NEXT
1326 end)
1327
1328 function dump(startAddr::Int64; count::Int64 = 100, cellsPerLine::Int64 = 10)
1329     chars = Array{Char,1}(cellsPerLine)
1330
1331     lineStartAddr = cellsPerLine*div((startAddr-1),cellsPerLine) + 1
1332     endAddr = startAddr + count - 1
1333
1334     q, r = divrem((endAddr-lineStartAddr+1), cellsPerLine)
1335     numLines = q + (r > 0 ? 1 : 0)
1336
1337     i = lineStartAddr
1338     for l in 1:numLines
1339         print(i,":")
1340
1341         for c in 1:cellsPerLine
1342             if i >= startAddr && i <= endAddr
1343                 print("\t",mem[i])
1344                 if mem[i]>=32 && mem[i]<128
1345                     chars[c] = Char(mem[i])
1346                 else
1347                     chars[c] = '.'
1348                 end
1349             else
1350                 print("\t")
1351                 chars[c] = ' '
1352             end
1353
1354             i += 1
1355         end
1356
1357         println("\t", AbstractString(chars))
1358     end
1359 end
1360
1361 function printPS()
1362     count = reg.PSP - PSP0
1363
1364     if count > 0
1365         print("<$count>")
1366         for i in (PSP0+1):reg.PSP
1367             print(" $(mem[i])")
1368         end
1369         println()
1370     else
1371         println("Parameter stack empty")
1372     end
1373 end
1374
1375 function printRS()
1376     count = reg.RSP - RSP0
1377
1378     if count > 0
1379         print("<$count>")
1380         for i in (RSP0+1):reg.RSP
1381             print(" $(mem[i])")
1382         end
1383         println()
1384     else
1385         println("Return stack empty")
1386     end
1387 end
1388
1389 DUMP = defPrimWord("DUMP", () -> begin
1390     count = popPS()
1391     addr = popPS()
1392
1393     println()
1394     dump(addr, count=count)
1395
1396     return NEXT
1397 end)
1398
1399 end