ez.el

   1 ;;; ez.el --- Emacs Z-machine
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 13 Oct 2021
   7 ;; Version: 1.0
   8 ;; Keywords: game
   9 ;; Homepage: http://thelambdalab.xyz/ez
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 ;; Utility functions
  32
  33 (defun ez-decode-signed-bits (n nbits)
  34   (if (= 0 (lsh n (- 1 nbits)))
  35       n
  36     (- n (lsh 1 nbits))))
  37
  38 (defun ez-decode-signed-byte (b)
  39   (ez-decode-signed-bits b 8))
  40
  41 (defun ez-decode-signed-word (w)
  42   (ez-decode-signed-bits w 16))
  43
  44 (defun ez-decode-signed-operand (operand operand-type)
  45   (if (eq operand-type 'b)
  46       (ez-decode-signed-byte operand)
  47     (ez-decode-signed-word operand)))
  48
  49 (defun binformat (n &optional s)
  50   (unless s
  51     (setq s ""))
  52   (let ((d (/ n 2))
  53         (new-s (concat (number-to-string (mod n 2)) s)))
  54     (if (= d 0)
  55         new-s
  56       (binformat d new-s))))
  57
  58 (defun ez-list-to-string-hex (l)
  59   (concat "("
  60           (when l
  61             (concat
  62              (format "%x" (car l))
  63              (apply 'concat (mapcar (lambda (n) (format " %x" n)) (cdr l)))))
  64           ")"))
  65
  66 ;; Memory
  67
  68 (defvar ez-memory nil
  69   "Memory of z-machine.")
  70
  71 (defvar ez-version nil)
  72
  73 (defvar ez-start-pc nil)
  74 (defvar ez-himem-base nil)
  75 (defvar ez-dict-base nil)
  76 (defvar ez-objtab-addr nil)
  77 (defvar ez-abbrevtab-addr nil)
  78 (defvar ez-globalvartab-addr nil)
  79
  80 (defun ez-mem-ref-byte (addr)
  81   (aref ez-memory addr))
  82
  83 (defun ez-mem-set-byte (addr val)
  84   (aset ez-memory addr val))
  85
  86 (defun ez-mem-ref-word (addr)
  87   (+ (* 256 (aref ez-memory addr))
  88      (aref ez-memory (+ addr 1))))
  89
  90 (defun ez-mem-set-word (addr val)
  91   (let ((byte-high (/ val 256))
  92         (byte-low (mod val 256)))
  93     (aset ez-memory addr byte-high)
  94     (aset ez-memory (+ addr 1) byte-low)))
  95
  96 (defun ez-parse-header ()
  97   (setq ez-version (ez-mem-ref-byte #x0))
  98   (setq ez-himem-addr (ez-mem-ref-word #x4))
  99   (setq ez-start-pc (ez-mem-ref-word #x6))
 100   (setq ez-dict-base (ez-mem-ref-word #x8))
 101   (setq ez-objtab-addr (ez-mem-ref-word #xA))
 102   (setq ez-globalvartab-addr (ez-mem-ref-word #xC))
 103   (setq ez-abbrevtab-addr (ez-mem-ref-word #x18)))
 104
 105 (defun ez-load-file (filename)
 106   "Load story file into memory."
 107   (with-temp-buffer
 108     (insert-file-contents-literally filename)
 109     (setq ez-memory (encode-coding-string (buffer-string) 'raw-text)))
 110   'done)
 111
 112 ;; Global variables
 113
 114 (defun ez-get-global-var (gvar)
 115   (if (> gvar 239)
 116       (error "Invalid global variable %d" gvar))
 117   (let ((val
 118          (ez-mem-ref-word (+ (* 2 gvar) ez-globalvartab-addr))))
 119     (message "\tRetrieved %x from global variable %x" val gvar)
 120     val))
 121
 122 (defun ez-set-global-var (gvar val)
 123   (ez-mem-set-word (+ (* 2 gvar) ez-globalvartab-addr) val)
 124   (message "\tSet global variabl %x to %x" gvar val))
 125
 126 ;; Object tree
 127
 128 (defvar ez-property-defaults nil)
 129
 130 (defun ez-load-property-defaults ()
 131   (setq ez-property-defaults (make-vector 31 0))
 132   (dotimes (i 31)
 133     (aset ez-property-defaults i (aref ez-memory (+ ez-objtab-addr (* 2 i))))))
 134
 135 (defun ez-get-obj-addr (obj)
 136   (+ ez-objtab-addr (* 2 31) (* 9 (- obj 1))))
 137
 138 (defun ez-get-obj-parent (obj)
 139   (let ((addr (ez-get-obj-addr obj)))
 140     (ez-mem-ref-byte (+ addr 4))))
 141
 142 (defun ez-set-obj-parent (obj new-parent)
 143   (let ((addr (ez-get-obj-addr obj)))
 144     (ez-mem-set-byte (+ addr 4) new-parent)))
 145
 146 (defun ez-get-obj-sibling (obj)
 147   (let ((addr (ez-get-obj-addr obj)))
 148     (ez-mem-ref-byte (+ addr 5))))
 149
 150 (defun ez-set-obj-sibling (obj new-sibling)
 151   (let ((addr (ez-get-obj-addr obj)))
 152     (ez-mem-set-byte (+ addr 5) new-sibling)))
 153
 154 (defun ez-get-obj-child (obj)
 155   (let ((addr (ez-get-obj-addr obj)))
 156     (ez-mem-ref-byte (+ addr 6))))
 157
 158 (defun ez-set-obj-child (obj new-child)
 159   (let ((addr (ez-get-obj-addr obj)))
 160     (ez-mem-set-byte (+ addr 6) new-child)))
 161
 162 (defun ez-get-obj-plist-addr (obj)
 163   (let ((addr (ez-get-obj-addr obj)))
 164     (ez-mem-ref-word (+ addr 7))))
 165
 166 (defun ez-get-obj-name (obj)
 167   (let ((plist-addr (ez-get-obj-plist-addr obj)))
 168     (if (> (ez-mem-ref-byte plist-addr) 0)
 169         (ez-get-zstring (+ 1 (ez-get-obj-plist-addr obj)))
 170       nil)))
 171
 172 (defun ez-get-prop-default (prop)
 173   (ez-mem-ref-word (+ ez-objtab-addr (* 2 (+ 1 prop)))))
 174
 175 (defun ez-get-prop-len (prop-size-byte)
 176   (lsh prop-size-byte -5))
 177
 178 (defun ez-get-prop-num (prop-size-byte)
 179   (logand #b00011111 prop-size-byte))
 180
 181 (defun ez-get-obj-prop-addr (obj prop)
 182   (let* ((plist-addr (ez-get-obj-plist-addr obj))
 183          (prop-addr (+ plist-addr 1 (* 2 (ez-mem-ref-byte plist-addr))))
 184          (size-byte (ez-mem-ref-byte prop-addr)))
 185     (while (not (or (= size-byte 0)
 186                     (= prop (ez-get-prop-num size-byte))))
 187       (setq prop-addr (+ prop-addr (ez-get-prop-len size-byte) 2)
 188             size-byte (ez-mem-ref-byte prop-addr)))
 189     prop-addr))
 190
 191 (defun ez-get-obj-prop (obj prop)
 192   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 193          (size-byte (ez-mem-ref-byte prop-addr)))
 194     (if (= size-byte 0)
 195         (ez-get-prop-default prop)
 196       (let ((prop-len (ez-get-prop-len size-byte))
 197             (data-addr (+ prop-addr 1)))
 198         (cond
 199          ((= prop-len 0)
 200           (ez-mem-ref-byte data-addr))
 201          ((>= prop-len 1)
 202           (ez-mem-ref-word data-addr)))))))
 203
 204 (defun ez-set-obj-prop (obj prop value)
 205   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 206          (size-byte (ez-mem-ref-byte prop-addr)))
 207     (cond
 208      ((= size-byte 0)
 209       (error "Tried to set non-existant property"))
 210      ((= (ez-get-prop-len size-byte) 1)
 211       (ez-mem-set-byte (+ prop-addr 1) value))
 212      (t
 213       (ez-mem-set-word (+ prop-addr 1) value)))))
 214
 215 (defun ez-get-obj-attr (obj attr)
 216   (let* ((byte-num (/ attr 8))
 217          (bit-num (mod attr 8))
 218          (bit-mask (lsh 1 (- 7 bit-num))))
 219     (if (> (logand bit-mask (ez-mem-ref-byte (+ (ez-get-obj-addr obj) byte-num))) 0)
 220         1
 221       0)))
 222
 223 (defun ez-set-obj-attr (obj attr val)
 224   (let* ((byte-num (/ attr 8))
 225          (bit-num (mod attr 8))
 226          (bit-mask (lsh 1 (- 7 bit-num)))
 227          (byte-addr (+ (ez-get-obj-addr obj) byte-num))
 228          (byte (ez-mem-ref-byte byte-addr))
 229          (current-set (> (logand bit-mask byte) 0)))
 230     (if (or (and current-set (= val 0))
 231             (and (not current-set) (> val 0)))
 232         (ez-mem-set-byte byte-addr (logxor byte bit-mask)))))
 233
 234
 235 (defun ez-remove-obj (obj)
 236   (let ((parent (ez-get-obj-parent obj))
 237         (sibling (ez-get-obj-sibling obj)))
 238     (unless (= parent 0)
 239       (let ((child (ez-get-obj-child parent)))
 240         (if (= child obj)
 241             (ez-set-obj-child parent sibling)
 242           (while (not (= obj (ez-get-obj-sibling child)))
 243             (setq child (ez-get-obj-sibling child)))
 244           (ez-set-obj-sibling child (ez-get-obj-sibling obj))))
 245       (ez-set-obj-parent obj 0))
 246     (ez-set-obj-sibling obj 0)))
 247
 248 (defun ez-insert-obj (obj new-parent)
 249   (ez-remove-obj obj)
 250   (unless (= new-parent 0)
 251     (ez-set-obj-sibling obj (ez-get-obj-child new-parent))
 252     (ez-set-obj-child new-parent obj)))
 253
 254 ;; Z-strings
 255
 256 (defvar ez-zstring-alphabets
 257   ;                1    1    2    2    3
 258   ;      0    5    0    5    0    5    0
 259   (list "      abcdefghijklmnopqrstuvwxyz"
 260         "      ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 261         "       \n0123456789.,!?_#'\"/\\-:()")
 262   "Alphabets used by V3")
 263
 264 (defun ez-parse-zstring-word (word)
 265   (list (lsh word -15)
 266         (logand (lsh word -10) #b11111)
 267         (logand (lsh word -5) #b11111)
 268         (logand word #b11111)))
 269
 270 (defun ez-get-zstring-chars-and-length (base-addr)
 271   (let ((addr base-addr)
 272         (chars nil)
 273         (not-done t)
 274         (word-count 0))
 275     (while not-done
 276       (let ((components (ez-parse-zstring-word (ez-mem-ref-word addr))))
 277         (setq chars (append chars (cdr components)))
 278         (setq addr (+ addr 2))
 279         (setq word-count (+ word-count 1))
 280         (when (= (car components) 1)
 281           (setq not-done nil))))
 282     (cons word-count chars)))
 283
 284 (defun ez-get-zstring-and-length (base-addr)
 285   (let* ((word-count-and-chars (ez-get-zstring-chars-and-length base-addr))
 286          (word-count (car word-count-and-chars))
 287          (chars (cdr word-count-and-chars))
 288          (cur 0)
 289          (lock 0)
 290          (abbrev-char nil)
 291          (s ""))
 292     (dolist (char chars)
 293       (cond
 294        (abbrev-char
 295         (let ((abbrev-addr
 296                (* 2 (ez-mem-ref-word (+ ez-abbrevtab-addr
 297                                         (* 2 (+ (* (- abbrev-char 1) 32) char)))))))
 298           (setq s (concat s (cdr (ez-get-zstring-and-length abbrev-addr)))))
 299         (setq abbrev-char nil))
 300        ((memq char '(1 2 3)) ;Abbreviation
 301         (setq abbrev-char char))
 302        ((= char 4)
 303         (setq cur (mod (+ cur 1) 3)))
 304        ((= char 5)
 305         (setq cur (mod (+ 3 (- cur 1)) 3)))
 306        (t
 307         (setq s (concat s (substring (elt ez-zstring-alphabets cur)
 308                                      char (+ char 1))))
 309         (setq cur lock))))
 310     (cons word-count s)))
 311
 312 (defun ez-get-zstring (base-addr)
 313   (cdr (ez-get-zstring-and-length base-addr)))
 314
 315
 316 ;; Call stack
 317
 318 (defvar ez-call-stack nil)
 319
 320 (defun ez-make-call-stack-frame (pc &optional call-method)
 321   (list pc
 322         nil
 323         (make-vector 15 0)
 324         call-method))
 325
 326 (defun ez-add-call-stack-frame (pc &optional call-method)
 327   (push (ez-make-call-stack-frame pc call-method) ez-call-stack))
 328
 329 (defun ez-pop-call-stack-frame ()
 330   (pop ez-call-stack))
 331
 332 (defun ez-routine-stack ()
 333   (elt (car ez-call-stack) 1))
 334
 335 (defun ez-routine-stack-push (val)
 336   (let ((frame (car ez-call-stack)))
 337     (message "\tPushed %x to stack" val)
 338     (setf (elt frame 1) (cons val (elt frame 1)))))
 339
 340 (defun ez-routine-stack-pop ()
 341   (let* ((frame (car ez-call-stack))
 342          (rs-head (car (elt frame 1))))
 343     (setf (elt frame 1) (cdr (elt frame 1)))
 344     (message "\tPopped %x from stack" rs-head)
 345     rs-head))
 346
 347 (defun ez-get-local-var (lvar)
 348   (let* ((frame (car ez-call-stack))
 349          (val (aref (elt frame 2) (- lvar 1))))
 350     (message "\tRetrieved value %x from local variable %x" val lvar)
 351     val))
 352
 353 (defun ez-set-local-var (lvar val)
 354   (let ((frame (car ez-call-stack)))
 355     (message "\tSet local variable %x to %x" lvar val)
 356     (aset (elt frame 2) (- lvar 1) val)))
 357
 358 (defun ez-get-pc ()
 359   (caar ez-call-stack))
 360
 361 (defun ez-set-pc (new-pc)
 362   (setf (car (car ez-call-stack)) new-pc))
 363
 364 (defun ez-increment-pc (inc)
 365   (ez-set-pc (+ (ez-get-pc) inc)))
 366
 367 (defun ez-read-pc-byte-and-inc ()
 368   (let ((res (ez-mem-ref-byte (ez-get-pc))))
 369     (ez-increment-pc 1)
 370     res))
 371
 372 (defun ez-read-pc-word-and-inc ()
 373   (let ((res (ez-mem-ref-word (ez-get-pc))))
 374     (ez-increment-pc 2)
 375     res))
 376
 377 ;; Instruction execution
 378
 379 (defun ez-get-var (var)
 380   (cond
 381    ((= var 0)
 382     (ez-routine-stack-pop))
 383    ((< var 16)
 384     (ez-get-local-var var))
 385    (t
 386     (ez-get-global-var (- var 16)))))
 387
 388 (defun ez-set-var (var val)
 389   (cond
 390    ((= var 0)
 391     (ez-routine-stack-push val))
 392    ((< var 16)
 393     (ez-set-local-var var val))
 394    (t
 395     (ez-set-global-var (- var 16) val))))
 396
 397 (defun ez-read-pc-var-and-inc ()
 398   (ez-get-var (ez-read-pc-byte-and-inc)))
 399
 400 (defun ez-execute-instr ()
 401   (let ((instr-pc (ez-get-pc))
 402         (opbyte (ez-read-pc-byte-and-inc))
 403         (optype) (opcode) (operands))
 404     (cond
 405      ((<= #x0 opbyte #x1f)
 406       (setq optype '2op
 407             opcode opbyte
 408             operands (list (ez-read-pc-byte-and-inc)
 409                            (ez-read-pc-byte-and-inc))
 410             operand-types '(b b)))
 411      ((<= #x20 opbyte #x3F)
 412       (setq optype '2op
 413             opcode (- opbyte #x20)
 414             operands (list (ez-read-pc-byte-and-inc)
 415                            (ez-read-pc-var-and-inc))
 416             operand-types '(b w)))
 417      ((<= #x40 opbyte #x5F)
 418       (setq optype '2op
 419             opcode (- opbyte #x40)
 420             operands (list (ez-read-pc-var-and-inc)
 421                            (ez-read-pc-byte-and-inc))
 422             operand-types '(w b)))
 423      ((<= #x60 opbyte #x7F)
 424       (setq optype '2op
 425             opcode (- opbyte #x60)
 426             operands (list (ez-read-pc-var-and-inc)
 427                            (ez-read-pc-var-and-inc))
 428             operand-types '(w w)))
 429      ((<= #x80 opbyte #x8F)
 430       (setq optype '1op
 431             opcode (- opbyte #x80)
 432             operands (list (ez-read-pc-word-and-inc))
 433             operand-types '(w)))
 434      ((<= #x90 opbyte #x9F)
 435       (setq optype '1op
 436             opcode (- opbyte #x90)
 437             operands (list (ez-read-pc-byte-and-inc))
 438             operand-types '(b)))
 439      ((<= #xA0 opbyte #xAF)
 440       (setq optype '1op
 441             opcode (- opbyte #xa0)
 442             operands (list (ez-read-pc-var-and-inc))
 443             operand-types '(w)))
 444      ((<= #xB0 opbyte #xBF)
 445       (setq optype '0op
 446             opcode (- opbyte #xb0)
 447             operands '()
 448             operand-types '()))
 449      ((<= #xC0 opbyte #xDF)
 450       (setq optype '2op
 451             opcode (- opbyte #xc0))
 452       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 453         (setq operands (car operands-and-types)
 454               operand-types (cdr operands-and-types))))
 455      ((<= #xE0 opbyte #xFF)
 456       (setq optype 'var
 457             opcode (- opbyte #xe0))
 458       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 459         (setq operands (car operands-and-types)
 460               operand-types (cdr operands-and-types)))))
 461     (let ((table-row (assoc (list optype opcode) ez-op-table)))
 462       (unless table-row
 463         (error "Unsupported op PC:%x Optype:%s Opcode:%x Operands:%s Operand-types:%s"
 464                instr-pc optype opcode (ez-list-to-string-hex operands) operand-types))
 465       (let ((mnemonic (elt table-row 1)))
 466         (message "PC:%x Optype:%s Opcode:%x Mnemonic:%s Operands:%s Operand-types:%s"
 467                  instr-pc optype opcode mnemonic
 468                  (ez-list-to-string-hex operands) operand-types))
 469       (funcall (elt table-row 2) operands operand-types))))
 470
 471 (defun ez-read-var-operands-and-inc ()
 472   (let* ((type-byte (ez-read-pc-byte-and-inc))
 473          (types (let ((type1 (lsh type-byte -6)))
 474                   (if (= type1 #b11)
 475                       nil
 476                     (cons type1
 477                           (let ((type2 (mod (lsh type-byte -4) 4)))
 478                             (if (= type2 #b11)
 479                                 nil
 480                               (cons type2
 481                                     (let ((type3 (mod (lsh type-byte -2) 4)))
 482                                       (if (= type3 #b11)
 483                                           nil
 484                                         (cons type3
 485                                               (let ((type4 (mod type-byte 4)))
 486                                                 (if (= type4 #b11)
 487                                                     nil
 488                                                   (list type4))))))))))))))
 489     (cons
 490      (mapcar
 491       (lambda (type)
 492         (cond
 493          ((= type 0) (ez-read-pc-word-and-inc))
 494          ((= type 1) (ez-read-pc-byte-and-inc))
 495          ((= type 2) (ez-read-pc-var-and-inc))))
 496       types)
 497      (mapcar
 498       (lambda (type)
 499         (if (= type 1)
 500             'b
 501           'w))
 502       types))))
 503
 504 ;; Branches
 505
 506 (defun ez-do-branch (branch)
 507   (let* ((branch-byte (ez-read-pc-byte-and-inc))
 508          (invert (= 0 (logand branch-byte #b10000000)))
 509          (single-byte (> (logand branch-byte #b01000000) 0))
 510          (offset
 511           (if single-byte
 512               (logand branch-byte #b00111111)
 513             (let ((pos (= (logand branch-byte #b00100000) 0))
 514                   (val (+ (* 256 (logand branch-byte #b00011111))
 515                           (ez-read-pc-byte-and-inc))))
 516               (if pos
 517                   val
 518                 (- val 8192))))))
 519     (if (or (and branch (not invert))
 520             (and (not branch) invert))
 521         (cond
 522          ((= offset 0)
 523           (ez-op-rfalse))
 524          ((= offset 1)
 525           (ez-op-rtrue))
 526          (t
 527           (ez-set-pc (+ (ez-get-pc) offset -2)))))))
 528
 529 ;; Operations
 530
 531 (defvar ez-op-table
 532   '(((0op #x00) rtrue ez-op-rtrue)
 533     ((0op #x01) rfalse ez-op-rfalse)
 534     ((1op #x00) jz ez-op-jz)
 535     ((1op #x05) inc ez-op-inc)
 536     ((1op #x06) dec ez-op-dec)
 537     ((1op #x0B) ret ez-op-ret)
 538     ((0op #x08) ret_pulled ez-op-ret-pulled)
 539     ((1op #x0C) jump ez-op-jump)
 540     ((2op #x05) inc_jg ez-op-inc-jg)
 541     ((2op #x04) dec_jg ez-op-dec-jg)
 542     ((2op #x0D) store ez-op-store)
 543     ((1op #x0E) load ez-op-load)
 544     ((var #x01) storew ez-op-storew)
 545     ((2op #x0F) loadw ez-op-loadw)
 546     ((var #x02) storeb ez-op-storeb)
 547     ((2op #x10) loadb ez-op-loadb)
 548     ((2op #x01) je ez-op-je)
 549     ((2op #x02) jl ez-op-jl)
 550     ((2op #x03) jg ez-op-jg)
 551     ((2op #x06) jin ez-op-jin)
 552     ((2op #x07) test ez-op-test)
 553     ((2op #x08) or ez-op-or)
 554     ((2op #x09) and ez-op-and)
 555     ((2op #x14) add ez-op-add)
 556     ((2op #x15) sub ez-op-sub)
 557     ((2op #x16) mul ez-op-mul)
 558     ((2op #x17) div ez-op-div)
 559     ((2op #x18) mod ez-op-mod)
 560     ((var #x00) call_fv ez-op-callfv)
 561     ((1op #x01) get_sibling ez-op-get-sibling)
 562     ((1op #x02) get_child ez-op-get-child)
 563     ((1op #x03) get_parent ez-op-get-parent)
 564     ((2op #x0A) test_attr ez-op-test-attr)
 565     ((2op #x0B) set_attr ez-op-set-attr)
 566     ((2op #x0C) clear_attr ez-op-clear-attr)
 567     ((1op #x09) remove_obj ez-op-remove-obj)
 568     ((2op #x0E) insert_obj ez-op-insert-obj)
 569     ((var #x03) put_prop ez-op-put-prop)
 570     ((2op #x11) get_prop ez-op-get-prop)
 571     ((0op #x02) print ez-op-print)
 572     ((0op #x0B) new_line ez-op-new-line)
 573     ((var #x06) print_num ez-op-print-num)
 574     ((var #x05) print_char ez-op-print-char)
 575     ((1op #x0A) print_obj ez-op-print-obj)))
 576
 577 (defun ez-op-ret (operands &optional operand-types)
 578   (let ((retval (car operands)))
 579     (message "\tReturning value %x" retval)
 580     (ez-pop-call-stack-frame)
 581     (ez-set-var (ez-read-pc-byte-and-inc) retval))
 582   t)
 583
 584 (defun ez-op-ret-pulled (operands operand-types)
 585   (let ((retval (ez-routine-stack-pop)))
 586     (message "\tReturning value %x" retval)
 587     (ez-op-ret (list retval)))
 588   t)
 589
 590 (defun ez-op-rtrue (&optional operands operand-types)
 591   (ez-op-ret (list 1))
 592   t)
 593
 594 (defun ez-op-rfalse (&optional operands operand-types)
 595   (ez-op-ret (list 0))
 596   t)
 597
 598 (defun ez-op-jz (operands operand-types)
 599   (ez-do-branch (= (car operands) 0))
 600   t)
 601
 602 (defun ez-op-je (operands operand-types)
 603   (ez-do-branch (memq (car operands) (cdr operands)))
 604   t)
 605
 606 (defun ez-op-jg (operands operand-types)
 607   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 608         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 609     (ez-do-branch (> s1 s2)))
 610   t)
 611
 612 (defun ez-op-jl (operands operand-types)
 613   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 614         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 615     (ez-do-branch (< s1 s2)))
 616   t)
 617
 618 (defun ez-op-inc-jg (operands operand-types)
 619   (let ((var (car operands)))
 620     (ez-op-inc (list var))
 621     (ez-op-jg (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 622   t)
 623
 624 (defun ez-op-dec-jl (operands operand-types)
 625   (let ((var (car operands)))
 626     (ez-op-dec (list var))
 627     (ez-op-jl (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 628   t)
 629
 630 (defun ez-op-jin (operands operand-types)
 631   (let ((obj (car operands))
 632         (n (cadr operands)))
 633     (ez-do-branch (or (= n 0)
 634                       (= n (ez-get-obj-parent obj)))))
 635   t)
 636
 637 (defun ez-op-test (operands operand-types)
 638   (let ((a (car operands))
 639         (b (cadr operands)))
 640     (ez-do-branch (= (logand a b) b)))
 641   t)
 642
 643 (defun ez-op-jump (operands operand-types)
 644   (let ((offset (if (eq (car operand-types) 'b)
 645                     (ez-decode-signed-byte (car operands))
 646                   (ez-decode-signed-word (car operands)))))
 647     (ez-set-pc (+ (ez-get-pc) offset -2)))
 648   t)
 649
 650 (defun ez-op-inc (operands &optional operand-types)
 651   (let ((var (car operands)))
 652     (ez-set-var var (mod (+ 1 (ez-get-var var)) #x10000)))
 653   t)
 654
 655 (defun ez-op-dec (operands &optional operand-types)
 656   (let ((var (car operands)))
 657     (ez-set-var var (mod (+ (ez-get-var var) 1) #x10000)))
 658   t)
 659
 660 (defun ez-op-store (operands operand-types)
 661   (let ((var (car operands))
 662         (a (cadr operands)))
 663     (ez-set-var var a))
 664   t)
 665
 666 (defun ez-op-load (operands operand-types)
 667   (let ((var (car operands)))
 668     (ez-set-var (ez-read-pc-byte-and-inc) (ez-get-var var)))
 669   t)
 670
 671 (defun ez-op-storew (operands operand-types)
 672   (let ((baddr (car operands))
 673         (n (cadr operands))
 674         (a (caddr operands)))
 675     (ez-mem-set-word (+ baddr (* 2 n)) a))
 676   t)
 677
 678 (defun ez-op-loadw (operands operand-types)
 679   (let ((baddr (car operands))
 680         (n (cadr operands)))
 681     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-word (+ baddr (* 2 n)))))
 682   t)
 683
 684 (defun ez-op-storeb (operands operand-types)
 685   (let ((baddr (car operands))
 686         (n (cadr operands))
 687         (a (caddr operands)))
 688     (ez-mem-set-byte (+ baddr n) a))
 689   t)
 690
 691 (defun ez-op-loadb (operands operand-types)
 692   (let ((baddr (car operands))
 693         (n (cadr operands)))
 694     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-byte (+ baddr n))))
 695   t)
 696
 697 (defun ez-op-and (operands operand-types)
 698   (let ((a (car operands))
 699         (b (cadr operands)))
 700     (ez-set-var (ez-read-pc-byte-and-inc) (logand a b)))
 701   t)
 702
 703 (defun ez-op-or (operands operand-types)
 704   (let ((a (car operands))
 705         (b (cadr operands)))
 706     (ez-set-var (ez-read-pc-byte-and-inc) (logior a b)))
 707   t)
 708
 709 (defun ez-op-add (operands operand-types)
 710   (let ((a (car operands))
 711         (b (cadr operands)))
 712     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ a b) #x10000)))
 713   t)
 714
 715 (defun ez-op-sub (operands operand-types)
 716   (let ((a (car operands))
 717         (b (cadr operands)))
 718     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ (- a b) #x10000) #x10000)))
 719   t)
 720
 721 (defun ez-op-mul (a b)
 722   (let ((a (car operands))
 723         (b (cadr operands)))
 724     (ez-set-var (ez-read-pc-byte-and-inc) (mod (* a b) #x10000)))
 725   t)
 726
 727 (defun ez-op-div (a b)
 728   (error "Not implemented"))
 729
 730 (defun ez-op-mod (a b)
 731   (error "Not implemented"))
 732
 733 (defun ez-op-callfv (operands operand-types)
 734   (let* ((raddr (car operands))
 735          (call-operands (cdr operands))
 736          (r (* 2 raddr))
 737          (L (ez-mem-ref-byte r))
 738          (n (length call-operands))
 739          (new-pc (+ r 1 (* L 2))))
 740     (if (= raddr 0)
 741         (ez-set-var (ez-read-pc-byte-and-inc) 0) ; Simply return 0
 742       (ez-add-call-stack-frame new-pc)
 743       (dotimes (i L)
 744         (if (< i n)
 745             (ez-set-local-var (+ i 1) (elt call-operands i))
 746           (ez-set-local-var (+ i 1) (ez-mem-ref-word (+ r 1 (* 2 i))))))))
 747   t)
 748
 749 (defun ez-op-test-attr (operands operand-types)
 750   (let ((obj (car operands))
 751         (attr (cadr operands)))
 752     (ez-do-branch (= 1 (ez-get-obj-attr obj attr)))
 753     t))
 754
 755 (defun ez-op-set-attr (operands operand-types)
 756   (let ((obj (car operands))
 757         (attr (cadr operands)))
 758     (ez-set-obj-attr obj attr 1))
 759   t)
 760
 761 (defun ez-op-clear-attr (operands operand-types)
 762   (let ((obj (car operands))
 763         (attr (cadr operands)))
 764     (ez-set-obj-attr obj attr 0))
 765   t)
 766
 767 (defun ez-op-get-sibling (operands operand-types)
 768   (let ((sib (ez-get-obj-sibling (car operands))))
 769     (ez-set-var (ez-read-pc-byte-and-inc) sib)
 770     (ez-do-branch (> sib 0)))
 771   t)
 772
 773 (defun ez-op-get-child (operands operand-types)
 774   (let ((child (ez-get-obj-child (car operands))))
 775     (ez-set-var (ez-read-pc-byte-and-inc) child)
 776     (ez-do-branch (> child 0)))
 777   t)
 778
 779 (defun ez-op-get-parent (operands operand-types)
 780   (let ((parent (ez-get-obj-parent (car operands))))
 781     (ez-set-var (ez-read-pc-byte-and-inc) parent))
 782   t)
 783
 784 (defun ez-op-remove-obj (operands operand-types)
 785   (let ((obj (car operands)))
 786     (ez-remove-obj obj))
 787   t)
 788
 789 (defun ez-op-insert-obj (operands operand-types)
 790   (let ((obj1 (car operands))
 791         (obj2 (cadr operands)))
 792     (ez-insert-obj obj1 obj2))
 793   t)
 794
 795 (defun ez-op-put-prop (operands operand-types)
 796   (let* ((obj (car operands))
 797          (prop (cadr operands))
 798          (a (caddr operands)))
 799     (ez-set-obj-prop obj prop a))
 800   t)
 801
 802 (defun ez-op-get-prop (operands operand-types)
 803   (let* ((obj (car operands))
 804          (prop (cadr operands)))
 805     (ez-set-var (ez-read-pc-byte-and-inc)
 806                 (ez-get-obj-prop obj prop)))
 807   t)
 808
 809 (defun ez-op-print (operands operand-types)
 810   (let* ((word-count-and-string (ez-get-zstring-and-length (ez-get-pc)))
 811          (word-count (car word-count-and-string))
 812          (string (cdr word-count-and-string)))
 813     (ez-print string)
 814     (ez-increment-pc (* 2 word-count)))
 815   t)
 816
 817 (defun ez-op-new-line (operands operand-types)
 818   (ez-print "\n")
 819   t)
 820
 821 (defun ez-op-print-num (operands operand-types)
 822   (let ((s (ez-decode-signed-operand (car operands) (car operand-types))))
 823     (ez-print (number-to-string s)))
 824   t)
 825
 826 (defun ez-op-print-char (operands operand-types)
 827   (let ((c (car operands)))
 828     (ez-print (string c)))
 829   t)
 830
 831 (defun ez-op-print-obj (operands operand-types)
 832   (let ((obj (car operands)))
 833     (ez-print (ez-get-obj-name obj)))
 834   t)
 835
 836 ;; Execution loop
 837
 838 (defun ez-run (filename)
 839   (ez-load-file filename)
 840   (ez-parse-header)
 841   (setq ez-call-stack (list (ez-make-call-stack-frame ez-start-pc)))
 842
 843   (while (ez-execute-instr)))
 844
 845
 846 ;;; Buffer and I/O
 847 ;;
 848
 849 (defvar ez-input-marker nil
 850   "Marker for input position in buffer.")
 851
 852 (defun ez-setup-buffer ()
 853   (with-current-buffer (get-buffer-create "*ez*")
 854     (let ((inhibit-read-only t))
 855       (delete-region (point-min) (point-max)))
 856     (setq-local scroll-conservatively 1)
 857     (if (markerp ez-input-marker)
 858         (set-marker ez-input-marker (point-max))
 859       (setq ez-input-marker (point-max-marker)))
 860     (goto-char (point-max))))
 861
 862
 863 (defun ez-print (string)
 864   (with-current-buffer "*ez*"
 865     (save-excursion
 866       (goto-char ez-input-marker)
 867       (insert-before-markers string))))
 868
 869 ;; Mode
 870
 871 (defvar ez-mode-map
 872   (let ((map (make-sparse-keymap)))
 873     (define-key map (kbd "RET") 'ez-enter)
 874     map))
 875
 876 (define-derived-mode ez-mode text-mode "ez"
 877   "Major mode for EZ.")
 878
 879 (when (fboundp 'evil-set-initial-state)
 880   (evil-set-initial-state 'ez-mode 'insert))
 881
 882 (defun ez (zfile)
 883   (interactive "fEnter name of z3 story file: ")
 884   (if (get-buffer "*ez*")
 885       (switch-to-buffer "*ez*")
 886     (switch-to-buffer "*ez*")
 887     (ez-mode)
 888     (ez-setup-buffer)
 889     (ez-run zfile))
 890   "Started EZ.")
 891
 892 (defun ez-debug ()
 893   (interactive)
 894   (switch-to-buffer "*ez*")
 895   (ez-mode)
 896   (ez-setup-buffer)
 897   (ez-run "zork1.z3"))
 898
 899 ;;; ez.el ends here