murk.el

   1 ;;; murk.el --- Multiserver Unibuffer iRc Klient -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2024 plugd
   4
   5 ;; Author: plugd <plugd@thelambdalab.xyz>
   6 ;; Created: 11 May 2024
   7 ;; Version: 0.0
   8 ;; Homepage: http://thelambdalab.xyz/murk
   9 ;; Keywords: comm
  10 ;; Package-Requires: ((emacs "26.1"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; A very simple IRC server which uses only a single buffer.
  30
  31 ;;; Code:
  32
  33 (provide 'murk)
  34
  35
  36 ;;; Customizations
  37
  38 (defgroup murk nil
  39   "Multiserver Unibuffer iRc Klient"
  40   :group 'network)
  41
  42 (defcustom murk-default-nick "plugd"
  43   "Default nick."
  44   :type '(string))
  45
  46 (defcustom murk-default-quit-msg "Bye"
  47   "Default quit message when none supplied."
  48   :type '(string))
  49
  50 (defcustom murk-networks
  51   '(("debug" "localhost" 6667 :notls)
  52     ("libera" "irc.libera.chat" 6697)
  53     ("tilde" "tilde.chat" 6697))
  54   "IRC networks."
  55   :type '(alist :key-type string))
  56
  57 (defcustom murk-display-header t
  58   "If non-nil, use buffer header to display current host and channel."
  59   :type '(boolean))
  60
  61
  62 ;;; Faces
  63 ;;
  64
  65 (defface murk-text
  66   '((t :inherit default))
  67   "Face used for murk text.")
  68
  69 (defface murk-prompt
  70   '((t :inherit font-lock-keyword-face))
  71   "Face used for the prompt.")
  72
  73 (defface murk-context
  74   '((t :inherit murk-context))
  75   "Face used for the context name in the prompt.")
  76
  77 (defface murk-faded
  78   '((t :inherit shadow))
  79   "Face used for faded murk text.")
  80
  81 (defface murk-timestamp
  82   '((t :inherit shadow))
  83   "Face used for timestamps.")
  84
  85 (defface murk-error
  86   '((t :inherit error))
  87   "Face used for murk error text.")
  88
  89 (defface murk-notice
  90   '((t :inherit warning))
  91   "Face used for murk notice text.")
  92
  93
  94 ;;; Global variables
  95 ;;
  96
  97 (defvar murk-version "Murk v0.0"
  98   "Value of this string is used in response to CTCP version queries.")
  99
 100 (defvar murk-notice-prefix "-!-")
 101 (defvar murk-error-prefix "!!!")
 102 (defvar murk-prompt-string ">")
 103
 104 (defvar murk-debug nil
 105   "If non-nil, enable debug mode.")
 106
 107
 108 ;;; Utility procedures
 109 ;;
 110
 111 (defun murk--filtered-join (&rest args)
 112   (string-join (seq-filter (lambda (el) el) args) " "))
 113
 114 (defun murk--as-string (obj)
 115   (if obj
 116       (with-output-to-string (princ obj))
 117     nil))
 118
 119
 120 ;;; Network processes
 121 ;;
 122
 123 (defvar murk-connection-table nil
 124   "An alist associating servers to connection information.
 125 This includes the process and the response string.")
 126
 127 (defun murk-connection-process (server)
 128   (elt (assoc server murk-connection-table) 1))
 129
 130 (defun murk-connection-nick (server)
 131   (elt (assoc server murk-connection-table) 2))
 132
 133 (defun murk-set-connection-nick (server nick)
 134   (setf (elt (assoc server murk-connection-table) 2) nick))
 135
 136 (defun murk-connection-response (server)
 137   (elt (assoc server murk-connection-table) 3))
 138
 139 (defun murk-set-connection-response (server string)
 140   (setf (elt (assoc server murk-connection-table) 3) string))
 141
 142 (defun murk-connection-new (server process nick)
 143   (add-to-list 'murk-connection-table
 144                (list server process nick "")))
 145
 146 (defun murk-connection-remove (server)
 147   (setq murk-connection-table
 148         (seq-remove (lambda (row) (equal (car row) server))
 149                     murk-connection-table)))
 150
 151 (defun murk-make-server-filter (server)
 152   (lambda (_proc string)
 153     (dolist (line (split-string (concat (murk-connection-response server) string)
 154                                 "\n"))
 155       (if (string-suffix-p "\r" line)
 156           (murk-eval-msg-string server (string-trim line))
 157         (murk-set-connection-response server line)))))
 158
 159 (defun murk-make-server-sentinel (server)
 160   (lambda (_proc string)
 161     (unless (equal "open" (string-trim string))
 162       (murk-display-error "Disconnected from server.")
 163       (murk-connection-remove server)
 164       (murk-remove-server-contexts server)
 165       (murk-render-prompt))))
 166
 167 (defun murk-start-process (server)
 168   (let* ((row (assoc server murk-networks))
 169          (host (elt row 1))
 170          (port (elt row 2))
 171          (flags (seq-drop row 3)))
 172     (make-network-process :name (concat "murk-" server)
 173                           :host host
 174                           :service port
 175                           :family nil
 176                           :filter (murk-make-server-filter server)
 177                           :sentinel (murk-make-server-sentinel server)
 178                           :nowait nil
 179                           :tls-parameters (if (memq :notls flags)
 180                                               nil
 181                                             (cons 'gnutls-x509pki
 182                                                   (gnutls-boot-parameters
 183                                                    :type 'gnutls-x509pki
 184                                                    :hostname host)))
 185                           :buffer "*murk*")))
 186
 187 (defvar murk-ping-period 60)
 188
 189 ;; IDEA: Have a single ping timer which pings all connected hosts
 190
 191 (defun murk-connect (server)
 192   (if (assoc server murk-connection-table)
 193       (murk-display-error "Already connected to this network")
 194     (if (not (assoc server murk-networks))
 195         (murk-display-error "Network '" server "' is unknown.")
 196       (let ((proc (murk-start-process server)))
 197         (murk-connection-new server proc murk-default-nick))
 198       (murk-send-msg server (murk-msg nil nil "USER" murk-default-nick 0 "*" murk-default-nick))
 199       (murk-send-msg server (murk-msg nil nil "NICK" murk-default-nick))
 200       (murk-add-context (list server))
 201       (murk-render-prompt))))
 202
 203 (defun murk-send-msg (server msg)
 204   (if murk-debug
 205       (murk-display-string nil nil (murk-msg->string msg)))
 206   (let ((proc (murk-connection-process server)))
 207     (if (and proc (eq (process-status proc) 'open))
 208         (process-send-string proc (concat (murk-msg->string msg) "\r\n"))
 209       (murk-display-error "No server connection established"))))
 210
 211
 212 ;;; Server messages
 213 ;;
 214
 215 (defun murk-msg (tags src cmd &rest params)
 216   (list (murk--as-string tags)
 217         (murk--as-string src)
 218         (upcase (murk--as-string cmd))
 219         (mapcar #'murk--as-string
 220                 (if (and params (listp (elt params 0)))
 221                     (elt params 0)
 222                   params))))
 223
 224 (defun murk-msg-tags (msg) (elt msg 0))
 225 (defun murk-msg-src (msg) (elt msg 1))
 226 (defun murk-msg-cmd (msg) (elt msg 2))
 227 (defun murk-msg-params (msg) (elt msg 3))
 228 (defun murk-msg-trail (msg)
 229   (let ((params (murk-msg-params msg)))
 230     (if params
 231         (elt params (- (length params) 1)))))
 232
 233 (defvar murk-msg-regex
 234   (rx
 235    (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
 236         (* whitespace))
 237    (opt (: ":" (: (group (* (not (any space "!" "@"))))
 238                   (* (not (any space)))))
 239         (* whitespace))
 240    (group (: (* (not whitespace))))
 241    (* whitespace)
 242    (opt (group (+ not-newline))))
 243   "Regex used to parse IRC messages.
 244 Note that this regex is incomplete.  Noteably, we discard the non-nick
 245 portion of the source component of the message, as mURK doesn't use this.")
 246
 247 (defun murk-string->msg (string)
 248   (if (string-match murk-msg-regex string)
 249       (let* ((tags (match-string 1 string))
 250              (src (match-string 2 string))
 251              (cmd (upcase (match-string 3 string)))
 252              (params-str (match-string 4 string))
 253              (params
 254               (if params-str
 255                   (let* ((idx (seq-position params-str ?:))
 256                          (l (split-string (string-trim (substring params-str 0 idx))))
 257                          (r (if idx (list (substring params-str (+ 1 idx))) nil)))
 258                     (append l r))
 259                 nil)))
 260         (apply #'murk-msg (append (list tags src cmd) params)))
 261     (error "Failed to parse string %s" string)))
 262
 263 (defun murk-msg->string (msg)
 264   (let ((tags (murk-msg-tags msg))
 265         (src (murk-msg-src msg))
 266         (cmd (murk-msg-cmd msg))
 267         (params (murk-msg-params msg)))
 268     (murk--filtered-join
 269      (if tags (concat "@" tags) nil)
 270      (if src (concat ":" src) nil)
 271      cmd
 272      (if (> (length params) 1)
 273          (string-join (seq-take params (- (length params) 1)) " ")
 274        nil)
 275      (if (> (length params) 0)
 276          (concat ":" (elt params (- (length params) 1)))
 277        nil))))
 278
 279
 280 ;;; Contexts and Servers
 281 ;;
 282
 283 ;; A context is a list (server name ...) where name is a string
 284 ;; representing either a channel name or nick, and server is a symbol
 285 ;; identifying the server.
 286 ;;
 287 ;; Each server has a special context (server nil) used for messages
 288 ;; to/from the server itself.
 289
 290 (defvar murk-contexts nil
 291   "List of currently-available contexts.
 292 The head of this list is always the current context.")
 293
 294 (defun murk-current-context ()
 295   "Returns the current context."
 296   (if murk-contexts
 297       (car murk-contexts)
 298     nil))
 299
 300 (defun murk-contexts-equal (c1 c2)
 301   (if (murk-server-context-p c1)
 302       (and (murk-server-context-p c2)
 303            (equal (murk-context-server c1)
 304                   (murk-context-server c2)))
 305     (and (not (murk-server-context-p c2))
 306          (equal (seq-take c1 2)
 307                 (seq-take c2 2)))))
 308
 309 (defun murk-context-server (ctx) (elt ctx 0))
 310 (defun murk-context-name (ctx) (elt ctx 1))
 311 (defun murk-context-users (ctx) (seq-drop ctx 2))
 312 (defun murk-server-context-p (ctx) (not (cdr ctx)))
 313
 314 (defun murk-add-context (ctx)
 315   (add-to-list 'murk-contexts ctx))
 316
 317 (defun murk-remove-context (ctx)
 318   (setq murk-contexts
 319         (seq-remove
 320          (lambda (this-ctx)
 321            (murk-contexts-equal this-ctx ctx))
 322          murk-contexts)))
 323
 324 (defun murk-remove-server-contexts (server)
 325   (setq murk-contexts
 326         (seq-remove (lambda (row) (equal (car row) server))
 327                     murk-contexts)))
 328
 329 (defun murk-context->string (ctx)
 330    (if (murk-server-context-p ctx)
 331        (concat "[" (murk-context-server ctx) "]")
 332      (concat (murk-context-name ctx) "@"
 333              (murk-context-server ctx))))
 334
 335 (defun murk-get-context (server &optional name)
 336   (if name
 337       (assoc server murk-contexts)
 338     (let ((test-ctx (list server name)))
 339       (seq-find (lambda (ctx)
 340                   (equal (seq-take ctx 2) test-ctx))
 341                 murk-contexts))))
 342
 343 (defun murk-cycle-contexts (&optional reverse)
 344   (setq murk-contexts
 345         (if reverse
 346             (let ((nminus1 (- (length murk-contexts) 1)))
 347               (cons
 348                (elt murk-contexts nminus1)
 349                (seq-take murk-contexts nminus1)))
 350           (append (cdr murk-contexts) (list (car murk-contexts))))))
 351
 352 ;;; Buffer
 353 ;;
 354
 355 (defvar murk-prompt-marker nil
 356   "Marker for prompt position in murk buffer.")
 357
 358 (defvar murk-input-marker nil
 359   "Marker for prompt position in murk buffer.")
 360
 361 (defun murk-render-prompt ()
 362   (with-current-buffer "*murk*"
 363     (let ((update-point (= murk-input-marker (point)))
 364           (update-window-points (mapcar (lambda (w)
 365                                           (list (= (window-point w) murk-input-marker)
 366                                                 w))
 367                                         (get-buffer-window-list nil nil t))))
 368       (save-excursion
 369         (set-marker-insertion-type murk-prompt-marker nil)
 370         (set-marker-insertion-type murk-input-marker t)
 371         (let ((inhibit-read-only t))
 372           (delete-region murk-prompt-marker murk-input-marker)
 373           (goto-char murk-prompt-marker)
 374           (insert
 375            (propertize (let ((ctx (murk-current-context)))
 376                          (if ctx
 377                              (murk-context->string ctx)
 378                            ""))
 379                        'face 'murk-context
 380                        'read-only t)
 381            (propertize murk-prompt-string
 382                        'face 'murk-prompt
 383                        'read-only t)
 384            (propertize " " ; Need this to be separate to mark it as rear-nonsticky
 385                        'read-only t
 386                        'rear-nonsticky t)))
 387         (set-marker-insertion-type murk-input-marker nil))
 388       (if update-point
 389           (goto-char murk-input-marker))
 390       (dolist (v update-window-points)
 391         (if (car v)
 392             (set-window-point (cadr v) murk-input-marker))))))
 393
 394 (defun murk-setup-header ()
 395   (with-current-buffer "*murk*"
 396     (setq-local header-line-format
 397                 '((:eval
 398                    (let* ((ctx (murk-current-context)))
 399                      (if ctx
 400                          (let ((server (murk-context-server ctx)))
 401                            (concat
 402                             "Network: " server ", "
 403                             (if (murk-server-context-p ctx)
 404                                 "Server"
 405                               (concat
 406                                "Channel: "
 407                                (murk-context-name ctx)
 408                                " ("
 409                                (number-to-string
 410                                 (length (murk-context-users ctx)))
 411                                ")"))))
 412                        "No connection")))))))
 413
 414 (defun murk-setup-buffer ()
 415   (with-current-buffer (get-buffer-create "*murk*")
 416     (setq-local scroll-conservatively 1)
 417     (setq-local buffer-invisibility-spec nil)
 418     (if (markerp murk-prompt-marker)
 419         (set-marker murk-prompt-marker (point-max))
 420       (setq murk-prompt-marker (point-max-marker)))
 421     (if (markerp murk-input-marker)
 422         (set-marker murk-input-marker (point-max))
 423       (setq murk-input-marker (point-max-marker)))
 424     (goto-char (point-max))
 425     (murk-render-prompt)
 426     (if murk-display-header
 427         (murk-setup-header))))
 428
 429 (defun murk-clear-buffer ()
 430   "Completely erase all non-prompt and non-input text from murk buffer."
 431   (with-current-buffer "*murk*"
 432     (let ((inhibit-read-only t))
 433       (delete-region (point-min) murk-prompt-marker))))
 434
 435
 436 ;;; Output formatting and highlighting
 437 ;;
 438
 439 (defun murk--fill-strings (col indent &rest strings)
 440   (with-temp-buffer
 441     (setq buffer-invisibility-spec nil)
 442     (let ((fill-column col)
 443           (adaptive-fill-regexp (rx-to-string `(= ,indent anychar))))
 444       (apply #'insert strings)
 445       (fill-region (point-min) (point-max) nil t)
 446       (buffer-string))))
 447
 448 (defun murk-display-string (context prefix &rest strings)
 449   (with-current-buffer "*murk*"
 450     (save-excursion
 451       (goto-char murk-prompt-marker)
 452       (let* ((inhibit-read-only t)
 453              (old-pos (marker-position murk-prompt-marker))
 454              (padded-timestamp (concat (format-time-string "%H:%M ")))
 455              (padded-prefix (if prefix (concat prefix " ") ""))
 456              (context-atom (if context (intern (murk-context->string context)) nil)))
 457         (insert-before-markers
 458          (murk--fill-strings
 459           80
 460           (+ (length padded-timestamp)
 461              (length padded-prefix))
 462           (propertize padded-timestamp
 463                       'face 'murk-timestamp
 464                       'read-only t
 465                       'context context
 466                       'invisible context-atom)
 467           (propertize padded-prefix
 468                       'read-only t
 469                       'context context
 470                       'invisible context-atom)
 471           (murk-add-formatting
 472            (propertize (concat (apply #'murk-buttonify-urls strings) "\n")
 473                        'read-only t
 474                        'context context
 475                        'invisible context-atom)))))))
 476   (murk-scroll-windows-to-last-line))
 477
 478 (defun murk-display-message (server from to text)
 479   (let ((context (if (string-prefix-p "#" to)
 480                      (murk-get-context server to)
 481                    (murk-get-context server))))
 482     (murk-display-string
 483      context
 484      (if (murk-server-context-p context)
 485          (concat "[" from " -> " to "]")
 486        (concat (murk-context->string context) " <" from ">"))
 487      text)))
 488
 489 (defun murk-display-notice (context &rest notices)
 490   (murk-display-string
 491    context
 492    (propertize murk-notice-prefix 'face 'murk-notice)
 493    (apply #'concat notices)))
 494
 495 (defun murk-display-error (&rest messages)
 496   (murk-display-string
 497    nil
 498    (propertize murk-error-prefix 'face 'murk-error)
 499    (apply #'concat messages)))
 500
 501 (defun murk--start-of-final-line ()
 502   (with-current-buffer "*murk*"
 503     (save-excursion
 504       (goto-char (point-max))
 505       (line-beginning-position))))
 506
 507 (defun murk-scroll-windows-to-last-line ()
 508   (with-current-buffer "*murk*"
 509     (dolist (window (get-buffer-window-list))
 510       (if (>= (window-point window) (murk--start-of-final-line))
 511           (with-selected-window window
 512             (recenter -1))))))
 513
 514 (defconst murk-url-regex
 515   (rx (:
 516        (group (+ alpha))
 517        "://"
 518        (group (or (+ (any alnum "." "-"))
 519                   (+ (any alnum ":"))))
 520        (opt (group (: ":" (+ digit))))
 521        (opt (group (: "/"
 522                       (opt
 523                        (* (any alnum "-/.,#:%=&_?~@+"))
 524                        (any alnum "-/#:%=&_~@+")))))))
 525   "Imperfect regex used to find URLs in plain text.")
 526
 527 (defun murk-click-url (button)
 528   (browse-url (button-get button 'url)))
 529
 530 (defun murk-buttonify-urls (&rest strings)
 531   "Turn substrings which look like urls in STRING into clickable buttons."
 532   (with-temp-buffer
 533     (apply #'insert strings)
 534     (goto-char (point-min))
 535     (while (re-search-forward murk-url-regex nil t)
 536       (let ((url (match-string 0)))
 537         (make-text-button (match-beginning 0)
 538                           (match-end 0)
 539                           'action #'murk-click-url
 540                           'url url
 541                           'follow-link t
 542                           'face 'button
 543                           'help-echo "Open URL in browser.")))
 544     (buffer-string)))
 545
 546 (defun murk-add-formatting (string)
 547   (with-temp-buffer
 548     (insert string)
 549     (goto-char (point-min))
 550     (let ((bold nil)
 551           (italics nil)
 552           (underline nil)
 553           (strikethrough nil)
 554           (prev-point (point)))
 555       (while (re-search-forward (rx (or (any "\x02\x1D\x1F\x1E\x0F")
 556                                         (: "\x03" (+ digit) (opt "," (* digit)))))
 557                                 nil t)
 558         (let ((beg (+ (match-beginning 0) 1)))
 559           (if bold
 560               (add-face-text-property prev-point beg '(:weight bold)))
 561           (if italics
 562               (add-face-text-property prev-point beg '(:slant italic)))
 563           (if underline
 564               (add-face-text-property prev-point beg '(:underline t)))
 565           (if strikethrough
 566               (add-face-text-property prev-point beg '(:strike-through t)))
 567           (pcase (match-string 0)
 568             ("\x02" (setq bold (not bold)))
 569             ("\x1D" (setq italics (not italics)))
 570             ("\x1F" (setq underline (not underline)))
 571             ("\x1E" (setq strikethrough (not strikethrough)))
 572             ("\x0F" ; Reset
 573              (setq bold nil)
 574              (setq italics nil)
 575              (setq underline nil)
 576              (setq strikethrough nil))
 577             (_))
 578           (delete-region (match-beginning 0) (match-end 0))
 579           (setq prev-point (point)))))
 580     (buffer-string)))
 581
 582
 583 ;;; Message evaluation
 584 ;;
 585
 586 (defun murk-eval-msg-string (server string)
 587   (if murk-debug
 588       (murk-display-string nil nil string))
 589   (let* ((msg (murk-string->msg string)))
 590     (pcase (murk-msg-cmd msg)
 591       ("PING"
 592        (murk-send-msg server
 593         (murk-msg nil nil "PONG" (murk-msg-params msg))))
 594
 595       ("PONG")
 596
 597       ("001"
 598        (let* ((params (murk-msg-params msg))
 599               (nick (elt params 0))
 600               (text (string-join (seq-drop params 1) " ")))
 601          (murk-set-connection-nick server nick)
 602          (murk-display-notice nil text)))
 603
 604       ((rx (= 3 (any digit)))
 605        (murk-display-notice nil (mapconcat 'identity (cdr (murk-msg-params msg)) " ")))
 606
 607       ((and "JOIN"
 608             (guard (equal (murk-connection-nick server)
 609                           (murk-msg-src msg))))
 610        (let ((channel (car (murk-msg-params msg))))
 611          (murk-add-context (list server channel))
 612          (murk-display-notice (murk-current-context)
 613                               "Joining channel " channel " on " server)
 614          (murk-render-prompt)))
 615
 616       ((and "PART"
 617             (guard (equal (murk-connection-nick server)
 618                           (murk-msg-src msg))))
 619        (let ((channel (car (murk-msg-params msg))))
 620          (murk-display-notice (murk-current-context) "Left channel " channel)
 621          (murk-remove-context (list server channel))
 622          (murk-render-prompt)))
 623
 624       ("QUIT"
 625        (let ((nick (murk-msg-src msg))
 626              (reason (mapconcat 'identity (murk-msg-params msg) " ")))
 627          (murk-del-user nick)
 628          (if murk-show-joins
 629              (murk-display-notice nil nick " quit: " reason))))
 630
 631       ("PRIVMSG"
 632        (let* ((from (murk-msg-src msg))
 633               (params (murk-msg-params msg))
 634               (to (car params))
 635               (text (cadr params)))
 636          (pcase text
 637            ("\01VERSION\01"
 638             (let ((version-string (concat murk-version " - running on GNU Emacs " emacs-version)))
 639               (murk-send-msg server
 640                              (murk-msg nil nil "NOTICE"
 641                                        (list from (concat "\01VERSION "
 642                                                           version-string
 643                                                           "\01")))))
 644             (murk-display-notice nil "CTCP version request received from "
 645                                  from " on " server))
 646
 647            ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
 648             (murk-send-msg server (murk-msg nil nil "NOTICE" (list from ping)))
 649             (murk-display-notice nil "CTCP ping received from " from " on " server))
 650
 651            ("\01USERINFO\01"
 652             (murk-display-notice nil "CTCP userinfo request from " from
 653                                  " on " server " (no response sent)"))
 654
 655            ("\01CLIENTINFO\01"
 656             (murk-display-notice nil "CTCP clientinfo request from " from
 657                                  " on " server " (no response sent)"))
 658
 659            ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
 660             (murk-display-action from to action-text))
 661
 662            (_
 663             (murk-display-message server from to text)))))
 664
 665       (_
 666        (murk-display-notice nil (murk-msg->string msg))))))
 667
 668 ;;; Commands
 669 ;;
 670
 671 (defvar murk-command-table
 672   '(("DEBUG" "Toggle debug mode on/off." murk-command-debug murk-boolean-completions)
 673     ("HEADER" "Toggle display of header." murk-command-header murk-boolean-completions)
 674     ("NETWORKS" "List known IRC networks." murk-command-networks)
 675     ("CONNECT" "Connect to an IRC network." murk-command-connect murk-network-completions)
 676     ("QUIT" "Disconnect from current network." murk-command-quit)
 677     ("JOIN" "Join one or more channels." murk-command-join)
 678     ("PART" "Leave channel." murk-command-part murk-context-completions)
 679     ("NICK" "Change nick." murk-command-nick)
 680     ("MSG" "Send private message to user." murk-command-msg murk-nick-completions)
 681     ("CLEAR" "Clear buffer text." murk-command-clear murk-context-completions)
 682     ("HELP" "Display help on client commands." murk-command-help murk-help-completions))
 683   "Table of commands explicitly supported by murk.")
 684
 685 (defun murk-boolean-completions ()
 686   '("on" "off"))
 687
 688 (defun murk-network-completions ()
 689   (mapcar (lambda (row) (car row)) murk-networks))
 690
 691 (defun murk-command-help (params)
 692   (if params
 693       (let* ((cmd-str (upcase (car params)))
 694              (row (assoc cmd-str murk-command-table #'equal)))
 695         (if row
 696             (progn
 697               (murk-display-notice nil "Help for \x02" cmd-str "\x02:")
 698               (murk-display-notice nil "  " (elt row 1)))
 699           (murk-display-notice nil "No such (client-interpreted) command.")))
 700     (murk-display-notice nil "Client-interpreted commands:")
 701     (dolist (row murk-command-table)
 702       (murk-display-notice nil "  \x02" (elt row 0) "\x02: " (elt row 1)))
 703     (murk-display-notice nil "Use /HELP COMMAND to display information about a specific command.")))
 704
 705 (defun murk-command-debug (params)
 706   (setq murk-debug
 707         (if params
 708             (if (equal (upcase (car params)) "ON")
 709                 t
 710               nil)
 711           (not murk-debug)))
 712   (murk-display-notice nil "Debug mode now " (if murk-debug "on" "off") "."))
 713
 714 (defun murk-command-header (params)
 715   (if
 716       (if params
 717           (equal (upcase (car params)) "ON")
 718         (not header-line-format))
 719       (progn
 720         (murk-setup-header)
 721         (murk-display-notice nil "Header enabled."))
 722     (setq-local header-line-format nil)
 723     (murk-display-notice nil "Header disabled.")))
 724
 725 (defun murk-command-clear (params)
 726   (if (not params)
 727       (murk-clear-buffer)
 728     (dolist (context params)
 729       (murk-clear-context context))))
 730
 731 (defun murk-command-connect (params)
 732   (if params
 733       (let ((network (car params)))
 734         (murk-display-notice nil "Attempting to connect to " network "...")
 735         (murk-connect network))
 736     (murk-display-notice nil "Usage: /connect <network>")))
 737
 738 (defun murk-command-networks (_params)
 739   (murk-display-notice nil "Currently-known networks:")
 740   (dolist (row murk-networks)
 741     (seq-let (network server port &rest _others) row
 742       (murk-display-notice nil "\t" network
 743                            " [" server
 744                            " " (number-to-string port) "]")))
 745   (murk-display-notice nil "(Modify the `murk-networks' variable to add more.)"))
 746
 747 (defun murk-command-quit (params)
 748   (let ((ctx (murk-current-context)))
 749     (if (not ctx)
 750         (murk-display-error "No current context")
 751       (let ((quit-msg (if params (string-join params " ") murk-default-quit-msg)))
 752         (murk-send-msg
 753          (murk-context-server ctx)
 754          (murk-msg nil nil "QUIT" quit-msg))))))
 755
 756 (defun murk-command-join (params)
 757   (if params
 758       (let ((server (murk-context-server (murk-current-context))))
 759         (dolist (channel params)
 760           (murk-send-msg server (murk-msg nil nil "JOIN" channel))))
 761     (murk-display-notice nil "Usage: /join channel [channel2 ...]")))
 762
 763 (defun murk-command-part (params)
 764   (let* ((server (murk-context-server (murk-current-context)))
 765          (channel (if params
 766                       (car params)
 767                     (murk-context-name (murk-current-context)))))
 768     (if channel
 769         (murk-send-msg server (murk-msg nil nil "PART" channel))
 770       (murk-display-error "No current channel to leave"))))
 771
 772 (defun murk-command-msg (params)
 773   (let ((server (murk-context-server (murk-current-context))))
 774     (if (and params (>= (length params) 2))
 775         (let ((to (car params))
 776               (text (string-join (cdr params) " ")))
 777           (murk-send-msg server (murk-msg nil nil "PRIVMSG" to text))
 778           (murk-display-message server
 779                                 (murk-connection-nick server)
 780                                 to text))
 781       (murk-display-notice nil "Usage: /msg <nick> <message>"))))
 782
 783 ;;; Command entering
 784 ;;
 785
 786 (defun murk-enter-string (string)
 787   (if (string-prefix-p "/" string)
 788       (pcase string
 789         ((rx (: "/" (let cmd-str (+ (not whitespace)))
 790                 (opt (+ whitespace)
 791                      (let params-str (+ anychar))
 792                      string-end)))
 793          (let ((command-row (assoc (upcase  cmd-str) murk-command-table #'equal))
 794                (params (if params-str
 795                            (split-string params-str nil t)
 796                          nil)))
 797            (if (and command-row (elt command-row 2))
 798                (funcall (elt command-row 2) params)
 799              (murk-send-msg
 800               (murk-context-server (murk-current-context))
 801               (murk-msg nil nil (upcase cmd-str) params)))))
 802         (_
 803          (murk-display-error "Badly formed command")))
 804     (unless (string-empty-p string)
 805       (if (murk-current-context)
 806           (let ((server (murk-context-server (murk-current-context))))
 807             (murk-send-msg server
 808                            (murk-msg nil nil "PRIVMSG"
 809                                      (murk-context-name (murk-current-context))
 810                                      string))
 811             (murk-display-message server
 812                                   (murk-connection-nick server)
 813                                   (murk-context->string (murk-current-context))
 814                                   string))
 815         (murk-display-error "No current context")))))
 816
 817
 818 ;;; Command history
 819 ;;
 820
 821 (defvar murk-history nil
 822   "Commands and messages sent in current session.")
 823
 824 (defvar murk-history-index nil)
 825
 826 (defun murk-history-cycle (delta)
 827   (when murk-history
 828     (with-current-buffer "*murk*"
 829       (if murk-history-index
 830           (setq murk-history-index
 831                 (max 0
 832                      (min (- (length murk-history) 1)
 833                           (+ delta murk-history-index))))
 834         (setq murk-history-index 0))
 835       (delete-region murk-input-marker (point-max))
 836       (insert (elt murk-history murk-history-index)))))
 837
 838
 839 ;;; Interactive commands
 840 ;;
 841
 842 (defun murk-enter ()
 843   "Enter current contents of line after prompt."
 844   (interactive)
 845   (with-current-buffer "*murk*"
 846     (let ((line (buffer-substring murk-input-marker (point-max))))
 847       (push line murk-history)
 848       (setq murk-history-index nil)
 849       (let ((inhibit-read-only t))
 850         (delete-region murk-input-marker (point-max)))
 851       (murk-enter-string line))))
 852
 853 (defun murk-history-next ()
 854   (interactive)
 855   (murk-history-cycle -1))
 856
 857 (defun murk-history-prev ()
 858   (interactive)
 859   (murk-history-cycle +1))
 860
 861 (defun murk-complete-input ()
 862   (interactive)
 863   (let ((completion-ignore-case t))
 864     (when (>= (point) murk-input-marker)
 865       (pcase (buffer-substring murk-input-marker (point))
 866         ((rx (: "/" (let cmd-str (+ (not whitespace))) (+ " ") (* (not whitespace)) string-end))
 867          (let ((space-idx (save-excursion
 868                             (re-search-backward " " murk-input-marker t)))
 869                (table-row (assoc (upcase cmd-str) murk-command-table #'equal)))
 870            (if (and table-row (elt table-row 3))
 871                (let* ((completions-nospace (funcall (elt table-row 3)))
 872                       (completions (mapcar (lambda (el) (concat el " ")) completions-nospace)))
 873                  (completion-in-region (+ 1 space-idx) (point) completions)))))
 874         ((rx (: "/" (* (not whitespace)) string-end))
 875          (message (buffer-substring murk-input-marker (point)))
 876          (completion-in-region murk-input-marker (point)
 877                                (mapcar (lambda (row) (concat "/" (car row) " "))
 878                                        murk-command-table)))
 879         (_
 880          (let* ((end (max murk-input-marker (point)))
 881                 (space-idx (save-excursion
 882                              (re-search-backward " " murk-input-marker t)))
 883                 (start (if space-idx (+ 1 space-idx) murk-input-marker)))
 884            (unless (string-prefix-p "/" (buffer-substring start end))
 885              (let* ((users (murk-get-context-users (murk-current-context)))
 886                     (users-no@ (mapcar
 887                                 (lambda (u) (car (split-string u "@" t)))
 888                                 users)))
 889                (completion-in-region start end users-no@)))))))))
 890
 891 ;;; Mode
 892 ;;
 893
 894 (defvar murk-mode-map
 895   (let ((map (make-sparse-keymap)))
 896     (define-key map (kbd "RET") 'murk-enter)
 897     (define-key map (kbd "TAB") 'murk-complete-input)
 898     (define-key map (kbd "<C-up>") 'murk-history-prev)
 899     (define-key map (kbd "<C-down>") 'murk-history-next)
 900     (define-key map (kbd "<C-tab>") 'murk-cycle-contexts-forward)
 901     (define-key map (kbd "<C-S-tab>") 'murk-cycle-contexts-reverse)
 902     (when (fboundp 'evil-define-key*)
 903       (evil-define-key* 'motion map
 904         (kbd "TAB") 'murk-complete-input))
 905     map))
 906
 907 (define-derived-mode murk-mode text-mode "murk"
 908   "Major mode for murk.")
 909
 910 (when (fboundp 'evil-set-initial-state)
 911   (evil-set-initial-state 'murk-mode 'insert))
 912
 913 ;;; Main start procedure
 914 ;;
 915
 916 (defun murk ()
 917   "Start murk or just switch to the murk buffer if one already exists."
 918   (interactive)
 919   (if (get-buffer "*murk*")
 920       (switch-to-buffer "*murk*")
 921     (switch-to-buffer "*murk*")
 922     (murk-mode)
 923     (murk-setup-buffer))
 924   "Started murk.")
 925
 926 ;;; murk.el ends here