gratchy.scm

   1 (import (chicken io)
   2         (chicken port)
   3         (chicken file)
   4         (chicken string)
   5         (chicken pathname)
   6         (chicken condition)
   7         (chicken time posix)
   8         (chicken process)
   9         (chicken process-context)
  10         matchable srfi-13
  11         uri-common tcp6 openssl)
  12
  13 (define-record config
  14   root-dir host port certfile keyfile)
  15
  16 (define file-types
  17   '(("gmi" "text/gemini" "charset=utf-8")
  18     ("txt" "text/plain" "charset=utf-8")))
  19
  20 (define (process-request config request-line)
  21   (let ((uri (uri-normalize-path-segments (absolute-uri request-line))))
  22     (cond
  23      ((not (eq? (uri-scheme uri) 'gemini))
  24       (fail-permanent "Unsupported scheme."))
  25      ((not (uri-host uri))
  26       (fail-permanent "URL lacks host name."))
  27      ((not (equal? (uri-host uri) (config-host config)))
  28       (fail-permanent "Proxy requests forbidden."))
  29      ((uri-path-relative? uri)
  30       (fail-permanent "Path must be absolute."))
  31      ((not (document-available? config uri))
  32       (fail-permanent "Document not found."))
  33      (else
  34       (serve-document config uri)))))
  35
  36 (define (fail-permanent reason)
  37   (print "50 " reason "\r"))
  38
  39 (define (document-available? config uri)
  40   (file-exists? (document-path config uri)))
  41
  42 (define (document-path config uri)
  43   (let* ((crumbs (reverse (cons (config-root-dir config) (cdr (uri-path uri)))))
  44          (path (make-pathname (reverse (cdr crumbs)) (car crumbs))))
  45     (if (directory-exists? path)
  46         (make-pathname path "index.gmi")
  47         path)))
  48
  49 (define (serve-document config uri)
  50   (let* ((path (document-path config uri))
  51          (ext (pathname-extension path))
  52          (mime-detected (assoc ext file-types))
  53          (mime (if mime-detected mime-detected (assoc "txt" file-types)))
  54          (mime-type (cadr mime)))
  55     (print "20 " (string-intersperse (cdr mime) ";") "\r")
  56     (cond
  57       ((equal? mime-type "text/gemini") (serve-dynamic-gemini path))
  58       ((equal? mime-type "text/plain") (serve-text-plain path))
  59       (else (serve-binary)))))
  60
  61 (define (serve-text-plain path)
  62   (with-input-from-file path
  63     (lambda ()
  64       (let loop ((str (read-string)))
  65         (unless (eof-object? str)
  66           (print* str)
  67           (loop (read-string)))))))
  68
  69 (define (serve-dynamic-gemini path)
  70   (with-input-from-file path
  71     (lambda ()
  72       (let loop ((c (peek-char)))
  73         (if (eof-object? c)
  74             'done
  75             (begin
  76               (if (eq? c #\,)
  77                   (begin
  78                     (read-char)
  79                     (serve-dynamic-element (read) (pathname-directory path))
  80                     (read-line))
  81                   (print (read-line)))
  82               (loop (peek-char))))))))
  83
  84 (define (serve-dynamic-element element working-directory)
  85   (match element
  86     (('eval expression)
  87      (with-current-working-directory
  88       working-directory
  89       (lambda ()
  90         (eval expression))))
  91     (('shell command)
  92      (with-current-working-directory
  93       working-directory
  94       (lambda ()
  95         (let-values (((in-port out-port id) (process command)))
  96           (let ((string (read-string #f in-port)))
  97             (unless (eof-object? string)
  98               (print string))
  99             (close-input-port in-port)
 100             (close-output-port out-port))))))
 101     (else (error "Unknown element type."))))
 102
 103 (define (with-current-working-directory directory thunk)
 104   (let ((old-wd (current-directory))
 105         (result 'none))
 106     (condition-case
 107         (begin
 108           (change-directory directory)
 109           (set! result (thunk))
 110           (change-directory old-wd)
 111           result)
 112       (o (exn)
 113          (change-directory old-wd)
 114          (signal o)))))
 115
 116
 117 (define (run-server config)
 118   (define listener (ssl-listen* hostname: (config-host config)
 119                                 port: (config-port config)
 120                                 certificate: (config-certfile config)
 121                                 private-key: (config-keyfile config)))
 122
 123   (print "Host: '" (config-host config) "'\n"
 124          "Port: '" (config-port config) "'\n"
 125          "Root directory: '" (config-root-dir config) "'\n"
 126          "Cert file: '" (config-certfile config) "'\n"
 127          "Key file: '" (config-keyfile config) "'\n"
 128          "\n"
 129          "Gemini server listening ...")
 130
 131   (server-loop listener config))
 132
 133 (define (server-loop listener config)
 134   (let-values (((in-port out-port) (ssl-accept listener)))
 135     (let-values (((local-ip remote-ip) (tcp-addresses (ssl-port->tcp-port in-port))))
 136       (print "Accepted connection from " remote-ip
 137              " on " (seconds->string))
 138       (condition-case
 139           (let ((request-line (read-line in-port)))
 140             (print* "Serving request '" request-line "' ... ")
 141             (with-output-to-port out-port
 142               (lambda ()
 143                 (process-request config request-line)))
 144             (print "done."))
 145         (o (exn)
 146            (print-error-message o))))
 147     (close-input-port in-port)
 148     (close-output-port out-port))
 149   (server-loop listener config))
 150
 151
 152 (define (print-usage progname)
 153   (print "Usage: " progname " [-h] [-p port] server-root-dir hostname certfile keyfile"))
 154
 155 (define (main)
 156   (let* ((progname (pathname-file (car (argv))))
 157          (config (make-config #f #f 1965 #f #f)))
 158     (if (null? (cdr (argv)))
 159         (print-usage progname)
 160         (let loop ((args (cdr (argv))))
 161           (let ((this-arg (car args))
 162                 (rest-args (cdr args)))
 163             (if (string-prefix? "-" this-arg)
 164                 (cond
 165                  ((or (equal? this-arg "-h")
 166                       (equal? this-arg "--help"))
 167                   (print-usage progname))
 168                  ((or (equal? this-arg "-p")
 169                       (equal? this-arg "--port"))
 170                   (config-port-set! config (string->bumber (car rest-args)))
 171                   (loop (cdr rest-args)))
 172                  (else
 173                   (print-usage progname)))
 174                 (match args
 175                   ((root-dir host certfile keyfile)
 176                    (config-root-dir-set! config root-dir)
 177                    (config-host-set! config host)
 178                    (config-certfile-set! config certfile)
 179                    (config-keyfile-set! config keyfile)
 180                    (run-server config))
 181                   (else
 182                    (print "One or more invalid arguments.")
 183                    (print-usage progname)))))))))
 184
 185
 186 (main)