ez.el

   1 ;;; ez.el --- Emacs Z-machine
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 13 Oct 2021
   7 ;; Version: 1.0
   8 ;; Keywords: game
   9 ;; Homepage: http://thelambdalab.xyz/ez
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; There are many Z-machine interpreters, but this one is mine.
  30 ;; It only capable of interpreting the subset of Z-code necessary
  31 ;; to run the first Zork game in z3 format.
  32 ;;
  33 ;; It is based entirely on the description of the Z-machine contained
  34 ;; Marnix Klooster's wonderful document, "The Z-machine And How to Emulate It."
  35
  36 ;;; Code:
  37
  38 ;; Utility functions
  39
  40 (defun ez-decode-signed-bits (n nbits)
  41   (if (= 0 (lsh n (- 1 nbits)))
  42       n
  43     (- n (lsh 1 nbits))))
  44
  45 (defun ez-decode-signed-byte (b)
  46   (ez-decode-signed-bits b 8))
  47
  48 (defun ez-decode-signed-word (w)
  49   (ez-decode-signed-bits w 16))
  50
  51 (defun ez-decode-signed-operand (operand operand-type)
  52   (if (eq operand-type 'b)
  53       (ez-decode-signed-byte operand)
  54     (ez-decode-signed-word operand)))
  55
  56 (defun binformat (n &optional s)
  57   (unless s
  58     (setq s ""))
  59   (let ((d (/ n 2))
  60         (new-s (concat (number-to-string (mod n 2)) s)))
  61     (if (= d 0)
  62         new-s
  63       (binformat d new-s))))
  64
  65 (defun ez-list-to-string-hex (l)
  66   (concat "("
  67           (when l
  68             (concat
  69              (format "%x" (car l))
  70              (apply 'concat (mapcar (lambda (n) (format " %x" n)) (cdr l)))))
  71           ")"))
  72
  73 ;; Memory
  74
  75 (defvar ez-memory nil
  76   "Memory of z-machine.")
  77
  78 (defvar ez-version nil)
  79
  80 (defvar ez-start-pc nil)
  81 (defvar ez-himem-base nil)
  82 (defvar ez-dict-base nil)
  83 (defvar ez-objtab-addr nil)
  84 (defvar ez-abbrevtab-addr nil)
  85 (defvar ez-globalvartab-addr nil)
  86
  87 (defun ez-mem-ref-byte (addr)
  88   (aref ez-memory addr))
  89
  90 (defun ez-mem-set-byte (addr val)
  91   (aset ez-memory addr val))
  92
  93 (defun ez-mem-ref-word (addr)
  94   (+ (* 256 (aref ez-memory addr))
  95      (aref ez-memory (+ addr 1))))
  96
  97 (defun ez-mem-set-word (addr val)
  98   (let ((byte-high (/ val 256))
  99         (byte-low (mod val 256)))
 100     (aset ez-memory addr byte-high)
 101     (aset ez-memory (+ addr 1) byte-low)))
 102
 103 (defun ez-parse-header ()
 104   (setq ez-version (ez-mem-ref-byte #x0))
 105   (setq ez-himem-addr (ez-mem-ref-word #x4))
 106   (setq ez-start-pc (ez-mem-ref-word #x6))
 107   (setq ez-dict-base (ez-mem-ref-word #x8))
 108   (setq ez-objtab-addr (ez-mem-ref-word #xA))
 109   (setq ez-globalvartab-addr (ez-mem-ref-word #xC))
 110   (setq ez-abbrevtab-addr (ez-mem-ref-word #x18)))
 111
 112 (defun ez-load-file (filename)
 113   "Load story file into memory."
 114   (with-temp-buffer
 115     (insert-file-contents-literally filename)
 116     (setq ez-memory (encode-coding-string (buffer-string) 'raw-text)))
 117   'done)
 118
 119 ;; Global variables
 120
 121 (defun ez-get-global-var (gvar)
 122   (if (> gvar 239)
 123       (error "Invalid global variable %d" gvar))
 124   (let ((val
 125          (ez-mem-ref-word (+ (* 2 gvar) ez-globalvartab-addr))))
 126     (ez-debug-message "\tRetrieved %x from global variable %x" val gvar)
 127     val))
 128
 129 (defun ez-set-global-var (gvar val)
 130   (ez-mem-set-word (+ (* 2 gvar) ez-globalvartab-addr) val)
 131   (ez-debug-message "\tSet global variabl %x to %x" gvar val))
 132
 133 ;; Object tree
 134
 135 (defvar ez-property-defaults nil)
 136
 137 (defun ez-load-property-defaults ()
 138   (setq ez-property-defaults (make-vector 31 0))
 139   (dotimes (i 31)
 140     (aset ez-property-defaults i (aref ez-memory (+ ez-objtab-addr (* 2 i))))))
 141
 142 (defun ez-get-obj-addr (obj)
 143   (+ ez-objtab-addr (* 2 31) (* 9 (- obj 1))))
 144
 145 (defun ez-get-obj-parent (obj)
 146   (let ((addr (ez-get-obj-addr obj)))
 147     (ez-mem-ref-byte (+ addr 4))))
 148
 149 (defun ez-set-obj-parent (obj new-parent)
 150   (let ((addr (ez-get-obj-addr obj)))
 151     (ez-mem-set-byte (+ addr 4) new-parent)))
 152
 153 (defun ez-get-obj-sibling (obj)
 154   (let ((addr (ez-get-obj-addr obj)))
 155     (ez-mem-ref-byte (+ addr 5))))
 156
 157 (defun ez-set-obj-sibling (obj new-sibling)
 158   (let ((addr (ez-get-obj-addr obj)))
 159     (ez-mem-set-byte (+ addr 5) new-sibling)))
 160
 161 (defun ez-get-obj-child (obj)
 162   (let ((addr (ez-get-obj-addr obj)))
 163     (ez-mem-ref-byte (+ addr 6))))
 164
 165 (defun ez-set-obj-child (obj new-child)
 166   (let ((addr (ez-get-obj-addr obj)))
 167     (ez-mem-set-byte (+ addr 6) new-child)))
 168
 169 (defun ez-get-obj-plist-addr (obj)
 170   (let ((addr (ez-get-obj-addr obj)))
 171     (ez-mem-ref-word (+ addr 7))))
 172
 173 (defun ez-get-obj-name (obj)
 174   (let ((plist-addr (ez-get-obj-plist-addr obj)))
 175     (if (> (ez-mem-ref-byte plist-addr) 0)
 176         (ez-get-zstring (+ 1 (ez-get-obj-plist-addr obj)))
 177       nil)))
 178
 179 (defun ez-get-prop-default (prop)
 180   (ez-mem-ref-word (+ ez-objtab-addr (* 2 (+ 1 prop)))))
 181
 182 (defun ez-get-prop-len (prop-size-byte)
 183   (lsh prop-size-byte -5))
 184
 185 (defun ez-get-prop-num (prop-size-byte)
 186   (logand #b00011111 prop-size-byte))
 187
 188 (defun ez-get-obj-prop-addr (obj prop)
 189   (let* ((plist-addr (ez-get-obj-plist-addr obj))
 190          (prop-addr (+ plist-addr 1 (* 2 (ez-mem-ref-byte plist-addr))))
 191          (size-byte (ez-mem-ref-byte prop-addr)))
 192     (while (not (or (= size-byte 0)
 193                     (= prop (ez-get-prop-num size-byte))))
 194       (setq prop-addr (+ prop-addr (ez-get-prop-len size-byte) 2)
 195             size-byte (ez-mem-ref-byte prop-addr)))
 196     prop-addr))
 197
 198 (defun ez-get-obj-prop (obj prop)
 199   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 200          (size-byte (ez-mem-ref-byte prop-addr)))
 201     (if (= size-byte 0)
 202         (ez-get-prop-default prop)
 203       (let ((prop-len (ez-get-prop-len size-byte))
 204             (data-addr (+ prop-addr 1)))
 205         (cond
 206          ((= prop-len 0)
 207           (ez-mem-ref-byte data-addr))
 208          ((>= prop-len 1)
 209           (ez-mem-ref-word data-addr)))))))
 210
 211 (defun ez-set-obj-prop (obj prop value)
 212   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 213          (size-byte (ez-mem-ref-byte prop-addr)))
 214     (cond
 215      ((= size-byte 0)
 216       (error "Tried to set non-existant property"))
 217      ((= (ez-get-prop-len size-byte) 1)
 218       (ez-mem-set-byte (+ prop-addr 1) value))
 219      (t
 220       (ez-mem-set-word (+ prop-addr 1) value)))))
 221
 222 (defun ez-get-obj-attr (obj attr)
 223   (let* ((byte-num (/ attr 8))
 224          (bit-num (mod attr 8))
 225          (bit-mask (lsh 1 (- 7 bit-num))))
 226     (if (> (logand bit-mask (ez-mem-ref-byte (+ (ez-get-obj-addr obj) byte-num))) 0)
 227         1
 228       0)))
 229
 230 (defun ez-set-obj-attr (obj attr val)
 231   (let* ((byte-num (/ attr 8))
 232          (bit-num (mod attr 8))
 233          (bit-mask (lsh 1 (- 7 bit-num)))
 234          (byte-addr (+ (ez-get-obj-addr obj) byte-num))
 235          (byte (ez-mem-ref-byte byte-addr))
 236          (current-set (> (logand bit-mask byte) 0)))
 237     (if (or (and current-set (= val 0))
 238             (and (not current-set) (> val 0)))
 239         (ez-mem-set-byte byte-addr (logxor byte bit-mask)))))
 240
 241
 242 (defun ez-remove-obj (obj)
 243   (let ((parent (ez-get-obj-parent obj))
 244         (sibling (ez-get-obj-sibling obj)))
 245     (unless (= parent 0)
 246       (let ((child (ez-get-obj-child parent)))
 247         (if (= child obj)
 248             (ez-set-obj-child parent sibling)
 249           (while (not (= obj (ez-get-obj-sibling child)))
 250             (setq child (ez-get-obj-sibling child)))
 251           (ez-set-obj-sibling child (ez-get-obj-sibling obj))))
 252       (ez-set-obj-parent obj 0))
 253     (ez-set-obj-sibling obj 0)))
 254
 255 (defun ez-insert-obj (obj new-parent)
 256   (ez-remove-obj obj)
 257   (unless (= new-parent 0)
 258     (ez-set-obj-sibling obj (ez-get-obj-child new-parent))
 259     (ez-set-obj-child new-parent obj)))
 260
 261 ;; Z-strings
 262
 263 (defvar ez-zstring-alphabets
 264   ;                1    1    2    2    3
 265   ;      0    5    0    5    0    5    0
 266   (list "      abcdefghijklmnopqrstuvwxyz"
 267         "      ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 268         "       \n0123456789.,!?_#'\"/\\-:()")
 269   "Alphabets used by V3")
 270
 271 (defun ez-parse-zstring-word (word)
 272   (list (lsh word -15)
 273         (logand (lsh word -10) #b11111)
 274         (logand (lsh word -5) #b11111)
 275         (logand word #b11111)))
 276
 277 (defun ez-get-zstring-chars-and-length (base-addr)
 278   (let ((addr base-addr)
 279         (chars nil)
 280         (not-done t)
 281         (word-count 0))
 282     (while not-done
 283       (let ((components (ez-parse-zstring-word (ez-mem-ref-word addr))))
 284         (setq chars (append chars (cdr components)))
 285         (setq addr (+ addr 2))
 286         (setq word-count (+ word-count 1))
 287         (when (= (car components) 1)
 288           (setq not-done nil))))
 289     (cons word-count chars)))
 290
 291 (defun ez-get-zstring-and-length (base-addr)
 292   (let* ((word-count-and-chars (ez-get-zstring-chars-and-length base-addr))
 293          (word-count (car word-count-and-chars))
 294          (chars (cdr word-count-and-chars))
 295          (cur 0)
 296          (lock 0)
 297          (s ""))
 298     (while (> (length chars) 0)
 299       (let ((char (pop chars)))
 300         (cond
 301          ((memq char '(1 2 3)) ;Abbreviation
 302           (let* ((abbrev-char char)
 303                  (abbrev-addr
 304                   (* 2 (ez-mem-ref-word (+ ez-abbrevtab-addr
 305                                            (* 2 (+ (* (- abbrev-char 1) 32) (pop chars))))))))
 306             (setq s (concat s (cdr (ez-get-zstring-and-length abbrev-addr))))))
 307          ((= char 4)
 308           (setq cur (mod (+ cur 1) 3)))
 309          ((= char 5)
 310           (setq cur (mod (+ 3 (- cur 1)) 3)))
 311          ((and (= cur 2) (= char 6))
 312           (setq s (concat s (char-to-string (+ (lsh (pop chars) 5) (pop chars)))))
 313           (setq cur lock))
 314          (t
 315           (setq s (concat s (substring (elt ez-zstring-alphabets cur)
 316                                        char (+ char 1))))
 317           (setq cur lock)))))
 318     (cons word-count s)))
 319
 320 (defun ez-get-zstring (base-addr)
 321   (cdr (ez-get-zstring-and-length base-addr)))
 322
 323 ;; Dictionary
 324
 325 (defun ez-get-dictionary ()
 326   (let* ((nseps (ez-mem-ref-byte ez-dict-base))
 327          (separators
 328           (mapcar (lambda (i) (ez-mem-ref-byte (+ ez-dict-base i)))
 329                   (number-sequence 1 nseps)))
 330          (bytes-per-entry (ez-mem-ref-byte (+ ez-dict-base 1 nseps)))
 331          (nentries (ez-mem-ref-word (+ ez-dict-base 1 nseps 1)))
 332          (entries-base (+ ez-dict-base nseps 4))
 333          (entries nil))
 334     (dotimes (i nentries)
 335       (let ((this-base (+ entries-base (* 7 i))))
 336         (setq entries (cons (cons this-base
 337                                   (ez-get-zstring this-base))
 338                             entries))))
 339     (list entries separators entries)))
 340
 341 ;; Call stack
 342
 343 (defvar ez-call-stack nil)
 344
 345 (defun ez-make-call-stack-frame (pc &optional call-method)
 346   (list pc
 347         nil
 348         (make-vector 15 0)
 349         call-method))
 350
 351 (defun ez-add-call-stack-frame (pc &optional call-method)
 352   (push (ez-make-call-stack-frame pc call-method) ez-call-stack))
 353
 354 (defun ez-pop-call-stack-frame ()
 355   (pop ez-call-stack))
 356
 357 (defun ez-routine-stack ()
 358   (elt (car ez-call-stack) 1))
 359
 360 (defun ez-routine-stack-push (val)
 361   (let ((frame (car ez-call-stack)))
 362     (ez-debug-message "\tPushed %x to stack" val)
 363     (setf (elt frame 1) (cons val (elt frame 1)))))
 364
 365 (defun ez-routine-stack-pop ()
 366   (let* ((frame (car ez-call-stack))
 367          (rs-head (car (elt frame 1))))
 368     (setf (elt frame 1) (cdr (elt frame 1)))
 369     (ez-debug-message "\tPopped %x from stack" rs-head)
 370     rs-head))
 371
 372 (defun ez-get-local-var (lvar)
 373   (let* ((frame (car ez-call-stack))
 374          (val (aref (elt frame 2) (- lvar 1))))
 375     (ez-debug-message "\tRetrieved value %x from local variable %x" val lvar)
 376     val))
 377
 378 (defun ez-set-local-var (lvar val)
 379   (let ((frame (car ez-call-stack)))
 380     (ez-debug-message "\tSet local variable %x to %x" lvar val)
 381     (aset (elt frame 2) (- lvar 1) val)))
 382
 383 (defun ez-get-pc ()
 384   (caar ez-call-stack))
 385
 386 (defun ez-set-pc (new-pc)
 387   (setf (car (car ez-call-stack)) new-pc))
 388
 389 (defun ez-increment-pc (inc)
 390   (ez-set-pc (+ (ez-get-pc) inc)))
 391
 392 (defun ez-read-pc-byte-and-inc ()
 393   (let ((res (ez-mem-ref-byte (ez-get-pc))))
 394     (ez-increment-pc 1)
 395     res))
 396
 397 (defun ez-read-pc-word-and-inc ()
 398   (let ((res (ez-mem-ref-word (ez-get-pc))))
 399     (ez-increment-pc 2)
 400     res))
 401
 402 ;; Instruction execution
 403
 404 (defun ez-get-var (var)
 405   (cond
 406    ((= var 0)
 407     (ez-routine-stack-pop))
 408    ((< var 16)
 409     (ez-get-local-var var))
 410    (t
 411     (ez-get-global-var (- var 16)))))
 412
 413 (defun ez-set-var (var val)
 414   (cond
 415    ((= var 0)
 416     (ez-routine-stack-push val))
 417    ((< var 16)
 418     (ez-set-local-var var val))
 419    (t
 420     (ez-set-global-var (- var 16) val))))
 421
 422 (defun ez-read-pc-var-and-inc ()
 423   (ez-get-var (ez-read-pc-byte-and-inc)))
 424
 425 (defun ez-execute-instr ()
 426   (let ((instr-pc (ez-get-pc))
 427         (opbyte (ez-read-pc-byte-and-inc))
 428         (optype) (opcode) (operands))
 429     (cond
 430      ((<= #x0 opbyte #x1f)
 431       (setq optype '2op
 432             opcode opbyte
 433             operands (list (ez-read-pc-byte-and-inc)
 434                            (ez-read-pc-byte-and-inc))
 435             operand-types '(b b)))
 436      ((<= #x20 opbyte #x3F)
 437       (setq optype '2op
 438             opcode (- opbyte #x20)
 439             operands (list (ez-read-pc-byte-and-inc)
 440                            (ez-read-pc-var-and-inc))
 441             operand-types '(b w)))
 442      ((<= #x40 opbyte #x5F)
 443       (setq optype '2op
 444             opcode (- opbyte #x40)
 445             operands (list (ez-read-pc-var-and-inc)
 446                            (ez-read-pc-byte-and-inc))
 447             operand-types '(w b)))
 448      ((<= #x60 opbyte #x7F)
 449       (setq optype '2op
 450             opcode (- opbyte #x60)
 451             operands (list (ez-read-pc-var-and-inc)
 452                            (ez-read-pc-var-and-inc))
 453             operand-types '(w w)))
 454      ((<= #x80 opbyte #x8F)
 455       (setq optype '1op
 456             opcode (- opbyte #x80)
 457             operands (list (ez-read-pc-word-and-inc))
 458             operand-types '(w)))
 459      ((<= #x90 opbyte #x9F)
 460       (setq optype '1op
 461             opcode (- opbyte #x90)
 462             operands (list (ez-read-pc-byte-and-inc))
 463             operand-types '(b)))
 464      ((<= #xA0 opbyte #xAF)
 465       (setq optype '1op
 466             opcode (- opbyte #xa0)
 467             operands (list (ez-read-pc-var-and-inc))
 468             operand-types '(w)))
 469      ((<= #xB0 opbyte #xBF)
 470       (setq optype '0op
 471             opcode (- opbyte #xb0)
 472             operands '()
 473             operand-types '()))
 474      ((<= #xC0 opbyte #xDF)
 475       (setq optype '2op
 476             opcode (- opbyte #xc0))
 477       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 478         (setq operands (car operands-and-types)
 479               operand-types (cdr operands-and-types))))
 480      ((<= #xE0 opbyte #xFF)
 481       (setq optype 'var
 482             opcode (- opbyte #xe0))
 483       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 484         (setq operands (car operands-and-types)
 485               operand-types (cdr operands-and-types)))))
 486     (let ((table-row (assoc (list optype opcode) ez-op-table)))
 487       (unless table-row
 488         (error "Unsupported op PC:%x Optype:%s Opcode:%x Operands:%s Operand-types:%s"
 489                instr-pc optype opcode (ez-list-to-string-hex operands) operand-types))
 490       (let ((mnemonic (elt table-row 1)))
 491         (ez-debug-message "PC:%x Optype:%s Opcode:%x Mnemonic:%s Operands:%s Operand-types:%s"
 492                  instr-pc optype opcode mnemonic
 493                  (ez-list-to-string-hex operands) operand-types))
 494       (funcall (elt table-row 2) operands operand-types))))
 495
 496 (defun ez-read-var-operands-and-inc ()
 497   (let* ((type-byte (ez-read-pc-byte-and-inc))
 498          (types (let ((type1 (lsh type-byte -6)))
 499                   (if (= type1 #b11)
 500                       nil
 501                     (cons type1
 502                           (let ((type2 (mod (lsh type-byte -4) 4)))
 503                             (if (= type2 #b11)
 504                                 nil
 505                               (cons type2
 506                                     (let ((type3 (mod (lsh type-byte -2) 4)))
 507                                       (if (= type3 #b11)
 508                                           nil
 509                                         (cons type3
 510                                               (let ((type4 (mod type-byte 4)))
 511                                                 (if (= type4 #b11)
 512                                                     nil
 513                                                   (list type4))))))))))))))
 514     (cons
 515      (mapcar
 516       (lambda (type)
 517         (cond
 518          ((= type 0) (ez-read-pc-word-and-inc))
 519          ((= type 1) (ez-read-pc-byte-and-inc))
 520          ((= type 2) (ez-read-pc-var-and-inc))))
 521       types)
 522      (mapcar
 523       (lambda (type)
 524         (if (= type 1)
 525             'b
 526           'w))
 527       types))))
 528
 529 ;; Branches
 530
 531 (defun ez-do-branch (branch)
 532   (let* ((branch-byte (ez-read-pc-byte-and-inc))
 533          (invert (= 0 (logand branch-byte #b10000000)))
 534          (single-byte (> (logand branch-byte #b01000000) 0))
 535          (offset
 536           (if single-byte
 537               (logand branch-byte #b00111111)
 538             (let ((pos (= (logand branch-byte #b00100000) 0))
 539                   (val (+ (* 256 (logand branch-byte #b00011111))
 540                           (ez-read-pc-byte-and-inc))))
 541               (if pos
 542                   val
 543                 (- val 8192))))))
 544     (if (or (and branch (not invert))
 545             (and (not branch) invert))
 546         (cond
 547          ((= offset 0)
 548           (ez-op-rfalse))
 549          ((= offset 1)
 550           (ez-op-rtrue))
 551          (t
 552           (ez-set-pc (+ (ez-get-pc) offset -2)))))))
 553
 554 ;; Operations
 555
 556 (defvar ez-op-table
 557   '(((0op #x00) rtrue ez-op-rtrue)
 558     ((0op #x01) rfalse ez-op-rfalse)
 559     ((1op #x00) jz ez-op-jz)
 560     ((1op #x05) inc ez-op-inc)
 561     ((1op #x06) dec ez-op-dec)
 562     ((1op #x0B) ret ez-op-ret)
 563     ((0op #x08) ret_pulled ez-op-ret-pulled)
 564     ((1op #x0C) jump ez-op-jump)
 565     ((2op #x05) inc_jg ez-op-inc-jg)
 566     ((2op #x04) dec_jg ez-op-dec-jg)
 567     ((2op #x0D) store ez-op-store)
 568     ((1op #x0E) load ez-op-load)
 569     ((var #x01) storew ez-op-storew)
 570     ((2op #x0F) loadw ez-op-loadw)
 571     ((var #x02) storeb ez-op-storeb)
 572     ((2op #x10) loadb ez-op-loadb)
 573     ((2op #x01) je ez-op-je)
 574     ((2op #x02) jl ez-op-jl)
 575     ((2op #x03) jg ez-op-jg)
 576     ((2op #x06) jin ez-op-jin)
 577     ((2op #x07) test ez-op-test)
 578     ((2op #x08) or ez-op-or)
 579     ((2op #x09) and ez-op-and)
 580     ((2op #x14) add ez-op-add)
 581     ((2op #x15) sub ez-op-sub)
 582     ((2op #x16) mul ez-op-mul)
 583     ((2op #x17) div ez-op-div)
 584     ((2op #x18) mod ez-op-mod)
 585     ((var #x00) call_fv ez-op-callfv)
 586     ((1op #x01) get_sibling ez-op-get-sibling)
 587     ((1op #x02) get_child ez-op-get-child)
 588     ((1op #x03) get_parent ez-op-get-parent)
 589     ((2op #x0A) test_attr ez-op-test-attr)
 590     ((2op #x0B) set_attr ez-op-set-attr)
 591     ((2op #x0C) clear_attr ez-op-clear-attr)
 592     ((1op #x09) remove_obj ez-op-remove-obj)
 593     ((2op #x0E) insert_obj ez-op-insert-obj)
 594     ((var #x03) put_prop ez-op-put-prop)
 595     ((2op #x11) get_prop ez-op-get-prop)
 596     ((0op #x02) print ez-op-print)
 597     ((0op #x0B) new_line ez-op-new-line)
 598     ((var #x06) print_num ez-op-print-num)
 599     ((var #x05) print_char ez-op-print-char)
 600     ((1op #x0A) print_obj ez-op-print-obj)
 601     ((var #x04) read ez-op-read)))
 602
 603 (defun ez-op-ret (operands &optional operand-types)
 604   (let ((retval (car operands)))
 605     (ez-debug-message "\tReturning value %x" retval)
 606     (ez-pop-call-stack-frame)
 607     (ez-set-var (ez-read-pc-byte-and-inc) retval))
 608   'run)
 609
 610 (defun ez-op-ret-pulled (operands operand-types)
 611   (let ((retval (ez-routine-stack-pop)))
 612     (ez-debug-message "\tReturning value %x" retval)
 613     (ez-op-ret (list retval)))
 614   'run)
 615
 616 (defun ez-op-rtrue (&optional operands operand-types)
 617   (ez-op-ret (list 1))
 618   'run)
 619
 620 (defun ez-op-rfalse (&optional operands operand-types)
 621   (ez-op-ret (list 0))
 622   'run)
 623
 624 (defun ez-op-jz (operands operand-types)
 625   (ez-do-branch (= (car operands) 0))
 626   'run)
 627
 628 (defun ez-op-je (operands operand-types)
 629   (ez-do-branch (memq (car operands) (cdr operands)))
 630   'run)
 631
 632 (defun ez-op-jg (operands operand-types)
 633   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 634         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 635     (ez-do-branch (> s1 s2)))
 636   'run)
 637
 638 (defun ez-op-jl (operands operand-types)
 639   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 640         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 641     (ez-do-branch (< s1 s2)))
 642   'run)
 643
 644 (defun ez-op-inc-jg (operands operand-types)
 645   (let ((var (car operands)))
 646     (ez-op-inc (list var))
 647     (ez-op-jg (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 648   'run)
 649
 650 (defun ez-op-dec-jl (operands operand-types)
 651   (let ((var (car operands)))
 652     (ez-op-dec (list var))
 653     (ez-op-jl (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 654   'run)
 655
 656 (defun ez-op-jin (operands operand-types)
 657   (let ((obj (car operands))
 658         (n (cadr operands)))
 659     (ez-do-branch (or (= n 0)
 660                       (= n (ez-get-obj-parent obj)))))
 661   'run)
 662
 663 (defun ez-op-test (operands operand-types)
 664   (let ((a (car operands))
 665         (b (cadr operands)))
 666     (ez-do-branch (= (logand a b) b)))
 667   'run)
 668
 669 (defun ez-op-jump (operands operand-types)
 670   (let ((offset (if (eq (car operand-types) 'b)
 671                     (ez-decode-signed-byte (car operands))
 672                   (ez-decode-signed-word (car operands)))))
 673     (ez-set-pc (+ (ez-get-pc) offset -2)))
 674   'run)
 675
 676 (defun ez-op-inc (operands &optional operand-types)
 677   (let ((var (car operands)))
 678     (ez-set-var var (mod (+ 1 (ez-get-var var)) #x10000)))
 679   'run)
 680
 681 (defun ez-op-dec (operands &optional operand-types)
 682   (let ((var (car operands)))
 683     (ez-set-var var (mod (+ (ez-get-var var) 1) #x10000)))
 684   'run)
 685
 686 (defun ez-op-store (operands operand-types)
 687   (let ((var (car operands))
 688         (a (cadr operands)))
 689     (ez-set-var var a))
 690   'run)
 691
 692 (defun ez-op-load (operands operand-types)
 693   (let ((var (car operands)))
 694     (ez-set-var (ez-read-pc-byte-and-inc) (ez-get-var var)))
 695   'run)
 696
 697 (defun ez-op-storew (operands operand-types)
 698   (let ((baddr (car operands))
 699         (n (cadr operands))
 700         (a (caddr operands)))
 701     (ez-mem-set-word (+ baddr (* 2 n)) a))
 702   'run)
 703
 704 (defun ez-op-loadw (operands operand-types)
 705   (let ((baddr (car operands))
 706         (n (cadr operands)))
 707     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-word (+ baddr (* 2 n)))))
 708   'run)
 709
 710 (defun ez-op-storeb (operands operand-types)
 711   (let ((baddr (car operands))
 712         (n (cadr operands))
 713         (a (caddr operands)))
 714     (ez-mem-set-byte (+ baddr n) a))
 715   'run)
 716
 717 (defun ez-op-loadb (operands operand-types)
 718   (let ((baddr (car operands))
 719         (n (cadr operands)))
 720     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-byte (+ baddr n))))
 721   'run)
 722
 723 (defun ez-op-and (operands operand-types)
 724   (let ((a (car operands))
 725         (b (cadr operands)))
 726     (ez-set-var (ez-read-pc-byte-and-inc) (logand a b)))
 727   'run)
 728
 729 (defun ez-op-or (operands operand-types)
 730   (let ((a (car operands))
 731         (b (cadr operands)))
 732     (ez-set-var (ez-read-pc-byte-and-inc) (logior a b)))
 733   'run)
 734
 735 (defun ez-op-add (operands operand-types)
 736   (let ((a (car operands))
 737         (b (cadr operands)))
 738     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ a b) #x10000)))
 739   'run)
 740
 741 (defun ez-op-sub (operands operand-types)
 742   (let ((a (car operands))
 743         (b (cadr operands)))
 744     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ (- a b) #x10000) #x10000)))
 745   'run)
 746
 747 (defun ez-op-mul (a b)
 748   (let ((a (car operands))
 749         (b (cadr operands)))
 750     (ez-set-var (ez-read-pc-byte-and-inc) (mod (* a b) #x10000)))
 751   'run)
 752
 753 (defun ez-op-div (a b)
 754   (error "Not implemented"))
 755
 756 (defun ez-op-mod (a b)
 757   (error "Not implemented"))
 758
 759 (defun ez-op-callfv (operands operand-types)
 760   (let* ((raddr (car operands))
 761          (call-operands (cdr operands))
 762          (r (* 2 raddr))
 763          (L (ez-mem-ref-byte r))
 764          (n (length call-operands))
 765          (new-pc (+ r 1 (* L 2))))
 766     (if (= raddr 0)
 767         (ez-set-var (ez-read-pc-byte-and-inc) 0) ; Simply return 0
 768       (ez-add-call-stack-frame new-pc)
 769       (dotimes (i L)
 770         (if (< i n)
 771             (ez-set-local-var (+ i 1) (elt call-operands i))
 772           (ez-set-local-var (+ i 1) (ez-mem-ref-word (+ r 1 (* 2 i))))))))
 773   'run)
 774
 775 (defun ez-op-test-attr (operands operand-types)
 776   (let ((obj (car operands))
 777         (attr (cadr operands)))
 778     (ez-do-branch (= 1 (ez-get-obj-attr obj attr)))
 779     'run))
 780
 781 (defun ez-op-set-attr (operands operand-types)
 782   (let ((obj (car operands))
 783         (attr (cadr operands)))
 784     (ez-set-obj-attr obj attr 1))
 785   'run)
 786
 787 (defun ez-op-clear-attr (operands operand-types)
 788   (let ((obj (car operands))
 789         (attr (cadr operands)))
 790     (ez-set-obj-attr obj attr 0))
 791   'run)
 792
 793 (defun ez-op-get-sibling (operands operand-types)
 794   (let ((sib (ez-get-obj-sibling (car operands))))
 795     (ez-set-var (ez-read-pc-byte-and-inc) sib)
 796     (ez-do-branch (> sib 0)))
 797   'run)
 798
 799 (defun ez-op-get-child (operands operand-types)
 800   (let ((child (ez-get-obj-child (car operands))))
 801     (ez-set-var (ez-read-pc-byte-and-inc) child)
 802     (ez-do-branch (> child 0)))
 803   'run)
 804
 805 (defun ez-op-get-parent (operands operand-types)
 806   (let ((parent (ez-get-obj-parent (car operands))))
 807     (ez-set-var (ez-read-pc-byte-and-inc) parent))
 808   'run)
 809
 810 (defun ez-op-remove-obj (operands operand-types)
 811   (let ((obj (car operands)))
 812     (ez-remove-obj obj))
 813   'run)
 814
 815 (defun ez-op-insert-obj (operands operand-types)
 816   (let ((obj1 (car operands))
 817         (obj2 (cadr operands)))
 818     (ez-insert-obj obj1 obj2))
 819   'run)
 820
 821 (defun ez-op-put-prop (operands operand-types)
 822   (let* ((obj (car operands))
 823          (prop (cadr operands))
 824          (a (caddr operands)))
 825     (ez-set-obj-prop obj prop a))
 826   'run)
 827
 828 (defun ez-op-get-prop (operands operand-types)
 829   (let* ((obj (car operands))
 830          (prop (cadr operands)))
 831     (ez-set-var (ez-read-pc-byte-and-inc)
 832                 (ez-get-obj-prop obj prop)))
 833   'run)
 834
 835 (defun ez-op-print (operands operand-types)
 836   (let* ((word-count-and-string (ez-get-zstring-and-length (ez-get-pc)))
 837          (word-count (car word-count-and-string))
 838          (string (cdr word-count-and-string)))
 839     (ez-print string)
 840     (ez-increment-pc (* 2 word-count)))
 841   'run)
 842
 843 (defun ez-op-new-line (operands operand-types)
 844   (ez-print "\n")
 845   'run)
 846
 847 (defun ez-op-print-num (operands operand-types)
 848   (let ((s (ez-decode-signed-operand (car operands) (car operand-types))))
 849     (ez-print (number-to-string s)))
 850   'run)
 851
 852 (defun ez-op-print-char (operands operand-types)
 853   (let ((c (car operands)))
 854     (ez-print (string c)))
 855   'run)
 856
 857 (defun ez-op-print-obj (operands operand-types)
 858   (let ((obj (car operands)))
 859     (ez-print (ez-get-obj-name obj)))
 860   'run)
 861
 862 (defvar ez--next-read-args nil)
 863 (defun ez-op-read (operands operand-types)
 864   (let ((baddr1 (car operands))
 865         (baddr2 (cadr operands)))
 866     (setq ez--next-read-args (list baddr1 baddr2)))
 867   'wait-for-input)
 868
 869 (defun ez-op-read2 (input-string)
 870   (let ((baddr1 (car ez--next-read-args))
 871         (baddr2 (cadr ez--next-read-args)))
 872
 873     (dotimes (i (length input-string))
 874       (ez-mem-set-byte (+ baddr1 1 i) (downcase (elt input-string i))))
 875     (ez-mem-set-byte (+ baddr1 1 (length input-string)) 0)
 876
 877     ))
 878
 879 ;; Execution loop
 880
 881 (defun ez-load-and-run (filename)
 882   (ez-load-file filename)
 883   (ez-parse-header)
 884   (setq ez-call-stack (list (ez-make-call-stack-frame ez-start-pc)))
 885
 886   (ez-run))
 887
 888 (defvar ez-machine-state nil
 889   "Identifies the current executation state of the Z-machine.")
 890
 891 (defun ez-run ()
 892   (setq ez-machine-state 'run)
 893   (while (eq ez-machine-state 'run)
 894     (setq ez-machine-state (ez-execute-instr))))
 895
 896 ;;; Buffer and I/O
 897 ;;
 898
 899 (defvar ez-input-marker nil
 900   "Marker for input position in buffer.")
 901
 902 (defun ez-setup-buffer ()
 903   (with-current-buffer (get-buffer-create "*ez*")
 904     (ez-mode)
 905     (let ((inhibit-read-only t))
 906       (erase-buffer))
 907     (setq-local scroll-conservatively 1)
 908     (if (markerp ez-input-marker)
 909         (set-marker ez-input-marker (point-max))
 910       (setq ez-input-marker (point-max-marker)))
 911     (goto-char (point-max))))
 912
 913
 914 (defun ez-print (string)
 915   (with-current-buffer "*ez*"
 916     (save-excursion
 917       (goto-char ez-input-marker)
 918       (insert-before-markers string))))
 919
 920 (defun ez-enter ()
 921   (interactive)
 922   (if (not (eq ez-machine-state 'wait-for-input))
 923       (error "Z-machine not ready for input."))
 924   (let ((input-string (with-current-buffer "*ez*"
 925                         (buffer-substring ez-input-marker (point-max)))))
 926     (delete-region ez-input-marker (point-max))
 927     (ez-print (concat input-string "\n"))
 928     (ez-debug-message "\tReceived string \"%s\"" input-string)
 929     (ez-op-read2 input-string)
 930     (ez-run)))
 931
 932 ;; Debugging info
 933
 934 (defun ez-setup-debug-buffer ()
 935   (with-current-buffer (get-buffer-create "*ez-debug-trace*")
 936     (setq-local buffer-read-only t)
 937     (let ((inhibit-read-only t))
 938       (erase-buffer)
 939       (insert "--- Trace Start ---\n\n"))))
 940
 941 (defun ez-debug-message (&rest strings)
 942   (with-current-buffer (get-buffer-create "*ez-debug-trace*")
 943     (save-excursion
 944       (goto-char (point-max))
 945       (let ((inhibit-read-only t))
 946         (insert (apply #'format-message strings) "\n")))))
 947
 948 (defun ez-debug-memory ()
 949   (interactive)
 950   (with-current-buffer (get-buffer-create "*ez-debug-memory*")
 951     (setq-local buffer-read-only t)
 952     (let ((inhibit-read-only t)
 953           (old-point (point)))
 954       (hexl-mode-exit)
 955       (erase-buffer)
 956       (insert ez-memory)
 957       (setq-local buffer-undo-list nil)
 958       (hexl-mode)
 959       (goto-char old-point))))
 960
 961 ;; Mode
 962
 963 (defvar ez-mode-map
 964   (let ((map (make-sparse-keymap)))
 965     (define-key map (kbd "RET") 'ez-enter)
 966     map))
 967
 968 (define-derived-mode ez-mode text-mode "ez"
 969   "Major mode for EZ.")
 970
 971 (when (fboundp 'evil-set-initial-state)
 972   (evil-set-initial-state 'ez-mode 'insert))
 973
 974 (defun ez (zfile)
 975   (interactive "fEnter name of z3 story file: ")
 976   (if (get-buffer "*ez*")
 977       (switch-to-buffer "*ez*")
 978     (switch-to-buffer "*ez*")
 979     (ez-setup-buffer)
 980     (ez-load-and-run zfile))
 981   "Started EZ.")
 982
 983 (defun ez-debug ()
 984   (interactive)
 985   (ez-setup-buffer)
 986   (ez-setup-debug-buffer)
 987   (ez-load-and-run "zork1.z3"))
 988
 989 ;;; ez.el ends here