src/lib.4th

   1 : / /MOD SWAP DROP ;
   2 : MOD /MOD DROP ;
   3 : */ * / ;
   4
   5 : '\n' 10 ;
   6 : BL 32 ;
   7
   8 : CR '\n' emit ;
   9 : SPACE BL emit ;
  10
  11 : NEGATE 0 swap - ;
  12
  13 : TRUE -1 ;
  14 : FALSE 0 ;
  15 : NOT 0= ;
  16
  17 : CELLS ; \ Allow for slightly more portable code
  18
  19 : DEPTH PSP@ PSP0 @ - ;
  20
  21 : LITERAL IMMEDIATE ' LIT , , ;
  22
  23 : ':' [ CHAR : ] LITERAL ;
  24 : ';' [ CHAR ; ] LITERAL ;
  25 : '(' [ CHAR ( ] LITERAL ;
  26 : ')' [ CHAR ) ] LITERAL ;
  27 : '<' [ CHAR < ] LITERAL ;
  28 : '>' [ CHAR > ] LITERAL ;
  29 : '"' [ CHAR " ] LITERAL ;
  30 : 'A' [ CHAR A ] LITERAL ;
  31 : '0' [ CHAR 0 ] LITERAL ;
  32 : '-' [ CHAR - ] LITERAL ;
  33 : '.' [ CHAR . ] LITERAL ;
  34
  35 : [COMPILE] IMMEDIATE
  36         WORD            \ get the next word
  37         FIND            \ find it in the dictionary
  38         >CFA            \ get its codeword
  39         ,               \ and compile that
  40 ;
  41
  42 : RECURSE IMMEDIATE
  43         LATEST @        \ LATEST points to the word being compiled at the moment
  44         >CFA            \ get the codeword
  45         ,               \ compile it
  46 ;
  47
  48 \ CONTROL STRUCTURES ----------------------------------------------------------------------
  49
  50 : IF IMMEDIATE
  51         ' 0BRANCH ,     \ compile 0BRANCH
  52         HERE @          \ save location of the offset on the stack
  53         0 ,             \ compile a dummy offset
  54 ;
  55
  56 : THEN IMMEDIATE
  57         DUP
  58         HERE @ SWAP -   \ calculate the offset from the address saved on the stack
  59         SWAP !          \ store the offset in the back-filled location
  60 ;
  61
  62 : ELSE IMMEDIATE
  63         ' BRANCH ,      \ definite branch to just over the false-part
  64         HERE @          \ save location of the offset on the stack
  65         0 ,             \ compile a dummy offset
  66         SWAP            \ now back-fill the original (IF) offset
  67         DUP             \ same as for THEN word above
  68         HERE @ SWAP -
  69         SWAP !
  70 ;
  71
  72 : BEGIN IMMEDIATE
  73         HERE @          \ save location on the stack
  74 ;
  75
  76 : UNTIL IMMEDIATE
  77         ' 0BRANCH ,     \ compile 0BRANCH
  78         HERE @ -        \ calculate the offset from the address saved on the stack
  79         ,               \ compile the offset here
  80 ;
  81
  82 : AGAIN IMMEDIATE
  83         ' BRANCH ,      \ compile BRANCH
  84         HERE @ -        \ calculate the offset back
  85         ,               \ compile the offset here
  86 ;
  87
  88 : WHILE IMMEDIATE
  89         ' 0BRANCH ,     \ compile 0BRANCH
  90         HERE @          \ save location of the offset2 on the stack
  91         0 ,             \ compile a dummy offset2
  92 ;
  93
  94 : REPEAT IMMEDIATE
  95         ' BRANCH ,      \ compile BRANCH
  96         SWAP            \ get the original offset (from BEGIN)
  97         HERE @ - ,      \ and compile it after BRANCH
  98         DUP
  99         HERE @ SWAP -   \ calculate the offset2
 100         SWAP !          \ and back-fill it in the original location
 101 ;
 102
 103 : UNLESS IMMEDIATE
 104         ' NOT ,         \ compile NOT (to reverse the test)
 105         [COMPILE] IF    \ continue by calling the normal IF
 106 ;
 107
 108 : DO IMMEDIATE
 109         ' >R , ' >R ,
 110         HERE @
 111 ;
 112
 113 : I RSP@ 2- @ ;
 114
 115 : LOOP IMMEDIATE
 116         ' R> , ' R> , ' 1+ , ' 2DUP , ' - ,
 117         ' SWAP , ' >R , ' SWAP , ' >R ,
 118         ' 0<= , ' 0BRANCH ,
 119         HERE @ - ,
 120         ' RDROP , ' RDROP ,
 121 ;
 122
 123
 124 \ COMMENTS ----------------------------------------------------------------------
 125
 126 : ( IMMEDIATE
 127         1               \ allowed nested parens by keeping track of depth
 128         BEGIN
 129                 KEY             \ read next character
 130                 DUP '(' = IF    \ open paren?
 131                         DROP            \ drop the open paren
 132                         1+              \ depth increases
 133                 ELSE
 134                         ')' = IF        \ close paren?
 135                                 1-              \ depth decreases
 136                         THEN
 137                 THEN
 138         DUP 0= UNTIL            \ continue until we reach matching close paren, depth 0
 139         DROP            \ drop the depth counter
 140 ;
 141
 142 ( Some more complicated stack examples, showing the stack notation. )
 143 : NIP ( x y -- y ) SWAP DROP ;
 144 : TUCK ( x y -- y x y ) DUP ROT ;
 145 : PICK ( x_u ... x_1 x_0 u -- x_u ... x_1 x_0 x_u )
 146         1+              ( add one because of 'u' on the stack )
 147         PSP@ SWAP -     ( add to the stack pointer )
 148         @               ( and fetch )
 149 ;
 150
 151
 152 ( With the looping constructs, we can now write SPACES, which writes n spaces to stdout. )
 153 : SPACES        ( n -- )
 154         BEGIN
 155                 DUP 0>          ( while n > 0 )
 156         WHILE
 157                 SPACE           ( print a space )
 158                 1-              ( until we count down to 0 )
 159         REPEAT
 160         DROP
 161 ;
 162
 163 ( Standard words for manipulating BASE. )
 164 : DECIMAL ( -- ) 10 BASE ! ;
 165 : HEX ( -- ) 16 BASE ! ;
 166
 167 ( Compute absolute value. )
 168 : ABS           ( n -- m)
 169         dup 0< if
 170                 negate
 171         then
 172 ;
 173
 174 ( PRINTING NUMBERS ---------------------------------------------------------------------- )
 175
 176 ( This is the underlying recursive definition of U. )
 177 : U.            ( u -- )
 178         BASE @ /MOD     ( width rem quot )
 179         ?DUP IF                 ( if quotient <> 0 then )
 180                 RECURSE         ( print the quotient )
 181         THEN
 182
 183         ( print the remainder )
 184         DUP 10 < IF
 185                 '0'             ( decimal digits 0..9 )
 186         ELSE
 187                 10 -            ( hex and beyond digits A..Z )
 188                 'A'
 189         THEN
 190         +
 191         EMIT
 192 ;
 193
 194 ( This word returns the width (in characters) of an unsigned number in the current base )
 195 : UWIDTH        ( u -- width )
 196         BASE @ /        ( rem quot )
 197         ?DUP IF         ( if quotient <> 0 then )
 198                 RECURSE 1+      ( return 1+recursive call )
 199         ELSE
 200                 1               ( return 1 )
 201         THEN
 202 ;
 203
 204 : U.R           ( u width -- )
 205         SWAP            ( width u )
 206         DUP             ( width u u )
 207         UWIDTH          ( width u uwidth )
 208         -ROT            ( u uwidth width )
 209         SWAP -          ( u width-uwidth )
 210         ( At this point if the requested width is narrower, we'll have a negative number on the stack.
 211           Otherwise the number on the stack is the number of spaces to print.  But SPACES won't print
 212           a negative number of spaces anyway, so it's now safe to call SPACES ... )
 213         SPACES
 214         ( ... and then call the underlying implementation of U. )
 215         U.
 216 ;
 217
 218 : .R            ( n width -- )
 219         SWAP            ( width n )
 220         DUP 0< IF
 221                 NEGATE          ( width u )
 222                 1               ( save a flag to remember that it was negative | width n 1 )
 223                 ROT             ( 1 width u )
 224                 SWAP            ( 1 u width )
 225                 1-              ( 1 u width-1 )
 226         ELSE
 227                 0               ( width u 0 )
 228                 ROT             ( 0 width u )
 229                 SWAP            ( 0 u width )
 230         THEN
 231         SWAP            ( flag width u )
 232         DUP             ( flag width u u )
 233         UWIDTH          ( flag width u uwidth )
 234         -ROT            ( flag u uwidth width )
 235         SWAP -          ( flag u width-uwidth )
 236
 237         SPACES          ( flag u )
 238         SWAP            ( u flag )
 239
 240         IF                      ( was it negative? print the - character )
 241                 '-' EMIT
 242         THEN
 243
 244         U.
 245 ;
 246
 247 : . 0 .R SPACE ;
 248
 249 : .S            ( -- )
 250         '<' EMIT DEPTH U. '>' EMIT SPACE
 251         PSP0 @ 1+
 252         BEGIN
 253                 DUP PSP@ 2 - <=
 254         WHILE
 255                 DUP @ .
 256                 1+
 257         REPEAT
 258         DROP
 259 ;
 260
 261 : U. U. SPACE ;
 262
 263 ( ? fetches the integer at an address and prints it. )
 264 : ? ( addr -- ) @ . ;
 265
 266 ( c a b WITHIN returns true if a <= c and c < b )
 267 : WITHIN
 268         ROT             ( b c a )
 269         OVER            ( b c a c )
 270         <= IF
 271                 > IF            ( b c -- )
 272                         TRUE
 273                 ELSE
 274                         FALSE
 275                 THEN
 276         ELSE
 277                 2DROP           ( b c -- )
 278                 FALSE
 279         THEN
 280 ;
 281