Implemented authentication for remote delivery.
[lambdamail.git] / lambdamail.scm
1 ;; Super-basic bell-and-whistle-free SMTP server.
2 ;;
3 ;; Intended for a single-user system 
4
5 (import tcp6
6         (chicken port)
7         (chicken io)
8         (chicken string)
9         (chicken pathname)
10         (chicken file)
11         (chicken time)
12         (chicken time posix)
13         (chicken process)
14         (chicken process-context)
15         (chicken process-context posix)
16         (chicken condition)
17         srfi-1 srfi-13 matchable base64)
18
19 (define lambdamail-version "LambdaMail v0.0.1")
20
21 (define-record config host port spool-dir user group)
22 (define-record message to from text user password)
23 (define (make-empty-message) (make-message "" "" "" "" ""))
24
25
26 ;;; Server initialization
27 ;;
28
29 (define (drop-privs config)
30   (let ((uid (config-user config))
31         (gid (config-group config)))
32     (if (not (null? gid)) ; Group first, since only root can switch groups.
33         (set! (current-group-id) gid))
34     (if (not (null? uid))
35         (set! (current-user-id) uid))))
36
37 (define (run-server config)
38   (set-buffering-mode! (current-output-port) #:line)
39   (let ((listener (tcp-listen (config-port config) 10 "::")))
40     (print lambdamail-version
41            " listening on port " (config-port config) " ...")
42     (print "(Host name: " (config-host config)
43            ", Spool dir: " (config-spool-dir config) ")")
44     (drop-privs config)
45     (server-loop listener config '())))
46
47
48 ;;; Main server loop
49 ;;
50
51 (define (server-loop listener config undelivered-messages)
52   (let* ((messages (append (receive-messages listener config) undelivered-messages)))
53     (server-loop listener config (deliver-messages config messages))))
54
55
56 ;;; Receiving messages
57 ;;
58
59 (define (receive-messages listener config)
60   (let ((messages '()))
61     (let-values (((in-port out-port) (tcp-accept listener)))
62       (let-values (((local-ip remote-ip) (tcp-addresses in-port)))
63         (print "Accepted connection from " remote-ip " on " (seconds->string)))
64       (condition-case
65           (set! messages (process-smtp (make-smtp-session in-port out-port config) config))
66         (o (exn)
67            (print-error-message o)))
68       (print "Terminating connection.")
69       (close-input-port in-port)
70       (close-output-port out-port))
71     messages))
72
73 (define (make-smtp-session in-port out-port config)
74   (let ((user "")
75         (password ""))
76     (lambda msg
77       (match msg
78         (('get-line) (read-line in-port))
79         (('send-line strings ...) (write-line (conc (apply conc strings) "\r") out-port))
80         (('set-user! u) (set! user u))
81         (('set-password! p) (set! password p))
82         (('user) user)
83         (('password) password)))))
84
85 (define (smtp-command? cmd-string input-string)
86   (string-prefix? cmd-string (string-downcase input-string)))
87
88 (define (smtp-command-args cmd-string input-string)
89   (if (> (string-length input-string) (string-length cmd-string))
90       (string-trim (string-drop input-string (string-length cmd-string)))
91       ""))
92
93 (define (process-smtp smtp-session config)
94   (smtp-session 'send-line "220 " (config-host config) lambdamail-version)
95   (let loop ((msg (make-empty-message))
96              (received-messages '()))
97     (let ((line (smtp-session 'get-line)))
98       (when (string? line)
99         (print "got " line)
100         (cond
101          ((smtp-command? "helo" line)
102           (smtp-session 'send-line "250 ok")
103           (loop msg received-messages))
104          ((smtp-command? "ehlo" line)
105           (smtp-session 'send-line
106                         "250-" (config-host config)
107                         " Hello " (smtp-command-args "ehlo" line))
108           (smtp-session 'send-line "250 AUTH PLAIN")
109           ;; (smtp-session 'send-line "250 STARTTLS")
110           (loop msg received-messages))
111          ((smtp-command? "auth plain" line)
112           (let* ((auth-string (smtp-command-args "auth plain" line))
113                  (auth-decoded (base64-decode auth-string))
114                  (auth-list (string-split auth-decoded "\x00"))
115                  (user (car auth-list))
116                  (password (cadr auth-list)))
117             (smtp-session 'set-user! user)
118             (smtp-session 'set-password! password)
119             (print "Attempted login, user: " user ", password: " password)
120             (smtp-session 'send-line "235 authentication successful")
121             (loop msg received-messages)))
122          ((smtp-command? "mail from:" line)
123           (message-from-set! msg (smtp-command-args "mail from:" line))
124           (smtp-session 'send-line "250 ok")
125           (loop msg received-messages))
126          ((smtp-command? "rcpt to:" line)
127           (message-to-set! msg (smtp-command-args "rcpt to:" line))
128           (smtp-session 'send-line "250 ok")
129           (loop msg received-messages))
130          ((smtp-command? "data" line)
131           (smtp-session 'send-line "354 intermediate")
132           (let text-loop ((text ""))
133             (let ((text-line (smtp-session 'get-line)))
134               (if (string=? "." text-line)
135                   (message-text-set! msg text)
136                   (text-loop (conc text text-line "\n")))))
137           (message-user-set! msg (smtp-session 'user))
138           (message-password-set! msg (smtp-session 'password))
139           (smtp-session 'send-line "250 ok")
140           (loop (make-empty-message) (cons msg received-messages)))
141          ((smtp-command? "quit" line)
142           (smtp-session 'send-line "221 closing transmission channel")
143           received-messages)
144          ((string=? "" (string-trim line))
145           (loop msg received-messages))
146          (else
147           (smtp-session 'send-line "502 command not implemented")
148           (loop msg received-messages)))))))
149
150
151 ;;; Sending/Delivering messages
152 ;;
153
154 (define (deliver-messages config messages)
155   (print "Attempting delivery of " (length messages) " mail items.")
156   (filter (lambda (msg) (not (deliver-message msg config)))
157           messages))
158
159 (define (get-local-addresses config)
160   (map (lambda (p) (cons
161                     (conc "<" (car p) "@" (config-host config) ">")
162                     (cdr p)))
163        (map (lambda (file)
164               (list (pathname-file file) file
165                     (let ((password-file (conc file ".auth")))
166                       (if (file-exists? password-file)
167                           (with-input-from-file password-file read-line)
168                           #f))))
169             (filter directory-exists?
170                     (glob (conc (config-spool-dir config) "/*"))))))
171
172 (define (deliver-message-local msg dest-dir)
173   (with-output-to-file (conc dest-dir "/" (current-seconds))
174     (lambda ()
175       (print (message-text msg)))))
176
177 (define (deliver-message-remote msg)
178   (print "TODO"))
179
180 (define (deliver-message msg config)
181   (let* ((local-addresses (get-local-addresses config))
182          (dest (assoc (message-to msg) local-addresses))
183          (orig (assoc (message-from msg) local-addresses)))
184     (cond
185      (dest
186       (let ((dest-dir (cadr dest)))
187         (deliver-message-local msg dest-file))
188       (print "Message DELIVERED (local):"))
189      (orig
190       (let ((password (caddr orig)))
191         (if (and
192              (string=? (conc "<" (message-user msg) "@" (config-host config) ">")
193                        (message-from msg))
194              password
195              (string=? (message-password msg) password))
196             (begin
197               (deliver-message-remote msg)
198               (print "Message DELIVERED (remote):"))
199             (print "Message DELIVERY REJECTED (auth failure):"))))
200      (else
201       (print "Message DELIVERY REJECTED (relay forbidden):"))))
202   (print " * From: " (message-from msg))
203   (print " * To: " (message-to msg))
204   #t)
205
206
207 ;;; Command line argument parsing
208 ;;
209
210 (define (print-usage progname)
211   (print "Usage:\n"
212          progname " -h/--help\n"
213          progname " [-u/--user UID] [-g/--group GID] hostname [[port [spooldir]]\n"
214          "\n"
215          "The -u and -g options can be used to set the UID and GID of the process\n"
216          "following the creation of the TCP port listener (which often requires root)."))
217
218 (define (main)
219   (let ((progname (pathname-file (car (argv))))
220         (config (make-config "" 25 "/var/spool/mail" '() '())))
221     (if (null? (cdr (argv)))
222         (print-usage progname)
223         (let loop ((args (cdr (argv))))
224           (let ((this-arg (car args))
225                 (rest-args (cdr args)))
226             (if (string-prefix? "-" this-arg)
227                 (cond
228                  ((or (equal? this-arg "-u")
229                       (equal? this-arg "--user"))
230                   (config-user-set! config (string->number (car rest-args)))
231                   (loop (cdr rest-args)))
232                  ((or (equal? this-arg "-g")
233                       (equal? this-arg "--group"))
234                   (config-group-set! config (string->number (car rest-args)))
235                   (loop (cdr rest-args)))
236                  ((or (equal? this-arg "-h")
237                       (equal? this-arg "--help"))
238                   (print-usage progname))
239                  (else
240                   (print "Unknown option " this-arg "\n")
241                   (print-usage progname)))
242                 (begin
243                   (config-host-set! config this-arg)
244                   (unless (null? rest-args)
245                     (config-port-set! config (string->number (car rest-args)))
246                     (unless (null? (cdr rest-args))
247                       (config-spool-dir-set! config (cadr rest-args))))
248                   (run-server config))))))))
249
250 (main)
251
252 ;; (define (test)
253 ;;   (run-server (make-config "localhost" 2525 "spool" '() '())))