lurk.el

   1 ;;; lurk.el --- Little Unified iRc Klient -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 14 June 2021
   7 ;; Version: 1.0
   8 ;; Keywords: network
   9 ;; Homepage: http://thelambdalab.xyz/lurk
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (provide 'lurk)
  32
  33
  34 ;;; Customizations
  35 ;;
  36
  37 (defgroup lurk nil
  38   "Little Unified iRc Klient."
  39   :group 'network)
  40
  41 (defcustom lurk-nick "plugd"
  42   "Default nick.")
  43
  44 (defcustom lurk-default-quit-msg "Bye"
  45   "Default quit message when none supplied.")
  46
  47 (defcustom lurk-networks
  48   '(("libera" "irc.libera.chat" 6697)
  49     ("freenode" "chat.freenode.net" 6697)
  50     ("tilde" "tilde.chat" 6697)
  51     ("mbr" "mbrserver.com" 6667 :notls)
  52     ("local" "localhost" 6697))
  53   "IRC networks.")
  54
  55 (defcustom lurk-allow-ipv6 nil
  56   "Set to non-nil to allow use of IPv6.")
  57
  58 (defcustom lurk-show-joins nil
  59   "Set to non-nil to be notified of joins, parts and quits.")
  60
  61 ;;; Faces
  62 ;;
  63
  64 (defface lurk-text
  65   '((t :inherit default))
  66   "Face used for Lurk text.")
  67
  68 (defface lurk-prompt
  69   '((t :inherit org-priority))
  70   "Face used for the prompt.")
  71
  72 (defface lurk-context
  73   '((t :inherit org-tag))
  74   "Face used for the context name in the prompt.")
  75
  76 (defface lurk-faded
  77   '((t :inherit org-agenda-dimmed-todo-face))
  78   "Face used for faded Lurk text.")
  79
  80 (defface lurk-error
  81   '((t :inherit font-lock-regexp-grouping-construct))
  82   "Face used for Lurk error text.")
  83
  84 ;;; Global variables
  85 ;;
  86
  87 (defvar lurk-version "Lurk v0.1")
  88
  89 (defvar lurk-notice-prefix "-!-")
  90
  91 (defvar lurk-error-prefix "!!!")
  92
  93 (defvar lurk-prompt-string
  94   (propertize "> " 'face 'lurk-prompt))
  95
  96
  97 ;;; Network process
  98 ;;
  99
 100 (defvar lurk-response "")
 101
 102 (defun lurk-filter (proc string)
 103   (dolist (line (split-string (concat lurk-response string) "\n"))
 104     (if (string-suffix-p "\r" line)
 105         (lurk-eval-msg-string (string-trim line))
 106       (setq lurk-response line))))
 107
 108 (defun lurk-sentinel (proc string)
 109   (unless (equal "open" (string-trim string))
 110     (lurk-display-error "Disconnected from server.")
 111     (clrhash lurk-contexts)
 112     (lurk-set-current-context nil)
 113     (lurk-render-prompt)
 114     (cancel-timer lurk-ping-timer)))
 115
 116 (defun lurk-start-process (network)
 117   (let* ((row (assoc network lurk-networks))
 118          (host (elt row 1))
 119          (port (elt row 2))
 120          (flags (seq-drop row 3)))
 121     (make-network-process :name "lurk"
 122                           :host host
 123                           :service port
 124                           :family (if lurk-allow-ipv6 nil 'ipv4)
 125                           :filter #'lurk-filter
 126                           :sentinel #'lurk-sentinel
 127                           :nowait nil
 128                           :tls-parameters (if (memq :notls flags)
 129                                               nil
 130                                             (cons 'gnutls-x509pki
 131                                                   (gnutls-boot-parameters
 132                                                    :type 'gnutls-x509pki
 133                                                    :hostname host)))
 134                           :buffer "*lurk*")))
 135
 136 (defvar lurk-ping-timer nil)
 137 (defvar lurk-ping-period 60)
 138
 139 (defun lurk-ping-function ()
 140   (lurk-send-msg (lurk-msg nil nil "PING" (car (process-contact (get-process "lurk")))))
 141   (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))
 142
 143 (defun lurk-connect (network)
 144   (if (get-process "lurk")
 145       (lurk-display-error "Already connected.  Disconnect first.")
 146     (if (not (assoc network lurk-networks))
 147         (lurk-display-error "Network '" network "' is unknown.")
 148       (clrhash lurk-contexts)
 149       (lurk-set-current-context nil)
 150       (lurk-start-process network)
 151       (lurk-send-msg (lurk-msg nil nil "USER" lurk-nick 0 "*" lurk-nick))
 152       (lurk-send-msg (lurk-msg nil nil "NICK" lurk-nick))
 153       (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))))
 154
 155 (defun lurk-connected-p ()
 156   (let ((proc (get-process "lurk")))
 157     (and proc (eq (process-status proc) 'open))))
 158
 159 (defun lurk-send-msg (msg)
 160   (let ((proc (get-process "lurk")))
 161     (if (and proc (eq (process-status proc) 'open))
 162         (process-send-string proc (concat (lurk-msg->string msg) "\r\n"))
 163       (lurk-display-error "No server connection established.")
 164       (error "No server connection established"))))
 165
 166
 167 ;;; Server messages
 168 ;;
 169
 170 (defun lurk--as-string (obj)
 171   (if obj
 172       (with-output-to-string (princ obj))
 173     nil))
 174
 175 (defun lurk-msg (tags src cmd &rest params)
 176   (list (lurk--as-string tags)
 177         (lurk--as-string src)
 178         (upcase (lurk--as-string cmd))
 179         (mapcar #'lurk--as-string
 180                 (if (and params (listp (elt params 0)))
 181                     (elt params 0)
 182                   params))))
 183
 184 (defun lurk-msg-tags (msg) (elt msg 0))
 185 (defun lurk-msg-src (msg) (elt msg 1))
 186 (defun lurk-msg-cmd (msg) (elt msg 2))
 187 (defun lurk-msg-params (msg) (elt msg 3))
 188 (defun lurk-msg-trail (msg)
 189   (let ((params (lurk-msg-params msg)))
 190     (if params
 191         (elt params (- (length params) 1)))))
 192
 193 (defvar lurk-msg-regex
 194   (rx
 195    (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
 196         (* whitespace))
 197    (opt (: ":" (: (group (* (not (any space "!" "@"))))
 198                   (* (not (any space)))))
 199         (* whitespace))
 200    (group (: (* (not whitespace))))
 201    (* whitespace)
 202    (opt (group (+ not-newline))))
 203   "Regex used to parse IRC messages.
 204 Note that this regex is incomplete.  Noteably, we discard the non-nick
 205 portion of the source component of the message, as LURK doesn't use this.")
 206
 207 (defun lurk-string->msg (string)
 208   (if (string-match lurk-msg-regex string)
 209       (let* ((tags (match-string 1 string))
 210              (src (match-string 2 string))
 211              (cmd (upcase (match-string 3 string)))
 212              (params-str (match-string 4 string))
 213              (params
 214               (if params-str
 215                   (let* ((idx (cl-search ":" params-str))
 216                          (l (split-string (string-trim (substring params-str 0 idx))))
 217                          (r (if idx (list (substring params-str (+ 1 idx))) nil)))
 218                     (append l r))
 219                 nil)))
 220         (apply #'lurk-msg (append (list tags src cmd) params)))
 221     (error "Failed to parse string " string)))
 222
 223 (defun lurk--filtered-join (&rest args)
 224   (string-join (seq-filter (lambda (el) el) args) " "))
 225
 226 (defun lurk-msg->string (msg)
 227   (let ((tags (lurk-msg-tags msg))
 228         (src (lurk-msg-src msg))
 229         (cmd (lurk-msg-cmd msg))
 230         (params (lurk-msg-params msg)))
 231     (lurk--filtered-join
 232      (if tags (concat "@" tags) nil)
 233      (if src (concat ":" src) nil)
 234      cmd
 235      (if (> (length params) 1)
 236          (string-join (seq-take params (- (length params) 1)) " ")
 237        nil)
 238      (if (> (length params) 0)
 239          (concat ":" (elt params (- (length params) 1)))
 240        nil))))
 241
 242
 243 ;;; Contexts
 244 ;;
 245
 246 (defvar lurk-current-context nil)
 247 (defvar lurk-contexts (make-hash-table :test #'equal))
 248
 249 (defun lurk-add-context (name)
 250   (puthash name nil lurk-contexts))
 251
 252 (defun lurk-del-context (name)
 253   (remhash name lurk-contexts))
 254
 255 (defun lurk-get-context-users (name)
 256   (gethash name lurk-contexts))
 257
 258 (defun lurk-add-context-users (context users)
 259   (puthash context
 260            (append users
 261                    (gethash context lurk-contexts))
 262            lurk-contexts))
 263
 264 (defun lurk-del-context-user (context user)
 265   (puthash context
 266            (remove user (gethash context lurk-contexts))
 267            lurk-contexts))
 268
 269 (defun lurk-del-user (user)
 270   (dolist (context (lurk-get-context-list))
 271     (lurk-del-context-user context user)))
 272
 273 (defun lurk-rename-user (old-nick new-nick)
 274   (dolist (context (lurk-get-context-list))
 275     (lurk-del-context-user context old-nick)
 276     (lurk-add-context-users context (list new-nick))))
 277
 278 (defun lurk-get-context-type (name)
 279   (cond
 280    ((string-prefix-p "#" name) 'channel)
 281    ((string-match-p (rx (or "." "localhost")) name) 'host)
 282    (t 'nick)))
 283
 284 (defun lurk-get-context-list ()
 285   (let ((res nil))
 286     (maphash (lambda (key val)
 287                (cl-pushnew key res))
 288              lurk-contexts)
 289     res))
 290
 291 (defun lurk-get-next-context (&optional prev)
 292   (if lurk-current-context
 293       (let* ((context-list (if prev
 294                                (reverse (lurk-get-context-list))
 295                              (lurk-get-context-list)))
 296              (context-list* (member lurk-current-context context-list)))
 297         (if (> (length context-list*) 1)
 298             (cadr context-list*)
 299           (car context-list)))
 300     nil))
 301
 302 (defun lurk-set-current-context (context)
 303   (setq lurk-current-context context)
 304   (lurk-highlight-context context))
 305
 306 (defun lurk-cycle-contexts (&optional rev)
 307   (if lurk-current-context
 308       (progn
 309         (lurk-set-current-context (lurk-get-next-context rev))
 310         (lurk-render-prompt))
 311     (lurk-display-error "No channels joined.")))
 312
 313
 314 ;;; Buffer
 315 ;;
 316
 317 (defun lurk-render-prompt ()
 318   (with-current-buffer "*lurk*"
 319     (let ((update-point (= lurk-input-marker (point)))
 320           (update-window-points (mapcar (lambda (w)
 321                                           (list (= (window-point w) lurk-input-marker)
 322                                                 w))
 323                                         (get-buffer-window-list nil nil t))))
 324       (save-excursion
 325         (set-marker-insertion-type lurk-prompt-marker nil)
 326         (set-marker-insertion-type lurk-input-marker t)
 327         (let ((inhibit-read-only t))
 328           (delete-region lurk-prompt-marker lurk-input-marker)
 329           (goto-char lurk-prompt-marker)
 330           (insert
 331            (propertize (if lurk-current-context
 332                            lurk-current-context
 333                          "")
 334                        'face 'lurk-context
 335                        'read-only t)
 336            (propertize lurk-prompt-string
 337                        'face 'lurk-prompt
 338                        'read-only t
 339                        'rear-nonsticky t)))
 340         (set-marker-insertion-type lurk-input-marker nil))
 341       (if update-point
 342           (goto-char lurk-input-marker))
 343       (dolist (v update-window-points)
 344         (if (car v)
 345             (set-window-point (cadr v) lurk-input-marker))))))
 346
 347 (defvar lurk-prompt-marker nil
 348   "Marker for prompt position in LURK buffer.")
 349
 350 (defvar lurk-input-marker nil
 351   "Marker for prompt position in LURK buffer.")
 352
 353 (defun lurk-setup-buffer ()
 354   (with-current-buffer (get-buffer-create "*lurk*")
 355     (setq-local scroll-conservatively 1)
 356     (if (markerp lurk-prompt-marker)
 357         (set-marker lurk-prompt-marker (point-max))
 358       (setq lurk-prompt-marker (point-max-marker)))
 359     (if (markerp lurk-input-marker)
 360         (set-marker lurk-input-marker (point-max))
 361       (setq lurk-input-marker (point-max-marker)))
 362     (goto-char (point-max))
 363     (lurk-render-prompt)))
 364
 365
 366 ;;; Output formatting and highlighting
 367 ;;
 368
 369 ;; Partially-implemented idea: the face text property can be
 370 ;; a list of faces, applied in order.  By assigning each context
 371 ;; a unique list and keeping track of these in a hash table, we can
 372 ;; easily switch the face corresponding to a particular context
 373 ;; by modifying the elements of this list.
 374 ;;
 375 ;; More subtly, we make only the cdrs of this list shared among
 376 ;; all text of a given context, allowing the cars to be different
 377 ;; and for different elements of the context-specific text to have
 378 ;; different styling.
 379
 380 ;; Additionally, we can allow selective hiding of contexts via
 381 ;; the buffer-invisibility-spec.
 382
 383 (defvar lurk-context-facelists (make-hash-table :test 'equal)
 384   "List of seen contexts and associated face lists.")
 385
 386 (defun lurk-get-context-facelist (context)
 387   (let ((facelist (gethash context lurk-context-facelists)))
 388     (unless facelist
 389       (setq facelist (list 'lurk-text))
 390       (puthash context facelist lurk-context-facelists))
 391     facelist))
 392
 393 (defun lurk-display-string (context &rest strings)
 394   (with-current-buffer (get-buffer-create "*lurk*")
 395     (save-excursion
 396       (goto-char lurk-prompt-marker)
 397       (let ((inhibit-read-only t)
 398             (old-pos (marker-position lurk-prompt-marker))
 399             (adaptive-fill-regexp (rx (= 6 anychar)))
 400             (fill-column 80)
 401             (context-atom (if context (intern context) nil)))
 402         (insert-before-markers
 403          (propertize (concat (format-time-string "%H:%M") " ")
 404                      'face (lurk-get-context-facelist context)
 405                      'read-only t
 406                      'context context
 407                      'invisible context-atom
 408                      'help-echo (concat "Context: " (or context "none")))
 409          (propertize (concat (apply #'concat strings) "\n")
 410                      'face (lurk-get-context-facelist context)
 411                      'read-only t
 412                      'context context
 413                      'invisible context-atom
 414                      'help-echo (concat "Context: " (or context "none"))))
 415         (fill-region old-pos lurk-prompt-marker nil t)))))
 416
 417 (defun lurk-display-message (from to text)
 418   (let ((context (if (eq 'channel (lurk-get-context-type to))
 419                      to
 420                    (if (equal to lurk-nick) from to))))
 421     (if (string-match (rx (: "\01ACTION " (group (* (not "\01"))) "\01")) text)
 422         (lurk-display-string context to " * " from " " (match-string 1 text))
 423       (lurk-display-string
 424        context
 425        (pcase (lurk-get-context-type to)
 426          ('channel (concat to " <" from "> "))
 427          ('nick (concat "[" from " -> " to "] "))
 428          (_
 429           (error "Unsupported context type")))
 430        text))))
 431
 432 (defun lurk-display-notice (context &rest notices)
 433   (lurk-display-string
 434    context
 435    lurk-notice-prefix " "
 436    (apply #'concat notices)))
 437
 438 (defun lurk-display-error (&rest messages)
 439   (lurk-display-string
 440    nil
 441    lurk-error-prefix " "
 442    (apply #'concat messages)))
 443
 444 (defun lurk-highlight-context (context)
 445   (maphash
 446    (lambda (this-context facelist)
 447      (if (equal this-context context)
 448          (setcar facelist 'lurk-text)
 449        (setcar facelist 'lurk-faded)))
 450    lurk-context-facelists)
 451   (force-window-update "*lurk*"))
 452
 453 (defun lurk-zoom-in (context)
 454   (with-current-buffer "*lurk*"
 455     (maphash
 456      (lambda (this-context _)
 457        (when this-context
 458          (let ((this-context-atom (intern this-context)))
 459            (if (equal this-context context)
 460                (remove-from-invisibility-spec this-context-atom)
 461              (add-to-invisibility-spec this-context-atom)))))
 462      lurk-context-facelists)
 463     (force-window-update "*lurk*")))
 464
 465 (defun lurk-zoom-out ()
 466   (with-current-buffer "*lurk*"
 467     (maphash
 468      (lambda (this-context _)
 469        (let ((this-context-atom (if this-context (intern this-context) nil)))
 470          (remove-from-invisibility-spec this-context-atom)))
 471      lurk-context-facelists)
 472     (force-window-update "*lurk*")))
 473
 474 ;;; Message evaluation
 475 ;;
 476
 477 (defun lurk-eval-msg-string (string)
 478   ;; (lurk-display-string nil string)
 479   (let* ((msg (lurk-string->msg string)))
 480     (pcase (lurk-msg-cmd msg)
 481       ("PING"
 482        (lurk-send-msg
 483         (lurk-msg nil nil "PONG" (lurk-msg-params msg))))
 484        ;; (lurk-display-notice nil "ping-pong (server initiated)"))
 485
 486       ("PONG")
 487        ;; (lurk-display-notice nil "ping-pong (client initiated)"))
 488
 489       ("001"
 490        (let* ((params (lurk-msg-params msg))
 491               (nick (elt params 0))
 492               (text (string-join (seq-drop params 1) " ")))
 493          (setq lurk-nick nick)
 494          (lurk-display-notice nil text)))
 495
 496       ("353" ; NAMEREPLY
 497        (let* ((params (lurk-msg-params msg))
 498               (channel (elt params 2))
 499               (names (split-string (elt params 3))))
 500          (lurk-add-context-users channel names)))
 501
 502       ("366" ; ENDOFNAMES
 503        (let* ((params (lurk-msg-params msg))
 504               (channel (elt params 1)))
 505          (lurk-display-notice
 506           channel
 507           (lurk--as-string (length (lurk-get-context-users channel)))
 508           " users in " channel)))
 509
 510       ("331"
 511        (let* ((params (lurk-msg-params msg))
 512               (channel (elt params 1)))
 513          (lurk-display-notice
 514           channel
 515           "No topic set.")))
 516
 517       ("332"
 518        (let* ((params (lurk-msg-params msg))
 519               (channel (elt params 1))
 520               (topic (elt params 2)))
 521          (lurk-display-notice channel "Topic: " topic)))
 522
 523       ((rx (= 3 (any digit)))
 524        (lurk-display-notice nil (mapconcat 'identity (cdr (lurk-msg-params msg)) " ")))
 525
 526       ((and "JOIN"
 527             (guard (equal lurk-nick (lurk-msg-src msg))))
 528        (let ((channel (car (lurk-msg-params msg))))
 529          (lurk-add-context channel)
 530          (lurk-set-current-context channel)
 531          (lurk-display-notice channel "Joining channel " channel)
 532          (lurk-render-prompt)))
 533
 534       ("JOIN"
 535        (let ((channel (car (lurk-msg-params msg)))
 536              (nick (lurk-msg-src msg)))
 537          (lurk-add-context-users channel (list nick))
 538          (if lurk-show-joins
 539              (lurk-display-notice channel nick " joined channel " channel))))
 540
 541       ((and "PART"
 542             (guard (equal lurk-nick (lurk-msg-src msg))))
 543        (let ((channel (car (lurk-msg-params msg))))
 544          (lurk-display-notice channel "Left channel " channel)
 545          (lurk-del-context channel)
 546          (if (equal channel lurk-current-context)
 547              (lurk-set-current-context (lurk-get-next-context)))
 548          (lurk-render-prompt)))
 549
 550       ("PART"
 551        (let ((channel (car (lurk-msg-params msg)))
 552              (nick (lurk-msg-src msg)))
 553          (lurk-del-context-user channel nick)
 554          (if lurk-show-joins
 555              (lurk-display-notice channel nick " left channel " channel))))
 556
 557       ("QUIT"
 558        (let ((nick (lurk-msg-src msg))
 559              (reason (mapconcat 'identity (lurk-msg-params msg) " ")))
 560          (lurk-del-user nick)
 561          (if lurk-show-joins
 562              (lurk-display-notice nil nick " quit: " reason))))
 563
 564       ((and "NICK"
 565             (guard (equal lurk-nick (lurk-msg-src msg))))
 566        (setq lurk-nick (car (lurk-msg-params msg)))
 567        (lurk-display-notice nil "Set nick to " lurk-nick))
 568
 569       ("NICK"
 570        (let ((old-nick (lurk-msg-src msg))
 571              (new-nick (car (lurk-msg-params msg))))
 572          (lurk-display-notice nil old-nick " is now known as " new-nick)
 573          (lurk-rename-user old-nick new-nick)))
 574
 575       ("NOTICE"
 576        (let ((nick (lurk-msg-src msg))
 577              (channel (car (lurk-msg-params msg)))
 578              (text (cadr (lurk-msg-params msg))))
 579          (pcase text
 580            ((rx (: "\01VERSION "
 581                    (let version (* (not "\01")))
 582                    "\01"))
 583             (lurk-display-notice nil "CTCP version reply from " nick ": " version))
 584            (_
 585             (lurk-display-notice nil text)))))
 586
 587       ("PRIVMSG"
 588        (let* ((from (lurk-msg-src msg))
 589               (params (lurk-msg-params msg))
 590               (to (car params))
 591               (text (cadr params)))
 592          (pcase text
 593            ("\01VERSION\01"
 594             (let ((version-string (concat lurk-version " - running on GNU Emacs " emacs-version)))
 595               (lurk-send-msg (lurk-msg nil nil "NOTICE"
 596                                        (list from (concat "\01VERSION "
 597                                                           version-string
 598                                                           "\01")))))
 599             (lurk-display-notice nil "CTCP version request received from " from))
 600
 601            ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
 602             (lurk-send-msg (lurk-msg nil nil "NOTICE" (list from ping)))
 603             (lurk-display-notice "CTCP ping received from " from))
 604
 605            ("\01USERINFO\01"
 606             (lurk-display-notice "CTCP userinfo request from " from " (no response sent)"))
 607
 608            (_
 609             (if (and (equal from "BitBot")
 610                      (equal to "##moshpit")
 611                      (cl-search "\\_o< QUACK!" text))
 612               (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to ",bef")))
 613             (lurk-display-message from to text)))))
 614       (_
 615        (lurk-display-notice nil (lurk-msg->string msg))))))
 616
 617
 618 ;;; Command entering
 619 ;;
 620
 621 (defun lurk-enter-string (string)
 622   (if (string-prefix-p "/" string)
 623       (pcase (substring string 1)
 624         ((rx (: "CONNECT " (let network (* not-newline))))
 625          (lurk-display-notice nil "Attempting to connect to " network "...")
 626          (lurk-connect network))
 627
 628         ((rx (: "TOPIC " (let new-topic (* not-newline))))
 629          (lurk-send-msg (lurk-msg nil nil "TOPIC" lurk-current-context new-topic)))
 630
 631         ((rx (: "ME " (let action (* not-newline))))
 632          (let ((ctcp-text (concat "\01ACTION " action "\01")))
 633            (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 634                                     (list lurk-current-context ctcp-text)))
 635            (lurk-display-message lurk-nick lurk-current-context ctcp-text)))
 636
 637         ((rx (: "VERSION" " " (let nick (+ (not whitespace)))))
 638          (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 639                                   (list nick "\01VERSION\01")))
 640          (lurk-display-notice nil "CTCP version request sent to " nick))
 641
 642         ((rx "PART" (opt (: " " (let channel (* not-newline)))))
 643          (if (or lurk-current-context channel)
 644              (lurk-send-msg (lurk-msg nil nil "PART" (if channel
 645                                                          channel
 646                                                        lurk-current-context)))
 647            (lurk-display-error "No current channel to leave.")))
 648
 649         ((rx "QUIT" (opt (: " " (let quit-msg (* not-newline)))))
 650          (lurk-send-msg (lurk-msg nil nil "QUIT"
 651                                   (or quit-msg lurk-default-quit-msg))))
 652
 653         ((rx (: "NICK" (* whitespace) string-end))
 654          (lurk-display-notice nil "Current nick: " lurk-nick))
 655
 656         ((rx (: "NICK" (+ whitespace) (let nick (+ (not whitespace)))))
 657          (if (lurk-connected-p)
 658              (lurk-send-msg (lurk-msg nil nil "NICK" nick))
 659            (setq lurk-nick nick)
 660            (lurk-display-notice nil "Set default nick to '" nick "'")))
 661
 662         ((rx "MSG "
 663              (let to (* (not whitespace)))
 664              " "
 665              (let text (* not-newline)))
 666          (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to text))
 667          (lurk-display-message lurk-nick to text))
 668
 669         ((rx (: (let cmd-str (+ (not whitespace)))
 670                 (opt (: " " (let params-str (* not-newline))))))
 671          (lurk-send-msg (lurk-msg nil nil (upcase cmd-str)
 672                                   (if params-str
 673                                       (split-string params-str)
 674                                     nil)))))
 675
 676     (unless (string-empty-p string)
 677       (if lurk-current-context
 678           (progn
 679             (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 680                                      lurk-current-context
 681                                      string))
 682             (lurk-display-message lurk-nick lurk-current-context string))
 683         (lurk-display-error "No current context.")))))
 684
 685 (defun lurk-enter ()
 686   "Enter current contents of line after prompt."
 687   (interactive)
 688   (with-current-buffer "*lurk*"
 689     (let ((line (buffer-substring lurk-input-marker (point-max))))
 690       (let ((inhibit-read-only t))
 691         (delete-region lurk-input-marker (point-max)))
 692       (lurk-enter-string line))))
 693
 694
 695 ;;; Command completion
 696 ;;
 697
 698 ;;; Interactive functions
 699 ;;
 700
 701 (defun lurk-cycle-contexts-forward ()
 702   (interactive)
 703   (lurk-cycle-contexts))
 704
 705 (defun lurk-cycle-contexts-reverse ()
 706   (interactive)
 707   (lurk-cycle-contexts t))
 708
 709 (defvar lurk-zoomed nil
 710   "Keeps track of zoom status.")
 711
 712 (defun lurk-toggle-zoom ()
 713   (interactive)
 714   (if lurk-zoomed
 715       (lurk-zoom-out)
 716     (lurk-zoom-in lurk-current-context))
 717   (setq lurk-zoomed (not lurk-zoomed)))
 718
 719 ;;; Mode
 720 ;;
 721
 722 (defvar lurk-mode-map
 723   (let ((map (make-sparse-keymap)))
 724     (define-key map (kbd "RET") 'lurk-enter)
 725     (define-key map (kbd "<tab>") 'lurk-complete)
 726     (define-key map (kbd "C-c C-z") 'lurk-toggle-zoom)
 727     (define-key map (kbd "<C-tab>") 'lurk-cycle-contexts-forward)
 728     (define-key map (kbd "<C-S-tab>") 'lurk-cycle-contexts-reverse)
 729     map))
 730
 731 (define-derived-mode lurk-mode text-mode "lurk"
 732   "Major mode for LURK.")
 733
 734 (when (fboundp 'evil-set-initial-state)
 735   (evil-set-initial-state 'lurk-mode 'insert))
 736
 737 ;;; Main start procedure
 738 ;;
 739
 740 (defun lurk ()
 741   "Switch to *lurk* buffer."
 742   (interactive)
 743   (if (get-buffer "*lurk*")
 744       (switch-to-buffer "*lurk*")
 745     (switch-to-buffer "*lurk*"))
 746   (lurk-mode)
 747   (lurk-setup-buffer)
 748   "Started LURK.")
 749
 750
 751 ;;; lurk.el ends here