src/forth.jl

   1 module forth
   2
   3 # VM mem size
   4 size_mem = 1000000 # 1 mega-int
   5
   6 # Buffer sizes
   7 size_RS = 1000   # Return stack size
   8 size_PS = 1000   # Parameter stack size
   9 size_TIB = 1000  # Terminal input buffer size
  10
  11 # Memory arrays
  12 mem = Array{Int64,1}(size_mem)
  13 primitives = Array{Function,1}()
  14 primNames = Array{ASCIIString,1}()
  15
  16 # Memory geography and built-in variables
  17
  18 nextVarAddr = 1
  19 H = nextVarAddr; nextVarAddr += 1              # Next free memory address
  20 FORTH_LATEST = nextVarAddr; nextVarAddr += 1   # FORTH dict latest
  21 CURRENT = nextVarAddr; nextVarAddr += 1        # Current compilation dict
  22
  23 RSP0 = nextVarAddr                  # bottom of RS
  24 PSP0 = RSP0 + size_RS               # bottom of PS
  25 TIB = PSP0 + size_PS                # address of terminal input buffer
  26 mem[H] = TIB + size_TIB             # location of bottom of dictionary
  27 mem[FORTH_LATEST] = 0               # zero FORTH dict latest (no previous def)
  28 mem[CURRENT] = FORTH_LATEST-1       # Compile words to system dict initially
  29
  30 DICT = mem[H] # Save bottom of dictionary as constant
  31
  32 # VM registers
  33 type Reg
  34     RSP::Int64  # Return stack pointer
  35     PSP::Int64  # Parameter/data stack pointer
  36     IP::Int64   # Instruction pointer
  37     W::Int64    # Working register
  38 end
  39 reg = Reg(RSP0, PSP0, 0, 0)
  40
  41 # Stack manipulation functions
  42
  43 function ensurePSDepth(depth::Int64)
  44     if reg.PSP - PSP0 < depth
  45         error("Parameter stack underflow.")
  46     end
  47 end
  48
  49 function ensureRSDepth(depth::Int64)
  50     if reg.RSP - RSP0 < depth
  51         error("Return stack underflow.")
  52     end
  53 end
  54
  55 function pushRS(val::Int64)
  56     mem[reg.RSP+=1] = val
  57 end
  58
  59 function popRS()
  60     ensureRSDepth(1)
  61
  62     val = mem[reg.RSP]
  63     reg.RSP -= 1
  64     return val
  65 end
  66
  67 function pushPS(val::Int64)
  68     mem[reg.PSP += 1] = val
  69 end
  70
  71 function popPS()
  72     ensurePSDepth(1)
  73
  74     val = mem[reg.PSP]
  75     reg.PSP -= 1
  76     return val
  77 end
  78
  79 # Handy functions for adding/retrieving strings to/from memory.
  80
  81 getString(addr::Int64, len::Int64) = ASCIIString([Char(c) for c in mem[addr:(addr+len-1)]])
  82
  83 function putString(str::ASCIIString, addr::Int64)
  84     mem[addr:(addr+length(str)-1)] = [Int64(c) for c in str]
  85 end
  86
  87 stringAsInts(str::ASCIIString) = [Int(c) for c in collect(str)]
  88
  89 # Primitive creation and calling functions
  90
  91 function defPrim(f::Function; name="nameless")
  92     push!(primitives, f)
  93     push!(primNames, replace(name, "\004", "EOF"))
  94
  95     return -length(primitives)
  96 end
  97
  98 function callPrim(addr::Int64)
  99     if addr >=0 || -addr>length(primitives)
 100         error("Attempted to execute non-existent primitive at address $addr.")
 101     else
 102         primitives[-addr]()
 103     end
 104 end
 105 getPrimName(addr::Int64) = primNames[-addr]
 106
 107 # Word creation functions
 108
 109 F_LENMASK = 31
 110 F_IMMED = 32
 111 F_HIDDEN = 64
 112 NFA_MARK = 128
 113
 114 function dictWrite(ints::Array{Int64,1})
 115     mem[mem[H]:(mem[H]+length(ints)-1)] = ints
 116     mem[H] += length(ints)
 117 end
 118 dictWrite(int::Int64) = dictWrite([int])
 119 dictWriteString(string::ASCIIString) = dictWrite([Int64(c) for c in string])
 120
 121 function createHeader(name::AbstractString, flags::Int64)
 122     mem[mem[H]] = mem[mem[CURRENT]+1]
 123     mem[mem[CURRENT]+1] = mem[H]
 124     mem[H] += 1
 125
 126     dictWrite(length(name) | flags | NFA_MARK)
 127     dictWriteString(name)
 128 end
 129
 130 function defPrimWord(name::AbstractString, f::Function; flags::Int64=0)
 131     createHeader(name, flags)
 132
 133     codeWordAddr = mem[H]
 134     dictWrite(defPrim(f, name=name))
 135
 136     return codeWordAddr
 137 end
 138
 139 function defWord(name::AbstractString, wordAddrs::Array{Int64,1}; flags::Int64=0)
 140     createHeader(name, flags)
 141
 142     addr = mem[H]
 143     dictWrite(DOCOL)
 144
 145     dictWrite(wordAddrs)
 146
 147     return addr
 148 end
 149
 150 # Variable creation functions
 151
 152 function defExistingVar(name::AbstractString, varAddr::Int64; flags::Int64=0)
 153
 154     defPrimWord(name, eval(:(() -> begin
 155         pushPS($(varAddr))
 156         return NEXT
 157     end)))
 158 end
 159
 160 function defNewVar(name::AbstractString, initial::Array{Int64,1}; flags::Int64=0)
 161     createHeader(name, flags)
 162
 163     codeWordAddr = mem[H]
 164     varAddr = mem[H] + 1
 165
 166     dictWrite(DOVAR)
 167     dictWrite(initial)
 168
 169     return varAddr, codeWordAddr
 170 end
 171
 172 defNewVar(name::AbstractString, initial::Int64; flags::Int64=0) =
 173     defNewVar(name, [initial]; flags=flags)
 174
 175 function defConst(name::AbstractString, val::Int64; flags::Int64=0)
 176     createHeader(name, flags)
 177
 178     codeWordAddr = mem[H]
 179
 180     dictWrite(DOCON)
 181     dictWrite(val)
 182
 183     return codeWordAddr
 184 end
 185
 186 # Threading Primitives (inner interpreter)
 187
 188 NEXT = defPrim(() -> begin
 189     reg.W = mem[reg.IP]
 190     reg.IP += 1
 191     return mem[reg.W]
 192 end, name="NEXT")
 193
 194 DOCOL = defPrim(() -> begin
 195     pushRS(reg.IP)
 196     reg.IP = reg.W + 1
 197     return NEXT
 198 end, name="DOCOL")
 199
 200 DOVAR = defPrim(() -> begin
 201     pushPS(reg.W + 1)
 202     return NEXT
 203 end, name="DOVAR")
 204
 205 DOCON = defPrim(() -> begin
 206     pushPS(mem[reg.W + 1])
 207     return NEXT
 208 end, name="DOVAR")
 209
 210 EXIT_CFA = defPrimWord("EXIT", () -> begin
 211     reg.IP = popRS()
 212     return NEXT
 213 end)
 214
 215 # Dictionary entries for core built-in variables, constants
 216
 217 H_CFA = defExistingVar("H", H)
 218
 219 PSP0_CFA = defConst("PSP0", PSP0)
 220 RSP0_CFA = defConst("RSP0", RSP0)
 221
 222 defConst("DOCOL", DOCOL)
 223 defConst("DOCON", DOCON)
 224 defConst("DOVAR", DOVAR)
 225
 226 defConst("DICT", DICT)
 227 defConst("MEMSIZE", size_mem)
 228
 229 F_IMMED_CFA = defConst("F_IMMED", F_IMMED)
 230 F_HIDDEN_CFA = defConst("F_HIDDEN", F_HIDDEN)
 231 F_LENMASK_CFA = defConst("F_LENMASK", F_LENMASK)
 232 NFA_MARK_CFA = defConst("NFA_MARK", NFA_MARK)
 233
 234 # Basic forth primitives
 235
 236 DROP_CFA = defPrimWord("DROP", () -> begin
 237     popPS()
 238     return NEXT
 239 end)
 240
 241 SWAP_CFA = defPrimWord("SWAP", () -> begin
 242     a = popPS()
 243     b = popPS()
 244     pushPS(a)
 245     pushPS(b)
 246     return NEXT
 247 end)
 248
 249 DUP_CFA = defPrimWord("DUP", () -> begin
 250     ensurePSDepth(1)
 251     pushPS(mem[reg.PSP])
 252     return NEXT
 253 end)
 254
 255 OVER_CFA = defPrimWord("OVER", () -> begin
 256     ensurePSDepth(2)
 257     pushPS(mem[reg.PSP-1])
 258     return NEXT
 259 end)
 260
 261 ROT_CFA = defPrimWord("ROT", () -> begin
 262     a = popPS()
 263     b = popPS()
 264     c = popPS()
 265     pushPS(b)
 266     pushPS(a)
 267     pushPS(c)
 268     return NEXT
 269 end)
 270
 271 NROT_CFA = defPrimWord("-ROT", () -> begin
 272     a = popPS()
 273     b = popPS()
 274     c = popPS()
 275     pushPS(a)
 276     pushPS(c)
 277     pushPS(b)
 278     return NEXT
 279 end)
 280
 281
 282 TWODROP_CFA = defPrimWord("2DROP", () -> begin
 283     popPS()
 284     popPS()
 285     return NEXT
 286 end)
 287
 288 TWODUP_CFA = defPrimWord("2DUP", () -> begin
 289     ensurePSDepth(2)
 290     a = mem[reg.PSP-1]
 291     b = mem[reg.PSP]
 292     pushPS(a)
 293     pushPS(b)
 294     return NEXT
 295 end)
 296
 297 TWOSWAP_CFA = defPrimWord("2SWAP", () -> begin
 298     a = popPS()
 299     b = popPS()
 300     c = popPS()
 301     d = popPS()
 302     pushPS(b)
 303     pushPS(a)
 304     pushPS(d)
 305     pushPS(c)
 306     return NEXT
 307 end)
 308
 309 TWOOVER_CFA = defPrimWord("2OVER", () -> begin
 310     ensurePSDepth(4)
 311     a = mem[reg.PSP-3]
 312     b = mem[reg.PSP-2]
 313     pushPS(a)
 314     pushPS(b)
 315     return NEXT
 316 end)
 317
 318 QDUP_CFA = defPrimWord("?DUP", () -> begin
 319     ensurePSDepth(1)
 320     val = mem[reg.PSP]
 321     if val != 0
 322         pushPS(val)
 323     end
 324     return NEXT
 325 end)
 326
 327 INCR_CFA = defPrimWord("1+", () -> begin
 328     ensurePSDepth(1)
 329     mem[reg.PSP] += 1
 330     return NEXT
 331 end)
 332
 333 DECR_CFA = defPrimWord("1-", () -> begin
 334     ensurePSDepth(1)
 335     mem[reg.PSP] -= 1
 336     return NEXT
 337 end)
 338
 339 INCR2_CFA = defPrimWord("2+", () -> begin
 340     ensurePSDepth(1)
 341     mem[reg.PSP] += 2
 342     return NEXT
 343 end)
 344
 345 DECR2_CFA = defPrimWord("2-", () -> begin
 346     ensurePSDepth(1)
 347     mem[reg.PSP] -= 2
 348     return NEXT
 349 end)
 350
 351 ADD_CFA = defPrimWord("+", () -> begin
 352     b = popPS()
 353     a = popPS()
 354     pushPS(a+b)
 355     return NEXT
 356 end)
 357
 358 SUB_CFA = defPrimWord("-", () -> begin
 359     b = popPS()
 360     a = popPS()
 361     pushPS(a-b)
 362     return NEXT
 363 end)
 364
 365 MUL_CFA = defPrimWord("*", () -> begin
 366     b = popPS()
 367     a = popPS()
 368     pushPS(a*b)
 369     return NEXT
 370 end)
 371
 372 DIVMOD_CFA = defPrimWord("/MOD", () -> begin
 373     b = popPS()
 374     a = popPS()
 375     q,r = divrem(a,b)
 376     pushPS(r)
 377     pushPS(q)
 378     return NEXT
 379 end)
 380
 381 TWOMUL_CFA = defPrimWord("2*", () -> begin
 382     pushPS(popPS() << 1)
 383     return NEXT
 384 end)
 385
 386 TWODIV_CFA = defPrimWord("2/", () -> begin
 387     pushPS(popPS() >> 1)
 388     return NEXT
 389 end)
 390
 391 EQ_CFA = defPrimWord("=", () -> begin
 392     b = popPS()
 393     a = popPS()
 394     pushPS(a==b ? -1 : 0)
 395     return NEXT
 396 end)
 397
 398 NE_CFA = defPrimWord("<>", () -> begin
 399     b = popPS()
 400     a = popPS()
 401     pushPS(a!=b ? -1 : 0)
 402     return NEXT
 403 end)
 404
 405 LT_CFA = defPrimWord("<", () -> begin
 406     b = popPS()
 407     a = popPS()
 408     pushPS(a<b ? -1 : 0)
 409     return NEXT
 410 end)
 411
 412 GT_CFA = defPrimWord(">", () -> begin
 413     b = popPS()
 414     a = popPS()
 415     pushPS(a>b ? -1 : 0)
 416     return NEXT
 417 end)
 418
 419 LE_CFA = defPrimWord("<=", () -> begin
 420     b = popPS()
 421     a = popPS()
 422     pushPS(a<=b ? -1 : 0)
 423     return NEXT
 424 end)
 425
 426 GE_CFA = defPrimWord(">=", () -> begin
 427     b = popPS()
 428     a = popPS()
 429     pushPS(a>=b ? -1 : 0)
 430     return NEXT
 431 end)
 432
 433 ZE_CFA = defPrimWord("0=", () -> begin
 434     pushPS(popPS() == 0 ? -1 : 0)
 435     return NEXT
 436 end)
 437
 438 ZNE_CFA = defPrimWord("0<>", () -> begin
 439     pushPS(popPS() != 0 ? -1 : 0)
 440     return NEXT
 441 end)
 442
 443 ZLT_CFA = defPrimWord("0<", () -> begin
 444     pushPS(popPS() < 0 ? -1 : 0)
 445     return NEXT
 446 end)
 447
 448 ZGT_CFA = defPrimWord("0>", () -> begin
 449     pushPS(popPS() > 0 ? -1 : 0)
 450     return NEXT
 451 end)
 452
 453 ZLE_CFA = defPrimWord("0<=", () -> begin
 454     pushPS(popPS() <= 0 ? -1 : 0)
 455     return NEXT
 456 end)
 457
 458 ZGE_CFA = defPrimWord("0>=", () -> begin
 459     pushPS(popPS() >= 0 ? -1 : 0)
 460     return NEXT
 461 end)
 462
 463 AND_CFA = defPrimWord("AND", () -> begin
 464     b = popPS()
 465     a = popPS()
 466     pushPS(a & b)
 467     return NEXT
 468 end)
 469
 470 OR_CFA = defPrimWord("OR", () -> begin
 471     b = popPS()
 472     a = popPS()
 473     pushPS(a | b)
 474     return NEXT
 475 end)
 476
 477 XOR_CFA = defPrimWord("XOR", () -> begin
 478     b = popPS()
 479     a = popPS()
 480     pushPS(a $ b)
 481     return NEXT
 482 end)
 483
 484 INVERT_CFA = defPrimWord("INVERT", () -> begin
 485     pushPS(~popPS())
 486     return NEXT
 487 end)
 488
 489 # Literals
 490
 491 LIT_CFA = defPrimWord("LIT", () -> begin
 492     pushPS(mem[reg.IP])
 493     reg.IP += 1
 494     return NEXT
 495 end)
 496
 497 # Memory primitives
 498
 499 STORE_CFA = defPrimWord("!", () -> begin
 500     addr = popPS()
 501     dat = popPS()
 502     mem[addr] = dat
 503     return NEXT
 504 end)
 505
 506 FETCH_CFA = defPrimWord("@", () -> begin
 507     addr = popPS()
 508     pushPS(mem[addr])
 509     return NEXT
 510 end)
 511
 512 ADDSTORE_CFA = defPrimWord("+!", () -> begin
 513     addr = popPS()
 514     toAdd = popPS()
 515     mem[addr] += toAdd
 516     return NEXT
 517 end)
 518
 519 SUBSTORE_CFA = defPrimWord("-!", () -> begin
 520     addr = popPS()
 521     toSub = popPS()
 522     mem[addr] -= toSub
 523     return NEXT
 524 end)
 525
 526
 527 # Return Stack
 528
 529 TOR_CFA = defPrimWord(">R", () -> begin
 530     pushRS(popPS())
 531     return NEXT
 532 end)
 533
 534 FROMR_CFA = defPrimWord("R>", () -> begin
 535     pushPS(popRS())
 536     return NEXT
 537 end)
 538
 539 RFETCH_CFA = defPrimWord("R@", () -> begin
 540     pushPS(mem[reg.RSP])
 541     return NEXT
 542 end)
 543
 544 RSPFETCH_CFA = defPrimWord("RSP@", () -> begin
 545     pushPS(reg.RSP)
 546     return NEXT
 547 end)
 548
 549 RSPSTORE_CFA = defPrimWord("RSP!", () -> begin
 550     reg.RSP = popPS()
 551     return NEXT
 552 end)
 553
 554 RDROP_CFA = defPrimWord("RDROP", () -> begin
 555     popRS()
 556     return NEXT
 557 end)
 558
 559 # Parameter Stack
 560
 561 PSPFETCH_CFA = defPrimWord("PSP@", () -> begin
 562     pushPS(reg.PSP)
 563     return NEXT
 564 end)
 565
 566 PSPSTORE_CFA = defPrimWord("PSP!", () -> begin
 567     reg.PSP = popPS()
 568     return NEXT
 569 end)
 570
 571 # Working Register
 572
 573 WFETCH_CFA = defPrimWord("W@", () -> begin
 574     pushPS(reg.W)
 575     return NEXT
 576 end)
 577
 578 WSTORE_CFA = defPrimWord("W!", () -> begin
 579     reg.W = popPS()
 580     return NEXT
 581 end)
 582
 583 # I/O
 584
 585 sources = Array{Any,1}()
 586 currentSource() = sources[length(sources)]
 587
 588 CLOSEFILES_CFA = defPrimWord("CLOSEFILES", () -> begin
 589     while currentSource() != STDIN
 590         close(pop!(sources))
 591     end
 592
 593     return NEXT
 594 end)
 595
 596 EOF_CFA = defPrimWord("\x04", () -> begin
 597     if currentSource() != STDIN
 598         close(pop!(sources))
 599         return NEXT
 600     else
 601         return 0
 602     end
 603 end)
 604
 605 EMIT_CFA = defPrimWord("EMIT", () -> begin
 606     print(Char(popPS()))
 607     return NEXT
 608 end)
 609
 610 function raw_mode!(mode::Bool)
 611     if ccall(:jl_tty_set_mode, Int32, (Ptr{Void}, Int32), STDIN.handle, mode) != 0
 612         throw("FATAL: Terminal unable to enter raw mode.")
 613     end
 614 end
 615
 616 function getKey()
 617     raw_mode!(true)
 618     byte = readbytes(STDIN, 1)[1]
 619     raw_mode!(false)
 620
 621     if byte == 0x0d
 622         return 0x0a
 623     elseif byte == 127
 624         return 0x08
 625     else
 626         return byte
 627     end
 628 end
 629
 630 KEY_CFA = defPrimWord("KEY", () -> begin
 631     pushPS(Int(getKey()))
 632     return NEXT
 633 end)
 634
 635 function getLineFromSTDIN()
 636     line = ""
 637     while true
 638         key = Char(getKey())
 639
 640         if key == '\n'
 641             print(" ")
 642             return ASCIIString(line)
 643
 644         elseif key == '\x04'
 645             if isempty(line)
 646                 return string("\x04")
 647             end
 648
 649         elseif key == '\b'
 650             if !isempty(line)
 651                 line = line[1:length(line)-1]
 652                 print("\b \b")
 653             end
 654
 655         elseif key == '\e'
 656             # Strip ANSI escape sequence
 657             nextKey = Char(getKey())
 658             if nextKey == '['
 659                 while true
 660                     nextKey = Char(getKey())
 661                     if nextKey >= '@' || nextKey <= '~'
 662                         break
 663                     end
 664                 end
 665             end
 666
 667         else
 668             print(key)
 669             line = string(line, key)
 670         end
 671     end
 672 end
 673
 674 SPAN, SPAN_CFA = defNewVar("SPAN", 0)
 675 EXPECT_CFA = defPrimWord("EXPECT", () -> begin
 676     maxLen = popPS()
 677     addr = popPS()
 678
 679     if currentSource() == STDIN
 680         line = getLineFromSTDIN()
 681     else
 682         if !eof(currentSource())
 683             line = chomp(readline(currentSource()))
 684         else
 685             line = "\x04" # eof
 686         end
 687     end
 688
 689     mem[SPAN] = min(length(line), maxLen)
 690     putString(line[1:mem[SPAN]], addr)
 691
 692     return NEXT
 693 end)
 694
 695 BASE, BASE_CFA = defNewVar("BASE", 10)
 696 NUMBER_CFA = defPrimWord("NUMBER", () -> begin
 697     wordAddr = popPS()+1
 698     wordLen = mem[wordAddr-1]
 699
 700     s = getString(wordAddr, wordLen)
 701
 702     pushPS(parse(Int64, s, mem[BASE]))
 703
 704     return NEXT
 705 end)
 706
 707 # Dictionary searches
 708
 709 FROMLINK_CFA = defPrimWord("LINK>", () -> begin
 710
 711     addr = popPS()
 712     lenAndFlags = mem[addr+1]
 713     len = lenAndFlags & F_LENMASK
 714
 715     pushPS(addr + 2 + len)
 716
 717     return NEXT
 718 end)
 719
 720 NUMCONTEXT, NUMCONTEXT_CFA = defNewVar("#CONTEXT", 1)
 721
 722 createHeader("FORTH", 0)
 723 FORTH_CFA = mem[H]
 724 dictWrite(defPrim(() -> begin
 725     mem[CONTEXT + mem[NUMCONTEXT] - 1] = reg.W
 726     return NEXT
 727 end, name="FORTH"))
 728 dictWrite(0) # cell for latest
 729
 730 CURRENT_CFA = defExistingVar("CURRENT", CURRENT)
 731
 732 # Switch to new FORTH vocabulary cfa
 733 mem[FORTH_CFA+1] = mem[mem[CURRENT]+1]
 734 mem[CURRENT] = FORTH_CFA
 735
 736 CONTEXT, CONTEXT_CFA = defNewVar("CONTEXT", zeros(Int64, 10))
 737 mem[CONTEXT] = FORTH_CFA
 738
 739 FINDVOCAB_CFA = defPrimWord("FINDVOCAB", () -> begin
 740     vocabCFA = popPS()
 741     countedAddr = popPS()
 742
 743     wordAddr = countedAddr + 1
 744     wordLen = mem[countedAddr]
 745     word = lowercase(getString(wordAddr, wordLen))
 746
 747     lfa = vocabCFA+1
 748     lenAndFlags = 0
 749
 750     while (lfa = mem[lfa]) > 0
 751
 752         lenAndFlags = mem[lfa+1]
 753         len = lenAndFlags & F_LENMASK
 754         hidden = (lenAndFlags & F_HIDDEN) == F_HIDDEN
 755
 756         if hidden || len != wordLen
 757             continue
 758         end
 759
 760         thisWord = lowercase(getString(lfa+2, len))
 761
 762         if thisWord == word
 763             break
 764         end
 765     end
 766
 767     if lfa > 0
 768         pushPS(lfa)
 769         callPrim(mem[FROMLINK_CFA])
 770         if (lenAndFlags & F_IMMED) == F_IMMED
 771             pushPS(1)
 772         else
 773             pushPS(-1)
 774         end
 775     else
 776         pushPS(countedAddr)
 777         pushPS(0)
 778     end
 779
 780     return NEXT
 781 end)
 782
 783 FIND_CFA = defPrimWord("FIND", () -> begin
 784
 785     countedAddr = popPS()
 786     context = mem[CONTEXT:(CONTEXT+mem[NUMCONTEXT]-1)]
 787
 788     for vocabCFA in reverse(context)
 789         pushPS(countedAddr)
 790         pushPS(vocabCFA)
 791         callPrim(mem[FINDVOCAB_CFA])
 792
 793         callPrim(mem[DUP_CFA])
 794         if popPS() != 0
 795             return NEXT
 796         else
 797             popPS()
 798             popPS()
 799         end
 800     end
 801
 802     pushPS(countedAddr)
 803     pushPS(0)
 804
 805     return NEXT
 806 end)
 807
 808
 809 # Branching
 810
 811 BRANCH_CFA = defPrimWord("BRANCH", () -> begin
 812     reg.IP += mem[reg.IP]
 813     return NEXT
 814 end)
 815
 816 ZBRANCH_CFA = defPrimWord("0BRANCH", () -> begin
 817     if (popPS() == 0)
 818         reg.IP += mem[reg.IP]
 819     else
 820         reg.IP += 1
 821     end
 822
 823     return NEXT
 824 end)
 825
 826 # Strings
 827
 828 LITSTRING_CFA = defPrimWord("LITSTRING", () -> begin
 829     len = mem[reg.IP]
 830     reg.IP += 1
 831     pushPS(reg.IP)
 832     pushPS(len)
 833     reg.IP += len
 834
 835     return NEXT
 836 end)
 837
 838 TYPE_CFA = defPrimWord("TYPE", () -> begin
 839     len = popPS()
 840     addr = popPS()
 841     str = getString(addr, len)
 842     print(str)
 843     return NEXT
 844 end)
 845
 846 # Interpreter/Compiler-specific I/O
 847
 848 TIB_CFA = defConst("TIB", TIB)
 849 NUMTIB, NUMTIB_CFA = defNewVar("#TIB", 0)
 850 TOIN, TOIN_CFA = defNewVar(">IN", 0)
 851
 852 QUERY_CFA = defWord("QUERY",
 853     [TIB_CFA, LIT_CFA, 160, EXPECT_CFA,
 854     SPAN_CFA, FETCH_CFA, NUMTIB_CFA, STORE_CFA,
 855     LIT_CFA, 0, TOIN_CFA, STORE_CFA,
 856     EXIT_CFA])
 857
 858 WORD_CFA = defPrimWord("WORD", () -> begin
 859     delim = popPS()
 860
 861     # Chew up initial occurrences of delim
 862     while (mem[TOIN]<mem[NUMTIB] && mem[TIB+mem[TOIN]] == delim)
 863         mem[TOIN] += 1
 864     end
 865
 866     countAddr = mem[H]
 867     addr = mem[H]+1
 868
 869     # Start reading in word
 870     count = 0
 871     while (mem[TOIN]<mem[NUMTIB])
 872         mem[addr] = mem[TIB+mem[TOIN]]
 873         mem[TOIN] += 1
 874
 875         if (mem[addr] == delim)
 876             break
 877         end
 878
 879         count += 1
 880         addr += 1
 881     end
 882
 883     # Record count
 884     mem[countAddr] = count
 885     pushPS(countAddr)
 886
 887     return NEXT
 888 end)
 889
 890 # Compilation
 891
 892 STATE, STATE_CFA = defNewVar("STATE", 0)
 893
 894 COMMA_CFA = defPrimWord(",", () -> begin
 895     mem[mem[H]] = popPS()
 896     mem[H] += 1
 897
 898     return NEXT
 899 end)
 900
 901 HERE_CFA = defWord("HERE",
 902     [H_CFA, FETCH_CFA, EXIT_CFA])
 903
 904 HEADER_CFA = defPrimWord("HEADER", () -> begin
 905     wordAddr = popPS()+1
 906     wordLen = mem[wordAddr-1]
 907     word = getString(wordAddr, wordLen)
 908
 909     createHeader(word, 0)
 910
 911     return NEXT
 912 end)
 913
 914 CREATE_CFA = defWord("CREATE",
 915     [LIT_CFA, 32, WORD_CFA, HEADER_CFA,
 916     LIT_CFA, DOVAR, COMMA_CFA,
 917     EXIT_CFA])
 918
 919 DODOES = defPrim(() -> begin
 920     pushRS(reg.IP)
 921     reg.IP = popPS()
 922     pushPS(reg.W + 1)
 923     return NEXT
 924 end, name="DODOES")
 925
 926 DOES_HELPER_CFA = defPrimWord("(DOES>)", () -> begin
 927
 928     pushPS(mem[mem[CURRENT]+1])
 929     callPrim(mem[FROMLINK_CFA])
 930     cfa = popPS()
 931
 932     runtimeAddr = popPS()
 933
 934     mem[cfa] = defPrim(eval(:(() -> begin
 935         pushPS($(runtimeAddr))
 936         return DODOES
 937     end)), name="doesPrim")
 938
 939     return NEXT
 940 end, flags=F_IMMED | F_HIDDEN)
 941
 942 DOES_CFA = defWord("DOES>",
 943     [LIT_CFA, LIT_CFA, COMMA_CFA, HERE_CFA, LIT_CFA, 3, ADD_CFA, COMMA_CFA,
 944     LIT_CFA, DOES_HELPER_CFA, COMMA_CFA, LIT_CFA, EXIT_CFA, COMMA_CFA, EXIT_CFA],
 945     flags=F_IMMED)
 946
 947 LBRAC_CFA = defPrimWord("[", () -> begin
 948     mem[STATE] = 0
 949     return NEXT
 950 end, flags=F_IMMED)
 951
 952 RBRAC_CFA = defPrimWord("]", () -> begin
 953     mem[STATE] = 1
 954     return NEXT
 955 end, flags=F_IMMED)
 956
 957 HIDDEN_CFA = defPrimWord("HIDDEN", () -> begin
 958     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
 959     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_HIDDEN
 960     return NEXT
 961 end)
 962
 963 COLON_CFA = defWord(":",
 964     [LIT_CFA, 32, WORD_CFA,
 965     HEADER_CFA,
 966     LIT_CFA, DOCOL, COMMA_CFA,
 967     HIDDEN_CFA,
 968     RBRAC_CFA,
 969     EXIT_CFA])
 970
 971 SEMICOLON_CFA = defWord(";",
 972     [LIT_CFA, EXIT_CFA, COMMA_CFA,
 973     HIDDEN_CFA,
 974     LBRAC_CFA,
 975     EXIT_CFA], flags=F_IMMED)
 976
 977 IMMEDIATE_CFA = defPrimWord("IMMEDIATE", () -> begin
 978     lenAndFlagsAddr = mem[mem[CURRENT]+1] + 1
 979     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_IMMED
 980     return NEXT
 981 end, flags=F_IMMED)
 982
 983 # Outer Interpreter
 984
 985 EXECUTE_CFA = defPrimWord("EXECUTE", () -> begin
 986     reg.W = popPS()
 987     return mem[reg.W]
 988 end)
 989
 990 INTERPRET_CFA = defWord("INTERPRET",
 991     [LIT_CFA, 32, WORD_CFA, # Read next space-delimited word
 992
 993     DUP_CFA, FETCH_CFA, ZE_CFA, ZBRANCH_CFA, 3,
 994         DROP_CFA, EXIT_CFA, # Exit if TIB is exhausted
 995
 996     STATE_CFA, FETCH_CFA, ZBRANCH_CFA, 24,
 997         # Compiling
 998         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 13,
 999
1000             # Found word.
1001             LIT_CFA, -1, EQ_CFA, INVERT_CFA, ZBRANCH_CFA, 4,
1002
1003                 # Immediate: Execute!
1004                 EXECUTE_CFA, BRANCH_CFA, -26,
1005
1006                 # Not immediate: Compile!
1007                 COMMA_CFA, BRANCH_CFA, -29,
1008
1009             # No word found, parse number
1010             NUMBER_CFA, LIT_CFA, LIT_CFA, COMMA_CFA, COMMA_CFA, BRANCH_CFA, -36,
1011
1012        # Interpreting
1013         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 5,
1014
1015             # Found word. Execute!
1016             DROP_CFA, EXECUTE_CFA, BRANCH_CFA, -44,
1017
1018             # No word found, parse number and leave on stack
1019             NUMBER_CFA, BRANCH_CFA, -47,
1020     EXIT_CFA])
1021
1022 PROMPT_CFA = defPrimWord("PROMPT", () -> begin
1023     if currentSource() == STDIN
1024         if mem[STATE] == 0
1025             print(" ok")
1026         end
1027         println()
1028     end
1029
1030     return NEXT
1031 end)
1032
1033 QUIT_CFA = defWord("QUIT",
1034     [LIT_CFA, 0, STATE_CFA, STORE_CFA,
1035     LIT_CFA, 0, NUMTIB_CFA, STORE_CFA,
1036     RSP0_CFA, RSPSTORE_CFA,
1037     QUERY_CFA,
1038     INTERPRET_CFA, PROMPT_CFA,
1039     BRANCH_CFA,-4])
1040
1041 ABORT_CFA = defWord("ABORT",
1042     [CLOSEFILES_CFA, PSP0_CFA, PSPSTORE_CFA, QUIT_CFA])
1043
1044 BYE_CFA = defPrimWord("BYE", () -> begin
1045     println("\nBye!")
1046     return 0
1047 end)
1048
1049 # File I/O
1050
1051 INCLUDE_CFA = defPrimWord("INCLUDE", () -> begin
1052     pushPS(32)
1053     callPrim(mem[WORD_CFA])
1054     wordAddr = popPS()+1
1055     wordLen = mem[wordAddr-1]
1056     word = getString(wordAddr, wordLen)
1057
1058     fname = word
1059     if !isfile(fname)
1060         fname = Pkg.dir("forth","src",word)
1061         if !isfile(fname)
1062             error("No file named $word found in current directory or package source directory.")
1063         end
1064     end
1065     push!(sources, open(fname, "r"))
1066
1067     # Clear input buffer
1068     mem[NUMTIB] = 0
1069
1070     return NEXT
1071 end)
1072
1073
1074 #### VM loop ####
1075
1076 initialized = false
1077 initFileName = nothing
1078 if isfile("lib.4th")
1079     initFileName = "lib.4th"
1080 elseif isfile(Pkg.dir("forth","src", "lib.4th"))
1081     initFileName = Pkg.dir("forth","src","lib.4th")
1082 end
1083
1084 function run(;initialize=true)
1085     # Begin with STDIN as source
1086     push!(sources, STDIN)
1087
1088     global initialized, initFileName
1089     if !initialized && initialize
1090         if initFileName != nothing
1091             print("Including definitions from $initFileName...")
1092             push!(sources, open(initFileName, "r"))
1093             initialized = true
1094         else
1095             println("No library file found. Only primitive words available.")
1096         end
1097     end
1098
1099     # Start with IP pointing to first instruction of outer interpreter
1100     reg.IP = QUIT_CFA + 1
1101
1102     # Primitive processing loop.
1103     # Everyting else is simply a consequence of this loop!
1104     jmp = NEXT
1105     while jmp != 0
1106         try
1107             #println("Entering prim $(getPrimName(jmp))")
1108             jmp = callPrim(jmp)
1109
1110         catch ex
1111             showerror(STDOUT, ex)
1112             println()
1113
1114             while !isempty(sources) && currentSource() != STDIN
1115                 close(pop!(sources))
1116             end
1117
1118             # QUIT
1119             reg.IP = ABORT_CFA + 1
1120             jmp = NEXT
1121         end
1122     end
1123 end
1124
1125 # Debugging tools
1126
1127 TRACE_CFA = defPrimWord("TRACE", () -> begin
1128     println("reg.W: $(reg.W) reg.IP: $(reg.IP)")
1129     print("PS: "); printPS()
1130     print("RS: "); printRS()
1131     print("[paused]")
1132     readline()
1133
1134     return NEXT
1135 end)
1136
1137 function dump(startAddr::Int64; count::Int64 = 100, cellsPerLine::Int64 = 10)
1138     chars = Array{Char,1}(cellsPerLine)
1139
1140     lineStartAddr = cellsPerLine*div((startAddr-1),cellsPerLine) + 1
1141     endAddr = startAddr + count - 1
1142
1143     q, r = divrem((endAddr-lineStartAddr+1), cellsPerLine)
1144     numLines = q + (r > 0 ? 1 : 0)
1145
1146     i = lineStartAddr
1147     for l in 1:numLines
1148         print(i,":")
1149
1150         for c in 1:cellsPerLine
1151             if i >= startAddr && i <= endAddr
1152                 print("\t",mem[i])
1153                 if mem[i]>=32 && mem[i]<128
1154                     chars[c] = Char(mem[i])
1155                 else
1156                     chars[c] = '.'
1157                 end
1158             else
1159                 print("\t")
1160                 chars[c] = ' '
1161             end
1162
1163             i += 1
1164         end
1165
1166         println("\t", ASCIIString(chars))
1167     end
1168 end
1169
1170 function printPS()
1171     count = reg.PSP - PSP0
1172
1173     if count > 0
1174         print("<$count>")
1175         for i in (PSP0+1):reg.PSP
1176             print(" $(mem[i])")
1177         end
1178         println()
1179     else
1180         println("Parameter stack empty")
1181     end
1182 end
1183
1184 function printRS()
1185     count = reg.RSP - RSP0
1186
1187     if count > 0
1188         print("<$count>")
1189         for i in (RSP0+1):reg.RSP
1190             print(" $(mem[i])")
1191         end
1192         println()
1193     else
1194         println("Return stack empty")
1195     end
1196 end
1197
1198 DUMP = defPrimWord("DUMP", () -> begin
1199     count = popPS()
1200     addr = popPS()
1201
1202     println()
1203     dump(addr, count=count)
1204
1205     return NEXT
1206 end)
1207
1208 end