lurk.el

   1 ;;; lurk.el --- Little Uni-buffer iRc Klient -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 14 June 2021
   7 ;; Version: 1.0
   8 ;; Keywords: network
   9 ;; Homepage: http://thelambdalab.xyz/lurk
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (provide 'lurk)
  32
  33
  34 ;;; Customizations
  35 ;;
  36
  37 (defgroup lurk nil
  38   "Little Unified iRc Klient."
  39   :group 'network)
  40
  41 (defcustom lurk-nick "plugd"
  42   "Default nick.")
  43
  44 (defcustom lurk-default-quit-msg "Bye"
  45   "Default quit message when none supplied.")
  46
  47 (defcustom lurk-networks
  48   '(("libera" "irc.libera.chat" 6697)
  49     ("freenode" "chat.freenode.net" 6697)
  50     ("tilde" "tilde.chat" 6697)
  51     ("mbr" "mbrserver.com" 6667 :notls)
  52     ("local" "localhost" 6697))
  53   "IRC networks.")
  54
  55 (defcustom lurk-allow-ipv6 nil
  56   "Set to non-nil to allow use of IPv6.")
  57
  58 (defcustom lurk-show-joins nil
  59   "Set to non-nil to be notified of joins, parts and quits.")
  60
  61 ;;; Faces
  62 ;;
  63
  64 (defface lurk-text
  65   '((t :inherit default))
  66   "Face used for Lurk text.")
  67
  68 (defface lurk-prompt
  69   '((t :inherit org-priority))
  70   "Face used for the prompt.")
  71
  72 (defface lurk-context
  73   '((t :inherit org-tag))
  74   "Face used for the context name in the prompt.")
  75
  76 (defface lurk-faded
  77   '((t :inherit org-agenda-dimmed-todo-face))
  78   "Face used for faded Lurk text.")
  79
  80 (defface lurk-error
  81   '((t :inherit font-lock-regexp-grouping-construct))
  82   "Face used for Lurk error text.")
  83
  84 ;;; Global variables
  85 ;;
  86
  87 (defvar lurk-version "Lurk v0.1")
  88
  89 (defvar lurk-notice-prefix "-!-")
  90
  91 (defvar lurk-error-prefix "!!!")
  92
  93 (defvar lurk-prompt-string
  94   (propertize "> " 'face 'lurk-prompt))
  95
  96
  97 ;;; Network process
  98 ;;
  99
 100 (defvar lurk-response "")
 101
 102 (defun lurk-filter (proc string)
 103   (dolist (line (split-string (concat lurk-response string) "\n"))
 104     (if (string-suffix-p "\r" line)
 105         (lurk-eval-msg-string (string-trim line))
 106       (setq lurk-response line))))
 107
 108 (defun lurk-sentinel (proc string)
 109   (unless (equal "open" (string-trim string))
 110     (lurk-display-error "Disconnected from server.")
 111     (clrhash lurk-contexts)
 112     (lurk-set-current-context nil)
 113     (lurk-render-prompt)
 114     (cancel-timer lurk-ping-timer)))
 115
 116 (defun lurk-start-process (network)
 117   (let* ((row (assoc network lurk-networks))
 118          (host (elt row 1))
 119          (port (elt row 2))
 120          (flags (seq-drop row 3)))
 121     (make-network-process :name "lurk"
 122                           :host host
 123                           :service port
 124                           :family (if lurk-allow-ipv6 nil 'ipv4)
 125                           :filter #'lurk-filter
 126                           :sentinel #'lurk-sentinel
 127                           :nowait nil
 128                           :tls-parameters (if (memq :notls flags)
 129                                               nil
 130                                             (cons 'gnutls-x509pki
 131                                                   (gnutls-boot-parameters
 132                                                    :type 'gnutls-x509pki
 133                                                    :hostname host)))
 134                           :buffer "*lurk*")))
 135
 136 (defvar lurk-ping-timer nil)
 137 (defvar lurk-ping-period 60)
 138
 139 (defun lurk-ping-function ()
 140   (lurk-send-msg (lurk-msg nil nil "PING" (car (process-contact (get-process "lurk")))))
 141   (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))
 142
 143 (defun lurk-connect (network)
 144   (if (get-process "lurk")
 145       (lurk-display-error "Already connected.  Disconnect first.")
 146     (if (not (assoc network lurk-networks))
 147         (lurk-display-error "Network '" network "' is unknown.")
 148       (clrhash lurk-contexts)
 149       (lurk-set-current-context nil)
 150       (lurk-start-process network)
 151       (lurk-send-msg (lurk-msg nil nil "USER" lurk-nick 0 "*" lurk-nick))
 152       (lurk-send-msg (lurk-msg nil nil "NICK" lurk-nick))
 153       (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))))
 154
 155 (defun lurk-connected-p ()
 156   (let ((proc (get-process "lurk")))
 157     (and proc (eq (process-status proc) 'open))))
 158
 159 (defun lurk-send-msg (msg)
 160   (let ((proc (get-process "lurk")))
 161     (if (and proc (eq (process-status proc) 'open))
 162         (process-send-string proc (concat (lurk-msg->string msg) "\r\n"))
 163       (lurk-display-error "No server connection established.")
 164       (error "No server connection established"))))
 165
 166
 167 ;;; Server messages
 168 ;;
 169
 170 (defun lurk--as-string (obj)
 171   (if obj
 172       (with-output-to-string (princ obj))
 173     nil))
 174
 175 (defun lurk-msg (tags src cmd &rest params)
 176   (list (lurk--as-string tags)
 177         (lurk--as-string src)
 178         (upcase (lurk--as-string cmd))
 179         (mapcar #'lurk--as-string
 180                 (if (and params (listp (elt params 0)))
 181                     (elt params 0)
 182                   params))))
 183
 184 (defun lurk-msg-tags (msg) (elt msg 0))
 185 (defun lurk-msg-src (msg) (elt msg 1))
 186 (defun lurk-msg-cmd (msg) (elt msg 2))
 187 (defun lurk-msg-params (msg) (elt msg 3))
 188 (defun lurk-msg-trail (msg)
 189   (let ((params (lurk-msg-params msg)))
 190     (if params
 191         (elt params (- (length params) 1)))))
 192
 193 (defvar lurk-msg-regex
 194   (rx
 195    (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
 196         (* whitespace))
 197    (opt (: ":" (: (group (* (not (any space "!" "@"))))
 198                   (* (not (any space)))))
 199         (* whitespace))
 200    (group (: (* (not whitespace))))
 201    (* whitespace)
 202    (opt (group (+ not-newline))))
 203   "Regex used to parse IRC messages.
 204 Note that this regex is incomplete.  Noteably, we discard the non-nick
 205 portion of the source component of the message, as LURK doesn't use this.")
 206
 207 (defun lurk-string->msg (string)
 208   (if (string-match lurk-msg-regex string)
 209       (let* ((tags (match-string 1 string))
 210              (src (match-string 2 string))
 211              (cmd (upcase (match-string 3 string)))
 212              (params-str (match-string 4 string))
 213              (params
 214               (if params-str
 215                   (let* ((idx (cl-search ":" params-str))
 216                          (l (split-string (string-trim (substring params-str 0 idx))))
 217                          (r (if idx (list (substring params-str (+ 1 idx))) nil)))
 218                     (append l r))
 219                 nil)))
 220         (apply #'lurk-msg (append (list tags src cmd) params)))
 221     (error "Failed to parse string " string)))
 222
 223 (defun lurk--filtered-join (&rest args)
 224   (string-join (seq-filter (lambda (el) el) args) " "))
 225
 226 (defun lurk-msg->string (msg)
 227   (let ((tags (lurk-msg-tags msg))
 228         (src (lurk-msg-src msg))
 229         (cmd (lurk-msg-cmd msg))
 230         (params (lurk-msg-params msg)))
 231     (lurk--filtered-join
 232      (if tags (concat "@" tags) nil)
 233      (if src (concat ":" src) nil)
 234      cmd
 235      (if (> (length params) 1)
 236          (string-join (seq-take params (- (length params) 1)) " ")
 237        nil)
 238      (if (> (length params) 0)
 239          (concat ":" (elt params (- (length params) 1)))
 240        nil))))
 241
 242
 243 ;;; Contexts
 244 ;;
 245
 246 (defvar lurk-current-context nil)
 247 (defvar lurk-contexts (make-hash-table :test #'equal))
 248
 249 (defun lurk-add-context (name)
 250   (puthash name nil lurk-contexts))
 251
 252 (defun lurk-del-context (name)
 253   (remhash name lurk-contexts))
 254
 255 (defun lurk-get-context-users (name)
 256   (gethash name lurk-contexts))
 257
 258 (defun lurk-add-context-users (context users)
 259   (puthash context
 260            (append users
 261                    (gethash context lurk-contexts))
 262            lurk-contexts))
 263
 264 (defun lurk-del-context-user (context user)
 265   (puthash context
 266            (remove user (gethash context lurk-contexts))
 267            lurk-contexts))
 268
 269 (defun lurk-del-user (user)
 270   (dolist (context (lurk-get-context-list))
 271     (lurk-del-context-user context user)))
 272
 273 (defun lurk-rename-user (old-nick new-nick)
 274   (dolist (context (lurk-get-context-list))
 275     (lurk-del-context-user context old-nick)
 276     (lurk-add-context-users context (list new-nick))))
 277
 278 (defun lurk-get-context-type (name)
 279   (cond
 280    ((string-prefix-p "#" name) 'channel)
 281    ((string-match-p (rx (or "." "localhost")) name) 'host)
 282    (t 'nick)))
 283
 284 (defun lurk-get-context-list ()
 285   (let ((res nil))
 286     (maphash (lambda (key val)
 287                (cl-pushnew key res))
 288              lurk-contexts)
 289     res))
 290
 291 (defun lurk-get-next-context (&optional prev)
 292   (if lurk-current-context
 293       (let* ((context-list (if prev
 294                                (reverse (lurk-get-context-list))
 295                              (lurk-get-context-list)))
 296              (context-list* (member lurk-current-context context-list)))
 297         (if (> (length context-list*) 1)
 298             (cadr context-list*)
 299           (car context-list)))
 300     nil))
 301
 302 (defun lurk-set-current-context (context)
 303   (setq lurk-current-context context)
 304   (lurk-highlight-context context))
 305
 306 (defun lurk-cycle-contexts (&optional rev)
 307   (if lurk-current-context
 308       (progn
 309         (lurk-set-current-context (lurk-get-next-context rev))
 310         (lurk-render-prompt))
 311     (lurk-display-error "No channels joined.")))
 312
 313
 314 ;;; Buffer
 315 ;;
 316
 317 (defun lurk-render-prompt ()
 318   (with-current-buffer "*lurk*"
 319     (let ((update-point (= lurk-input-marker (point)))
 320           (update-window-points (mapcar (lambda (w)
 321                                           (list (= (window-point w) lurk-input-marker)
 322                                                 w))
 323                                         (get-buffer-window-list nil nil t))))
 324       (save-excursion
 325         (set-marker-insertion-type lurk-prompt-marker nil)
 326         (set-marker-insertion-type lurk-input-marker t)
 327         (let ((inhibit-read-only t))
 328           (delete-region lurk-prompt-marker lurk-input-marker)
 329           (goto-char lurk-prompt-marker)
 330           (insert
 331            (propertize (if lurk-current-context
 332                            lurk-current-context
 333                          "")
 334                        'face 'lurk-context
 335                        'read-only t)
 336            (propertize lurk-prompt-string
 337                        'face 'lurk-prompt
 338                        'read-only t
 339                        'rear-nonsticky t)))
 340         (set-marker-insertion-type lurk-input-marker nil))
 341       (if update-point
 342           (goto-char lurk-input-marker))
 343       (dolist (v update-window-points)
 344         (if (car v)
 345             (set-window-point (cadr v) lurk-input-marker))))))
 346
 347 (defvar lurk-prompt-marker nil
 348   "Marker for prompt position in LURK buffer.")
 349
 350 (defvar lurk-input-marker nil
 351   "Marker for prompt position in LURK buffer.")
 352
 353 (defun lurk-setup-buffer ()
 354   (with-current-buffer (get-buffer-create "*lurk*")
 355     (setq-local scroll-conservatively 1)
 356     (setq-local buffer-invisibility-spec nil)
 357     (if (markerp lurk-prompt-marker)
 358         (set-marker lurk-prompt-marker (point-max))
 359       (setq lurk-prompt-marker (point-max-marker)))
 360     (if (markerp lurk-input-marker)
 361         (set-marker lurk-input-marker (point-max))
 362       (setq lurk-input-marker (point-max-marker)))
 363     (goto-char (point-max))
 364     (lurk-render-prompt)))
 365
 366
 367 ;;; Output formatting and highlighting
 368 ;;
 369
 370 ;; Partially-implemented idea: the face text property can be
 371 ;; a list of faces, applied in order.  By assigning each context
 372 ;; a unique list and keeping track of these in a hash table, we can
 373 ;; easily switch the face corresponding to a particular context
 374 ;; by modifying the elements of this list.
 375 ;;
 376 ;; More subtly, we make only the cdrs of this list shared among
 377 ;; all text of a given context, allowing the cars to be different
 378 ;; and for different elements of the context-specific text to have
 379 ;; different styling.
 380
 381 ;; Additionally, we can allow selective hiding of contexts via
 382 ;; the buffer-invisibility-spec.
 383
 384 (defvar lurk-context-facelists (make-hash-table :test 'equal)
 385   "List of seen contexts and associated face lists.")
 386
 387 (defun lurk-get-context-facelist (context)
 388   (let ((facelist (gethash context lurk-context-facelists)))
 389     (unless facelist
 390       (setq facelist (list 'lurk-text))
 391       (puthash context facelist lurk-context-facelists))
 392     facelist))
 393
 394 (defun lurk-display-string (context &rest strings)
 395   (with-current-buffer (get-buffer-create "*lurk*")
 396     (save-excursion
 397       (goto-char lurk-prompt-marker)
 398       (let ((inhibit-read-only t)
 399             (old-pos (marker-position lurk-prompt-marker))
 400             (adaptive-fill-regexp (rx (= 6 anychar)))
 401             (fill-column 80)
 402             (context-atom (if context (intern context) nil)))
 403         (insert-before-markers
 404          (propertize (concat (format-time-string "%H:%M") " ")
 405                      'face (lurk-get-context-facelist context)
 406                      'read-only t
 407                      'context context
 408                      'invisible context-atom
 409                      'help-echo (concat "Context: " (or context "none")))
 410          (propertize (concat (apply #'concat strings) "\n")
 411                      'face (lurk-get-context-facelist context)
 412                      'read-only t
 413                      'context context
 414                      'invisible context-atom
 415                      'help-echo (concat "Context: " (or context "none"))))
 416         (fill-region old-pos lurk-prompt-marker nil t)))))
 417
 418 (defun lurk-display-message (from to text)
 419   (let ((context (if (eq 'channel (lurk-get-context-type to))
 420                      to
 421                    (if (equal to lurk-nick) from to))))
 422     (lurk-display-string
 423      context
 424      (pcase (lurk-get-context-type to)
 425        ('channel (concat to " <" from "> "))
 426        ('nick (concat "[" from " -> " to "] "))
 427        (_
 428         (error "Unsupported context type")))
 429      text)))
 430
 431 (defun lurk-display-action (from to action-text)
 432   (let ((context (if (eq 'channel (lurk-get-context-type to))
 433                      to
 434                    (if (equal to lurk-nick) from to))))
 435     (lurk-display-string
 436      context
 437      "* " from " " action-text)))
 438
 439
 440 (defun lurk-display-notice (context &rest notices)
 441   (lurk-display-string
 442    context
 443    lurk-notice-prefix " "
 444    (apply #'concat notices)))
 445
 446 (defun lurk-display-error (&rest messages)
 447   (lurk-display-string
 448    nil
 449    lurk-error-prefix " "
 450    (apply #'concat messages)))
 451
 452 (defun lurk-highlight-context (context)
 453   (maphash
 454    (lambda (this-context facelist)
 455      (if (equal this-context context)
 456          (setcar facelist 'lurk-text)
 457        (setcar facelist 'lurk-faded)))
 458    lurk-context-facelists)
 459   (force-window-update "*lurk*"))
 460
 461 (defun lurk-zoom-in (context)
 462   (with-current-buffer "*lurk*"
 463     (maphash
 464      (lambda (this-context _)
 465        (when this-context
 466          (let ((this-context-atom (intern this-context)))
 467            (if (equal this-context context)
 468                (remove-from-invisibility-spec this-context-atom)
 469              (add-to-invisibility-spec this-context-atom)))))
 470      lurk-context-facelists)
 471     (force-window-update "*lurk*")))
 472
 473 (defun lurk-zoom-out ()
 474   (with-current-buffer "*lurk*"
 475     (maphash
 476      (lambda (this-context _)
 477        (let ((this-context-atom (if this-context (intern this-context) nil)))
 478          (remove-from-invisibility-spec this-context-atom)))
 479      lurk-context-facelists)
 480     (force-window-update "*lurk*")))
 481
 482 ;;; Message evaluation
 483 ;;
 484
 485 (defun lurk-eval-msg-string (string)
 486   ;; (lurk-display-string nil string)
 487   (let* ((msg (lurk-string->msg string)))
 488     (pcase (lurk-msg-cmd msg)
 489       ("PING"
 490        (lurk-send-msg
 491         (lurk-msg nil nil "PONG" (lurk-msg-params msg))))
 492        ;; (lurk-display-notice nil "ping-pong (server initiated)"))
 493
 494       ("PONG")
 495        ;; (lurk-display-notice nil "ping-pong (client initiated)"))
 496
 497       ("001"
 498        (let* ((params (lurk-msg-params msg))
 499               (nick (elt params 0))
 500               (text (string-join (seq-drop params 1) " ")))
 501          (setq lurk-nick nick)
 502          (lurk-display-notice nil text)))
 503
 504       ("353" ; NAMEREPLY
 505        (let* ((params (lurk-msg-params msg))
 506               (channel (elt params 2))
 507               (names (split-string (elt params 3))))
 508          (lurk-add-context-users channel names)))
 509
 510       ("366" ; ENDOFNAMES
 511        (let* ((params (lurk-msg-params msg))
 512               (channel (elt params 1)))
 513          (lurk-display-notice
 514           channel
 515           (lurk--as-string (length (lurk-get-context-users channel)))
 516           " users in " channel)))
 517
 518       ("331"
 519        (let* ((params (lurk-msg-params msg))
 520               (channel (elt params 1)))
 521          (lurk-display-notice
 522           channel
 523           "No topic set.")))
 524
 525       ("332"
 526        (let* ((params (lurk-msg-params msg))
 527               (channel (elt params 1))
 528               (topic (elt params 2)))
 529          (lurk-display-notice channel "Topic: " topic)))
 530
 531       ((rx (= 3 (any digit)))
 532        (lurk-display-notice nil (mapconcat 'identity (cdr (lurk-msg-params msg)) " ")))
 533
 534       ((and "JOIN"
 535             (guard (equal lurk-nick (lurk-msg-src msg))))
 536        (let ((channel (car (lurk-msg-params msg))))
 537          (lurk-add-context channel)
 538          (lurk-set-current-context channel)
 539          (lurk-display-notice channel "Joining channel " channel)
 540          (lurk-render-prompt)))
 541
 542       ("JOIN"
 543        (let ((channel (car (lurk-msg-params msg)))
 544              (nick (lurk-msg-src msg)))
 545          (lurk-add-context-users channel (list nick))
 546          (if lurk-show-joins
 547              (lurk-display-notice channel nick " joined channel " channel))))
 548
 549       ((and "PART"
 550             (guard (equal lurk-nick (lurk-msg-src msg))))
 551        (let ((channel (car (lurk-msg-params msg))))
 552          (lurk-display-notice channel "Left channel " channel)
 553          (lurk-del-context channel)
 554          (if (equal channel lurk-current-context)
 555              (lurk-set-current-context (lurk-get-next-context)))
 556          (lurk-render-prompt)))
 557
 558       ("PART"
 559        (let ((channel (car (lurk-msg-params msg)))
 560              (nick (lurk-msg-src msg)))
 561          (lurk-del-context-user channel nick)
 562          (if lurk-show-joins
 563              (lurk-display-notice channel nick " left channel " channel))))
 564
 565       ("QUIT"
 566        (let ((nick (lurk-msg-src msg))
 567              (reason (mapconcat 'identity (lurk-msg-params msg) " ")))
 568          (lurk-del-user nick)
 569          (if lurk-show-joins
 570              (lurk-display-notice nil nick " quit: " reason))))
 571
 572       ((and "NICK"
 573             (guard (equal lurk-nick (lurk-msg-src msg))))
 574        (setq lurk-nick (car (lurk-msg-params msg)))
 575        (lurk-display-notice nil "Set nick to " lurk-nick))
 576
 577       ("NICK"
 578        (let ((old-nick (lurk-msg-src msg))
 579              (new-nick (car (lurk-msg-params msg))))
 580          (lurk-display-notice nil old-nick " is now known as " new-nick)
 581          (lurk-rename-user old-nick new-nick)))
 582
 583       ("NOTICE"
 584        (let ((nick (lurk-msg-src msg))
 585              (channel (car (lurk-msg-params msg)))
 586              (text (cadr (lurk-msg-params msg))))
 587          (pcase text
 588            ((rx (: "\01VERSION "
 589                    (let version (* (not "\01")))
 590                    "\01"))
 591             (lurk-display-notice nil "CTCP version reply from " nick ": " version))
 592            (_
 593             (lurk-display-notice nil text)))))
 594
 595       ("PRIVMSG"
 596        (let* ((from (lurk-msg-src msg))
 597               (params (lurk-msg-params msg))
 598               (to (car params))
 599               (text (cadr params)))
 600          (pcase text
 601            ("\01VERSION\01"
 602             (let ((version-string (concat lurk-version " - running on GNU Emacs " emacs-version)))
 603               (lurk-send-msg (lurk-msg nil nil "NOTICE"
 604                                        (list from (concat "\01VERSION "
 605                                                           version-string
 606                                                           "\01")))))
 607             (lurk-display-notice nil "CTCP version request received from " from))
 608
 609            ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
 610             (lurk-send-msg (lurk-msg nil nil "NOTICE" (list from ping)))
 611             (lurk-display-notice from "CTCP ping received from " from))
 612
 613            ("\01USERINFO\01"
 614             (lurk-display-notice from "CTCP userinfo request from " from " (no response sent)"))
 615
 616            ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
 617             (lurk-display-action from to action-text))
 618
 619            (_
 620             (if (and (equal from "BitBot")
 621                      (equal to "##moshpit")
 622                      (cl-search "\\_o< QUACK!" text))
 623               (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to ",bef")))
 624             (lurk-display-message from to text)))))
 625       (_
 626        (lurk-display-notice nil (lurk-msg->string msg))))))
 627
 628
 629 ;;; Command entering
 630 ;;
 631
 632 (defun lurk-enter-string (string)
 633   (if (string-prefix-p "/" string)
 634       (pcase (substring string 1)
 635         ((rx (: "CONNECT " (let network (* not-newline))))
 636          (lurk-display-notice nil "Attempting to connect to " network "...")
 637          (lurk-connect network))
 638
 639         ((rx (: "TOPIC " (let new-topic (* not-newline))))
 640          (lurk-send-msg (lurk-msg nil nil "TOPIC" lurk-current-context new-topic)))
 641
 642         ((rx (: "ME " (let action (* not-newline))))
 643          (let ((ctcp-text (concat "\01ACTION " action "\01")))
 644            (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 645                                     (list lurk-current-context ctcp-text)))
 646            (lurk-display-action lurk-nick lurk-current-context action)))
 647
 648         ((rx (: "VERSION" " " (let nick (+ (not whitespace)))))
 649          (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 650                                   (list nick "\01VERSION\01")))
 651          (lurk-display-notice nil "CTCP version request sent to " nick))
 652
 653         ((rx "PART" (opt (: " " (let channel (* not-newline)))))
 654          (if (or lurk-current-context channel)
 655              (lurk-send-msg (lurk-msg nil nil "PART" (if channel
 656                                                          channel
 657                                                        lurk-current-context)))
 658            (lurk-display-error "No current channel to leave.")))
 659
 660         ((rx "QUIT" (opt (: " " (let quit-msg (* not-newline)))))
 661          (lurk-send-msg (lurk-msg nil nil "QUIT"
 662                                   (or quit-msg lurk-default-quit-msg))))
 663
 664         ((rx (: "NICK" (* whitespace) string-end))
 665          (lurk-display-notice nil "Current nick: " lurk-nick))
 666
 667         ((rx (: "NICK" (+ whitespace) (let nick (+ (not whitespace)))))
 668          (if (lurk-connected-p)
 669              (lurk-send-msg (lurk-msg nil nil "NICK" nick))
 670            (setq lurk-nick nick)
 671            (lurk-display-notice nil "Set default nick to '" nick "'")))
 672
 673         ((rx "MSG "
 674              (let to (* (not whitespace)))
 675              " "
 676              (let text (* not-newline)))
 677          (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to text))
 678          (lurk-display-message lurk-nick to text))
 679
 680         ((rx (: (let cmd-str (+ (not whitespace)))
 681                 (opt (: " " (let params-str (* not-newline))))))
 682          (lurk-send-msg (lurk-msg nil nil (upcase cmd-str)
 683                                   (if params-str
 684                                       (split-string params-str)
 685                                     nil)))))
 686
 687     (unless (string-empty-p string)
 688       (if lurk-current-context
 689           (progn
 690             (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
 691                                      lurk-current-context
 692                                      string))
 693             (lurk-display-message lurk-nick lurk-current-context string))
 694         (lurk-display-error "No current context.")))))
 695
 696 (defun lurk-enter ()
 697   "Enter current contents of line after prompt."
 698   (interactive)
 699   (with-current-buffer "*lurk*"
 700     (let ((line (buffer-substring lurk-input-marker (point-max))))
 701       (let ((inhibit-read-only t))
 702         (delete-region lurk-input-marker (point-max)))
 703       (lurk-enter-string line))))
 704
 705
 706 ;;; Command completion
 707 ;;
 708
 709 ;;; Interactive functions
 710 ;;
 711
 712 (defun lurk-cycle-contexts-forward ()
 713   (interactive)
 714   (lurk-cycle-contexts))
 715
 716 (defun lurk-cycle-contexts-reverse ()
 717   (interactive)
 718   (lurk-cycle-contexts t))
 719
 720 (defvar lurk-zoomed nil
 721   "Keeps track of zoom status.")
 722
 723 (defun lurk-toggle-zoom ()
 724   (interactive)
 725   (if lurk-zoomed
 726       (lurk-zoom-out)
 727     (lurk-zoom-in lurk-current-context))
 728   (setq lurk-zoomed (not lurk-zoomed)))
 729
 730 ;;; Mode
 731 ;;
 732
 733 (defvar lurk-mode-map
 734   (let ((map (make-sparse-keymap)))
 735     (define-key map (kbd "RET") 'lurk-enter)
 736     (define-key map (kbd "<tab>") 'lurk-complete)
 737     (define-key map (kbd "C-c C-z") 'lurk-toggle-zoom)
 738     (define-key map (kbd "<C-tab>") 'lurk-cycle-contexts-forward)
 739     (define-key map (kbd "<C-S-tab>") 'lurk-cycle-contexts-reverse)
 740     map))
 741
 742 (define-derived-mode lurk-mode text-mode "lurk"
 743   "Major mode for LURK.")
 744
 745 (when (fboundp 'evil-set-initial-state)
 746   (evil-set-initial-state 'lurk-mode 'insert))
 747
 748 ;;; Main start procedure
 749 ;;
 750
 751 (defun lurk ()
 752   "Switch to *lurk* buffer."
 753   (interactive)
 754   (if (get-buffer "*lurk*")
 755       (switch-to-buffer "*lurk*")
 756     (switch-to-buffer "*lurk*"))
 757   (lurk-mode)
 758   (lurk-setup-buffer)
 759   "Started LURK.")
 760
 761
 762 ;;; lurk.el ends here