murk.el

   1 ;;; MURK --- Multiserver Unibuffer iRc Klient -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2024 plugd
   4
   5 ;; Author: plugd <plugd@thelambdalab.xyz>
   6 ;; Created: 11 May 2024
   7 ;; Version: 0.0
   8 ;; Keywords: network
   9 ;; Homepage: http://thelambdalab.xyz/murk
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (provide 'murk)
  32
  33
  34 ;;; Customizations
  35
  36 (defgroup murk nil
  37   "Multiserver Unibuffer iRc Klient"
  38   :group 'network)
  39
  40 (defcustom murk-default-nick "plugd"
  41   "Default nick."
  42   :type '(string))
  43
  44 (defcustom murk-default-quit-msg "Bye"
  45   "Default quit message when none supplied."
  46   :type '(string))
  47
  48 (defcustom murk-networks
  49   '(("debug" "localhost" 6667 :notls)
  50     ("libera" "irc.libera.chat" 6697)
  51     ("tilde" "tilde.chat" 6697))
  52   "IRC networks."
  53   :type '(alist :key-type string))
  54
  55 (defcustom murk-display-header t
  56   "If non-nil, use buffer header to display current host and channel."
  57   :type '(boolean))
  58
  59
  60 ;;; Faces
  61 ;;
  62
  63 (defface murk-text
  64   '((t :inherit default))
  65   "Face used for murk text.")
  66
  67 (defface murk-prompt
  68   '((t :inherit font-lock-keyword-face))
  69   "Face used for the prompt.")
  70
  71 (defface murk-context
  72   '((t :inherit murk-context))
  73   "Face used for the context name in the prompt.")
  74
  75 (defface murk-faded
  76   '((t :inherit shadow))
  77   "Face used for faded murk text.")
  78
  79 (defface murk-timestamp
  80   '((t :inherit shadow))
  81   "Face used for timestamps.")
  82
  83 (defface murk-error
  84   '((t :inherit error))
  85   "Face used for murk error text.")
  86
  87 (defface murk-notice
  88   '((t :inherit warning))
  89   "Face used for murk notice text.")
  90
  91
  92 ;;; Global variables
  93 ;;
  94
  95 (defvar murk-version "Murk v0.0"
  96   "Value of this string is used in response to CTCP version queries.")
  97
  98 (defvar murk-notice-prefix "-!-")
  99 (defvar murk-error-prefix "!!!")
 100 (defvar murk-prompt-string ">")
 101
 102 (defvar murk-debug nil
 103   "If non-nil, enable debug mode.")
 104
 105
 106 ;;; Utility procedures
 107 ;;
 108
 109 (defun murk--filtered-join (&rest args)
 110   (string-join (seq-filter (lambda (el) el) args) " "))
 111
 112 (defun murk--as-string (obj)
 113   (if obj
 114       (with-output-to-string (princ obj))
 115     nil))
 116
 117
 118 ;;; Network processes
 119 ;;
 120
 121 (defvar murk-connection-table nil
 122   "An alist associating servers to connection information.
 123 This includes the process and the response string.")
 124
 125 (defun murk-connection-process (server)
 126   (elt (assoc server murk-connection-table) 1))
 127
 128 (defun murk-connection-nick (server)
 129   (elt (assoc server murk-connection-table) 2))
 130
 131 (defun murk-set-connection-nick (server nick)
 132   (setf (elt (assoc server murk-connection-table) 2) nick))
 133
 134 (defun murk-connection-response (server)
 135   (elt (assoc server murk-connection-table) 3))
 136
 137 (defun murk-set-connection-response (server string)
 138   (setf (elt (assoc server murk-connection-table) 3) string))
 139
 140 (defun murk-connection-new (server process nick)
 141   (add-to-list 'murk-connection-table
 142                (list server process nick "")))
 143
 144 (defun murk-connection-remove (server)
 145   (setq murk-connection-table (assoc-delete-all server murk-connection-table)))
 146
 147 (defun murk-make-server-filter (server)
 148   (lambda (_proc string)
 149     (dolist (line (split-string (concat (murk-connection-response server) string)
 150                                 "\n"))
 151       (if (string-suffix-p "\r" line)
 152           (murk-eval-msg-string server (string-trim line))
 153         (murk-set-connection-response server line)))))
 154
 155 (defun murk-make-server-sentinel (server)
 156   (lambda (_proc string)
 157     (unless (equal "open" (string-trim string))
 158       (murk-display-error "Disconnected from server.")
 159       (murk-connection-remove server)
 160       (murk-remove-server-contexts server)
 161       (murk-render-prompt))))
 162
 163 (defun murk-start-process (server)
 164   (let* ((row (assoc server murk-networks))
 165          (host (elt row 1))
 166          (port (elt row 2))
 167          (flags (seq-drop row 3)))
 168     (make-network-process :name (concat "murk-" server)
 169                           :host host
 170                           :service port
 171                           :family nil
 172                           :filter (murk-make-server-filter server)
 173                           :sentinel (murk-make-server-sentinel server)
 174                           :nowait nil
 175                           :tls-parameters (if (memq :notls flags)
 176                                               nil
 177                                             (cons 'gnutls-x509pki
 178                                                   (gnutls-boot-parameters
 179                                                    :type 'gnutls-x509pki
 180                                                    :hostname host)))
 181                           :buffer "*murk*")))
 182
 183 (defvar murk-ping-period 60)
 184
 185 ;; IDEA: Have a single ping timer which pings all connected hosts
 186
 187 (defun murk-connect (server)
 188   (if (assoc server murk-connection-table)
 189       (murk-display-error "Already connected to this network")
 190     (if (not (assoc server murk-networks))
 191         (murk-display-error "Network '" server "' is unknown.")
 192       (let ((proc (murk-start-process server)))
 193         (murk-connection-new server proc murk-default-nick))
 194       (murk-send-msg server (murk-msg nil nil "USER" murk-default-nick 0 "*" murk-default-nick))
 195       (murk-send-msg server (murk-msg nil nil "NICK" murk-default-nick))
 196       (murk-add-context (list server))
 197       (murk-render-prompt))))
 198
 199 (defun murk-send-msg (server msg)
 200   (if murk-debug
 201       (murk-display-string nil nil (murk-msg->string msg)))
 202   (let ((proc (murk-connection-process server)))
 203     (if (and proc (eq (process-status proc) 'open))
 204         (process-send-string proc (concat (murk-msg->string msg) "\r\n"))
 205       (murk-display-error "No server connection established"))))
 206
 207
 208 ;;; Server messages
 209 ;;
 210
 211 (defun murk-msg (tags src cmd &rest params)
 212   (list (murk--as-string tags)
 213         (murk--as-string src)
 214         (upcase (murk--as-string cmd))
 215         (mapcar #'murk--as-string
 216                 (if (and params (listp (elt params 0)))
 217                     (elt params 0)
 218                   params))))
 219
 220 (defun murk-msg-tags (msg) (elt msg 0))
 221 (defun murk-msg-src (msg) (elt msg 1))
 222 (defun murk-msg-cmd (msg) (elt msg 2))
 223 (defun murk-msg-params (msg) (elt msg 3))
 224 (defun murk-msg-trail (msg)
 225   (let ((params (murk-msg-params msg)))
 226     (if params
 227         (elt params (- (length params) 1)))))
 228
 229 (defvar murk-msg-regex
 230   (rx
 231    (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
 232         (* whitespace))
 233    (opt (: ":" (: (group (* (not (any space "!" "@"))))
 234                   (* (not (any space)))))
 235         (* whitespace))
 236    (group (: (* (not whitespace))))
 237    (* whitespace)
 238    (opt (group (+ not-newline))))
 239   "Regex used to parse IRC messages.
 240 Note that this regex is incomplete.  Noteably, we discard the non-nick
 241 portion of the source component of the message, as mURK doesn't use this.")
 242
 243 (defun murk-string->msg (string)
 244   (if (string-match murk-msg-regex string)
 245       (let* ((tags (match-string 1 string))
 246              (src (match-string 2 string))
 247              (cmd (upcase (match-string 3 string)))
 248              (params-str (match-string 4 string))
 249              (params
 250               (if params-str
 251                   (let* ((idx (cl-search ":" params-str))
 252                          (l (split-string (string-trim (substring params-str 0 idx))))
 253                          (r (if idx (list (substring params-str (+ 1 idx))) nil)))
 254                     (append l r))
 255                 nil)))
 256         (apply #'murk-msg (append (list tags src cmd) params)))
 257     (error "Failed to parse string %s" string)))
 258
 259 (defun murk-msg->string (msg)
 260   (let ((tags (murk-msg-tags msg))
 261         (src (murk-msg-src msg))
 262         (cmd (murk-msg-cmd msg))
 263         (params (murk-msg-params msg)))
 264     (murk--filtered-join
 265      (if tags (concat "@" tags) nil)
 266      (if src (concat ":" src) nil)
 267      cmd
 268      (if (> (length params) 1)
 269          (string-join (seq-take params (- (length params) 1)) " ")
 270        nil)
 271      (if (> (length params) 0)
 272          (concat ":" (elt params (- (length params) 1)))
 273        nil))))
 274
 275
 276 ;;; Contexts and Servers
 277 ;;
 278
 279 ;; A context is a list (server name ...) where name is a string
 280 ;; representing either a channel name or nick, and server is a symbol
 281 ;; identifying the server.
 282 ;;
 283 ;; Each server has a special context (server nil) used for messages
 284 ;; to/from the server itself.
 285
 286 (defvar murk-contexts nil
 287   "List of currently-available contexts.
 288 The head of this list is always the current context.")
 289
 290 (defun murk-current-context ()
 291   "Returns the current context."
 292   (if murk-contexts
 293       (car murk-contexts)
 294     nil))
 295
 296 (defun murk-contexts-equal (c1 c2)
 297   (if (murk-server-context-p c1)
 298       (and (murk-server-context-p c2)
 299            (equal (murk-context-server c1)
 300                   (murk-context-server c2)))
 301     (and (not (murk-server-context-p c2))
 302          (equal (seq-take c1 2)
 303                 (seq-take c2 2)))))
 304
 305 (defun murk-context-server (ctx) (elt ctx 0))
 306 (defun murk-context-name (ctx) (elt ctx 1))
 307 (defun murk-context-users (ctx) (seq-drop ctx 2))
 308 (defun murk-server-context-p (ctx) (not (cdr ctx)))
 309
 310 (defun murk-add-context (ctx)
 311   (add-to-list 'murk-contexts ctx))
 312
 313 (defun murk-remove-context (ctx)
 314   (setq murk-contexts
 315         (seq-remove
 316          (lambda (this-ctx)
 317            (murk-contexts-equal this-ctx ctx))
 318          murk-contexts)))
 319
 320 (defun murk-remove-server-contexts (server)
 321   (setq murk-contexts
 322         (assoc-delete-all server murk-contexts)))
 323
 324 (defun murk-context->string (ctx)
 325    (if (murk-server-context-p ctx)
 326        (concat "[" (murk-context-server ctx) "]")
 327      (concat (murk-context-name ctx) "@"
 328              (murk-context-server ctx))))
 329
 330 (defun murk-get-context (server &optional name)
 331   (if name
 332       (assoc server murk-contexts)
 333     (let ((test-ctx (list server name)))
 334       (seq-find (lambda (ctx)
 335                   (equal (seq-take ctx 2) test-ctx))
 336                 murk-contexts))))
 337
 338 (defun murk-cycle-contexts (&optional reverse)
 339   (setq murk-contexts
 340         (if reverse
 341             (let ((nminus1 (- (length murk-contexts) 1)))
 342               (cons
 343                (elt murk-contexts nminus1)
 344                (seq-take murk-contexts nminus1)))
 345           (append (cdr murk-contexts) (list (car murk-contexts))))))
 346
 347 ;;; Buffer
 348 ;;
 349
 350 (defvar murk-prompt-marker nil
 351   "Marker for prompt position in murk buffer.")
 352
 353 (defvar murk-input-marker nil
 354   "Marker for prompt position in murk buffer.")
 355
 356 (defun murk-render-prompt ()
 357   (with-current-buffer "*murk*"
 358     (let ((update-point (= murk-input-marker (point)))
 359           (update-window-points (mapcar (lambda (w)
 360                                           (list (= (window-point w) murk-input-marker)
 361                                                 w))
 362                                         (get-buffer-window-list nil nil t))))
 363       (save-excursion
 364         (set-marker-insertion-type murk-prompt-marker nil)
 365         (set-marker-insertion-type murk-input-marker t)
 366         (let ((inhibit-read-only t))
 367           (delete-region murk-prompt-marker murk-input-marker)
 368           (goto-char murk-prompt-marker)
 369           (insert
 370            (propertize (let ((ctx (murk-current-context)))
 371                          (if ctx
 372                              (murk-context->string ctx)
 373                            ""))
 374                        'face 'murk-context
 375                        'read-only t)
 376            (propertize murk-prompt-string
 377                        'face 'murk-prompt
 378                        'read-only t)
 379            (propertize " " ; Need this to be separate to mark it as rear-nonsticky
 380                        'read-only t
 381                        'rear-nonsticky t)))
 382         (set-marker-insertion-type murk-input-marker nil))
 383       (if update-point
 384           (goto-char murk-input-marker))
 385       (dolist (v update-window-points)
 386         (if (car v)
 387             (set-window-point (cadr v) murk-input-marker))))))
 388
 389 (defun murk-setup-header ()
 390   (with-current-buffer "*murk*"
 391     (setq-local header-line-format
 392                 '((:eval
 393                    (let* ((ctx (murk-current-context)))
 394                      (if ctx
 395                          (let ((server (murk-context-server ctx)))
 396                            (concat
 397                             "Network: " server ", "
 398                             (if (murk-server-context-p ctx)
 399                                 "Server"
 400                               (concat
 401                                "Channel: "
 402                                (murk-context-name ctx)
 403                                " ("
 404                                (number-to-string
 405                                 (length (murk-context-users ctx)))
 406                                ")"))))
 407                        "No connection")))))))
 408
 409 (defun murk-setup-buffer ()
 410   (with-current-buffer (get-buffer-create "*murk*")
 411     (setq-local scroll-conservatively 1)
 412     (setq-local buffer-invisibility-spec nil)
 413     (if (markerp murk-prompt-marker)
 414         (set-marker murk-prompt-marker (point-max))
 415       (setq murk-prompt-marker (point-max-marker)))
 416     (if (markerp murk-input-marker)
 417         (set-marker murk-input-marker (point-max))
 418       (setq murk-input-marker (point-max-marker)))
 419     (goto-char (point-max))
 420     (murk-render-prompt)
 421     (if murk-display-header
 422         (murk-setup-header))))
 423
 424 (defun murk-clear-buffer ()
 425   "Completely erase all non-prompt and non-input text from murk buffer."
 426   (with-current-buffer "*murk*"
 427     (let ((inhibit-read-only t))
 428       (delete-region (point-min) murk-prompt-marker))))
 429
 430
 431 ;;; Output formatting and highlighting
 432 ;;
 433
 434 (defun murk--fill-strings (col indent &rest strings)
 435   (with-temp-buffer
 436     (setq buffer-invisibility-spec nil)
 437     (let ((fill-column col)
 438           (adaptive-fill-regexp (rx-to-string `(= ,indent anychar))))
 439       (apply #'insert strings)
 440       (fill-region (point-min) (point-max) nil t)
 441       (buffer-string))))
 442
 443 (defun murk-display-string (context prefix &rest strings)
 444   (with-current-buffer "*murk*"
 445     (save-excursion
 446       (goto-char murk-prompt-marker)
 447       (let* ((inhibit-read-only t)
 448              (old-pos (marker-position murk-prompt-marker))
 449              (padded-timestamp (concat (format-time-string "%H:%M ")))
 450              (padded-prefix (if prefix (concat prefix " ") ""))
 451              (context-atom (if context (intern (murk-context->string context)) nil)))
 452         (insert-before-markers
 453          (murk--fill-strings
 454           80
 455           (+ (length padded-timestamp)
 456              (length padded-prefix))
 457           (propertize padded-timestamp
 458                       'face 'murk-timestamp
 459                       'read-only t
 460                       'context context
 461                       'invisible context-atom)
 462           (propertize padded-prefix
 463                       'read-only t
 464                       'context context
 465                       'invisible context-atom)
 466           (murk-add-formatting
 467            (propertize (concat (apply #'murk-buttonify-urls strings) "\n")
 468                        'read-only t
 469                        'context context
 470                        'invisible context-atom)))))))
 471   (murk-scroll-windows-to-last-line))
 472
 473 (defun murk-display-message (server from to text)
 474   (let ((context (if (string-prefix-p "#" to)
 475                      (murk-get-context server to)
 476                    (murk-get-context server))))
 477     (murk-display-string
 478      context
 479      (if (murk-server-context-p context)
 480          (concat "[" from " -> " to "]")
 481        (concat (murk-context->string context) " <" from ">"))
 482      text)))
 483
 484 (defun murk-display-notice (context &rest notices)
 485   (murk-display-string
 486    context
 487    (propertize murk-notice-prefix 'face 'murk-notice)
 488    (apply #'concat notices)))
 489
 490 (defun murk-display-error (&rest messages)
 491   (murk-display-string
 492    nil
 493    (propertize murk-error-prefix 'face 'murk-error)
 494    (apply #'concat messages)))
 495
 496 (defun murk--start-of-final-line ()
 497   (with-current-buffer "*murk*"
 498     (save-excursion
 499       (goto-char (point-max))
 500       (line-beginning-position))))
 501
 502 (defun murk-scroll-windows-to-last-line ()
 503   (with-current-buffer "*murk*"
 504     (dolist (window (get-buffer-window-list))
 505       (if (>= (window-point window) (murk--start-of-final-line))
 506           (with-selected-window window
 507             (recenter -1))))))
 508
 509 (defconst murk-url-regex
 510   (rx (:
 511        (group (+ alpha))
 512        "://"
 513        (group (or (+ (any alnum "." "-"))
 514                   (+ (any alnum ":"))))
 515        (opt (group (: ":" (+ digit))))
 516        (opt (group (: "/"
 517                       (opt
 518                        (* (any alnum "-/.,#:%=&_?~@+"))
 519                        (any alnum "-/#:%=&_~@+")))))))
 520   "Imperfect regex used to find URLs in plain text.")
 521
 522 (defun murk-click-url (button)
 523   (browse-url (button-get button 'url)))
 524
 525 (defun murk-buttonify-urls (&rest strings)
 526   "Turn substrings which look like urls in STRING into clickable buttons."
 527   (with-temp-buffer
 528     (apply #'insert strings)
 529     (goto-char (point-min))
 530     (while (re-search-forward murk-url-regex nil t)
 531       (let ((url (match-string 0)))
 532         (make-text-button (match-beginning 0)
 533                           (match-end 0)
 534                           'action #'murk-click-url
 535                           'url url
 536                           'follow-link t
 537                           'face 'button
 538                           'help-echo "Open URL in browser.")))
 539     (buffer-string)))
 540
 541 (defun murk-add-formatting (string)
 542   (with-temp-buffer
 543     (insert string)
 544     (goto-char (point-min))
 545     (let ((bold nil)
 546           (italics nil)
 547           (underline nil)
 548           (strikethrough nil)
 549           (prev-point (point)))
 550       (while (re-search-forward (rx (or (any "\x02\x1D\x1F\x1E\x0F")
 551                                         (: "\x03" (+ digit) (opt "," (* digit)))))
 552                                 nil t)
 553         (let ((beg (+ (match-beginning 0) 1)))
 554           (if bold
 555               (add-face-text-property prev-point beg '(:weight bold)))
 556           (if italics
 557               (add-face-text-property prev-point beg '(:slant italic)))
 558           (if underline
 559               (add-face-text-property prev-point beg '(:underline t)))
 560           (if strikethrough
 561               (add-face-text-property prev-point beg '(:strike-through t)))
 562           (pcase (match-string 0)
 563             ("\x02" (setq bold (not bold)))
 564             ("\x1D" (setq italics (not italics)))
 565             ("\x1F" (setq underline (not underline)))
 566             ("\x1E" (setq strikethrough (not strikethrough)))
 567             ("\x0F" ; Reset
 568              (setq bold nil)
 569              (setq italics nil)
 570              (setq underline nil)
 571              (setq strikethrough nil))
 572             (_))
 573           (delete-region (match-beginning 0) (match-end 0))
 574           (setq prev-point (point)))))
 575     (buffer-string)))
 576
 577
 578 ;;; Message evaluation
 579 ;;
 580
 581 (defun murk-eval-msg-string (server string)
 582   (if murk-debug
 583       (murk-display-string nil nil string))
 584   (let* ((msg (murk-string->msg string)))
 585     (pcase (murk-msg-cmd msg)
 586       ("PING"
 587        (murk-send-msg server
 588         (murk-msg nil nil "PONG" (murk-msg-params msg))))
 589
 590       ("PONG")
 591
 592       ("001"
 593        (let* ((params (murk-msg-params msg))
 594               (nick (elt params 0))
 595               (text (string-join (seq-drop params 1) " ")))
 596          (murk-set-connection-nick server nick)
 597          (murk-display-notice nil text)))
 598
 599       ((rx (= 3 (any digit)))
 600        (murk-display-notice nil (mapconcat 'identity (cdr (murk-msg-params msg)) " ")))
 601
 602       ((and "JOIN"
 603             (guard (equal (murk-connection-nick server)
 604                           (murk-msg-src msg))))
 605        (let ((channel (car (murk-msg-params msg))))
 606          (murk-add-context (list server channel))
 607          (murk-display-notice (murk-current-context)
 608                               "Joining channel " channel " on " server)
 609          (murk-render-prompt)))
 610
 611       ((and "PART"
 612             (guard (equal (murk-connection-nick server)
 613                           (murk-msg-src msg))))
 614        (let ((channel (car (murk-msg-params msg))))
 615          (murk-display-notice (murk-current-context) "Left channel " channel)
 616          (murk-remove-context (list server channel))
 617          (murk-render-prompt)))
 618
 619       ("QUIT"
 620        (let ((nick (murk-msg-src msg))
 621              (reason (mapconcat 'identity (murk-msg-params msg) " ")))
 622          (murk-del-user nick)
 623          (if murk-show-joins
 624              (murk-display-notice nil nick " quit: " reason))))
 625
 626       ("PRIVMSG"
 627        (let* ((from (murk-msg-src msg))
 628               (params (murk-msg-params msg))
 629               (to (car params))
 630               (text (cadr params)))
 631          (pcase text
 632            ("\01VERSION\01"
 633             (let ((version-string (concat murk-version " - running on GNU Emacs " emacs-version)))
 634               (murk-send-msg server
 635                              (murk-msg nil nil "NOTICE"
 636                                        (list from (concat "\01VERSION "
 637                                                           version-string
 638                                                           "\01")))))
 639             (murk-display-notice nil "CTCP version request received from "
 640                                  from " on " server))
 641
 642            ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
 643             (murk-send-msg server (murk-msg nil nil "NOTICE" (list from ping)))
 644             (murk-display-notice nil "CTCP ping received from " from " on " server))
 645
 646            ("\01USERINFO\01"
 647             (murk-display-notice nil "CTCP userinfo request from " from
 648                                  " on " server " (no response sent)"))
 649
 650            ("\01CLIENTINFO\01"
 651             (murk-display-notice nil "CTCP clientinfo request from " from
 652                                  " on " server " (no response sent)"))
 653
 654            ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
 655             (murk-display-action from to action-text))
 656
 657            (_
 658             (murk-display-message server from to text)))))
 659
 660       (_
 661        (murk-display-notice nil (murk-msg->string msg))))))
 662
 663 ;;; Commands
 664 ;;
 665
 666 (defvar murk-command-table
 667   '(("DEBUG" "Toggle debug mode on/off." murk-command-debug murk-boolean-completions)
 668     ("HEADER" "Toggle display of header." murk-command-header murk-boolean-completions)
 669     ("NETWORKS" "List known IRC networks." murk-command-networks)
 670     ("CONNECT" "Connect to an IRC network." murk-command-connect murk-network-completions)
 671     ("QUIT" "Disconnect from current network." murk-command-quit)
 672     ("JOIN" "Join one or more channels." murk-command-join)
 673     ("PART" "Leave channel." murk-command-part murk-context-completions)
 674     ("NICK" "Change nick." murk-command-nick)
 675     ("MSG" "Send private message to user." murk-command-msg murk-nick-completions)
 676     ("CLEAR" "Clear buffer text." murk-command-clear murk-context-completions)
 677     ("HELP" "Display help on client commands." murk-command-help murk-help-completions))
 678   "Table of commands explicitly supported by murk.")
 679
 680 (defun murk-boolean-completions ()
 681   '("on" "off"))
 682
 683 (defun murk-network-completions ()
 684   (mapcar (lambda (row) (car row)) murk-networks))
 685
 686 (defun murk-command-help (params)
 687   (if params
 688       (let* ((cmd-str (upcase (car params)))
 689              (row (assoc cmd-str murk-command-table #'equal)))
 690         (if row
 691             (progn
 692               (murk-display-notice nil "Help for \x02" cmd-str "\x02:")
 693               (murk-display-notice nil "  " (elt row 1)))
 694           (murk-display-notice nil "No such (client-interpreted) command.")))
 695     (murk-display-notice nil "Client-interpreted commands:")
 696     (dolist (row murk-command-table)
 697       (murk-display-notice nil "  \x02" (elt row 0) "\x02: " (elt row 1)))
 698     (murk-display-notice nil "Use /HELP COMMAND to display information about a specific command.")))
 699
 700 (defun murk-command-debug (params)
 701   (setq murk-debug
 702         (if params
 703             (if (equal (upcase (car params)) "ON")
 704                 t
 705               nil)
 706           (not murk-debug)))
 707   (murk-display-notice nil "Debug mode now " (if murk-debug "on" "off") "."))
 708
 709 (defun murk-command-header (params)
 710   (if
 711       (if params
 712           (equal (upcase (car params)) "ON")
 713         (not header-line-format))
 714       (progn
 715         (murk-setup-header)
 716         (murk-display-notice nil "Header enabled."))
 717     (setq-local header-line-format nil)
 718     (murk-display-notice nil "Header disabled.")))
 719
 720 (defun murk-command-clear (params)
 721   (if (not params)
 722       (murk-clear-buffer)
 723     (dolist (context params)
 724       (murk-clear-context context))))
 725
 726 (defun murk-command-connect (params)
 727   (if params
 728       (let ((network (car params)))
 729         (murk-display-notice nil "Attempting to connect to " network "...")
 730         (murk-connect network))
 731     (murk-display-notice nil "Usage: /connect <network>")))
 732
 733 (defun murk-command-networks (_params)
 734   (murk-display-notice nil "Currently-known networks:")
 735   (dolist (row murk-networks)
 736     (seq-let (network server port &rest _others) row
 737       (murk-display-notice nil "\t" network
 738                            " [" server
 739                            " " (number-to-string port) "]")))
 740   (murk-display-notice nil "(Modify the `murk-networks' variable to add more.)"))
 741
 742 (defun murk-command-quit (params)
 743   (let ((ctx (murk-current-context)))
 744     (if (not ctx)
 745         (murk-display-error "No current context")
 746       (let ((quit-msg (if params (string-join params " ") murk-default-quit-msg)))
 747         (murk-send-msg
 748          (murk-context-server ctx)
 749          (murk-msg nil nil "QUIT" quit-msg))))))
 750
 751 (defun murk-command-join (params)
 752   (if params
 753       (let ((server (murk-context-server (murk-current-context))))
 754         (dolist (channel params)
 755           (murk-send-msg server (murk-msg nil nil "JOIN" channel))))
 756     (murk-display-notice nil "Usage: /join channel [channel2 ...]")))
 757
 758 (defun murk-command-part (params)
 759   (let* ((server (murk-context-server (murk-current-context)))
 760          (channel (if params
 761                       (car params)
 762                     (murk-context-name (murk-current-context)))))
 763     (if channel
 764         (murk-send-msg server (murk-msg nil nil "PART" channel))
 765       (murk-display-error "No current channel to leave"))))
 766
 767 (defun murk-command-msg (params)
 768   (let ((server (murk-context-server (murk-current-context))))
 769     (if (and params (>= (length params) 2))
 770         (let ((to (car params))
 771               (text (string-join (cdr params) " ")))
 772           (murk-send-msg server (murk-msg nil nil "PRIVMSG" to text))
 773           (murk-display-message server
 774                                 (murk-connection-nick server)
 775                                 to text))
 776       (murk-display-notice nil "Usage: /msg <nick> <message>"))))
 777
 778 ;;; Command entering
 779 ;;
 780
 781 (defun murk-enter-string (string)
 782   (if (string-prefix-p "/" string)
 783       (pcase string
 784         ((rx (: "/" (let cmd-str (+ (not whitespace)))
 785                 (opt (+ whitespace)
 786                      (let params-str (+ anychar))
 787                      string-end)))
 788          (let ((command-row (assoc (upcase  cmd-str) murk-command-table #'equal))
 789                (params (if params-str
 790                            (split-string params-str nil t)
 791                          nil)))
 792            (if (and command-row (elt command-row 2))
 793                (funcall (elt command-row 2) params)
 794              (murk-send-msg
 795               (murk-context-server (murk-current-context))
 796               (murk-msg nil nil (upcase cmd-str) params)))))
 797         (_
 798          (murk-display-error "Badly formed command")))
 799     (unless (string-empty-p string)
 800       (if (murk-current-context)
 801           (let ((server (murk-context-server (murk-current-context))))
 802             (murk-send-msg server
 803                            (murk-msg nil nil "PRIVMSG"
 804                                      (murk-context-name (murk-current-context))
 805                                      string))
 806             (murk-display-message server
 807                                   (murk-connection-nick server)
 808                                   (murk-context->string (murk-current-context))
 809                                   string))
 810         (murk-display-error "No current context")))))
 811
 812
 813 ;;; Command history
 814 ;;
 815
 816 (defvar murk-history nil
 817   "Commands and messages sent in current session.")
 818
 819 (defvar murk-history-index nil)
 820
 821 (defun murk-history-cycle (delta)
 822   (when murk-history
 823     (with-current-buffer "*murk*"
 824       (if murk-history-index
 825           (setq murk-history-index
 826                 (max 0
 827                      (min (- (length murk-history) 1)
 828                           (+ delta murk-history-index))))
 829         (setq murk-history-index 0))
 830       (delete-region murk-input-marker (point-max))
 831       (insert (elt murk-history murk-history-index)))))
 832
 833
 834 ;;; Interactive commands
 835 ;;
 836
 837 (defun murk-enter ()
 838   "Enter current contents of line after prompt."
 839   (interactive)
 840   (with-current-buffer "*murk*"
 841     (let ((line (buffer-substring murk-input-marker (point-max))))
 842       (push line murk-history)
 843       (setq murk-history-index nil)
 844       (let ((inhibit-read-only t))
 845         (delete-region murk-input-marker (point-max)))
 846       (murk-enter-string line))))
 847
 848 (defun murk-history-next ()
 849   (interactive)
 850   (murk-history-cycle -1))
 851
 852 (defun murk-history-prev ()
 853   (interactive)
 854   (murk-history-cycle +1))
 855
 856 (defun murk-complete-input ()
 857   (interactive)
 858   (let ((completion-ignore-case t))
 859     (when (>= (point) murk-input-marker)
 860       (pcase (buffer-substring murk-input-marker (point))
 861         ((rx (: "/" (let cmd-str (+ (not whitespace))) (+ " ") (* (not whitespace)) string-end))
 862          (let ((space-idx (save-excursion
 863                             (re-search-backward " " murk-input-marker t)))
 864                (table-row (assoc (upcase cmd-str) murk-command-table #'equal)))
 865            (if (and table-row (elt table-row 3))
 866                (let* ((completions-nospace (funcall (elt table-row 3)))
 867                       (completions (mapcar (lambda (el) (concat el " ")) completions-nospace)))
 868                  (completion-in-region (+ 1 space-idx) (point) completions)))))
 869         ((rx (: "/" (* (not whitespace)) string-end))
 870          (message (buffer-substring murk-input-marker (point)))
 871          (completion-in-region murk-input-marker (point)
 872                                (mapcar (lambda (row) (concat "/" (car row) " "))
 873                                        murk-command-table)))
 874         (_
 875          (let* ((end (max murk-input-marker (point)))
 876                 (space-idx (save-excursion
 877                              (re-search-backward " " murk-input-marker t)))
 878                 (start (if space-idx (+ 1 space-idx) murk-input-marker)))
 879            (unless (string-prefix-p "/" (buffer-substring start end))
 880              (let* ((users (murk-get-context-users (murk-current-context)))
 881                     (users-no@ (mapcar
 882                                 (lambda (u) (car (split-string u "@" t)))
 883                                 users)))
 884                (completion-in-region start end users-no@)))))))))
 885
 886 ;;; Mode
 887 ;;
 888
 889 (defvar murk-mode-map
 890   (let ((map (make-sparse-keymap)))
 891     (define-key map (kbd "RET") 'murk-enter)
 892     (define-key map (kbd "TAB") 'murk-complete-input)
 893     (define-key map (kbd "<C-up>") 'murk-history-prev)
 894     (define-key map (kbd "<C-down>") 'murk-history-next)
 895     (define-key map (kbd "<C-tab>") 'murk-cycle-contexts-forward)
 896     (define-key map (kbd "<C-S-tab>") 'murk-cycle-contexts-reverse)
 897     (when (fboundp 'evil-define-key*)
 898       (evil-define-key* 'motion map
 899         (kbd "TAB") 'murk-complete-input))
 900     map))
 901
 902 (define-derived-mode murk-mode text-mode "murk"
 903   "Major mode for murk.")
 904
 905 (when (fboundp 'evil-set-initial-state)
 906   (evil-set-initial-state 'murk-mode 'insert))
 907
 908 ;;; Main start procedure
 909 ;;
 910
 911 (defun murk ()
 912   "Start murk or just switch to the murk buffer if one already exists."
 913   (interactive)
 914   (if (get-buffer "*murk*")
 915       (switch-to-buffer "*murk*")
 916     (switch-to-buffer "*murk*")
 917     (murk-mode)
 918     (murk-setup-buffer))
 919   "Started murk.")
 920
 921
 922 ;;; murk.el ends here