murk.el

   1 ;;; murk.el --- Multiserver Unibuffer iRc Klient -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2024 plugd
   4
   5 ;; Author: plugd <plugd@thelambdalab.xyz>
   6 ;; Created: 11 May 2024
   7 ;; Version: 0.0
   8 ;; Homepage: http://thelambdalab.xyz/murk
   9 ;; Keywords: comm
  10 ;; Package-Requires: ((emacs "26.1"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; A very simple IRC server which uses only a single buffer.
  30
  31 ;;; Code:
  32
  33 (provide 'murk)
  34
  35 (require 'cl-lib)
  36
  37
  38 ;;; Customizations
  39
  40 (defgroup murk nil
  41   "Multiserver Unibuffer iRc Klient"
  42   :group 'network)
  43
  44 (defcustom murk-default-nick "plugd"
  45   "Default nick."
  46   :type '(string))
  47
  48 (defcustom murk-default-quit-msg "Bye"
  49   "Default quit message when none supplied."
  50   :type '(string))
  51
  52 (defcustom murk-networks
  53   '(("debug" "localhost" 6667 :notls)
  54     ("libera" "irc.libera.chat" 6697)
  55     ("tilde" "tilde.chat" 6697)
  56     ("freenode" "chat.freenode.net" 6697))
  57   "IRC networks."
  58   :type '(alist :key-type string))
  59
  60 (defcustom murk-display-header t
  61   "If non-nil, use buffer header to display current host and channel."
  62   :type '(boolean))
  63
  64
  65 ;;; Faces
  66 ;;
  67
  68 (defface murk-text
  69   '((t :inherit default))
  70   "Face used for murk text.")
  71
  72 (defface murk-prompt
  73   '((t :inherit font-lock-keyword-face))
  74   "Face used for the prompt.")
  75
  76 (defface murk-context
  77   '((t :inherit murk-context))
  78   "Face used for the context name in the prompt.")
  79
  80 (defface murk-faded
  81   '((t :inherit shadow))
  82   "Face used for faded murk text.")
  83
  84 (defface murk-timestamp
  85   '((t :inherit shadow))
  86   "Face used for timestamps.")
  87
  88 (defface murk-error
  89   '((t :inherit error))
  90   "Face used for murk error text.")
  91
  92 (defface murk-notice
  93   '((t :inherit warning))
  94   "Face used for murk notice text.")
  95
  96
  97 ;;; Global variables
  98 ;;
  99
 100 (defvar murk-version "Murk v0.0"
 101   "Value of this string is used in response to CTCP version queries.")
 102
 103 (defvar murk-notice-prefix "-!-")
 104 (defvar murk-error-prefix "!!!")
 105 (defvar murk-prompt-string ">")
 106
 107 (defvar murk-debug nil
 108   "If non-nil, enable debug mode.")
 109
 110
 111 ;;; Utility procedures
 112 ;;
 113
 114 (defun murk--filtered-join (&rest args)
 115   (string-join (seq-filter (lambda (el) el) args) " "))
 116
 117 (defun murk--as-string (obj)
 118   (if obj
 119       (with-output-to-string (princ obj))
 120     nil))
 121
 122
 123 ;;; Network processes
 124 ;;
 125
 126 (defvar murk-connection-table nil
 127   "An alist associating servers to connection information.
 128 This includes the process and the response string.")
 129
 130 (defun murk-connection-process (server)
 131   (elt (assoc server murk-connection-table) 1))
 132
 133 (defun murk-connection-nick (server)
 134   (elt (assoc server murk-connection-table) 2))
 135
 136 (defun murk-set-connection-nick (server nick)
 137   (setf (elt (assoc server murk-connection-table) 2) nick))
 138
 139 (defun murk-connection-response (server)
 140   (elt (assoc server murk-connection-table) 3))
 141
 142 (defun murk-set-connection-response (server string)
 143   (setf (elt (assoc server murk-connection-table) 3) string))
 144
 145 (defun murk-connection-new (server process nick)
 146   (add-to-list 'murk-connection-table
 147                (list server process nick "")))
 148
 149 (defun murk-connection-remove (server)
 150   (setq murk-connection-table
 151         (seq-remove (lambda (row) (equal (car row) server))
 152                     murk-connection-table)))
 153
 154 (defun murk-make-server-filter (server)
 155   (lambda (_proc string)
 156     (dolist (line (split-string (concat (murk-connection-response server) string)
 157                                 "\n"))
 158       (if (string-suffix-p "\r" line)
 159           (murk-eval-msg-string server (string-trim line))
 160         (murk-set-connection-response server line)))))
 161
 162 (defun murk-make-server-sentinel (server)
 163   (lambda (_proc string)
 164     (unless (equal "open" (string-trim string))
 165       (murk-display-error "Disconnected from server.")
 166       (murk-connection-remove server)
 167       (murk-remove-server-contexts server)
 168       (murk-render-prompt))))
 169
 170 (defun murk-start-process (server)
 171   (let* ((row (assoc server murk-networks))
 172          (host (elt row 1))
 173          (port (elt row 2))
 174          (flags (seq-drop row 3)))
 175     (make-network-process :name (concat "murk-" server)
 176                           :host host
 177                           :service port
 178                           :family nil
 179                           :filter (murk-make-server-filter server)
 180                           :sentinel (murk-make-server-sentinel server)
 181                           :nowait nil
 182                           :tls-parameters (if (memq :notls flags)
 183                                               nil
 184                                             (cons 'gnutls-x509pki
 185                                                   (gnutls-boot-parameters
 186                                                    :type 'gnutls-x509pki
 187                                                    :hostname host)))
 188                           :buffer "*murk*")))
 189
 190 (defvar murk-ping-period 60)
 191
 192 ;; IDEA: Have a single ping timer which pings all connected hosts
 193
 194 (defun murk-connect (server)
 195   (if (assoc server murk-connection-table)
 196       (murk-display-error "Already connected to this network")
 197     (if (not (assoc server murk-networks))
 198         (murk-display-error "Network '" server "' is unknown.")
 199       (let ((proc (murk-start-process server)))
 200         (murk-connection-new server proc murk-default-nick))
 201       (murk-send-msg server (murk-msg nil nil "USER" murk-default-nick 0 "*" murk-default-nick))
 202       (murk-send-msg server (murk-msg nil nil "NICK" murk-default-nick))
 203       (murk-add-context (list server))
 204       (murk-render-prompt))))
 205
 206 (defun murk-send-msg (server msg)
 207   (if murk-debug
 208       (murk-display-string nil nil (murk-msg->string msg)))
 209   (let ((proc (murk-connection-process server)))
 210     (if (and proc (eq (process-status proc) 'open))
 211         (process-send-string proc (concat (murk-msg->string msg) "\r\n"))
 212       (murk-display-error "No server connection established"))))
 213
 214
 215 ;;; Server messages
 216 ;;
 217
 218 (defun murk-msg (tags src cmd &rest params)
 219   (list (murk--as-string tags)
 220         (murk--as-string src)
 221         (upcase (murk--as-string cmd))
 222         (mapcar #'murk--as-string
 223                 (if (and params (listp (elt params 0)))
 224                     (elt params 0)
 225                   params))))
 226
 227 (defun murk-msg-tags (msg) (elt msg 0))
 228 (defun murk-msg-src (msg) (elt msg 1))
 229 (defun murk-msg-cmd (msg) (elt msg 2))
 230 (defun murk-msg-params (msg) (elt msg 3))
 231 (defun murk-msg-trail (msg)
 232   (let ((params (murk-msg-params msg)))
 233     (if params
 234         (elt params (- (length params) 1)))))
 235
 236 (defvar murk-msg-regex
 237   (rx
 238    (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
 239         (* whitespace))
 240    (opt (: ":" (: (group (* (not (any space "!" "@"))))
 241                   (* (not (any space)))))
 242         (* whitespace))
 243    (group (: (* (not whitespace))))
 244    (* whitespace)
 245    (opt (group (+ not-newline))))
 246   "Regex used to parse IRC messages.
 247 Note that this regex is incomplete.  Noteably, we discard the non-nick
 248 portion of the source component of the message, as mURK doesn't use this.")
 249
 250 (defun murk-string->msg (string)
 251   (if (string-match murk-msg-regex string)
 252       (let* ((tags (match-string 1 string))
 253              (src (match-string 2 string))
 254              (cmd (upcase (match-string 3 string)))
 255              (params-str (match-string 4 string))
 256              (params
 257               (if params-str
 258                   (let* ((idx (seq-position params-str ?:))
 259                          (l (split-string (string-trim (substring params-str 0 idx))))
 260                          (r (if idx (list (substring params-str (+ 1 idx))) nil)))
 261                     (append l r))
 262                 nil)))
 263         (apply #'murk-msg (append (list tags src cmd) params)))
 264     (error "Failed to parse string %s" string)))
 265
 266 (defun murk-msg->string (msg)
 267   (let ((tags (murk-msg-tags msg))
 268         (src (murk-msg-src msg))
 269         (cmd (murk-msg-cmd msg))
 270         (params (murk-msg-params msg)))
 271     (murk--filtered-join
 272      (if tags (concat "@" tags) nil)
 273      (if src (concat ":" src) nil)
 274      cmd
 275      (if (> (length params) 1)
 276          (string-join (seq-take params (- (length params) 1)) " ")
 277        nil)
 278      (if (> (length params) 0)
 279          (concat ":" (elt params (- (length params) 1)))
 280        nil))))
 281
 282
 283 ;;; Contexts
 284 ;;
 285
 286 ;; A context is a list (server channel users) identifying the server
 287 ;; and channel.  The tail of the list contains the nicks of users
 288 ;; present in the channel.
 289 ;;
 290 ;; Each server has a special context (server) used for messages
 291 ;; to/from the server itself.
 292
 293 (defvar murk-contexts nil
 294   "List of currently-available contexts.
 295 The head of this list is always the current context.")
 296
 297 (defun murk-current-context ()
 298   "Return the current context."
 299   (if murk-contexts
 300       (car murk-contexts)
 301     nil))
 302
 303 (defun murk-contexts-equal (c1 c2)
 304   (if (murk-server-context-p c1)
 305       (and (murk-server-context-p c2)
 306            (equal (murk-context-server c1)
 307                   (murk-context-server c2)))
 308     (and (not (murk-server-context-p c2))
 309          (equal (seq-take c1 2)
 310                 (seq-take c2 2)))))
 311
 312 (defun murk-context-server (ctx) (elt ctx 0))
 313 (defun murk-context-channel (ctx) (elt ctx 1))
 314 (defun murk-context-users (ctx) (elt ctx 2))
 315 (defun murk-set-context-users (ctx users)
 316   (setcar (cddr ctx) users))
 317 (defun murk-server-context-p (ctx) (not (cdr ctx)))
 318
 319 (defun murk-add-context (ctx)
 320   (add-to-list 'murk-contexts ctx))
 321
 322 (defun murk-remove-context (ctx)
 323   (setq murk-contexts
 324         (seq-remove
 325          (lambda (this-ctx)
 326            (murk-contexts-equal this-ctx ctx))
 327          murk-contexts)))
 328
 329 (defun murk-remove-server-contexts (server)
 330   (setq murk-contexts
 331         (seq-remove (lambda (row) (equal (car row) server))
 332                     murk-contexts)))
 333
 334 (defun murk-context->string (ctx)
 335    (if (murk-server-context-p ctx)
 336        (concat "[" (murk-context-server ctx) "]")
 337      (concat (murk-context-channel ctx) "@"
 338              (murk-context-server ctx))))
 339
 340 (defun murk-get-context (server &optional name)
 341   (if name
 342       (let ((test-ctx (list server name)))
 343         (seq-find (lambda (ctx)
 344                     (equal (seq-take ctx 2) test-ctx))
 345                   murk-contexts))
 346     (assoc server murk-contexts)))
 347
 348 (defun murk-cycle-contexts (&optional reverse)
 349   (setq murk-contexts
 350         (if reverse
 351             (let ((nminus1 (- (length murk-contexts) 1)))
 352               (cons
 353                (elt murk-contexts nminus1)
 354                (seq-take murk-contexts nminus1)))
 355           (append (cdr murk-contexts) (list (car murk-contexts))))))
 356
 357 (defun murk-add-context-users (ctx users)
 358   (murk-set-context-users
 359    ctx
 360    (cl-union users (murk-context-users ctx))))
 361
 362 ;;; Buffer
 363 ;;
 364
 365 (defvar murk-prompt-marker nil
 366   "Marker for prompt position in murk buffer.")
 367
 368 (defvar murk-input-marker nil
 369   "Marker for prompt position in murk buffer.")
 370
 371 (defun murk-render-prompt ()
 372   (with-current-buffer "*murk*"
 373     (let ((update-point (= murk-input-marker (point)))
 374           (update-window-points (mapcar (lambda (w)
 375                                           (list (= (window-point w) murk-input-marker)
 376                                                 w))
 377                                         (get-buffer-window-list nil nil t))))
 378       (save-excursion
 379         (set-marker-insertion-type murk-prompt-marker nil)
 380         (set-marker-insertion-type murk-input-marker t)
 381         (let ((inhibit-read-only t))
 382           (delete-region murk-prompt-marker murk-input-marker)
 383           (goto-char murk-prompt-marker)
 384           (insert
 385            (propertize (let ((ctx (murk-current-context)))
 386                          (if ctx
 387                              (murk-context->string ctx)
 388                            ""))
 389                        'face 'murk-context
 390                        'read-only t)
 391            (propertize murk-prompt-string
 392                        'face 'murk-prompt
 393                        'read-only t)
 394            (propertize " " ; Need this to be separate to mark it as rear-nonsticky
 395                        'read-only t
 396                        'rear-nonsticky t)))
 397         (set-marker-insertion-type murk-input-marker nil))
 398       (if update-point
 399           (goto-char murk-input-marker))
 400       (dolist (v update-window-points)
 401         (if (car v)
 402             (set-window-point (cadr v) murk-input-marker))))))
 403
 404 (defun murk-setup-header ()
 405   (with-current-buffer "*murk*"
 406     (setq-local header-line-format
 407                 '((:eval
 408                    (let* ((ctx (murk-current-context)))
 409                      (if ctx
 410                          (let ((server (murk-context-server ctx)))
 411                            (concat
 412                             "Network: " server ", "
 413                             (if (murk-server-context-p ctx)
 414                                 "Server"
 415                               (concat
 416                                "Channel: "
 417                                (murk-context-channel ctx)
 418                                " ("
 419                                (number-to-string
 420                                 (length (murk-context-users ctx)))
 421                                ")"))))
 422                        "No connection")))))))
 423
 424 (defun murk-setup-buffer ()
 425   (with-current-buffer (get-buffer-create "*murk*")
 426     (setq-local scroll-conservatively 1)
 427     (setq-local buffer-invisibility-spec nil)
 428     (if (markerp murk-prompt-marker)
 429         (set-marker murk-prompt-marker (point-max))
 430       (setq murk-prompt-marker (point-max-marker)))
 431     (if (markerp murk-input-marker)
 432         (set-marker murk-input-marker (point-max))
 433       (setq murk-input-marker (point-max-marker)))
 434     (goto-char (point-max))
 435     (murk-render-prompt)
 436     (if murk-display-header
 437         (murk-setup-header))))
 438
 439 (defun murk-clear-buffer ()
 440   "Completely erase all non-prompt and non-input text from murk buffer."
 441   (with-current-buffer "*murk*"
 442     (let ((inhibit-read-only t))
 443       (delete-region (point-min) murk-prompt-marker))))
 444
 445
 446 ;;; Output formatting and highlighting
 447 ;;
 448
 449 (defun murk--fill-strings (col indent &rest strings)
 450   (with-temp-buffer
 451     (setq buffer-invisibility-spec nil)
 452     (let ((fill-column col)
 453           (adaptive-fill-regexp (rx-to-string `(= ,indent anychar))))
 454       (apply #'insert strings)
 455       (fill-region (point-min) (point-max) nil t)
 456       (buffer-string))))
 457
 458 (defun murk-display-string (context prefix &rest strings)
 459   (with-current-buffer "*murk*"
 460     (save-excursion
 461       (goto-char murk-prompt-marker)
 462       (let* ((inhibit-read-only t)
 463              (old-pos (marker-position murk-prompt-marker))
 464              (padded-timestamp (concat (format-time-string "%H:%M ")))
 465              (padded-prefix (if prefix (concat prefix " ") ""))
 466              (context-atom (if context (intern (murk-context->string context)) nil)))
 467         (insert-before-markers
 468          (murk--fill-strings
 469           80
 470           (+ (length padded-timestamp)
 471              (length padded-prefix))
 472           (propertize padded-timestamp
 473                       'face 'murk-timestamp
 474                       'read-only t
 475                       'context context
 476                       'invisible context-atom)
 477           (propertize padded-prefix
 478                       'read-only t
 479                       'context context
 480                       'invisible context-atom)
 481           (murk-add-formatting
 482            (propertize (concat (apply #'murk-buttonify-urls strings) "\n")
 483                        'read-only t
 484                        'context context
 485                        'invisible context-atom)))))))
 486   (murk-scroll-windows-to-last-line))
 487
 488 (defun murk-display-message (server from to text)
 489   (let ((context (if (string-prefix-p "#" to)
 490                      (murk-get-context server to)
 491                    (murk-get-context server))))
 492     (murk-display-string
 493      context
 494      (if (murk-server-context-p context)
 495          (concat "[" from " -> " to "]")
 496        (concat (murk-context->string context) " <" from ">"))
 497      text)))
 498
 499 (defun murk-display-notice (context &rest notices)
 500   (murk-display-string
 501    context
 502    (propertize murk-notice-prefix 'face 'murk-notice)
 503    (apply #'concat notices)))
 504
 505 (defun murk-display-error (&rest messages)
 506   (murk-display-string
 507    nil
 508    (propertize murk-error-prefix 'face 'murk-error)
 509    (apply #'concat messages)))
 510
 511 (defun murk--start-of-final-line ()
 512   (with-current-buffer "*murk*"
 513     (save-excursion
 514       (goto-char (point-max))
 515       (line-beginning-position))))
 516
 517 (defun murk-scroll-windows-to-last-line ()
 518   (with-current-buffer "*murk*"
 519     (dolist (window (get-buffer-window-list))
 520       (if (>= (window-point window) (murk--start-of-final-line))
 521           (with-selected-window window
 522             (recenter -1))))))
 523
 524 (defconst murk-url-regex
 525   (rx (:
 526        (group (+ alpha))
 527        "://"
 528        (group (or (+ (any alnum "." "-"))
 529                   (+ (any alnum ":"))))
 530        (opt (group (: ":" (+ digit))))
 531        (opt (group (: "/"
 532                       (opt
 533                        (* (any alnum "-/.,#:%=&_?~@+"))
 534                        (any alnum "-/#:%=&_~@+")))))))
 535   "Imperfect regex used to find URLs in plain text.")
 536
 537 (defun murk-click-url (button)
 538   (browse-url (button-get button 'url)))
 539
 540 (defun murk-buttonify-urls (&rest strings)
 541   "Turn substrings which look like urls in STRING into clickable buttons."
 542   (with-temp-buffer
 543     (apply #'insert strings)
 544     (goto-char (point-min))
 545     (while (re-search-forward murk-url-regex nil t)
 546       (let ((url (match-string 0)))
 547         (make-text-button (match-beginning 0)
 548                           (match-end 0)
 549                           'action #'murk-click-url
 550                           'url url
 551                           'follow-link t
 552                           'face 'button
 553                           'help-echo "Open URL in browser.")))
 554     (buffer-string)))
 555
 556 (defun murk-add-formatting (string)
 557   (with-temp-buffer
 558     (insert string)
 559     (goto-char (point-min))
 560     (let ((bold nil)
 561           (italics nil)
 562           (underline nil)
 563           (strikethrough nil)
 564           (prev-point (point)))
 565       (while (re-search-forward (rx (or (any "\x02\x1D\x1F\x1E\x0F")
 566                                         (: "\x03" (+ digit) (opt "," (* digit)))))
 567                                 nil t)
 568         (let ((beg (+ (match-beginning 0) 1)))
 569           (if bold
 570               (add-face-text-property prev-point beg '(:weight bold)))
 571           (if italics
 572               (add-face-text-property prev-point beg '(:slant italic)))
 573           (if underline
 574               (add-face-text-property prev-point beg '(:underline t)))
 575           (if strikethrough
 576               (add-face-text-property prev-point beg '(:strike-through t)))
 577           (pcase (match-string 0)
 578             ("\x02" (setq bold (not bold)))
 579             ("\x1D" (setq italics (not italics)))
 580             ("\x1F" (setq underline (not underline)))
 581             ("\x1E" (setq strikethrough (not strikethrough)))
 582             ("\x0F" ; Reset
 583              (setq bold nil)
 584              (setq italics nil)
 585              (setq underline nil)
 586              (setq strikethrough nil))
 587             (_))
 588           (delete-region (match-beginning 0) (match-end 0))
 589           (setq prev-point (point)))))
 590     (buffer-string)))
 591
 592
 593 ;;; Message evaluation
 594 ;;
 595
 596 (defun murk-eval-msg-string (server string)
 597   (if murk-debug
 598       (murk-display-string nil nil string))
 599   (let* ((msg (murk-string->msg string)))
 600     (pcase (murk-msg-cmd msg)
 601       ("PING"
 602        (murk-send-msg server
 603         (murk-msg nil nil "PONG" (murk-msg-params msg))))
 604
 605       ("PONG")
 606
 607       ("001"
 608        (let* ((params (murk-msg-params msg))
 609               (nick (elt params 0))
 610               (text (string-join (seq-drop params 1) " ")))
 611          (murk-set-connection-nick server nick)
 612          (murk-display-notice nil text)))
 613
 614       ("353" ; NAMEREPLY
 615        (let* ((params (murk-msg-params msg))
 616               (channel (elt params 2))
 617               (names (split-string (elt params 3)))
 618               (ctx (murk-get-context server channel)))
 619          (if ctx
 620              (murk-add-context-users ctx names)
 621            (murk-display-notice nil "Users in " channel
 622                                 ": " (string-join names " ")))))
 623
 624       ("366" ; ENDOFNAMES
 625        (let* ((params (murk-msg-params msg))
 626               (channel (elt params 1))
 627               (ctx (murk-get-context server channel)))
 628          (if ctx
 629              (murk-display-notice
 630               ctx
 631               (murk--as-string (length (murk-context-users ctx)))
 632               " users in " channel)
 633            (murk-display-notice nil "End of " channel " names list."))))
 634
 635
 636       ((rx (= 3 (any digit)))
 637        (murk-display-notice nil (mapconcat 'identity (cdr (murk-msg-params msg)) " ")))
 638
 639       ((and "JOIN"
 640             (guard (equal (murk-connection-nick server)
 641                           (murk-msg-src msg))))
 642        (let ((channel (car (murk-msg-params msg))))
 643          (murk-add-context (list server channel nil))
 644          (murk-display-notice (murk-current-context)
 645                               "Joining channel " channel " on " server)
 646          (murk-render-prompt)))
 647
 648       ((and "PART"
 649             (guard (equal (murk-connection-nick server)
 650                           (murk-msg-src msg))))
 651        (let ((channel (car (murk-msg-params msg))))
 652          (murk-display-notice (murk-current-context) "Left channel " channel)
 653          (murk-remove-context (list server channel))
 654          (murk-render-prompt)))
 655
 656       ("QUIT"
 657        (let ((nick (murk-msg-src msg))
 658              (reason (mapconcat 'identity (murk-msg-params msg) " ")))
 659          (murk-del-user nick)
 660          (if murk-show-joins
 661              (murk-display-notice nil nick " quit: " reason))))
 662
 663       ("PRIVMSG"
 664        (let* ((from (murk-msg-src msg))
 665               (params (murk-msg-params msg))
 666               (to (car params))
 667               (text (cadr params)))
 668          (pcase text
 669            ("\01VERSION\01"
 670             (let ((version-string (concat murk-version " - running on GNU Emacs " emacs-version)))
 671               (murk-send-msg server
 672                              (murk-msg nil nil "NOTICE"
 673                                        (list from (concat "\01VERSION "
 674                                                           version-string
 675                                                           "\01")))))
 676             (murk-display-notice nil "CTCP version request received from "
 677                                  from " on " server))
 678
 679            ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
 680             (murk-send-msg server (murk-msg nil nil "NOTICE" (list from ping)))
 681             (murk-display-notice nil "CTCP ping received from " from " on " server))
 682
 683            ("\01USERINFO\01"
 684             (murk-display-notice nil "CTCP userinfo request from " from
 685                                  " on " server " (no response sent)"))
 686
 687            ("\01CLIENTINFO\01"
 688             (murk-display-notice nil "CTCP clientinfo request from " from
 689                                  " on " server " (no response sent)"))
 690
 691            ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
 692             (murk-display-action from to action-text))
 693
 694            (_
 695             (murk-display-message server from to text)))))
 696
 697       (_
 698        (murk-display-notice nil (murk-msg->string msg))))))
 699
 700 ;;; Commands
 701 ;;
 702
 703 (defvar murk-command-table
 704   '(("DEBUG" "Toggle debug mode on/off." murk-command-debug murk-boolean-completions)
 705     ("HEADER" "Toggle display of header." murk-command-header murk-boolean-completions)
 706     ("NETWORKS" "List known IRC networks." murk-command-networks)
 707     ("CONNECT" "Connect to an IRC network." murk-command-connect murk-network-completions)
 708     ("QUIT" "Disconnect from current network." murk-command-quit)
 709     ("JOIN" "Join one or more channels." murk-command-join)
 710     ("PART" "Leave channel." murk-command-part murk-context-completions)
 711     ("NICK" "Change nick." murk-command-nick)
 712     ("MSG" "Send private message to user." murk-command-msg murk-nick-completions)
 713     ("CLEAR" "Clear buffer text." murk-command-clear murk-context-completions)
 714     ("HELP" "Display help on client commands." murk-command-help murk-help-completions))
 715   "Table of commands explicitly supported by murk.")
 716
 717 (defun murk-boolean-completions ()
 718   '("on" "off"))
 719
 720 (defun murk-network-completions ()
 721   (mapcar (lambda (row) (car row)) murk-networks))
 722
 723 (defun murk-command-help (params)
 724   (if params
 725       (let* ((cmd-str (upcase (car params)))
 726              (row (assoc cmd-str murk-command-table #'equal)))
 727         (if row
 728             (progn
 729               (murk-display-notice nil "Help for \x02" cmd-str "\x02:")
 730               (murk-display-notice nil "  " (elt row 1)))
 731           (murk-display-notice nil "No such (client-interpreted) command.")))
 732     (murk-display-notice nil "Client-interpreted commands:")
 733     (dolist (row murk-command-table)
 734       (murk-display-notice nil "  \x02" (elt row 0) "\x02: " (elt row 1)))
 735     (murk-display-notice nil "Use /HELP COMMAND to display information about a specific command.")))
 736
 737 (defun murk-command-debug (params)
 738   (setq murk-debug
 739         (if params
 740             (if (equal (upcase (car params)) "ON")
 741                 t
 742               nil)
 743           (not murk-debug)))
 744   (murk-display-notice nil "Debug mode now " (if murk-debug "on" "off") "."))
 745
 746 (defun murk-command-header (params)
 747   (if
 748       (if params
 749           (equal (upcase (car params)) "ON")
 750         (not header-line-format))
 751       (progn
 752         (murk-setup-header)
 753         (murk-display-notice nil "Header enabled."))
 754     (setq-local header-line-format nil)
 755     (murk-display-notice nil "Header disabled.")))
 756
 757 (defun murk-command-clear (params)
 758   (if (not params)
 759       (murk-clear-buffer)
 760     (dolist (context params)
 761       (murk-clear-context context))))
 762
 763 (defun murk-command-connect (params)
 764   (if params
 765       (let ((network (car params)))
 766         (murk-display-notice nil "Attempting to connect to " network "...")
 767         (murk-connect network))
 768     (murk-display-notice nil "Usage: /connect <network>")))
 769
 770 (defun murk-command-networks (_params)
 771   (murk-display-notice nil "Currently-known networks:")
 772   (dolist (row murk-networks)
 773     (seq-let (network server port &rest _others) row
 774       (murk-display-notice nil "\t" network
 775                            " [" server
 776                            " " (number-to-string port) "]")))
 777   (murk-display-notice nil "(Modify the `murk-networks' variable to add more.)"))
 778
 779 (defun murk-command-quit (params)
 780   (let ((ctx (murk-current-context)))
 781     (if (not ctx)
 782         (murk-display-error "No current context")
 783       (let ((quit-msg (if params (string-join params " ") murk-default-quit-msg)))
 784         (murk-send-msg
 785          (murk-context-server ctx)
 786          (murk-msg nil nil "QUIT" quit-msg))))))
 787
 788 (defun murk-command-join (params)
 789   (if params
 790       (let ((server (murk-context-server (murk-current-context))))
 791         (dolist (channel params)
 792           (murk-send-msg server (murk-msg nil nil "JOIN" channel))))
 793     (murk-display-notice nil "Usage: /join channel [channel2 ...]")))
 794
 795 (defun murk-command-part (params)
 796   (let* ((server (murk-context-server (murk-current-context)))
 797          (channel (if params
 798                       (car params)
 799                     (murk-context-channel (murk-current-context)))))
 800     (if channel
 801         (murk-send-msg server (murk-msg nil nil "PART" channel))
 802       (murk-display-error "No current channel to leave"))))
 803
 804 (defun murk-command-msg (params)
 805   (let ((server (murk-context-server (murk-current-context))))
 806     (if (and params (>= (length params) 2))
 807         (let ((to (car params))
 808               (text (string-join (cdr params) " ")))
 809           (murk-send-msg server (murk-msg nil nil "PRIVMSG" to text))
 810           (murk-display-message server
 811                                 (murk-connection-nick server)
 812                                 to text))
 813       (murk-display-notice nil "Usage: /msg <nick> <message>"))))
 814
 815 ;;; Command entering
 816 ;;
 817
 818 (defun murk-enter-string (string)
 819   (if (string-prefix-p "/" string)
 820       (pcase string
 821         ((rx (: "/" (let cmd-str (+ (not whitespace)))
 822                 (opt (+ whitespace)
 823                      (let params-str (+ anychar))
 824                      string-end)))
 825          (let ((command-row (assoc (upcase  cmd-str) murk-command-table #'equal))
 826                (params (if params-str
 827                            (split-string params-str nil t)
 828                          nil)))
 829            (if (and command-row (elt command-row 2))
 830                (funcall (elt command-row 2) params)
 831              (murk-send-msg
 832               (murk-context-server (murk-current-context))
 833               (murk-msg nil nil (upcase cmd-str) params)))))
 834         (_
 835          (murk-display-error "Badly formed command")))
 836     (unless (string-empty-p string)
 837       (let ((ctx (murk-current-context)))
 838         (if ctx
 839             (if (not (murk-server-context-p ctx))
 840                 (let ((server (murk-context-server ctx))
 841                       (channel (murk-context-channel ctx)))
 842                   (murk-send-msg server
 843                                  (murk-msg nil nil "PRIVMSG" channel string))
 844                   (murk-display-message server
 845                                         (murk-connection-nick server)
 846                                         channel string))
 847               (murk-display-error "No current channel"))
 848           (murk-display-error "No current context"))))))
 849
 850
 851 ;;; Command history
 852 ;;
 853
 854 (defvar murk-history nil
 855   "Commands and messages sent in current session.")
 856
 857 (defvar murk-history-index nil)
 858
 859 (defun murk-history-cycle (delta)
 860   (when murk-history
 861     (with-current-buffer "*murk*"
 862       (if murk-history-index
 863           (setq murk-history-index
 864                 (max 0
 865                      (min (- (length murk-history) 1)
 866                           (+ delta murk-history-index))))
 867         (setq murk-history-index 0))
 868       (delete-region murk-input-marker (point-max))
 869       (insert (elt murk-history murk-history-index)))))
 870
 871
 872 ;;; Interactive commands
 873 ;;
 874
 875 (defun murk-enter ()
 876   "Enter current contents of line after prompt."
 877   (interactive)
 878   (with-current-buffer "*murk*"
 879     (let ((line (buffer-substring murk-input-marker (point-max))))
 880       (push line murk-history)
 881       (setq murk-history-index nil)
 882       (let ((inhibit-read-only t))
 883         (delete-region murk-input-marker (point-max)))
 884       (murk-enter-string line))))
 885
 886 (defun murk-history-next ()
 887   (interactive)
 888   (murk-history-cycle -1))
 889
 890 (defun murk-history-prev ()
 891   (interactive)
 892   (murk-history-cycle +1))
 893
 894 (defun murk-cycle-contexts-forward ()
 895   (interactive)
 896   (murk-cycle-contexts)
 897   (murk-render-prompt))
 898
 899 (defun murk-cycle-contexts-reverse ()
 900   (interactive)
 901   (murk-cycle-contexts t)
 902   (murk-render-prompt))
 903
 904 (defun murk-complete-input ()
 905   (interactive)
 906   (let ((completion-ignore-case t))
 907     (when (>= (point) murk-input-marker)
 908       (pcase (buffer-substring murk-input-marker (point))
 909         ((rx (: "/" (let cmd-str (+ (not whitespace))) (+ " ") (* (not whitespace)) string-end))
 910          (let ((space-idx (save-excursion
 911                             (re-search-backward " " murk-input-marker t)))
 912                (table-row (assoc (upcase cmd-str) murk-command-table #'equal)))
 913            (if (and table-row (elt table-row 3))
 914                (let* ((completions-nospace (funcall (elt table-row 3)))
 915                       (completions (mapcar (lambda (el) (concat el " ")) completions-nospace)))
 916                  (completion-in-region (+ 1 space-idx) (point) completions)))))
 917         ((rx (: "/" (* (not whitespace)) string-end))
 918          (message (buffer-substring murk-input-marker (point)))
 919          (completion-in-region murk-input-marker (point)
 920                                (mapcar (lambda (row) (concat "/" (car row) " "))
 921                                        murk-command-table)))
 922         (_
 923          (let* ((end (max murk-input-marker (point)))
 924                 (space-idx (save-excursion
 925                              (re-search-backward " " murk-input-marker t)))
 926                 (start (if space-idx (+ 1 space-idx) murk-input-marker)))
 927            (unless (string-prefix-p "/" (buffer-substring start end))
 928              (let* ((users (murk-context-users (murk-current-context)))
 929                     (users-no@ (mapcar
 930                                 (lambda (u) (car (split-string u "@" t)))
 931                                 users)))
 932                (completion-in-region start end users-no@)))))))))
 933
 934 ;;; Mode
 935 ;;
 936
 937 (defvar murk-mode-map
 938   (let ((map (make-sparse-keymap)))
 939     (define-key map (kbd "RET") 'murk-enter)
 940     (define-key map (kbd "TAB") 'murk-complete-input)
 941     (define-key map (kbd "<C-up>") 'murk-history-prev)
 942     (define-key map (kbd "<C-down>") 'murk-history-next)
 943     (define-key map (kbd "<C-tab>") 'murk-cycle-contexts-forward)
 944     (define-key map (kbd "<C-S-iso-lefttab>") 'murk-cycle-contexts-reverse)
 945     (define-key map (kbd "<C-S-tab>") 'murk-cycle-contexts-reverse)
 946     (when (fboundp 'evil-define-key*)
 947       (evil-define-key* 'motion map
 948         (kbd "TAB") 'murk-complete-input))
 949     map))
 950
 951 (define-derived-mode murk-mode text-mode "murk"
 952   "Major mode for murk.")
 953
 954 (when (fboundp 'evil-set-initial-state)
 955   (evil-set-initial-state 'murk-mode 'insert))
 956
 957 ;;; Main start procedure
 958 ;;
 959
 960 (defun murk ()
 961   "Start murk or just switch to the murk buffer if one already exists."
 962   (interactive)
 963   (if (get-buffer "*murk*")
 964       (switch-to-buffer "*murk*")
 965     (switch-to-buffer "*murk*")
 966     (murk-mode)
 967     (murk-setup-buffer))
 968   "Started murk.")
 969
 970 ;;; murk.el ends here