src/forth.jl

   1 module forth
   2
   3 import Base.REPLCompletions
   4
   5 # VM mem size
   6 size_mem = 1000000 # 1 mega-int
   7
   8 # Buffer sizes
   9 size_RS = 1000   # Return stack size
  10 size_PS = 1000   # Parameter stack size
  11 size_TIB = 1000  # Terminal input buffer size
  12
  13 # Memory arrays
  14 mem = Array{Int64,1}(size_mem)
  15 primitives = Array{Function,1}()
  16 primNames = Array{AbstractString,1}()
  17
  18 # Memory geography and built-in variables
  19
  20 nextVarAddr = 1
  21 H = nextVarAddr; nextVarAddr += 1              # Next free memory address
  22 FORTH_LATEST = nextVarAddr; nextVarAddr += 1   # FORTH dict latest
  23 CURRENT = nextVarAddr; nextVarAddr += 1        # Current compilation dict
  24
  25 RSP0 = nextVarAddr                  # bottom of RS
  26 PSP0 = RSP0 + size_RS               # bottom of PS
  27 TIB = PSP0 + size_PS                # address of terminal input buffer
  28 mem[H] = TIB + size_TIB             # location of bottom of dictionary
  29 mem[FORTH_LATEST] = 0               # zero FORTH dict latest (no previous def)
  30 mem[CURRENT] = FORTH_LATEST-1       # Compile words to system dict initially
  31
  32 DICT = mem[H] # Save bottom of dictionary as constant
  33
  34 # VM registers
  35 type Reg
  36     RSP::Int64  # Return stack pointer
  37     PSP::Int64  # Parameter/data stack pointer
  38     IP::Int64   # Instruction pointer
  39     W::Int64    # Working register
  40 end
  41 reg = Reg(RSP0, PSP0, 0, 0)
  42
  43 # Stack manipulation functions
  44
  45 function ensurePSDepth(depth::Int64)
  46     if reg.PSP - PSP0 < depth
  47         error("Parameter stack underflow.")
  48     end
  49 end
  50
  51 function ensurePSCapacity(toAdd::Int64)
  52     if reg.PSP + toAdd >= PSP0 + size_PS
  53         error("Parameter stack overflow.")
  54     end
  55 end
  56
  57 function ensureRSDepth(depth::Int64)
  58     if reg.RSP - RSP0 < depth
  59         error("Return stack underflow.")
  60     end
  61 end
  62
  63 function ensureRSCapacity(toAdd::Int64)
  64     if reg.RSP + toAdd >= RSP0 + size_RS
  65         error("Return stack overflow.")
  66     end
  67 end
  68
  69 function pushRS(val::Int64)
  70     ensureRSCapacity(1)
  71     mem[reg.RSP+=1] = val
  72 end
  73
  74 function popRS()
  75     ensureRSDepth(1)
  76
  77     val = mem[reg.RSP]
  78     reg.RSP -= 1
  79     return val
  80 end
  81
  82 function pushPS(val::Int64)
  83     ensurePSCapacity(1)
  84
  85     mem[reg.PSP += 1] = val
  86 end
  87
  88 function popPS()
  89     ensurePSDepth(1)
  90
  91     val = mem[reg.PSP]
  92     reg.PSP -= 1
  93     return val
  94 end
  95
  96 # Handy functions for adding/retrieving strings to/from memory.
  97
  98 getString(addr::Int64, len::Int64) = AbstractString([Char(c) for c in mem[addr:(addr+len-1)]])
  99
 100 function putString(str::AbstractString, addr::Int64, maxLen::Int64)
 101     len = min(length(str), maxLen)
 102     mem[addr:(addr+len-1)] = [Int64(c) for c in str]
 103 end
 104
 105 stringAsInts(str::AbstractString) = [Int(c) for c in collect(str)]
 106
 107 # Primitive creation and calling functions
 108
 109 function defPrim(f::Function; name="nameless")
 110     push!(primitives, f)
 111     push!(primNames, replace(name, "\004", "EOF"))
 112
 113     return -length(primitives)
 114 end
 115
 116 function callPrim(addr::Int64)
 117     if addr >=0 || -addr>length(primitives)
 118         error("Attempted to execute non-existent primitive at address $addr.")
 119     else
 120         primitives[-addr]()
 121     end
 122 end
 123 getPrimName(addr::Int64) = primNames[-addr]
 124
 125 # Word creation functions
 126
 127 F_LENMASK = 31
 128 F_IMMED = 32
 129 F_HIDDEN = 64
 130 NFA_MARK = 128
 131
 132 function dictWrite(ints::Array{Int64,1})
 133     mem[mem[H]:(mem[H]+length(ints)-1)] = ints
 134     mem[H] += length(ints)
 135 end
 136 dictWrite(int::Int64) = dictWrite([int])
 137 dictWriteString(string::AbstractString) = dictWrite([Int64(c) for c in string])
 138
 139 function createHeader(name::AbstractString, flags::Int64)
 140     mem[mem[H]] = mem[mem[CURRENT]+1]
 141     mem[mem[CURRENT]+1] = mem[H]
 142     mem[H] += 1
 143
 144     dictWrite(length(name) | flags | NFA_MARK)
 145     dictWriteString(name)
 146 end
 147
 148 function defPrimWord(name::AbstractString, f::Function; flags::Int64=0)
 149     createHeader(name, flags)
 150
 151     codeWordAddr = mem[H]
 152     dictWrite(defPrim(f, name=name))
 153
 154     return codeWordAddr
 155 end
 156
 157 function defWord(name::AbstractString, wordAddrs::Array{Int64,1}; flags::Int64=0)
 158     createHeader(name, flags)
 159
 160     addr = mem[H]
 161     dictWrite(DOCOL)
 162
 163     dictWrite(wordAddrs)
 164
 165     return addr
 166 end
 167
 168 # Variable creation functions
 169
 170 function defExistingVar(name::AbstractString, varAddr::Int64; flags::Int64=0)
 171
 172     defPrimWord(name, eval(:(() -> begin
 173         pushPS($(varAddr))
 174         return NEXT
 175     end)))
 176 end
 177
 178 function defNewVar(name::AbstractString, initial::Array{Int64,1}; flags::Int64=0)
 179     createHeader(name, flags)
 180
 181     codeWordAddr = mem[H]
 182     varAddr = mem[H] + 1
 183
 184     dictWrite(DOVAR)
 185     dictWrite(initial)
 186
 187     return varAddr, codeWordAddr
 188 end
 189
 190 defNewVar(name::AbstractString, initial::Int64; flags::Int64=0) =
 191     defNewVar(name, [initial]; flags=flags)
 192
 193 function defConst(name::AbstractString, val::Int64; flags::Int64=0)
 194     createHeader(name, flags)
 195
 196     codeWordAddr = mem[H]
 197
 198     dictWrite(DOCON)
 199     dictWrite(val)
 200
 201     return codeWordAddr
 202 end
 203
 204 # Threading Primitives (inner interpreter)
 205
 206 NEXT = defPrim(() -> begin
 207     reg.W = mem[reg.IP]
 208     reg.IP += 1
 209     return mem[reg.W]
 210 end, name="NEXT")
 211
 212 DOCOL = defPrim(() -> begin
 213     pushRS(reg.IP)
 214     reg.IP = reg.W + 1
 215     return NEXT
 216 end, name="DOCOL")
 217
 218 DOVAR = defPrim(() -> begin
 219     pushPS(reg.W + 1)
 220     return NEXT
 221 end, name="DOVAR")
 222
 223 DOCON = defPrim(() -> begin
 224     pushPS(mem[reg.W + 1])
 225     return NEXT
 226 end, name="DOVAR")
 227
 228 EXIT_CFA = defPrimWord("EXIT", () -> begin
 229     reg.IP = popRS()
 230     return NEXT
 231 end)
 232
 233 # Dictionary entries for core built-in variables, constants
 234
 235 H_CFA = defExistingVar("H", H)
 236
 237 PSP0_CFA = defConst("PSP0", PSP0)
 238 RSP0_CFA = defConst("RSP0", RSP0)
 239
 240 defConst("DOCOL", DOCOL)
 241 defConst("DOCON", DOCON)
 242 defConst("DOVAR", DOVAR)
 243
 244 defConst("DICT", DICT)
 245 defConst("MEMSIZE", size_mem)
 246
 247 F_IMMED_CFA = defConst("F_IMMED", F_IMMED)
 248 F_HIDDEN_CFA = defConst("F_HIDDEN", F_HIDDEN)
 249 F_LENMASK_CFA = defConst("F_LENMASK", F_LENMASK)
 250 NFA_MARK_CFA = defConst("NFA_MARK", NFA_MARK)
 251
 252 # Basic forth primitives
 253
 254 DROP_CFA = defPrimWord("DROP", () -> begin
 255     popPS()
 256     return NEXT
 257 end)
 258
 259 SWAP_CFA = defPrimWord("SWAP", () -> begin
 260     a = popPS()
 261     b = popPS()
 262     pushPS(a)
 263     pushPS(b)
 264     return NEXT
 265 end)
 266
 267 DUP_CFA = defPrimWord("DUP", () -> begin
 268     ensurePSDepth(1)
 269     pushPS(mem[reg.PSP])
 270     return NEXT
 271 end)
 272
 273 OVER_CFA = defPrimWord("OVER", () -> begin
 274     ensurePSDepth(2)
 275     pushPS(mem[reg.PSP-1])
 276     return NEXT
 277 end)
 278
 279 ROT_CFA = defPrimWord("ROT", () -> begin
 280     a = popPS()
 281     b = popPS()
 282     c = popPS()
 283     pushPS(b)
 284     pushPS(a)
 285     pushPS(c)
 286     return NEXT
 287 end)
 288
 289 NROT_CFA = defPrimWord("-ROT", () -> begin
 290     a = popPS()
 291     b = popPS()
 292     c = popPS()
 293     pushPS(a)
 294     pushPS(c)
 295     pushPS(b)
 296     return NEXT
 297 end)
 298
 299
 300 TWODROP_CFA = defPrimWord("2DROP", () -> begin
 301     popPS()
 302     popPS()
 303     return NEXT
 304 end)
 305
 306 TWODUP_CFA = defPrimWord("2DUP", () -> begin
 307     ensurePSDepth(2)
 308     a = mem[reg.PSP-1]
 309     b = mem[reg.PSP]
 310     pushPS(a)
 311     pushPS(b)
 312     return NEXT
 313 end)
 314
 315 TWOSWAP_CFA = defPrimWord("2SWAP", () -> begin
 316     a = popPS()
 317     b = popPS()
 318     c = popPS()
 319     d = popPS()
 320     pushPS(b)
 321     pushPS(a)
 322     pushPS(d)
 323     pushPS(c)
 324     return NEXT
 325 end)
 326
 327 TWOOVER_CFA = defPrimWord("2OVER", () -> begin
 328     ensurePSDepth(4)
 329     a = mem[reg.PSP-3]
 330     b = mem[reg.PSP-2]
 331     pushPS(a)
 332     pushPS(b)
 333     return NEXT
 334 end)
 335
 336 QDUP_CFA = defPrimWord("?DUP", () -> begin
 337     ensurePSDepth(1)
 338     val = mem[reg.PSP]
 339     if val != 0
 340         pushPS(val)
 341     end
 342     return NEXT
 343 end)
 344
 345 INCR_CFA = defPrimWord("1+", () -> begin
 346     ensurePSDepth(1)
 347     mem[reg.PSP] += 1
 348     return NEXT
 349 end)
 350
 351 DECR_CFA = defPrimWord("1-", () -> begin
 352     ensurePSDepth(1)
 353     mem[reg.PSP] -= 1
 354     return NEXT
 355 end)
 356
 357 INCR2_CFA = defPrimWord("2+", () -> begin
 358     ensurePSDepth(1)
 359     mem[reg.PSP] += 2
 360     return NEXT
 361 end)
 362
 363 DECR2_CFA = defPrimWord("2-", () -> begin
 364     ensurePSDepth(1)
 365     mem[reg.PSP] -= 2
 366     return NEXT
 367 end)
 368
 369 ADD_CFA = defPrimWord("+", () -> begin
 370     b = popPS()
 371     a = popPS()
 372     pushPS(a+b)
 373     return NEXT
 374 end)
 375
 376 SUB_CFA = defPrimWord("-", () -> begin
 377     b = popPS()
 378     a = popPS()
 379     pushPS(a-b)
 380     return NEXT
 381 end)
 382
 383 MUL_CFA = defPrimWord("*", () -> begin
 384     b = popPS()
 385     a = popPS()
 386     pushPS(a*b)
 387     return NEXT
 388 end)
 389
 390 DIVMOD_CFA = defPrimWord("/MOD", () -> begin
 391     b = popPS()
 392     a = popPS()
 393     q,r = divrem(a,b)
 394     pushPS(r)
 395     pushPS(q)
 396     return NEXT
 397 end)
 398
 399 TWOMUL_CFA = defPrimWord("2*", () -> begin
 400     pushPS(popPS() << 1)
 401     return NEXT
 402 end)
 403
 404 TWODIV_CFA = defPrimWord("2/", () -> begin
 405     pushPS(popPS() >> 1)
 406     return NEXT
 407 end)
 408
 409 EQ_CFA = defPrimWord("=", () -> begin
 410     b = popPS()
 411     a = popPS()
 412     pushPS(a==b ? -1 : 0)
 413     return NEXT
 414 end)
 415
 416 NE_CFA = defPrimWord("<>", () -> begin
 417     b = popPS()
 418     a = popPS()
 419     pushPS(a!=b ? -1 : 0)
 420     return NEXT
 421 end)
 422
 423 LT_CFA = defPrimWord("<", () -> begin
 424     b = popPS()
 425     a = popPS()
 426     pushPS(a<b ? -1 : 0)
 427     return NEXT
 428 end)
 429
 430 GT_CFA = defPrimWord(">", () -> begin
 431     b = popPS()
 432     a = popPS()
 433     pushPS(a>b ? -1 : 0)
 434     return NEXT
 435 end)
 436
 437 LE_CFA = defPrimWord("<=", () -> begin
 438     b = popPS()
 439     a = popPS()
 440     pushPS(a<=b ? -1 : 0)
 441     return NEXT
 442 end)
 443
 444 GE_CFA = defPrimWord(">=", () -> begin
 445     b = popPS()
 446     a = popPS()
 447     pushPS(a>=b ? -1 : 0)
 448     return NEXT
 449 end)
 450
 451 ZE_CFA = defPrimWord("0=", () -> begin
 452     pushPS(popPS() == 0 ? -1 : 0)
 453     return NEXT
 454 end)
 455
 456 ZNE_CFA = defPrimWord("0<>", () -> begin
 457     pushPS(popPS() != 0 ? -1 : 0)
 458     return NEXT
 459 end)
 460
 461 ZLT_CFA = defPrimWord("0<", () -> begin
 462     pushPS(popPS() < 0 ? -1 : 0)
 463     return NEXT
 464 end)
 465
 466 ZGT_CFA = defPrimWord("0>", () -> begin
 467     pushPS(popPS() > 0 ? -1 : 0)
 468     return NEXT
 469 end)
 470
 471 ZLE_CFA = defPrimWord("0<=", () -> begin
 472     pushPS(popPS() <= 0 ? -1 : 0)
 473     return NEXT
 474 end)
 475
 476 ZGE_CFA = defPrimWord("0>=", () -> begin
 477     pushPS(popPS() >= 0 ? -1 : 0)
 478     return NEXT
 479 end)
 480
 481 AND_CFA = defPrimWord("AND", () -> begin
 482     b = popPS()
 483     a = popPS()
 484     pushPS(a & b)
 485     return NEXT
 486 end)
 487
 488 OR_CFA = defPrimWord("OR", () -> begin
 489     b = popPS()
 490     a = popPS()
 491     pushPS(a | b)
 492     return NEXT
 493 end)
 494
 495 XOR_CFA = defPrimWord("XOR", () -> begin
 496     b = popPS()
 497     a = popPS()
 498     pushPS(a $ b)
 499     return NEXT
 500 end)
 501
 502 INVERT_CFA = defPrimWord("INVERT", () -> begin
 503     pushPS(~popPS())
 504     return NEXT
 505 end)
 506
 507 # Literals
 508
 509 LIT_CFA = defPrimWord("LIT", () -> begin
 510     pushPS(mem[reg.IP])
 511     reg.IP += 1
 512     return NEXT
 513 end)
 514
 515 # Memory primitives
 516
 517 STORE_CFA = defPrimWord("!", () -> begin
 518     addr = popPS()
 519     dat = popPS()
 520     mem[addr] = dat
 521     return NEXT
 522 end)
 523
 524 FETCH_CFA = defPrimWord("@", () -> begin
 525     addr = popPS()
 526     pushPS(mem[addr])
 527     return NEXT
 528 end)
 529
 530 ADDSTORE_CFA = defPrimWord("+!", () -> begin
 531     addr = popPS()
 532     toAdd = popPS()
 533     mem[addr] += toAdd
 534     return NEXT
 535 end)
 536
 537 SUBSTORE_CFA = defPrimWord("-!", () -> begin
 538     addr = popPS()
 539     toSub = popPS()
 540     mem[addr] -= toSub
 541     return NEXT
 542 end)
 543
 544
 545 # Return Stack
 546
 547 TOR_CFA = defPrimWord(">R", () -> begin
 548     pushRS(popPS())
 549     return NEXT
 550 end)
 551
 552 FROMR_CFA = defPrimWord("R>", () -> begin
 553     pushPS(popRS())
 554     return NEXT
 555 end)
 556
 557 RFETCH_CFA = defPrimWord("R@", () -> begin
 558     pushPS(mem[reg.RSP])
 559     return NEXT
 560 end)
 561
 562 RSPFETCH_CFA = defPrimWord("RSP@", () -> begin
 563     pushPS(reg.RSP)
 564     return NEXT
 565 end)
 566
 567 RSPSTORE_CFA = defPrimWord("RSP!", () -> begin
 568     reg.RSP = popPS()
 569     return NEXT
 570 end)
 571
 572 RDROP_CFA = defPrimWord("RDROP", () -> begin
 573     popRS()
 574     return NEXT
 575 end)
 576
 577 # Parameter Stack
 578
 579 PSPFETCH_CFA = defPrimWord("PSP@", () -> begin
 580     pushPS(reg.PSP)
 581     return NEXT
 582 end)
 583
 584 PSPSTORE_CFA = defPrimWord("PSP!", () -> begin
 585     reg.PSP = popPS()
 586     return NEXT
 587 end)
 588
 589 # Working Register
 590
 591 WFETCH_CFA = defPrimWord("W@", () -> begin
 592     pushPS(reg.W)
 593     return NEXT
 594 end)
 595
 596 WSTORE_CFA = defPrimWord("W!", () -> begin
 597     reg.W = popPS()
 598     return NEXT
 599 end)
 600
 601 # I/O
 602
 603 sources = Array{Any,1}()
 604 currentSource() = sources[length(sources)]
 605
 606 CLOSEFILES_CFA = defPrimWord("CLOSEFILES", () -> begin
 607     while currentSource() != STDIN
 608         close(pop!(sources))
 609     end
 610
 611     return NEXT
 612 end)
 613
 614 EOF_CFA = defPrimWord("\x04", () -> begin
 615     if currentSource() != STDIN
 616         close(pop!(sources))
 617         return NEXT
 618     else
 619         return 0
 620     end
 621 end)
 622
 623 EMIT_CFA = defPrimWord("EMIT", () -> begin
 624     print(Char(popPS()))
 625     return NEXT
 626 end)
 627
 628 function raw_mode!(mode::Bool)
 629     if ccall(:jl_tty_set_mode, Int32, (Ptr{Void}, Int32), STDIN.handle, mode) != 0
 630         throw("FATAL: Terminal unable to enter raw mode.")
 631     end
 632 end
 633
 634 function getKey()
 635     raw_mode!(true)
 636     byte = readbytes(STDIN, 1)[1]
 637     raw_mode!(false)
 638
 639     if byte == 0x0d
 640         return 0x0a
 641     elseif byte == 127
 642         return 0x08
 643     else
 644         return byte
 645     end
 646 end
 647
 648 KEY_CFA = defPrimWord("KEY", () -> begin
 649     pushPS(Int(getKey()))
 650     return NEXT
 651 end)
 652
 653 function getLineFromSTDIN()
 654
 655     function getFrag(s)
 656         chars = collect(s)
 657         slashIdx = findlast(chars, '\\')
 658
 659         if slashIdx > 0
 660             return join(chars[slashIdx:length(chars)])
 661         else
 662             return nothing
 663         end
 664     end
 665
 666     function backspaceStr(s, bsCount)
 667         oldLen = length(s)
 668         newLen = max(0, oldLen - bsCount)
 669         return join(collect(s)[1:newLen])
 670     end
 671
 672     line = ""
 673     while true
 674         key = Char(getKey())
 675
 676         if key == '\n'
 677             print(" ")
 678             return AbstractString(line)
 679
 680         elseif key == '\x04'
 681             if isempty(line)
 682                 return string("\x04")
 683             end
 684
 685         elseif key == '\b'
 686             if !isempty(line)
 687                 print("\b\033[K")
 688                 line = backspaceStr(line, 1)
 689             end
 690
 691         elseif key == '\e'
 692             # Strip ANSI escape sequence
 693             nextKey = Char(getKey())
 694             if nextKey == '['
 695                 while true
 696                     nextKey = Char(getKey())
 697                     if nextKey >= '@' || nextKey <= '~'
 698                         break
 699                     end
 700                 end
 701             end
 702
 703         elseif key == '\t'
 704             # Currently do nothing
 705
 706             frag = getFrag(line)
 707             if frag != nothing
 708                 if haskey(REPLCompletions.latex_symbols, frag)
 709                     print(repeat("\b", length(frag)))
 710                     print("\033[K")
 711                     comp = REPLCompletions.latex_symbols[frag]
 712                     line = string(backspaceStr(line, length(frag)), comp)
 713                     print(comp)
 714                 end
 715             end
 716
 717         else
 718             print(key)
 719             line = string(line, key)
 720         end
 721     end
 722 end
 723
 724 SPAN, SPAN_CFA = defNewVar("SPAN", 0)
 725 EXPECT_CFA = defPrimWord("EXPECT", () -> begin
 726     maxLen = popPS()
 727     addr = popPS()
 728
 729     if currentSource() == STDIN
 730         line = getLineFromSTDIN()
 731     else
 732         if !eof(currentSource())
 733             line = chomp(readline(currentSource()))
 734         else
 735             line = "\x04" # eof
 736         end
 737     end
 738
 739     mem[SPAN] = min(length(line), maxLen)
 740     putString(line, addr, maxLen)
 741
 742     return NEXT
 743 end)
 744
 745 BASE, BASE_CFA = defNewVar("BASE", 10)
 746 NUMBER_CFA = defPrimWord("NUMBER", () -> begin
 747     wordAddr = popPS()+1
 748     wordLen = mem[wordAddr-1]
 749
 750     s = getString(wordAddr, wordLen)
 751
 752     pushPS(parse(Int64, s, mem[BASE]))
 753
 754     return NEXT
 755 end)
 756
 757 # Dictionary searches
 758
 759 FROMLINK_CFA = defPrimWord("LINK>", () -> begin
 760
 761     addr = popPS()
 762     lenAndFlags = mem[addr+1]
 763     len = lenAndFlags & F_LENMASK
 764
 765     pushPS(addr + 2 + len)
 766
 767     return NEXT
 768 end)
 769
 770 NUMCONTEXT, NUMCONTEXT_CFA = defNewVar("#CONTEXT", 1)
 771
 772 createHeader("FORTH", 0)
 773 FORTH_CFA = mem[H]
 774 dictWrite(defPrim(() -> begin
 775     mem[CONTEXT + mem[NUMCONTEXT] - 1] = reg.W
 776     return NEXT
 777 end, name="FORTH"))
 778 dictWrite(0) # cell for latest
 779
 780 CURRENT_CFA = defExistingVar("CURRENT", CURRENT)
 781
 782 # Switch to new FORTH vocabulary cfa
 783 mem[FORTH_CFA+1] = mem[mem[CURRENT]+1]
 784 mem[CURRENT] = FORTH_CFA
 785
 786 CONTEXT, CONTEXT_CFA = defNewVar("CONTEXT", zeros(Int64, 10))
 787 mem[CONTEXT] = FORTH_CFA
 788
 789 FINDVOCAB_CFA = defPrimWord("FINDVOCAB", () -> begin
 790     vocabCFA = popPS()
 791     countedAddr = popPS()
 792
 793     wordAddr = countedAddr + 1
 794     wordLen = mem[countedAddr]
 795     word = lowercase(getString(wordAddr, wordLen))
 796
 797     lfa = vocabCFA+1
 798     lenAndFlags = 0
 799
 800     while (lfa = mem[lfa]) > 0
 801
 802         lenAndFlags = mem[lfa+1]
 803         len = lenAndFlags & F_LENMASK
 804         hidden = (lenAndFlags & F_HIDDEN) == F_HIDDEN
 805
 806         if hidden || len != wordLen
 807             continue
 808         end
 809
 810         thisWord = lowercase(getString(lfa+2, len))
 811
 812         if thisWord == word
 813             break
 814         end
 815     end
 816
 817     if lfa > 0
 818         pushPS(lfa)
 819         callPrim(mem[FROMLINK_CFA])
 820         if (lenAndFlags & F_IMMED) == F_IMMED
 821             pushPS(1)
 822         else
 823             pushPS(-1)
 824         end
 825     else
 826         pushPS(countedAddr)
 827         pushPS(0)
 828     end
 829
 830     return NEXT
 831 end)
 832
 833 FIND_CFA = defPrimWord("FIND", () -> begin
 834
 835     countedAddr = popPS()
 836     context = mem[CONTEXT:(CONTEXT+mem[NUMCONTEXT]-1)]
 837
 838     for vocabCFA in reverse(context)
 839         pushPS(countedAddr)
 840         pushPS(vocabCFA)
 841         callPrim(mem[FINDVOCAB_CFA])
 842
 843         callPrim(mem[DUP_CFA])
 844         if popPS() != 0
 845             return NEXT
 846         else
 847             popPS()
 848             popPS()
 849         end
 850     end
 851
 852     pushPS(countedAddr)
 853     pushPS(0)
 854
 855     return NEXT
 856 end)
 857
 858
 859 # Branching
 860
 861 BRANCH_CFA = defPrimWord("BRANCH", () -> begin
 862     reg.IP += mem[reg.IP]
 863     return NEXT
 864 end)
 865
 866 ZBRANCH_CFA = defPrimWord("0BRANCH", () -> begin
 867     if (popPS() == 0)
 868         reg.IP += mem[reg.IP]
 869     else
 870         reg.IP += 1
 871     end
 872
 873     return NEXT
 874 end)
 875
 876 # Strings
 877
 878 LITSTRING_CFA = defPrimWord("LITSTRING", () -> begin
 879     len = mem[reg.IP]
 880     reg.IP += 1
 881     pushPS(reg.IP)
 882     pushPS(len)
 883     reg.IP += len
 884
 885     return NEXT
 886 end)
 887
 888 TYPE_CFA = defPrimWord("TYPE", () -> begin
 889     len = popPS()
 890     addr = popPS()
 891     str = getString(addr, len)
 892     print(str)
 893     return NEXT
 894 end)
 895
 896 # Interpreter/Compiler-specific I/O
 897
 898 TIB_CFA = defConst("TIB", TIB)
 899 NUMTIB, NUMTIB_CFA = defNewVar("#TIB", 0)
 900 TOIN, TOIN_CFA = defNewVar(">IN", 0)
 901
 902 QUERY_CFA = defWord("QUERY",
 903     [TIB_CFA, LIT_CFA, 160, EXPECT_CFA,
 904     SPAN_CFA, FETCH_CFA, NUMTIB_CFA, STORE_CFA,
 905     LIT_CFA, 0, TOIN_CFA, STORE_CFA,
 906     EXIT_CFA])
 907
 908 WORD_CFA = defPrimWord("WORD", () -> begin
 909     delim = popPS()
 910
 911     # Chew up initial occurrences of delim
 912     while (mem[TOIN]<mem[NUMTIB] && mem[TIB+mem[TOIN]] == delim)
 913         mem[TOIN] += 1
 914     end
 915
 916     countAddr = mem[H]
 917     addr = mem[H]+1
 918
 919     # Start reading in word
 920     count = 0
 921     while (mem[TOIN]<mem[NUMTIB])
 922         mem[addr] = mem[TIB+mem[TOIN]]
 923         mem[TOIN] += 1
 924
 925         if (mem[addr] == delim)
 926             break
 927         end
 928
 929         count += 1
 930         addr += 1
 931     end
 932
 933     # Record count
 934     mem[countAddr] = count
 935     pushPS(countAddr)
 936
 937     return NEXT
 938 end)
 939
 940 # Compilation
 941
 942 STATE, STATE_CFA = defNewVar("STATE", 0)
 943
 944 COMMA_CFA = defPrimWord(",", () -> begin
 945     mem[mem[H]] = popPS()
 946     mem[H] += 1
 947
 948     return NEXT
 949 end)
 950
 951 HERE_CFA = defWord("HERE",
 952     [H_CFA, FETCH_CFA, EXIT_CFA])
 953
 954 HEADER_CFA = defPrimWord("HEADER", () -> begin
 955     wordAddr = popPS()+1
 956     wordLen = mem[wordAddr-1]
 957     word = getString(wordAddr, wordLen)
 958
 959     createHeader(word, 0)
 960
 961     return NEXT
 962 end)
 963
 964 CREATE_CFA = defWord("CREATE",
 965     [LIT_CFA, 32, WORD_CFA, HEADER_CFA,
 966     LIT_CFA, DOVAR, COMMA_CFA,
 967     EXIT_CFA])
 968
 969 DODOES = defPrim(() -> begin
 970     pushRS(reg.IP)
 971     reg.IP = popPS()
 972     pushPS(reg.W + 1)
 973     return NEXT
 974 end, name="DODOES")
 975
 976 DOES_HELPER_CFA = defPrimWord("(DOES>)", () -> begin
 977
 978     pushPS(mem[mem[CURRENT]+1])
 979     callPrim(mem[FROMLINK_CFA])
 980     cfa = popPS()
 981
 982     runtimeAddr = popPS()
 983
 984     mem[cfa] = defPrim(eval(:(() -> begin
 985         pushPS($(runtimeAddr))
 986         return DODOES
 987     end)), name="doesPrim")
 988
 989     return NEXT
 990 end, flags=F_IMMED | F_HIDDEN)
 991
 992 DOES_CFA = defWord("DOES>",
 993     [LIT_CFA, LIT_CFA, COMMA_CFA, HERE_CFA, LIT_CFA, 3, ADD_CFA, COMMA_CFA,
 994     LIT_CFA, DOES_HELPER_CFA, COMMA_CFA, LIT_CFA, EXIT_CFA, COMMA_CFA, EXIT_CFA],
 995     flags=F_IMMED)
 996
 997 LBRAC_CFA = defPrimWord("[", () -> begin
 998     mem[STATE] = 0
 999     return NEXT
1000 end, flags=F_IMMED)
1001
1002 RBRAC_CFA = defPrimWord("]", () -> begin
1003     mem[STATE] = 1
1004     return NEXT
1005 end, flags=F_IMMED)
1006
1007 HIDDEN_CFA = defPrimWord("HIDDEN", () -> begin
1008     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
1009     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_HIDDEN
1010     return NEXT
1011 end)
1012
1013 COLON_CFA = defWord(":",
1014     [LIT_CFA, 32, WORD_CFA,
1015     HEADER_CFA,
1016     LIT_CFA, DOCOL, COMMA_CFA,
1017     HIDDEN_CFA,
1018     RBRAC_CFA,
1019     EXIT_CFA])
1020
1021 SEMICOLON_CFA = defWord(";",
1022     [LIT_CFA, EXIT_CFA, COMMA_CFA,
1023     HIDDEN_CFA,
1024     LBRAC_CFA,
1025     EXIT_CFA], flags=F_IMMED)
1026
1027 IMMEDIATE_CFA = defPrimWord("IMMEDIATE", () -> begin
1028     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
1029     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_IMMED
1030     return NEXT
1031 end, flags=F_IMMED)
1032
1033 CODE_CFA = defPrimWord("CODE", () -> begin
1034     pushPS(32)
1035     callPrim(mem[WORD_CFA])
1036     callPrim(mem[HEADER_CFA])
1037
1038     exprString = "() -> begin\n"
1039     while true
1040         if mem[TOIN] >= mem[NUMTIB]
1041             exprString = string(exprString, "\n")
1042             if currentSource() == STDIN
1043                 println()
1044             end
1045
1046             pushPS(TIB)
1047             pushPS(160)
1048             callPrim(mem[EXPECT_CFA])
1049             mem[NUMTIB] = mem[SPAN]
1050             mem[TOIN] = 0
1051         end
1052
1053         pushPS(32)
1054         callPrim(mem[WORD_CFA])
1055         cAddr = popPS()
1056         thisWord = getString(cAddr+1, mem[cAddr])
1057
1058         if uppercase(thisWord) == "END-CODE"
1059             break
1060         end
1061
1062         exprString = string(exprString, " ", thisWord)
1063     end
1064     exprString = string(exprString, "\nreturn NEXT\nend")
1065
1066     func = eval(parse(exprString))
1067     dictWrite(defPrim(func))
1068
1069     return NEXT
1070 end)
1071
1072 # Outer Interpreter
1073
1074 EXECUTE_CFA = defPrimWord("EXECUTE", () -> begin
1075     reg.W = popPS()
1076     return mem[reg.W]
1077 end)
1078
1079 INTERPRET_CFA = defWord("INTERPRET",
1080     [LIT_CFA, 32, WORD_CFA, # Read next space-delimited word
1081
1082     DUP_CFA, FETCH_CFA, ZE_CFA, ZBRANCH_CFA, 3,
1083         DROP_CFA, EXIT_CFA, # Exit if TIB is exhausted
1084
1085     STATE_CFA, FETCH_CFA, ZBRANCH_CFA, 24,
1086         # Compiling
1087         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 13,
1088
1089             # Found word.
1090             LIT_CFA, -1, EQ_CFA, INVERT_CFA, ZBRANCH_CFA, 4,
1091
1092                 # Immediate: Execute!
1093                 EXECUTE_CFA, BRANCH_CFA, -26,
1094
1095                 # Not immediate: Compile!
1096                 COMMA_CFA, BRANCH_CFA, -29,
1097
1098             # No word found, parse number
1099             NUMBER_CFA, LIT_CFA, LIT_CFA, COMMA_CFA, COMMA_CFA, BRANCH_CFA, -36,
1100
1101        # Interpreting
1102         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 5,
1103
1104             # Found word. Execute!
1105             DROP_CFA, EXECUTE_CFA, BRANCH_CFA, -44,
1106
1107             # No word found, parse number and leave on stack
1108             NUMBER_CFA, BRANCH_CFA, -47,
1109     EXIT_CFA])
1110
1111 PROMPT_CFA = defPrimWord("PROMPT", () -> begin
1112     if currentSource() == STDIN
1113         if mem[STATE] == 0
1114             print(" ok")
1115         end
1116         println()
1117     end
1118
1119     return NEXT
1120 end)
1121
1122 QUIT_CFA = defWord("QUIT",
1123     [LIT_CFA, 0, STATE_CFA, STORE_CFA,
1124     LIT_CFA, 0, NUMTIB_CFA, STORE_CFA,
1125     RSP0_CFA, RSPSTORE_CFA,
1126     QUERY_CFA,
1127     INTERPRET_CFA, PROMPT_CFA,
1128     BRANCH_CFA,-4])
1129
1130 ABORT_CFA = defWord("ABORT",
1131     [CLOSEFILES_CFA, PSP0_CFA, PSPSTORE_CFA, QUIT_CFA])
1132
1133 BYE_CFA = defPrimWord("BYE", () -> begin
1134     println("\nBye!")
1135     return 0
1136 end)
1137
1138 # File I/O
1139
1140 INCLUDE_CFA = defPrimWord("INCLUDE", () -> begin
1141     pushPS(32)
1142     callPrim(mem[WORD_CFA])
1143     wordAddr = popPS()+1
1144     wordLen = mem[wordAddr-1]
1145     word = getString(wordAddr, wordLen)
1146
1147     fname = word
1148     if !isfile(fname)
1149         fname = Pkg.dir("forth","src",word)
1150         if !isfile(fname)
1151             error("No file named $word found in current directory or package source directory.")
1152         end
1153     end
1154     push!(sources, open(fname, "r"))
1155
1156     # Clear input buffer
1157     mem[NUMTIB] = 0
1158
1159     return NEXT
1160 end)
1161
1162
1163 #### VM loop ####
1164
1165 initialized = false
1166 initFileName = nothing
1167 if isfile("lib.4th")
1168     initFileName = "lib.4th"
1169 elseif isfile(Pkg.dir("forth","src", "lib.4th"))
1170     initFileName = Pkg.dir("forth","src","lib.4th")
1171 end
1172
1173 function run(;initialize=true)
1174     # Begin with STDIN as source
1175     push!(sources, STDIN)
1176
1177     global initialized, initFileName
1178     if !initialized && initialize
1179         if initFileName != nothing
1180             print("Including definitions from $initFileName...")
1181             push!(sources, open(initFileName, "r"))
1182             initialized = true
1183         else
1184             println("No library file found. Only primitive words available.")
1185         end
1186     end
1187
1188     # Start with IP pointing to first instruction of outer interpreter
1189     reg.IP = QUIT_CFA + 1
1190
1191     # Primitive processing loop.
1192     # Everyting else is simply a consequence of this loop!
1193     jmp = NEXT
1194     while jmp != 0
1195         try
1196             #println("Entering prim $(getPrimName(jmp))")
1197             jmp = callPrim(jmp)
1198
1199         catch ex
1200             showerror(STDOUT, ex)
1201             println()
1202
1203             while !isempty(sources) && currentSource() != STDIN
1204                 close(pop!(sources))
1205             end
1206
1207             # QUIT
1208             reg.IP = ABORT_CFA + 1
1209             jmp = NEXT
1210         end
1211     end
1212 end
1213
1214 # Debugging tools
1215
1216 TRACE_CFA = defPrimWord("TRACE", () -> begin
1217     println("reg.W: $(reg.W) reg.IP: $(reg.IP)")
1218     print("PS: "); printPS()
1219     print("RS: "); printRS()
1220     print("[paused]")
1221     readline()
1222
1223     return NEXT
1224 end)
1225
1226 function dump(startAddr::Int64; count::Int64 = 100, cellsPerLine::Int64 = 10)
1227     chars = Array{Char,1}(cellsPerLine)
1228
1229     lineStartAddr = cellsPerLine*div((startAddr-1),cellsPerLine) + 1
1230     endAddr = startAddr + count - 1
1231
1232     q, r = divrem((endAddr-lineStartAddr+1), cellsPerLine)
1233     numLines = q + (r > 0 ? 1 : 0)
1234
1235     i = lineStartAddr
1236     for l in 1:numLines
1237         print(i,":")
1238
1239         for c in 1:cellsPerLine
1240             if i >= startAddr && i <= endAddr
1241                 print("\t",mem[i])
1242                 if mem[i]>=32 && mem[i]<128
1243                     chars[c] = Char(mem[i])
1244                 else
1245                     chars[c] = '.'
1246                 end
1247             else
1248                 print("\t")
1249                 chars[c] = ' '
1250             end
1251
1252             i += 1
1253         end
1254
1255         println("\t", AbstractString(chars))
1256     end
1257 end
1258
1259 function printPS()
1260     count = reg.PSP - PSP0
1261
1262     if count > 0
1263         print("<$count>")
1264         for i in (PSP0+1):reg.PSP
1265             print(" $(mem[i])")
1266         end
1267         println()
1268     else
1269         println("Parameter stack empty")
1270     end
1271 end
1272
1273 function printRS()
1274     count = reg.RSP - RSP0
1275
1276     if count > 0
1277         print("<$count>")
1278         for i in (RSP0+1):reg.RSP
1279             print(" $(mem[i])")
1280         end
1281         println()
1282     else
1283         println("Return stack empty")
1284     end
1285 end
1286
1287 DUMP = defPrimWord("DUMP", () -> begin
1288     count = popPS()
1289     addr = popPS()
1290
1291     println()
1292     dump(addr, count=count)
1293
1294     return NEXT
1295 end)
1296
1297 end